board/tqm8560/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003, Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   .bootpg 0xFFFFF000 :
  36   {
  37     cpu/mpc85xx/start.o (.bootpg)
  38     board/tqm8560/init.o (.bootpg)
  39   } = 0xffff
  40
  41   /* Read-only sections, merged into text segment: */
  42   . = + SIZEOF_HEADERS;
  43   .interp : { *(.interp) }
  44   .hash          : { *(.hash)           }
  45   .dynsym        : { *(.dynsym)         }
  46   .dynstr        : { *(.dynstr)         }
  47   .rel.text      : { *(.rel.text)               }
  48   .rela.text     : { *(.rela.text)      }
  49   .rel.data      : { *(.rel.data)               }
  50   .rela.data     : { *(.rela.data)      }
  51   .rel.rodata    : { *(.rel.rodata)     }
  52   .rela.rodata   : { *(.rela.rodata)    }
  53   .rel.got       : { *(.rel.got)                }
  54   .rela.got      : { *(.rela.got)               }
  55   .rel.ctors     : { *(.rel.ctors)      }
  56   .rela.ctors    : { *(.rela.ctors)     }
  57   .rel.dtors     : { *(.rel.dtors)      }
  58   .rela.dtors    : { *(.rela.dtors)     }
  59   .rel.bss       : { *(.rel.bss)                }
  60   .rela.bss      : { *(.rela.bss)               }
  61   .rel.plt       : { *(.rel.plt)                }
  62   .rela.plt      : { *(.rela.plt)               }
  63   .init          : { *(.init)   }
  64   .plt : { *(.plt) }
  65   .text      :
  66   {
  67     cpu/mpc85xx/start.o (.text)
  68     board/tqm8560/init.o (.text)
  69     cpu/mpc85xx/traps.o (.text)
  70     cpu/mpc85xx/interrupts.o (.text)
  71     cpu/mpc85xx/cpu_init.o (.text)
  72     cpu/mpc85xx/cpu.o (.text)
  73     cpu/mpc85xx/tsec.o (.text)
  74     cpu/mpc85xx/speed.o (.text)
  75     cpu/mpc85xx/pci.o (.text)
  76     common/dlmalloc.o (.text)
  77     lib_generic/crc32.o (.text)
  78     lib_ppc/extable.o (.text)
  79     lib_generic/zlib.o (.text)
  80     *(.text)
  81     *(.fixup)
  82     *(.got1)
  83    }
  84     _etext = .;
  85     PROVIDE (etext = .);
  86     .rodata    :
  87    {
  88     *(.rodata)
  89     *(.rodata1)
  90     *(.rodata.str1.4)
  91   }
  92   .fini      : { *(.fini)    } =0
  93   .ctors     : { *(.ctors)   }
  94   .dtors     : { *(.dtors)   }
  95
  96   /* Read-write section, merged into data segment: */
  97   . = (. + 0x00FF) & 0xFFFFFF00;
  98   _erotext = .;
  99   PROVIDE (erotext = .);
 100   .reloc   :
 101   {
 102     *(.got)
 103     _GOT2_TABLE_ = .;
 104     *(.got2)
 105     _FIXUP_TABLE_ = .;
 106     *(.fixup)
 107   }
 108   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 109   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 110
 111   .data    :
 112   {
 113     *(.data)
 114     *(.data1)
 115     *(.sdata)
 116     *(.sdata2)
 117     *(.dynamic)
 118     CONSTRUCTORS
 119   }
 120   _edata  =  .;
 121   PROVIDE (edata = .);
 122
 123   __u_boot_cmd_start = .;
 124   .u_boot_cmd : { *(.u_boot_cmd) }
 125   __u_boot_cmd_end = .;
 126
 127   __start___ex_table = .;
 128   __ex_table : { *(__ex_table) }
 129   __stop___ex_table = .;
 130
 131   . = ALIGN(256);
 132   __init_begin = .;
 133   .text.init : { *(.text.init) }
 134   .data.init : { *(.data.init) }
 135   . = ALIGN(256);
 136   __init_end = .;
 137
 138   __bss_start = .;
 139   .bss       :
 140   {
 141    *(.sbss) *(.scommon)
 142    *(.dynbss)
 143    *(.bss)
 144    *(COMMON)
 145   }
 146   _end = . ;
 147   PROVIDE (end = .);
 148 }