cpu/sh2/start.S

   1 /*
   2  * Copyright (C) 2007,2008 Nobuhiro Iwamatsu <iwamatsu@nigauri.org>
   3  * Copyright (C) 2008 Renesas Solutions Corp.
   4
   5  * This program is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU General Public License as
   7  * published by the Free Software Foundation; either version 2 of
   8  * the License, or (at your option) any later version.
   9  *
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with this program; if not, write to the Free Software
  17  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  18  * MA 02111-1307 USA
  19  */
  20
  21 #include <config.h>
  22 #include <version.h>
  23
  24         .text
  25         .align  2
  26
  27         .global _start
  28 _start:
  29         .long 0x00000010        /* Ppower ON reset PC*/
  30         .long 0x00000000
  31         .long 0x00000010        /* Manual reset PC */
  32         .long 0x00000000
  33 _init:
  34         mov.l   ._lowlevel_init, r0
  35 100:    bsrf    r0
  36         nop
  37         bsr     1f
  38         nop
  39 1:      sts     pr, r5
  40         mov.l   ._reloc_dst, r4
  41         add     #(_start-1b), r5
  42         mov.l   ._reloc_dst_end, r6
  43
  44 2:      mov.l   @r5+, r1
  45         mov.l   r1, @r4
  46         add     #4, r4
  47         cmp/hs  r6, r4
  48         bf      2b
  49
  50         mov.l   ._bss_start, r4
  51         mov.l   ._bss_end, r5
  52         mov     #0, r1
  53
  54 3:      mov.l   r1, @r4                 /* bss clear */
  55         add     #4, r4
  56         cmp/hs  r5, r4
  57         bf      3b
  58
  59         mov.l   ._gd_init, r13          /* global data */
  60         mov.l   ._stack_init, r15       /* stack */
  61
  62         mov.l   ._sh_generic_init, r0
  63         jsr     @r0
  64         nop
  65
  66 loop:
  67         bra     loop
  68
  69         .align  2
  70
  71 ._lowlevel_init:        .long   (lowlevel_init - (100b + 4))
  72 ._reloc_dst:            .long   reloc_dst
  73 ._reloc_dst_end:        .long   reloc_dst_end
  74 ._bss_start:            .long   bss_start
  75 ._bss_end:              .long   bss_end
  76 ._gd_init:              .long   (_start - CONFIG_SYS_GBL_DATA_SIZE)
  77 ._stack_init:   .long   (_start - CONFIG_SYS_GBL_DATA_SIZE - CONFIG_SYS_MALLOC_LEN - 16)
  78 ._sh_generic_init:      .long   sh_generic_init