arch/sparc/cpu/leon2/start.S

   1 /* This is where the SPARC/LEON3 starts
   2  * Copyright (C) 2007,
   3  * Daniel Hellstrom, daniel@gaisler.com
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 #include <asm-offsets.h>
   9 #include <config.h>
  10 #include <asm/asmmacro.h>
  11 #include <asm/winmacro.h>
  12 #include <asm/psr.h>
  13 #include <asm/stack.h>
  14 #include <asm/leon.h>
  15 #include <version.h>
  16
  17 /* Entry for traps which jump to a programmer-specified trap handler.  */
  18 #define TRAPR(H)  \
  19         wr      %g0, 0xfe0, %psr; \
  20         mov     %g0, %tbr; \
  21         ba      (H); \
  22         mov     %g0, %wim;
  23
  24 #define TRAP(H) \
  25         mov     %psr, %l0; \
  26         ba      (H); \
  27         nop; nop;
  28
  29 #define TRAPI(ilevel) \
  30         mov     ilevel, %l7; \
  31         mov     %psr, %l0; \
  32         b       _irq_entry; \
  33         mov     %wim, %l3
  34
  35 /* Unexcpected trap will halt the processor by forcing it to error state */
  36 #undef BAD_TRAP
  37 #define BAD_TRAP ta 0; nop; nop; nop;
  38
  39 /* Software trap. Treat as BAD_TRAP for the time being... */
  40 #define SOFT_TRAP TRAP(_hwerr)
  41
  42 #define PSR_INIT   0x1FC0       /* Disable traps, set s and ps */
  43 #define WIM_INIT   2
  44
  45 /* All traps low-level code here must end with this macro. */
  46 #define RESTORE_ALL b ret_trap_entry; clr %l6;
  47
  48 #define WRITE_PAUSE nop;nop;nop
  49
  50 WINDOWSIZE = (16 * 4)
  51 ARGPUSHSIZE = (6 * 4)
  52 ARGPUSH = (WINDOWSIZE + 4)
  53 MINFRAME = (WINDOWSIZE + ARGPUSHSIZE + 4)
  54
  55 /* Number of register windows */
  56 #ifndef CONFIG_SYS_SPARC_NWINDOWS
  57 #error Must define number of SPARC register windows, default is 8
  58 #endif
  59
  60 /* Macros to load address into a register. Uses GOT table for PIC */
  61 #ifdef __PIC__
  62
  63 #define SPARC_PIC_THUNK_CALL(reg) \
  64         sethi   %pc22(_GLOBAL_OFFSET_TABLE_-4), %##reg; \
  65         call    __sparc_get_pc_thunk.reg; \
  66          add    %##reg, %pc10(_GLOBAL_OFFSET_TABLE_+4), %##reg;
  67
  68 #define SPARC_LOAD_ADDRESS(sym, got, reg) \
  69         sethi   %gdop_hix22(sym), %##reg; \
  70         xor     %##reg, %gdop_lox10(sym), %##reg; \
  71         ld      [%##got + %##reg], %##reg, %gdop(sym);
  72
  73 #else
  74
  75 #define SPARC_PIC_THUNK_CALL(reg)
  76 #define SPARC_LOAD_ADDRESS(sym, got, tmp) \
  77         set     sym, %##reg;
  78
  79 #endif
  80
  81 #define STACK_ALIGN     8
  82 #define SA(X)   (((X)+(STACK_ALIGN-1)) & ~(STACK_ALIGN-1))
  83
  84         .section ".start", "ax"
  85         .globl  _start, start, _trap_table
  86         .globl  _irq_entry, nmi_trap
  87         .globl  _reset_reloc
  88
  89 /* at address 0
  90  * Hardware traps
  91  */
  92 start:
  93 _start:
  94 _trap_table:
  95         TRAPR(_hardreset);              ! 00 reset trap
  96         BAD_TRAP;                       ! 01 instruction_access_exception
  97         BAD_TRAP;                       ! 02 illegal_instruction
  98         BAD_TRAP;                       ! 03 priveleged_instruction
  99         BAD_TRAP;                       ! 04 fp_disabled
 100         TRAP(_window_overflow);         ! 05 window_overflow
 101         TRAP(_window_underflow);        ! 06 window_underflow
 102         BAD_TRAP;                       ! 07 Memory Address Not Aligned
 103         BAD_TRAP;                       ! 08 Floating Point Exception
 104         BAD_TRAP;                       ! 09 Data Miss Exception
 105         BAD_TRAP;                       ! 0a Tagged Instruction Ovrflw
 106         BAD_TRAP;                       ! 0b Watchpoint Detected
 107         BAD_TRAP;                       ! 0c
 108         BAD_TRAP;                       ! 0d
 109         BAD_TRAP;                       ! 0e
 110         BAD_TRAP;                       ! 0f
 111         BAD_TRAP;                       ! 10
 112         TRAPI(1);                       ! 11 IRQ level 1
 113         TRAPI(2);                       ! 12 IRQ level 2
 114         TRAPI(3);                       ! 13 IRQ level 3
 115         TRAPI(4);                       ! 14 IRQ level 4
 116         TRAPI(5);                       ! 15 IRQ level 5
 117         TRAPI(6);                       ! 16 IRQ level 6
 118         TRAPI(7);                       ! 17 IRQ level 7
 119         TRAPI(8);                       ! 18 IRQ level 8
 120         TRAPI(9);                       ! 19 IRQ level 9
 121         TRAPI(10);                      ! 1a IRQ level 10
 122         TRAPI(11);                      ! 1b IRQ level 11
 123         TRAPI(12);                      ! 1c IRQ level 12
 124         TRAPI(13);                      ! 1d IRQ level 13
 125         TRAPI(14);                      ! 1e IRQ level 14
 126         TRAP(_nmi_trap);                ! 1f IRQ level 15 /
 127                                         ! NMI (non maskable interrupt)
 128         BAD_TRAP;                       ! 20 r_register_access_error
 129         BAD_TRAP;                       ! 21 instruction access error
 130         BAD_TRAP;                       ! 22
 131         BAD_TRAP;                       ! 23
 132         BAD_TRAP;                       ! 24 co-processor disabled
 133         BAD_TRAP;                       ! 25 uniplemented FLUSH
 134         BAD_TRAP;                       ! 26
 135         BAD_TRAP;                       ! 27
 136         BAD_TRAP;                       ! 28 co-processor exception
 137         BAD_TRAP;                       ! 29 data access error
 138         BAD_TRAP;                       ! 2a division by zero
 139         BAD_TRAP;                       ! 2b data store error
 140         BAD_TRAP;                       ! 2c data access MMU miss
 141         BAD_TRAP;                       ! 2d
 142         BAD_TRAP;                       ! 2e
 143         BAD_TRAP;                       ! 2f
 144         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 30-33
 145         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 34-37
 146         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 38-3b
 147         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 3c-3f
 148         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 40-43
 149         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 44-47
 150         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 48-4b
 151         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 4c-4f
 152         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 50-53
 153         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 54-57
 154         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 58-5b
 155         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 5c-5f
 156
 157         /* implementaion dependent */
 158         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 60-63
 159         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 64-67
 160         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 68-6b
 161         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 6c-6f
 162         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 70-73
 163         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 74-77
 164         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 78-7b
 165         BAD_TRAP; BAD_TRAP; BAD_TRAP; BAD_TRAP; ! 7c-7f
 166
 167         /* Software traps, not handled */
 168         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 80-83
 169         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 84-87
 170         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 88-8b
 171         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 8c-8f
 172         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 90-93
 173         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 94-97
 174         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 98-9b
 175         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! 9c-9f
 176         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a0-a3
 177         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a4-a7
 178         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! a8-ab
 179         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ac-af
 180         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b0-b3
 181         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b4-b7
 182         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! b8-bb
 183         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! bc-bf
 184         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c0-c3
 185         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c4-c7
 186         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! c8-cb
 187         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! cc-cf
 188         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d0-d3
 189         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d4-d7
 190         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! d8-db
 191         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! dc-df
 192         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e0-e3
 193         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e4-e7
 194         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! e8-eb
 195         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! ec-ef
 196         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f0-f3
 197         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f4-f7
 198         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! f8-fb
 199         SOFT_TRAP; SOFT_TRAP; SOFT_TRAP; SOFT_TRAP;     ! fc-ff
 200 /*
 201  * Version string
 202  */
 203
 204         .data
 205         .globl  version_string
 206 version_string:
 207         .ascii U_BOOT_VERSION_STRING, "\0"
 208
 209         .section        ".text"
 210         .align 4
 211
 212 _hardreset:
 213 1000:
 214         flush
 215         nop
 216         nop
 217         nop
 218
 219         /* Init Cache */
 220         set     (LEON2_PREGS+LEON_REG_CACHECTRL_OFFSET), %g1
 221         set     0x0081000f, %g2
 222         st      %g2, [%g1]
 223
 224         mov     %g0, %y
 225         clr     %g1
 226         clr     %g2
 227         clr     %g3
 228         clr     %g4
 229         clr     %g5
 230         clr     %g6
 231         clr     %g7
 232
 233         mov     %asr17, %g3
 234         and     %g3, 0x1f, %g3
 235 clear_window:
 236         mov     %g0, %l0
 237         mov     %g0, %l1
 238         mov     %g0, %l2
 239         mov     %g0, %l3
 240         mov     %g0, %l4
 241         mov     %g0, %l5
 242         mov     %g0, %l6
 243         mov     %g0, %l7
 244         mov     %g0, %o0
 245         mov     %g0, %o1
 246         mov     %g0, %o2
 247         mov     %g0, %o3
 248         mov     %g0, %o4
 249         mov     %g0, %o5
 250         mov     %g0, %o6
 251         mov     %g0, %o7
 252         subcc   %g3, 1, %g3
 253         bge     clear_window
 254         save
 255
 256 leon2_init:
 257         /* LEON2 Register Base in g1 */
 258         set     LEON2_PREGS, %g1
 259
 260 leon2_init_cache:
 261         /* Set Cache control register */
 262         set     0x1000f, %g2
 263         st      %g2, [%g1 + 0x14]
 264
 265 leon2_init_clear:
 266
 267         /* Clear LEON2 registers */
 268         st      %g0, [%g1 + LEON2_ECTRL]
 269         st      %g0, [%g1 + LEON2_IMASK]
 270         st      %g0, [%g1 + LEON2_IPEND]
 271         st      %g0, [%g1 + LEON2_IFORCE]
 272         st      %g0, [%g1 + LEON2_ICLEAR]
 273         st      %g0, [%g1 + LEON2_IOREG]
 274         st      %g0, [%g1 + LEON2_IODIR]
 275         st      %g0, [%g1 + LEON2_IOICONF]
 276         st      %g0, [%g1 + LEON2_UCTRL0]
 277         st      %g0, [%g1 + LEON2_UCTRL1]
 278
 279 leon2_init_ioport:
 280         /* I/O port initialization */
 281         set     0xaa00, %g2
 282         st      %g2, [%g1 + LEON2_IOREG]
 283
 284 leon2_init_mctrl:
 285
 286         /* memory config register 1 */
 287         set     CONFIG_SYS_GRLIB_MEMCFG1, %g2
 288         ld      [%g1], %g3              !
 289         and     %g3, 0x300, %g3
 290         or      %g2, %g3, %g2
 291         st      %g2, [%g1 + LEON2_MCFG1]
 292         set     CONFIG_SYS_GRLIB_MEMCFG2, %g2           ! Load memory config register 2
 293 #if !( defined(TSIM) || !defined(BZIMAGE))
 294         st      %g2, [%g1 + LEON2_MCFG2]        ! only for prom version, else done by "dumon -i"
 295 #endif
 296         set     CONFIG_SYS_GRLIB_MEMCFG3, %g2           ! Init FT register
 297         st      %g2, [%g1 + LEON2_ECTRL]
 298         ld      [%g1 + LEON2_ECTRL], %g2
 299         srl     %g2, 30, %g2
 300         andcc   %g2, 3, %g6
 301         bne,a   leon2_init_wim
 302          mov    %g0, %asr16             ! clear err_reg
 303
 304 leon2_init_wim:
 305         set     WIM_INIT, %g3
 306         mov     %g3, %wim
 307
 308 leon2_init_psr:
 309         set     0x1000, %g3
 310         mov     %psr, %g2
 311         wr      %g2, %g3, %psr
 312         nop
 313         nop
 314         nop
 315
 316 leon2_init_stackp:
 317         set     CONFIG_SYS_INIT_SP_OFFSET, %fp
 318         andn    %fp, 0x0f, %fp
 319         sub     %fp, 64, %sp
 320
 321 cpu_init_unreloc:
 322         call    cpu_init_f
 323          nop
 324
 325 /* un relocated start address of monitor */
 326 #define TEXT_START _text
 327
 328 /* un relocated end address of monitor */
 329 #define DATA_END __init_end
 330
 331         SPARC_PIC_THUNK_CALL(l7)
 332 reloc:
 333         SPARC_LOAD_ADDRESS(TEXT_START, l7, g2)
 334         SPARC_LOAD_ADDRESS(DATA_END, l7, g3)
 335         set     CONFIG_SYS_RELOC_MONITOR_BASE,%g4
 336 reloc_loop:
 337         ldd     [%g2],%l0
 338         ldd     [%g2+8],%l2
 339         std     %l0,[%g4]
 340         std     %l2,[%g4+8]
 341         inc     16,%g2
 342         subcc   %g3,%g2,%g0
 343         bne     reloc_loop
 344          inc    16,%g4
 345
 346         clr     %l0
 347         clr     %l1
 348         clr     %l2
 349         clr     %l3
 350         clr     %g2
 351
 352 /* register g4 contain address to start
 353  * This means that BSS must be directly after data and code segments
 354  *
 355  * g3 is length of bss = (__bss_end-__bss_start)
 356  *
 357  */
 358
 359 clr_bss:
 360 /* clear bss area (the relocated) */
 361         SPARC_LOAD_ADDRESS(__bss_start, l7, g2)
 362         SPARC_LOAD_ADDRESS(__bss_end, l7, g3)
 363         sub     %g3,%g2,%g3
 364         add     %g3,%g4,%g3
 365         clr     %g1     /* std %g0 uses g0 and g1 */
 366 /* clearing 16byte a time ==> linker script need to align to 16 byte offset */
 367 clr_bss_16:
 368         std     %g0,[%g4]
 369         std     %g0,[%g4+8]
 370         inc     16,%g4
 371         cmp     %g3,%g4
 372         bne     clr_bss_16
 373          nop
 374
 375 /* add offsets to GOT table */
 376 fixup_got:
 377         SPARC_LOAD_ADDRESS(__got_start, l7, g4)
 378         SPARC_LOAD_ADDRESS(__got_end, l7, g3)
 379 /*
 380  * new got offset = (old GOT-PTR (read with ld) -
 381  *   CONFIG_SYS_RELOC_MONITOR_BASE(from define) ) +
 382  *   Destination Address (from define)
 383  */
 384         set     CONFIG_SYS_RELOC_MONITOR_BASE,%g2
 385         SPARC_LOAD_ADDRESS(TEXT_START, l7, g1)
 386         add     %g4,%g2,%g4
 387         sub     %g4,%g1,%g4
 388         add     %g3,%g2,%g3
 389         sub     %g3,%g1,%g3
 390         sub     %g2,%g1,%g2     ! prepare register with (new base address) -
 391                                 !  (old base address)
 392 got_loop:
 393         ld      [%g4],%l0       ! load old GOT-PTR
 394         add     %l0,%g2,%l0     ! increase with (new base address) -
 395                                 !  (old base)
 396         st      %l0,[%g4]
 397         inc     4,%g4
 398         cmp     %g3,%g4
 399         bne     got_loop
 400          nop
 401
 402 prom_relocate:
 403         SPARC_LOAD_ADDRESS(__prom_start, l7, g2)
 404         SPARC_LOAD_ADDRESS(__prom_end, l7, g3)
 405         set     CONFIG_SYS_PROM_OFFSET, %g4
 406
 407 prom_relocate_loop:
 408         ldd     [%g2],%l0
 409         ldd     [%g2+8],%l2
 410         std     %l0,[%g4]
 411         std     %l2,[%g4+8]
 412         inc     16,%g2
 413         subcc   %g3,%g2,%g0
 414         bne     prom_relocate_loop
 415          inc    16,%g4
 416
 417 /* Trap table has been moved, lets tell CPU about
 418  * the new trap table address
 419  */
 420
 421         set     CONFIG_SYS_RELOC_MONITOR_BASE, %g2
 422         wr      %g0, %g2, %tbr
 423
 424 /*      call    relocate*/
 425         nop
 426 /* Call relocated init functions */
 427 jump:
 428         SPARC_LOAD_ADDRESS(cpu_init_f2, l7, o1)
 429         set     CONFIG_SYS_RELOC_MONITOR_BASE,%o2
 430         add     %o1,%o2,%o1
 431         sub     %o1,%g1,%o1
 432         call    %o1
 433          clr    %o0
 434
 435         SPARC_LOAD_ADDRESS(board_init_f, l7, o1)
 436         set     CONFIG_SYS_RELOC_MONITOR_BASE,%o2
 437         add     %o1,%o2,%o1
 438         sub     %o1,%g1,%o1
 439         call    %o1
 440          clr    %o0
 441
 442 dead:   ta 0                            ! if call returns...
 443         nop
 444
 445 /* Interrupt handler caller,
 446  * reg L7: interrupt number
 447  * reg L0: psr after interrupt
 448  * reg L1: PC
 449  * reg L2: next PC
 450  * reg L3: wim
 451  */
 452 _irq_entry:
 453         SAVE_ALL
 454
 455         or      %l0, PSR_PIL, %g2
 456         wr      %g2, 0x0, %psr
 457         WRITE_PAUSE
 458         wr      %g2, PSR_ET, %psr
 459         WRITE_PAUSE
 460         mov     %l7, %o0                ! irq level
 461         set     handler_irq, %o1
 462         set     (CONFIG_SYS_RELOC_MONITOR_BASE-CONFIG_SYS_TEXT_BASE), %o2
 463         add     %o1, %o2, %o1
 464         call    %o1
 465         add     %sp, SF_REGS_SZ, %o1    ! pt_regs ptr
 466         or      %l0, PSR_PIL, %g2       ! restore PIL after handler_irq
 467         wr      %g2, PSR_ET, %psr       ! keep ET up
 468         WRITE_PAUSE
 469
 470         RESTORE_ALL
 471
 472 !Window overflow trap handler.
 473         .global _window_overflow
 474
 475 _window_overflow:
 476
 477         mov     %wim, %l3               ! Calculate next WIM
 478         mov     %g1, %l7
 479         srl     %l3, 1, %g1
 480         sll     %l3, (CONFIG_SYS_SPARC_NWINDOWS-1) , %l4
 481         or      %l4, %g1, %g1
 482
 483         save                            ! Get into window to be saved.
 484         mov     %g1, %wim
 485         nop;
 486         nop;
 487         nop
 488         st      %l0, [%sp + 0];
 489         st      %l1, [%sp + 4];
 490         st      %l2, [%sp + 8];
 491         st      %l3, [%sp + 12];
 492         st      %l4, [%sp + 16];
 493         st      %l5, [%sp + 20];
 494         st      %l6, [%sp + 24];
 495         st      %l7, [%sp + 28];
 496         st      %i0, [%sp + 32];
 497         st      %i1, [%sp + 36];
 498         st      %i2, [%sp + 40];
 499         st      %i3, [%sp + 44];
 500         st      %i4, [%sp + 48];
 501         st      %i5, [%sp + 52];
 502         st      %i6, [%sp + 56];
 503         st      %i7, [%sp + 60];
 504         restore                         ! Go back to trap window.
 505         mov     %l7, %g1
 506         jmp     %l1                     ! Re-execute save.
 507         rett    %l2
 508
 509 /* Window underflow trap handler.  */
 510
 511         .global  _window_underflow
 512
 513 _window_underflow:
 514
 515         mov  %wim, %l3                  ! Calculate next WIM
 516         sll  %l3, 1, %l4
 517         srl  %l3, (CONFIG_SYS_SPARC_NWINDOWS-1), %l5
 518         or   %l5, %l4, %l5
 519         mov  %l5, %wim
 520         nop; nop; nop
 521         restore                         ! Two restores to get into the
 522         restore                         ! window to restore
 523         ld      [%sp + 0], %l0;         ! Restore window from the stack
 524         ld      [%sp + 4], %l1;
 525         ld      [%sp + 8], %l2;
 526         ld      [%sp + 12], %l3;
 527         ld      [%sp + 16], %l4;
 528         ld      [%sp + 20], %l5;
 529         ld      [%sp + 24], %l6;
 530         ld      [%sp + 28], %l7;
 531         ld      [%sp + 32], %i0;
 532         ld      [%sp + 36], %i1;
 533         ld      [%sp + 40], %i2;
 534         ld      [%sp + 44], %i3;
 535         ld      [%sp + 48], %i4;
 536         ld      [%sp + 52], %i5;
 537         ld      [%sp + 56], %i6;
 538         ld      [%sp + 60], %i7;
 539         save                            ! Get back to the trap window.
 540         save
 541         jmp     %l1                     ! Re-execute restore.
 542         rett    %l2
 543
 544         retl
 545
 546 _nmi_trap:
 547         nop
 548         jmp %l1
 549         rett %l2
 550
 551 _hwerr:
 552         ta 0
 553         nop
 554         nop
 555         b _hwerr                        ! loop infinite
 556         nop
 557
 558 /* Registers to not touch at all. */
 559 #define t_psr      l0 /* Set by caller */
 560 #define t_pc       l1 /* Set by caller */
 561 #define t_npc      l2 /* Set by caller */
 562 #define t_wim      l3 /* Set by caller */
 563 #define t_twinmask l4 /* Set at beginning of this entry routine. */
 564 #define t_kstack   l5 /* Set right before pt_regs frame is built */
 565 #define t_retpc    l6 /* If you change this, change winmacro.h header file */
 566 #define t_systable l7 /* Never touch this, could be the syscall table ptr. */
 567 #define curptr     g6 /* Set after pt_regs frame is built */
 568
 569 trap_setup:
 570 /* build a pt_regs trap frame. */
 571         sub     %fp, (SF_REGS_SZ + PT_REGS_SZ), %t_kstack
 572         PT_STORE_ALL(t_kstack, t_psr, t_pc, t_npc, g2)
 573
 574         /* See if we are in the trap window. */
 575         mov     1, %t_twinmask
 576         sll     %t_twinmask, %t_psr, %t_twinmask ! t_twinmask = (1 << psr)
 577         andcc   %t_twinmask, %t_wim, %g0
 578         beq     1f              ! in trap window, clean up
 579         nop
 580
 581         /*-------------------------------------------------
 582          * Spill , adjust %wim and go.
 583          */
 584         srl     %t_wim, 0x1, %g2                ! begin computation of new %wim
 585
 586         set     (CONFIG_SYS_SPARC_NWINDOWS-1), %g3      !NWINDOWS-1
 587
 588         sll     %t_wim, %g3, %t_wim     ! NWINDOWS-1
 589         or      %t_wim, %g2, %g2
 590         and     %g2, 0xff, %g2
 591
 592         save    %g0, %g0, %g0           ! get in window to be saved
 593
 594         /* Set new %wim value */
 595         wr      %g2, 0x0, %wim
 596
 597         /* Save the kernel window onto the corresponding stack. */
 598         RW_STORE(sp)
 599
 600         restore %g0, %g0, %g0
 601         /*-------------------------------------------------*/
 602
 603 1:
 604         /* Trap from kernel with a window available.
 605          * Just do it...
 606          */
 607         jmpl    %t_retpc + 0x8, %g0     ! return to caller
 608          mov    %t_kstack, %sp          ! jump onto new stack
 609
 610 #define twin_tmp1 l4
 611 #define glob_tmp  g4
 612 #define curptr    g6
 613 ret_trap_entry:
 614         wr      %t_psr, 0x0, %psr       ! enable nesting again, clear ET
 615
 616         /* Will the rett land us in the invalid window? */
 617         mov     2, %g1
 618         sll     %g1, %t_psr, %g1
 619
 620         set     CONFIG_SYS_SPARC_NWINDOWS, %g2  !NWINDOWS
 621
 622         srl     %g1, %g2, %g2
 623         or      %g1, %g2, %g1
 624         rd      %wim, %g2
 625         andcc   %g2, %g1, %g0
 626         be      1f              ! Nope, just return from the trap
 627          sll    %g2, 0x1, %g1
 628
 629         /* We have to grab a window before returning. */
 630         set     (CONFIG_SYS_SPARC_NWINDOWS-1), %g3      !NWINDOWS-1
 631
 632         srl     %g2, %g3,  %g2
 633         or      %g1, %g2, %g1
 634         and     %g1, 0xff, %g1
 635
 636         wr      %g1, 0x0, %wim
 637
 638         /* Grrr, make sure we load from the right %sp... */
 639         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 640
 641         restore %g0, %g0, %g0
 642         RW_LOAD(sp)
 643         b       2f
 644         save    %g0, %g0, %g0
 645
 646         /* Reload the entire frame in case this is from a
 647          * kernel system call or whatever...
 648          */
 649 1:
 650         PT_LOAD_ALL(sp, t_psr, t_pc, t_npc, g1)
 651 2:
 652         wr      %t_psr, 0x0, %psr
 653         nop;
 654         nop;
 655         nop
 656
 657         jmp     %t_pc
 658         rett    %t_npc
 659
 660 /* This is called from relocated C-code.
 661  * It resets the system by jumping to _start
 662  */
 663 _reset_reloc:
 664         set     start, %l0
 665         call    %l0
 666         nop