board/ppmc7xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 /*
  25  * u-boot.lds - linker script for U-Boot on the Galileo Eval Board.
  26  */
  27
  28 OUTPUT_ARCH(powerpc)
  29 /* Do we need any of these for elf?
  30    __DYNAMIC = 0;    */
  31 SECTIONS
  32 {
  33   /* Read-only sections, merged into text segment: */
  34   . = + SIZEOF_HEADERS;
  35   .interp : { *(.interp) }
  36   .hash          : { *(.hash)           }
  37   .dynsym        : { *(.dynsym)         }
  38   .dynstr        : { *(.dynstr)         }
  39   .rel.text      : { *(.rel.text)               }
  40   .rela.text     : { *(.rela.text)      }
  41   .rel.data      : { *(.rel.data)               }
  42   .rela.data     : { *(.rela.data)      }
  43   .rel.rodata    : { *(.rel.rodata)     }
  44   .rela.rodata   : { *(.rela.rodata)    }
  45   .rel.got       : { *(.rel.got)                }
  46   .rela.got      : { *(.rela.got)               }
  47   .rel.ctors     : { *(.rel.ctors)      }
  48   .rela.ctors    : { *(.rela.ctors)     }
  49   .rel.dtors     : { *(.rel.dtors)      }
  50   .rela.dtors    : { *(.rela.dtors)     }
  51   .rel.bss       : { *(.rel.bss)                }
  52   .rela.bss      : { *(.rela.bss)               }
  53   .rel.plt       : { *(.rel.plt)                }
  54   .rela.plt      : { *(.rela.plt)               }
  55   .init          : { *(.init)   }
  56   .plt : { *(.plt) }
  57   .text      :
  58   {
  59     arch/ppc/cpu/74xx_7xx/start.o       (.text)
  60
  61 /* store the environment in a seperate sector in the boot flash */
  62 /*    . = env_offset; */
  63 /*    common/env_embedded.o(.text) */
  64
  65     *(.text)
  66     *(.got1)
  67   }
  68   _etext = .;
  69   PROVIDE (etext = .);
  70   .rodata    :
  71   {
  72     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  73   }
  74   .fini      : { *(.fini)    } =0
  75   .ctors     : { *(.ctors)   }
  76   .dtors     : { *(.dtors)   }
  77
  78   /* Read-write section, merged into data segment: */
  79   . = (. + 0x00FF) & 0xFFFFFF00;
  80   _erotext = .;
  81   PROVIDE (erotext = .);
  82   .reloc   :
  83   {
  84     *(.got)
  85     _GOT2_TABLE_ = .;
  86     *(.got2)
  87     _FIXUP_TABLE_ = .;
  88     *(.fixup)
  89   }
  90   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  91   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  92
  93   .data    :
  94   {
  95     *(.data)
  96     *(.data1)
  97     *(.sdata)
  98     *(.sdata2)
  99     *(.dynamic)
 100     CONSTRUCTORS
 101   }
 102   _edata  =  .;
 103   PROVIDE (edata = .);
 104
 105   __u_boot_cmd_start = .;
 106   .u_boot_cmd : { *(.u_boot_cmd) }
 107   __u_boot_cmd_end = .;
 108
 109
 110   __start___ex_table = .;
 111   __ex_table : { *(__ex_table) }
 112   __stop___ex_table = .;
 113
 114   . = ALIGN(256);
 115   __init_begin = .;
 116   .text.init : { *(.text.init) }
 117   .data.init : { *(.data.init) }
 118   . = ALIGN(256);
 119   __init_end = .;
 120
 121   __bss_start = .;
 122   .bss (NOLOAD)       :
 123   {
 124    *(.sbss) *(.scommon)
 125    *(.dynbss)
 126    *(.bss)
 127    *(COMMON)
 128    . = ALIGN(4);
 129   }
 130   _end = . ;
 131   PROVIDE (end = .);
 132 }