board/compulab/cm_t335/u-boot.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 *(.__image_copy_start)
  21                 *(.vectors)
  22                 CPUDIR/start.o (.text*)
  23                 board/compulab/cm_t335/built-in.o (.text*)
  24                 *(.text*)
  25         }
  26
  27         . = ALIGN(4);
  28         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  29
  30         . = ALIGN(4);
  31         .data : {
  32                 *(.data*)
  33         }
  34
  35         . = ALIGN(4);
  36
  37         . = .;
  38
  39         . = ALIGN(4);
  40         .u_boot_list : {
  41                 KEEP(*(SORT(.u_boot_list*)));
  42         }
  43
  44         . = ALIGN(4);
  45
  46         .image_copy_end :
  47         {
  48                 *(.__image_copy_end)
  49         }
  50
  51         .rel_dyn_start :
  52         {
  53                 *(.__rel_dyn_start)
  54         }
  55
  56         .rel.dyn : {
  57                 *(.rel*)
  58         }
  59
  60         .rel_dyn_end :
  61         {
  62                 *(.__rel_dyn_end)
  63         }
  64
  65         .end :
  66         {
  67                 *(.__end)
  68         }
  69
  70         _image_binary_end = .;
  71
  72         /*
  73          * Deprecated: this MMU section is used by pxa at present but
  74          * should not be used by new boards/CPUs.
  75          */
  76         . = ALIGN(4096);
  77         .mmutable : {
  78                 *(.mmutable)
  79         }
  80
  81 /*
  82  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  83  * __bss_base and __bss_limit are for linker only (overlay ordering)
  84  */
  85
  86         .bss_start __rel_dyn_start (OVERLAY) : {
  87                 KEEP(*(.__bss_start));
  88                 __bss_base = .;
  89         }
  90
  91         .bss __bss_base (OVERLAY) : {
  92                 *(.bss*)
  93                  . = ALIGN(4);
  94                  __bss_limit = .;
  95         }
  96
  97         .bss_end __bss_limit (OVERLAY) : {
  98                 KEEP(*(.__bss_end));
  99         }
 100
 101         .dynsym _image_binary_end : { *(.dynsym) }
 102         .hash : { *(.hash) }
 103         .got.plt : { *(.got.plt) }
 104         .dynbss : { *(.dynbss) }
 105         .dynstr : { *(.dynstr*) }
 106         .dynamic : { *(.dynamic*) }
 107         .plt : { *(.plt*) }
 108         .interp : { *(.interp*) }
 109         .gnu : { *(.gnu*) }
 110         .ARM.exidx : { *(.ARM.exidx*) }
 111 }