board/freescale/mpc8641hpcn/u-boot.lds

   1 /*
   2  * Copyright 2006, 2007 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24
  25 SECTIONS
  26 {
  27
  28   /* Read-only sections, merged into text segment: */
  29   .interp : { *(.interp) }
  30   .hash          : { *(.hash)           }
  31   .dynsym        : { *(.dynsym)         }
  32   .dynstr        : { *(.dynstr)         }
  33   .rel.text      : { *(.rel.text)               }
  34   .rela.text     : { *(.rela.text)      }
  35   .rel.data      : { *(.rel.data)               }
  36   .rela.data     : { *(.rela.data)      }
  37   .rel.rodata    : { *(.rel.rodata)     }
  38   .rela.rodata   : { *(.rela.rodata)    }
  39   .rel.got       : { *(.rel.got)                }
  40   .rela.got      : { *(.rela.got)               }
  41   .rel.ctors     : { *(.rel.ctors)      }
  42   .rela.ctors    : { *(.rela.ctors)     }
  43   .rel.dtors     : { *(.rel.dtors)      }
  44   .rela.dtors    : { *(.rela.dtors)     }
  45   .rel.bss       : { *(.rel.bss)                }
  46   .rela.bss      : { *(.rela.bss)               }
  47   .rel.plt       : { *(.rel.plt)                }
  48   .rela.plt      : { *(.rela.plt)               }
  49   .init          : { *(.init)   }
  50   .plt : { *(.plt) }
  51   .text      :
  52   {
  53     cpu/mpc86xx/start.o (.text)
  54     cpu/mpc86xx/traps.o (.text)
  55     cpu/mpc86xx/interrupts.o (.text)
  56     cpu/mpc86xx/cpu_init.o (.text)
  57     cpu/mpc86xx/cpu.o (.text)
  58     cpu/mpc86xx/speed.o (.text)
  59     common/dlmalloc.o (.text)
  60     lib_generic/crc32.o (.text)
  61     lib_ppc/extable.o (.text)
  62     lib_generic/zlib.o (.text)
  63     drivers/bios_emulator/atibios.o (.text)
  64     *(.text)
  65     *(.fixup)
  66     *(.got1)
  67    }
  68     _etext = .;
  69     PROVIDE (etext = .);
  70     .rodata    :
  71    {
  72     *(.rodata)
  73     *(.rodata1)
  74     *(.rodata.str1.4)
  75     *(.eh_frame)
  76   }
  77   .fini      : { *(.fini)    } =0
  78   .ctors     : { *(.ctors)   }
  79   .dtors     : { *(.dtors)   }
  80
  81   /* Read-write section, merged into data segment: */
  82   . = (. + 0x00FF) & 0xFFFFFF00;
  83   _erotext = .;
  84   PROVIDE (erotext = .);
  85   .reloc   :
  86   {
  87     *(.got)
  88     _GOT2_TABLE_ = .;
  89     *(.got2)
  90     _FIXUP_TABLE_ = .;
  91     *(.fixup)
  92   }
  93   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  94   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  95
  96   .data    :
  97   {
  98     *(.data)
  99     *(.data1)
 100     *(.sdata)
 101     *(.sdata2)
 102     *(.dynamic)
 103     CONSTRUCTORS
 104   }
 105   _edata  =  .;
 106   PROVIDE (edata = .);
 107
 108   . = .;
 109   __u_boot_cmd_start = .;
 110   .u_boot_cmd : { *(.u_boot_cmd) }
 111   __u_boot_cmd_end = .;
 112
 113   . = .;
 114   __start___ex_table = .;
 115   __ex_table : { *(__ex_table) }
 116   __stop___ex_table = .;
 117
 118   . = ALIGN(256);
 119   __init_begin = .;
 120   .text.init : { *(.text.init) }
 121   .data.init : { *(.data.init) }
 122   . = ALIGN(256);
 123   __init_end = .;
 124
 125   __bss_start = .;
 126   .bss (NOLOAD)       :
 127   {
 128    *(.sbss) *(.scommon)
 129    *(.dynbss)
 130    *(.bss)
 131    *(COMMON)
 132   }
 133   _end = . ;
 134   PROVIDE (end = .);
 135 }