board/dvlhost/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT ("elf32-bigarm", "elf32-bigarm", "elf32-bigarm")
  25 OUTPUT_ARCH (arm)
  26 ENTRY (_start)
  27 SECTIONS
  28 {
  29         . = 0x00000000;
  30
  31         . = ALIGN (4);
  32         .text : {
  33                 *(.__image_copy_start)
  34                 arch/arm/cpu/ixp/start.o(.text*)
  35                 net/libnet.o(.text*)
  36                 board/dvlhost/libdvlhost.o(.text*)
  37                 arch/arm/cpu/ixp/libixp.o(.text*)
  38                 drivers/serial/libserial.o(.text*)
  39
  40                 . = env_offset;
  41                 common/env_embedded.o(.ppcenv)
  42                 *(.text*)
  43         }
  44
  45         . = ALIGN (4);
  46         .rodata : {
  47                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  48         }
  49         . = ALIGN (4);
  50         .data : {
  51                 *(.data*)
  52         }
  53         . = ALIGN (4);
  54         .got : {
  55                 *(.got)
  56         }
  57         . =.;
  58
  59         . = ALIGN(4);
  60         .u_boot_list : {
  61                 KEEP(*(SORT(.u_boot_list*)));
  62         }
  63
  64         . = ALIGN (4);
  65
  66         .image_copy_end :
  67         {
  68                 *(.__image_copy_end)
  69         }
  70
  71         .rel_dyn_start :
  72         {
  73                 *(.__rel_dyn_start)
  74         }
  75
  76         .rel.dyn : {
  77                 *(.rel*)
  78         }
  79
  80         .rel_dyn_end :
  81         {
  82                 *(.__rel_dyn_end)
  83         }
  84
  85         _end = .;
  86
  87 /*
  88  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  89  * __bss_base and __bss_limit are for linker only (overlay ordering)
  90  */
  91
  92         .bss_start __rel_dyn_start (OVERLAY) : {
  93                 KEEP(*(.__bss_start));
  94                 __bss_base = .;
  95         }
  96
  97         .bss __bss_base (OVERLAY) : {
  98                 *(.bss*)
  99                  . = ALIGN(4);
 100                  __bss_limit = .;
 101         }
 102         .bss_end __bss_limit (OVERLAY) : {
 103                 KEEP(*(.__bss_end));
 104         }
 105
 106         /DISCARD/ : { *(.dynsym) }
 107         /DISCARD/ : { *(.dynstr*) }
 108         /DISCARD/ : { *(.dynamic*) }
 109         /DISCARD/ : { *(.plt*) }
 110         /DISCARD/ : { *(.interp*) }
 111         /DISCARD/ : { *(.gnu*) }
 112 }