arch/sh/cpu/sh2/u-boot.lds

   1 /*
   2  * Copyright (C) 2008 Nobuhiro Iwamatsu
   3  * Copyright (C) 2008 Renesas Solutions Corp.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  25 OUTPUT_ARCH(sh)
  26 ENTRY(_start)
  27
  28 SECTIONS
  29 {
  30         /*
  31          * entry and reloct_dst will be provided via ldflags
  32          */
  33         . = .;
  34
  35         PROVIDE (_ftext = .);
  36         PROVIDE (_fcode = .);
  37         PROVIDE (_start = .);
  38
  39         .text :
  40         {
  41                 KEEP(arch/sh/cpu/sh2/start.o    (.text))
  42                 . = ALIGN(8192);
  43                 common/env_embedded.o   (.ppcenv)
  44                 . = ALIGN(8192);
  45                 common/env_embedded.o   (.ppcenvr)
  46                 . = ALIGN(8192);
  47                 *(.text)
  48                 . = ALIGN(4);
  49         } =0xFF
  50         PROVIDE (_ecode = .);
  51         .rodata :
  52         {
  53                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  54                 . = ALIGN(4);
  55         }
  56         PROVIDE (_etext = .);
  57
  58
  59         PROVIDE (_fdata = .);
  60         .data :
  61         {
  62                 *(.data)
  63                 . = ALIGN(4);
  64         }
  65         PROVIDE (_edata = .);
  66
  67         PROVIDE (_fgot = .);
  68         .got :
  69         {
  70                 *(.got)
  71                 . = ALIGN(4);
  72         }
  73         PROVIDE (_egot = .);
  74
  75         PROVIDE (__u_boot_cmd_start = .);
  76         .u_boot_cmd :
  77         {
  78                 *(.u_boot_cmd)
  79                 . = ALIGN(4);
  80         }
  81         PROVIDE (__u_boot_cmd_end = .);
  82
  83         PROVIDE (reloc_dst_end = .);
  84
  85         PROVIDE (bss_start = .);
  86         PROVIDE (__bss_start = .);
  87         .bss :
  88         {
  89                 *(.bss)
  90                 . = ALIGN(4);
  91         }
  92         PROVIDE (bss_end = .);
  93
  94         PROVIDE (__bss_end__ = .);
  95 }