board/esd/wuh405/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   .resetvec 0xFFFFFFFC :
  30   {
  31     *(.resetvec)
  32   } = 0xffff
  33
  34   /* Read-only sections, merged into text segment: */
  35   . = + SIZEOF_HEADERS;
  36   .interp : { *(.interp) }
  37   .hash          : { *(.hash)           }
  38   .dynsym        : { *(.dynsym)         }
  39   .dynstr        : { *(.dynstr)         }
  40   .rel.text      : { *(.rel.text)               }
  41   .rela.text     : { *(.rela.text)      }
  42   .rel.data      : { *(.rel.data)               }
  43   .rela.data     : { *(.rela.data)      }
  44   .rel.rodata    : { *(.rel.rodata)     }
  45   .rela.rodata   : { *(.rela.rodata)    }
  46   .rel.got       : { *(.rel.got)                }
  47   .rela.got      : { *(.rela.got)               }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.bss       : { *(.rel.bss)                }
  53   .rela.bss      : { *(.rela.bss)               }
  54   .rel.plt       : { *(.rel.plt)                }
  55   .rela.plt      : { *(.rela.plt)               }
  56   .init          : { *(.init)   }
  57   .plt : { *(.plt) }
  58   .text      :
  59   {
  60     cpu/ppc4xx/start.o  (.text)
  61
  62     *(.text)
  63     *(.got1)
  64   }
  65   _etext = .;
  66   PROVIDE (etext = .);
  67   .rodata    :
  68   {
  69     *(.eh_frame)
  70     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  71   }
  72   .fini      : { *(.fini)    } =0
  73   .ctors     : { *(.ctors)   }
  74   .dtors     : { *(.dtors)   }
  75
  76   /* Read-write section, merged into data segment: */
  77   . = (. + 0x00FF) & 0xFFFFFF00;
  78   _erotext = .;
  79   PROVIDE (erotext = .);
  80   .reloc   :
  81   {
  82     *(.got)
  83     _GOT2_TABLE_ = .;
  84     *(.got2)
  85     _FIXUP_TABLE_ = .;
  86     *(.fixup)
  87   }
  88   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  89   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  90
  91   .data    :
  92   {
  93     *(.data)
  94     *(.data1)
  95     *(.sdata)
  96     *(.sdata2)
  97     *(.dynamic)
  98     CONSTRUCTORS
  99   }
 100   _edata  =  .;
 101   PROVIDE (edata = .);
 102
 103   . = .;
 104   __u_boot_cmd_start = .;
 105   .u_boot_cmd : { *(.u_boot_cmd) }
 106   __u_boot_cmd_end = .;
 107
 108   . = .;
 109   __start___ex_table = .;
 110   __ex_table : { *(__ex_table) }
 111   __stop___ex_table = .;
 112
 113   . = ALIGN(256);
 114   __init_begin = .;
 115   .text.init : { *(.text.init) }
 116   .data.init : { *(.data.init) }
 117   . = ALIGN(256);
 118   __init_end = .;
 119
 120   __bss_start = .;
 121   .bss (NOLOAD)       :
 122   {
 123    *(.sbss) *(.scommon)
 124    *(.dynbss)
 125    *(.bss)
 126    *(COMMON)
 127    . = ALIGN(4);
 128   }
 129   _end = . ;
 130   PROVIDE (end = .);
 131 }