board/amcc/bamboo/u-boot-nand.lds

   1 /*
   2  * (C) Copyright 2007
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SECTIONS
  26 {
  27   /* Read-only sections, merged into text segment: */
  28   . = + SIZEOF_HEADERS;
  29   .text      :
  30   {
  31     /* WARNING - the following is hand-optimized to fit within  */
  32     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  33
  34     arch/powerpc/cpu/ppc4xx/start.o     (.text*)
  35     board/amcc/bamboo/init.o            (.text*)
  36
  37     /* Align to next NAND block */
  38     . = ALIGN(0x4000);
  39     common/env_embedded.o  (.ppcenv)
  40     /* Keep some space here for redundant env and potential bad env blocks */
  41     . = ALIGN(0x10000);
  42
  43     *(.text*)
  44   }
  45   _etext = .;
  46   PROVIDE (etext = .);
  47   .rodata    :
  48   {
  49     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  50   }
  51
  52   /* Read-write section, merged into data segment: */
  53   . = (. + 0x00FF) & 0xFFFFFF00;
  54   _erotext = .;
  55   PROVIDE (erotext = .);
  56   .reloc   :
  57   {
  58     KEEP(*(.got))
  59     _GOT2_TABLE_ = .;
  60     KEEP(*(.got2))
  61     _FIXUP_TABLE_ = .;
  62     KEEP(*(.fixup))
  63   }
  64   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  65   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  66
  67   .data    :
  68   {
  69     *(.data*)
  70     *(.sdata*)
  71   }
  72   _edata  =  .;
  73   PROVIDE (edata = .);
  74
  75   . = .;
  76   __u_boot_cmd_start = .;
  77   .u_boot_cmd : { *(.u_boot_cmd) }
  78   __u_boot_cmd_end = .;
  79
  80
  81   . = .;
  82   __start___ex_table = .;
  83   __ex_table : { *(__ex_table) }
  84   __stop___ex_table = .;
  85
  86   . = ALIGN(256);
  87   __init_begin = .;
  88   .text.init : { *(.text.init) }
  89   .data.init : { *(.data.init) }
  90   . = ALIGN(256);
  91   __init_end = .;
  92
  93   __bss_start = .;
  94   .bss (NOLOAD)       :
  95   {
  96    *(.bss*)
  97    *(.sbss*)
  98    *(COMMON)
  99    . = ALIGN(4);
 100   }
 101
 102   __bss_end__ = . ;
 103   PROVIDE (end = .);
 104 }