board/ep88x/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * Modified by Yuli Barcohen <yuli@arabellasw.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .text          :
  32   {
  33     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  34     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  35     *(.text*)
  36     . = ALIGN(16);
  37     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38   }
  39
  40   /* Read-write section, merged into data segment: */
  41   . = (. + 0x0FFF) & 0xFFFFF000;
  42   _erotext = .;
  43   PROVIDE (erotext = .);
  44   .reloc   :
  45   {
  46     _GOT2_TABLE_ = .;
  47     KEEP(*(.got2))
  48     KEEP(*(.got))
  49     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  50     _FIXUP_TABLE_ = .;
  51     KEEP(*(.fixup))
  52   }
  53   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  54   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  55
  56   .data    :
  57   {
  58     *(.data*)
  59     *(.sdata*)
  60   }
  61   _edata  =  .;
  62   PROVIDE (edata = .);
  63
  64   . = .;
  65
  66   . = ALIGN(4);
  67   .u_boot_list : {
  68         KEEP(*(SORT(.u_boot_list*)));
  69   }
  70
  71
  72   . = .;
  73   __start___ex_table = .;
  74   __ex_table : { *(__ex_table) }
  75   __stop___ex_table = .;
  76
  77   . = ALIGN(4096);
  78   __init_begin = .;
  79   .text.init : { *(.text.init) }
  80   .data.init : { *(.data.init) }
  81   . = ALIGN(4096);
  82   __init_end = .;
  83
  84   __bss_start = .;
  85   .bss (NOLOAD)       :
  86   {
  87    *(.bss*)
  88    *(.sbss*)
  89    *(COMMON)
  90    . = ALIGN(4);
  91   }
  92   __bss_end__ = . ;
  93   PROVIDE (end = .);
  94 }
  95 ENTRY(_start)