board/r360mpi/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  35     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  36
  37     *(.text*)
  38   }
  39   _etext = .;
  40   PROVIDE (etext = .);
  41   .rodata    :
  42   {
  43     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  44   }
  45
  46   /* Read-write section, merged into data segment: */
  47   . = (. + 0x00FF) & 0xFFFFFF00;
  48   _erotext = .;
  49   PROVIDE (erotext = .);
  50   .reloc   :
  51   {
  52     _GOT2_TABLE_ = .;
  53     KEEP(*(.got2))
  54     KEEP(*(.got))
  55     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  56     _FIXUP_TABLE_ = .;
  57     KEEP(*(.fixup))
  58   }
  59   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  60   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  61
  62   .data    :
  63   {
  64     *(.data*)
  65     *(.sdata*)
  66   }
  67   _edata  =  .;
  68   PROVIDE (edata = .);
  69
  70   . = .;
  71
  72   . = ALIGN(4);
  73   .u_boot_list : {
  74         KEEP(*(SORT(.u_boot_list*)));
  75   }
  76
  77
  78   . = .;
  79   __start___ex_table = .;
  80   __ex_table : { *(__ex_table) }
  81   __stop___ex_table = .;
  82
  83   . = ALIGN(256);
  84   __init_begin = .;
  85   .text.init : { *(.text.init) }
  86   .data.init : { *(.data.init) }
  87   . = ALIGN(256);
  88   __init_end = .;
  89
  90   __bss_start = .;
  91   .bss (NOLOAD)       :
  92   {
  93    *(.bss*)
  94    *(.sbss*)
  95    *(COMMON)
  96    . = ALIGN(4);
  97   }
  98   __bss_end = . ;
  99   PROVIDE (end = .);
 100   . = ALIGN(128 * 1024);
 101   .ppcenv       :
 102   {
 103     common/env_embedded.o (.ppcenv)
 104   }
 105 }