board/freescale/m5208evbe/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(m68k)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   .text      :
  30   {
  31     arch/m68k/cpu/mcf52x2/start.o               (.text*)
  32
  33     . = DEFINED(env_offset) ? env_offset : .;
  34     common/env_embedded.o       (.text*)
  35
  36     *(.text*)
  37   }
  38   _etext = .;
  39   PROVIDE (etext = .);
  40   .rodata    :
  41   {
  42     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  43   }
  44
  45   /* Read-write section, merged into data segment: */
  46   . = (. + 0x00FF) & 0xFFFFFF00;
  47   _erotext = .;
  48   PROVIDE (erotext = .);
  49
  50   .reloc   :
  51   {
  52     __got_start = .;
  53     KEEP(*(.got))
  54     __got_end = .;
  55     _GOT2_TABLE_ = .;
  56     KEEP(*(.got2))
  57     _FIXUP_TABLE_ = .;
  58     KEEP(*(.fixup))
  59   }
  60   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  61   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  62
  63   .data    :
  64   {
  65     *(.data*)
  66     *(.sdata*)
  67   }
  68   _edata  =  .;
  69   PROVIDE (edata = .);
  70
  71   . = .;
  72
  73   . = ALIGN(4);
  74   .u_boot_list : {
  75         KEEP(*(SORT(.u_boot_list*)));
  76   }
  77
  78   . = .;
  79   __start___ex_table = .;
  80   __ex_table : { *(__ex_table) }
  81   __stop___ex_table = .;
  82
  83   . = ALIGN(256);
  84   __init_begin = .;
  85   .text.init : { *(.text.init) }
  86   .data.init : { *(.data.init) }
  87   . = ALIGN(256);
  88   __init_end = .;
  89
  90   __bss_start = .;
  91   .bss (NOLOAD)       :
  92   {
  93    _sbss = .;
  94    *(.sbss*)
  95    *(.bss*)
  96    *(COMMON)
  97    . = ALIGN(4);
  98    _ebss = .;
  99   }
 100   __bss_end__ = . ;
 101   PROVIDE (end = .);
 102 }