board/cds/mpc8541cds/u-boot.lds

   1 /*
   2  * Copyright 2004 Freescale Semiconductor.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   .resetvec 0xFFFFFFFC :
  30   {
  31     *(.resetvec)
  32   } = 0xffff
  33
  34   .bootpg 0xFFFFF000 :
  35   {
  36     cpu/mpc85xx/start.o (.bootpg)
  37     board/cds/mpc8541cds/init.o (.bootpg)
  38   } = 0xffff
  39
  40   /* Read-only sections, merged into text segment: */
  41   . = + SIZEOF_HEADERS;
  42   .interp : { *(.interp) }
  43   .hash          : { *(.hash)           }
  44   .dynsym        : { *(.dynsym)         }
  45   .dynstr        : { *(.dynstr)         }
  46   .rel.text      : { *(.rel.text)               }
  47   .rela.text     : { *(.rela.text)      }
  48   .rel.data      : { *(.rel.data)               }
  49   .rela.data     : { *(.rela.data)      }
  50   .rel.rodata    : { *(.rel.rodata)     }
  51   .rela.rodata   : { *(.rela.rodata)    }
  52   .rel.got       : { *(.rel.got)                }
  53   .rela.got      : { *(.rela.got)               }
  54   .rel.ctors     : { *(.rel.ctors)      }
  55   .rela.ctors    : { *(.rela.ctors)     }
  56   .rel.dtors     : { *(.rel.dtors)      }
  57   .rela.dtors    : { *(.rela.dtors)     }
  58   .rel.bss       : { *(.rel.bss)                }
  59   .rela.bss      : { *(.rela.bss)               }
  60   .rel.plt       : { *(.rel.plt)                }
  61   .rela.plt      : { *(.rela.plt)               }
  62   .init          : { *(.init)   }
  63   .plt : { *(.plt) }
  64   .text      :
  65   {
  66     cpu/mpc85xx/start.o (.text)
  67     board/cds/mpc8541cds/init.o (.text)
  68     cpu/mpc85xx/traps.o (.text)
  69     cpu/mpc85xx/interrupts.o (.text)
  70     cpu/mpc85xx/cpu_init.o (.text)
  71     cpu/mpc85xx/cpu.o (.text)
  72     cpu/mpc85xx/tsec.o (.text)
  73     cpu/mpc85xx/speed.o (.text)
  74     cpu/mpc85xx/pci.o (.text)
  75     common/dlmalloc.o (.text)
  76     lib_generic/crc32.o (.text)
  77     lib_ppc/extable.o (.text)
  78     lib_generic/zlib.o (.text)
  79     *(.text)
  80     *(.fixup)
  81     *(.got1)
  82    }
  83     _etext = .;
  84     PROVIDE (etext = .);
  85     .rodata    :
  86    {
  87     *(.rodata)
  88     *(.rodata1)
  89     *(.rodata.str1.4)
  90   }
  91   .fini      : { *(.fini)    } =0
  92   .ctors     : { *(.ctors)   }
  93   .dtors     : { *(.dtors)   }
  94
  95   /* Read-write section, merged into data segment: */
  96   . = (. + 0x00FF) & 0xFFFFFF00;
  97   _erotext = .;
  98   PROVIDE (erotext = .);
  99   .reloc   :
 100   {
 101     *(.got)
 102     _GOT2_TABLE_ = .;
 103     *(.got2)
 104     _FIXUP_TABLE_ = .;
 105     *(.fixup)
 106   }
 107   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 108   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 109
 110   .data    :
 111   {
 112     *(.data)
 113     *(.data1)
 114     *(.sdata)
 115     *(.sdata2)
 116     *(.dynamic)
 117     CONSTRUCTORS
 118   }
 119   _edata  =  .;
 120   PROVIDE (edata = .);
 121
 122   __u_boot_cmd_start = .;
 123   .u_boot_cmd : { *(.u_boot_cmd) }
 124   __u_boot_cmd_end = .;
 125
 126   __start___ex_table = .;
 127   __ex_table : { *(__ex_table) }
 128   __stop___ex_table = .;
 129
 130   . = ALIGN(256);
 131   __init_begin = .;
 132   .text.init : { *(.text.init) }
 133   .data.init : { *(.data.init) }
 134   . = ALIGN(256);
 135   __init_end = .;
 136
 137   __bss_start = .;
 138   .bss       :
 139   {
 140    *(.sbss) *(.scommon)
 141    *(.dynbss)
 142    *(.bss)
 143    *(COMMON)
 144   }
 145   _end = . ;
 146   PROVIDE (end = .);
 147 }