board/nx823/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     cpu/mpc8xx/start.o  (.text)
  57     common/environment.o(.text)
  58
  59     *(.text)
  60     *(.fixup)
  61     *(.got1)
  62   }
  63   _etext = .;
  64   PROVIDE (etext = .);
  65   .rodata    :
  66   {
  67     *(.rodata)
  68     *(.rodata1)
  69     *(.rodata.str1.4)
  70   }
  71   .fini      : { *(.fini)    } =0
  72   .ctors     : { *(.ctors)   }
  73   .dtors     : { *(.dtors)   }
  74
  75   /* Read-write section, merged into data segment: */
  76   . = (. + 0x00FF) & 0xFFFFFF00;
  77   _erotext = .;
  78   PROVIDE (erotext = .);
  79   .reloc   :
  80   {
  81     *(.got)
  82     _GOT2_TABLE_ = .;
  83     *(.got2)
  84     _FIXUP_TABLE_ = .;
  85     *(.fixup)
  86   }
  87   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  88   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  89
  90   .data    :
  91   {
  92     *(.data)
  93     *(.data1)
  94     *(.sdata)
  95     *(.sdata2)
  96     *(.dynamic)
  97     CONSTRUCTORS
  98   }
  99   _edata  =  .;
 100   PROVIDE (edata = .);
 101
 102   __u_boot_cmd_start = .;
 103   .u_boot_cmd : { *(.u_boot_cmd) }
 104   __u_boot_cmd_end = .;
 105
 106
 107   __start___ex_table = .;
 108   __ex_table : { *(__ex_table) }
 109   __stop___ex_table = .;
 110
 111   . = ALIGN(256);
 112   __init_begin = .;
 113   .text.init : { *(.text.init) }
 114   .data.init : { *(.data.init) }
 115   . = ALIGN(256);
 116   __init_end = .;
 117
 118   __bss_start = .;
 119   .bss       :
 120   {
 121    *(.sbss) *(.scommon)
 122    *(.dynbss)
 123    *(.bss)
 124    *(COMMON)
 125   }
 126   _end = . ;
 127   PROVIDE (end = .);
 128 }