board/matrix_vision/mvsmr/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  * (C) Copyright 2010
   5  * André Schwarz, Matrix Vision GmbH, as@matrix-vision.de
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   .text      :
  32   {
  33     /* WARNING - the following is hand-optimized to fit within  */
  34     /* the first two sectors (=8KB) of our S29GL flash chip */
  35     arch/powerpc/cpu/mpc5xxx/start.o    (.text*)
  36     arch/powerpc/cpu/mpc5xxx/traps.o    (.text*)
  37     board/matrix_vision/common/libmatrix_vision.o (.text*)
  38
  39     /* This is only needed to force failure if size of above code will ever */
  40     /* increase and grow into reserved space. */
  41     . = ALIGN(0x2000);  /* location counter has to be 0x4000 now */
  42     . += 0x4000;        /* ->0x8000, i.e. move to env_offset */
  43
  44     . = env_offset;     /* ld error as soon as above ALIGN misplaces lc */
  45     common/env_embedded.o        (.ppcenv)
  46
  47     *(.text*)
  48     . = ALIGN(16);
  49     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  50   }
  51
  52   /* Read-write section, merged into data segment: */
  53   . = (. + 0x0FFF) & 0xFFFFF000;
  54   _erotext = .;
  55   PROVIDE (erotext = .);
  56   .reloc   :
  57   {
  58     _GOT2_TABLE_ = .;
  59     KEEP(*(.got2))
  60     KEEP(*(.got))
  61     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  62     _FIXUP_TABLE_ = .;
  63     KEEP(*(.fixup))
  64   }
  65   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  66   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  67
  68   .data    :
  69   {
  70     *(.data*)
  71     *(.sdata*)
  72   }
  73   _edata  =  .;
  74   PROVIDE (edata = .);
  75
  76   . = .;
  77
  78   . = ALIGN(4);
  79   .u_boot_list : {
  80         KEEP(*(SORT(.u_boot_list*)));
  81   }
  82
  83
  84   . = .;
  85   __start___ex_table = .;
  86   __ex_table : { *(__ex_table) }
  87   __stop___ex_table = .;
  88
  89   . = ALIGN(4096);
  90   __init_begin = .;
  91   .text.init : { *(.text.init) }
  92   .data.init : { *(.data.init) }
  93   . = ALIGN(4096);
  94   __init_end = .;
  95
  96   __bss_start = .;
  97   .bss (NOLOAD)       :
  98   {
  99    *(.bss*)
 100    *(.sbss*)
 101    . = ALIGN(4);
 102   }
 103   __bss_end__ = . ;
 104   PROVIDE (end = .);
 105 }