board/xpedite1k/u-boot.lds.debug

   1 /*
   2  * (C) Copyright 2002-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/ppc4xx/start.o  (.text)
  60     board/xpedite1k/init.o (.text)
  61     cpu/ppc4xx/kgdb.o   (.text)
  62     cpu/ppc4xx/traps.o  (.text)
  63     cpu/ppc4xx/interrupts.o     (.text)
  64     cpu/ppc4xx/serial.o (.text)
  65     cpu/ppc4xx/cpu_init.o       (.text)
  66     cpu/ppc4xx/speed.o  (.text)
  67     cpu/ppc4xx/405gp_enet.o     (.text)
  68     common/dlmalloc.o   (.text)
  69     lib_generic/crc32.o         (.text)
  70     lib_ppc/extable.o   (.text)
  71     lib_generic/zlib.o          (.text)
  72
  73 /*    common/environment.o(.text) */
  74
  75     *(.text)
  76     *(.fixup)
  77     *(.got1)
  78   }
  79   _etext = .;
  80   PROVIDE (etext = .);
  81   .rodata    :
  82   {
  83     *(.rodata)
  84     *(.rodata1)
  85     *(.rodata.str1.4)
  86   }
  87   .fini      : { *(.fini)    } =0
  88   .ctors     : { *(.ctors)   }
  89   .dtors     : { *(.dtors)   }
  90
  91   /* Read-write section, merged into data segment: */
  92   . = (. + 0x0FFF) & 0xFFFFF000;
  93   _erotext = .;
  94   PROVIDE (erotext = .);
  95   .reloc   :
  96   {
  97     *(.got)
  98     _GOT2_TABLE_ = .;
  99     *(.got2)
 100     _FIXUP_TABLE_ = .;
 101     *(.fixup)
 102   }
 103   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 104   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 105
 106   .data    :
 107   {
 108     *(.data)
 109     *(.data1)
 110     *(.sdata)
 111     *(.sdata2)
 112     *(.dynamic)
 113     CONSTRUCTORS
 114   }
 115   _edata  =  .;
 116   PROVIDE (edata = .);
 117
 118   __u_boot_cmd_start = .;
 119   .u_boot_cmd : { *(.u_boot_cmd) }
 120   __u_boot_cmd_end = .;
 121
 122
 123   __start___ex_table = .;
 124   __ex_table : { *(__ex_table) }
 125   __stop___ex_table = .;
 126
 127   . = ALIGN(256);
 128   __init_begin = .;
 129   .text.init : { *(.text.init) }
 130   .data.init : { *(.data.init) }
 131   . = ALIGN(256);
 132   __init_end = .;
 133
 134   __bss_start = .;
 135   .bss       :
 136   {
 137    *(.sbss) *(.scommon)
 138    *(.dynbss)
 139    *(.bss)
 140    *(COMMON)
 141   }
 142   _end = . ;
 143   PROVIDE (end = .);
 144 }