board/amcc/sequoia/u-boot-nand.lds

   1 /*
   2  * (C) Copyright 2006
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9 SECTIONS
  10 {
  11   /* Read-only sections, merged into text segment: */
  12   . = + SIZEOF_HEADERS;
  13   .text      :
  14   {
  15     /* WARNING - the following is hand-optimized to fit within  */
  16     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  17
  18     arch/powerpc/cpu/ppc4xx/start.o     (.text)
  19     board/amcc/sequoia/init.o   (.text*)
  20
  21     /* Align to next NAND block */
  22     . = ALIGN(0x4000);
  23     common/env_embedded.o  (.ppcenv)
  24     /* Keep some space here for redundant env and potential bad env blocks */
  25     . = ALIGN(0x10000);
  26
  27     *(.text*)
  28   }
  29   _etext = .;
  30   PROVIDE (etext = .);
  31   .rodata    :
  32   {
  33     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  34   }
  35
  36   /* Read-write section, merged into data segment: */
  37   . = (. + 0x00FF) & 0xFFFFFF00;
  38   _erotext = .;
  39   PROVIDE (erotext = .);
  40   .reloc   :
  41   {
  42     KEEP(*(.got))
  43     _GOT2_TABLE_ = .;
  44     KEEP(*(.got2))
  45     _FIXUP_TABLE_ = .;
  46     KEEP(*(.fixup))
  47   }
  48   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  49   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  50
  51   .data    :
  52   {
  53     *(.data*)
  54     *(.sdata*)
  55   }
  56   _edata  =  .;
  57   PROVIDE (edata = .);
  58
  59   . = .;
  60
  61   .u_boot_list : {
  62         KEEP(*(SORT(.u_boot_list*)));
  63   }
  64
  65   . = .;
  66   __start___ex_table = .;
  67   __ex_table : { *(__ex_table) }
  68   __stop___ex_table = .;
  69
  70   . = ALIGN(256);
  71   __init_begin = .;
  72   .text.init : { *(.text.init) }
  73   .data.init : { *(.data.init) }
  74   . = ALIGN(256);
  75   __init_end = .;
  76
  77   __bss_start = .;
  78   .bss (NOLOAD)       :
  79   {
  80    *(.bss*)
  81    *(.sbss*)
  82    *(COMMON)
  83    . = ALIGN(4);
  84   }
  85
  86   __bss_end = . ;
  87   PROVIDE (end = .);
  88 }