board/mousse/u-boot.lds.rom

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     arch/powerpc/cpu/mpc824x/start.o    (.text)
  56          common/board.o (.text)
  57     arch/powerpc/lib/ppcstring.o        (.text)
  58     lib/vsprintf.o      (.text)
  59     lib/crc32.o         (.text)
  60     lib/zlib.o          (.text)
  61
  62                 . = env_offset;
  63     common/env_embedded.o (.text)
  64
  65                 *(.text)
  66
  67     *(.got1)
  68     . = ALIGN(16);
  69     *(.rodata)
  70     *(.rodata1)
  71     *(.rodata.str1.4)
  72     *(.eh_frame)
  73   }
  74   .fini      : { *(.fini)    } =0
  75   .ctors     : { *(.ctors)   }
  76   .dtors     : { *(.dtors)   }
  77
  78   /* Read-write section, merged into data segment: */
  79   . = (. + 0x0FF) & 0xFFFFFF00;
  80   _erotext = .;
  81   PROVIDE (erotext = .);
  82   .reloc   :
  83   {
  84     *(.got)
  85     _GOT2_TABLE_ = .;
  86     *(.got2)
  87     _FIXUP_TABLE_ = .;
  88     *(.fixup)
  89   }
  90   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  91   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  92
  93   .data    :
  94   {
  95     *(.data)
  96     *(.data1)
  97     *(.sdata)
  98     *(.sdata2)
  99     *(.dynamic)
 100     CONSTRUCTORS
 101   }
 102   _edata  =  .;
 103   PROVIDE (edata = .);
 104
 105   __u_boot_cmd_start = .;
 106   .u_boot_cmd : { *(.u_boot_cmd) }
 107   __u_boot_cmd_end = .;
 108
 109   __start___ex_table = .;
 110   __ex_table : { *(__ex_table) }
 111   __stop___ex_table = .;
 112
 113   . = ALIGN(4096);
 114   __init_begin = .;
 115   .text.init : { *(.text.init) }
 116   .data.init : { *(.data.init) }
 117   . = ALIGN(4096);
 118   __init_end = .;
 119
 120   __bss_start = .;
 121   .bss       :
 122   {
 123    *(.sbss) *(.scommon)
 124    *(.dynbss)
 125    *(.bss)
 126    *(COMMON)
 127   }
 128
 129   _end = . ;
 130   PROVIDE (end = .);
 131 }