cpu/sh3/u-boot.lds

   1 /*
   2  * Copyright (C) 2007
   3  * Yoshihiro Shimoda <shimoda.yoshihiro@renesas.com>
   4  *
   5  * Copyright (C) 2007
   6  * Nobuhiro Iwamatsu <iwamatsu@nigauri.org>
   7  *
   8  * Copyright (C) 2008
   9  * Mark Jonas <mark.jonas@de.bosch.com>
  10  *
  11  * See file CREDITS for list of people who contributed to this
  12  * project.
  13  *
  14  * This program is free software; you can redistribute it and/or
  15  * modify it under the terms of the GNU General Public License as
  16  * published by the Free Software Foundation; either version 2 of
  17  * the License, or (at your option) any later version.
  18  *
  19  * This program is distributed in the hope that it will be useful,
  20  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  21  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22  * GNU General Public License for more details.
  23  *
  24  * You should have received a copy of the GNU General Public License
  25  * along with this program; if not, write to the Free Software
  26  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  27  * MA 02111-1307 USA
  28  */
  29
  30 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  31 OUTPUT_ARCH(sh)
  32 ENTRY(_start)
  33
  34 SECTIONS
  35 {
  36         /*
  37          * entry and reloct_dst will be provided via ldflags
  38          */
  39         . = .;
  40
  41         PROVIDE (_ftext = .);
  42         PROVIDE (_fcode = .);
  43         PROVIDE (_start = .);
  44
  45         .text :
  46         {
  47                 cpu/sh3/start.o         (.text)
  48                 . = ALIGN(8192);
  49                 common/env_embedded.o   (.ppcenv)
  50                 . = ALIGN(8192);
  51                 common/env_embedded.o   (.ppcenvr)
  52                 . = ALIGN(8192);
  53                 *(.text)
  54                 . = ALIGN(4);
  55         } =0xFF
  56         PROVIDE (_ecode = .);
  57         .rodata :
  58         {
  59                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  60                 . = ALIGN(4);
  61         }
  62         PROVIDE (_etext = .);
  63
  64
  65         PROVIDE (_fdata = .);
  66         .data :
  67         {
  68                 *(.data)
  69                 . = ALIGN(4);
  70         }
  71         PROVIDE (_edata = .);
  72
  73         PROVIDE (_fgot = .);
  74         .got :
  75         {
  76                 *(.got)
  77                 . = ALIGN(4);
  78         }
  79         PROVIDE (_egot = .);
  80
  81         PROVIDE (__u_boot_cmd_start = .);
  82         .u_boot_cmd :
  83         {
  84                 *(.u_boot_cmd)
  85                 . = ALIGN(4);
  86         }
  87         PROVIDE (__u_boot_cmd_end = .);
  88
  89         PROVIDE (reloc_dst_end = .);
  90         /* _reloc_dst_end = .; */
  91
  92         PROVIDE (bss_start = .);
  93         PROVIDE (__bss_start = .);
  94         .bss :
  95         {
  96                 *(.bss)
  97                 . = ALIGN(4);
  98         }
  99         PROVIDE (bss_end = .);
 100
 101         PROVIDE (_end = .);
 102 }