board/matrix_vision/mvsmr/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  * (C) Copyright 2010
   5  * André Schwarz, Matrix Vision GmbH, as@matrix-vision.de
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_ARCH(powerpc)
  11
  12 SECTIONS
  13 {
  14   /* Read-only sections, merged into text segment: */
  15   .text      :
  16   {
  17     /* WARNING - the following is hand-optimized to fit within  */
  18     /* the first two sectors (=8KB) of our S29GL flash chip */
  19     arch/powerpc/cpu/mpc5xxx/start.o    (.text*)
  20     arch/powerpc/cpu/mpc5xxx/traps.o    (.text*)
  21     board/matrix_vision/common/libmatrix_vision.o (.text*)
  22
  23     /* This is only needed to force failure if size of above code will ever */
  24     /* increase and grow into reserved space. */
  25     . = ALIGN(0x2000);  /* location counter has to be 0x4000 now */
  26     . += 0x4000;        /* ->0x8000, i.e. move to env_offset */
  27
  28     . = env_offset;     /* ld error as soon as above ALIGN misplaces lc */
  29     common/env_embedded.o        (.ppcenv)
  30
  31     *(.text*)
  32     . = ALIGN(16);
  33     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  34   }
  35
  36   /* Read-write section, merged into data segment: */
  37   . = (. + 0x0FFF) & 0xFFFFF000;
  38   _erotext = .;
  39   PROVIDE (erotext = .);
  40   .reloc   :
  41   {
  42     _GOT2_TABLE_ = .;
  43     KEEP(*(.got2))
  44     KEEP(*(.got))
  45     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  46     _FIXUP_TABLE_ = .;
  47     KEEP(*(.fixup))
  48   }
  49   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  50   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  51
  52   .data    :
  53   {
  54     *(.data*)
  55     *(.sdata*)
  56   }
  57   _edata  =  .;
  58   PROVIDE (edata = .);
  59
  60   . = .;
  61
  62   . = ALIGN(4);
  63   .u_boot_list : {
  64         KEEP(*(SORT(.u_boot_list*)));
  65   }
  66
  67
  68   . = .;
  69   __start___ex_table = .;
  70   __ex_table : { *(__ex_table) }
  71   __stop___ex_table = .;
  72
  73   . = ALIGN(4096);
  74   __init_begin = .;
  75   .text.init : { *(.text.init) }
  76   .data.init : { *(.data.init) }
  77   . = ALIGN(4096);
  78   __init_end = .;
  79
  80   __bss_start = .;
  81   .bss (NOLOAD)       :
  82   {
  83    *(.bss*)
  84    *(.sbss*)
  85    . = ALIGN(4);
  86   }
  87   __bss_end = . ;
  88   PROVIDE (end = .);
  89 }