scripts/kconfig/streamline_config.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2005-2009 - Steven Rostedt
   4 # Licensed under the terms of the GNU GPL License version 2
   5 #
   6 #  It's simple enough to figure out how this works.
   7 #  If not, then you can ask me at stripconfig@goodmis.org
   8 #
   9 # What it does?
  10 #
  11 #   If you have installed a Linux kernel from a distribution
  12 #   that turns on way too many modules than you need, and
  13 #   you only want the modules you use, then this program
  14 #   is perfect for you.
  15 #
  16 #   It gives you the ability to turn off all the modules that are
  17 #   not loaded on your system.
  18 #
  19 # Howto:
  20 #
  21 #  1. Boot up the kernel that you want to stream line the config on.
  22 #  2. Change directory to the directory holding the source of the
  23 #       kernel that you just booted.
  24 #  3. Copy the configuraton file to this directory as .config
  25 #  4. Have all your devices that you need modules for connected and
  26 #      operational (make sure that their corresponding modules are loaded)
  27 #  5. Run this script redirecting the output to some other file
  28 #       like config_strip.
  29 #  6. Back up your old config (if you want too).
  30 #  7. copy the config_strip file to .config
  31 #  8. Run "make oldconfig"
  32 #
  33 #  Now your kernel is ready to be built with only the modules that
  34 #  are loaded.
  35 #
  36 # Here's what I did with my Debian distribution.
  37 #
  38 #    cd /usr/src/linux-2.6.10
  39 #    cp /boot/config-2.6.10-1-686-smp .config
  40 #    ~/bin/streamline_config > config_strip
  41 #    mv .config config_sav
  42 #    mv config_strip .config
  43 #    make oldconfig
  44 #
  45 use strict;
  46 use Getopt::Long;
  47
  48 # set the environment variable LOCALMODCONFIG_DEBUG to get
  49 # debug output.
  50 my $debugprint = 0;
  51 $debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
  52
  53 sub dprint {
  54     return if (!$debugprint);
  55     print STDERR @_;
  56 }
  57
  58 my $config = ".config";
  59
  60 my $uname = `uname -r`;
  61 chomp $uname;
  62
  63 my @searchconfigs = (
  64         {
  65             "file" => ".config",
  66             "exec" => "cat",
  67         },
  68         {
  69             "file" => "/proc/config.gz",
  70             "exec" => "zcat",
  71         },
  72         {
  73             "file" => "/boot/config-$uname",
  74             "exec" => "cat",
  75         },
  76         {
  77             "file" => "/boot/vmlinuz-$uname",
  78             "exec" => "scripts/extract-ikconfig",
  79             "test" => "scripts/extract-ikconfig",
  80         },
  81         {
  82             "file" => "vmlinux",
  83             "exec" => "scripts/extract-ikconfig",
  84             "test" => "scripts/extract-ikconfig",
  85         },
  86         {
  87             "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
  88             "exec" => "scripts/extract-ikconfig",
  89             "test" => "scripts/extract-ikconfig",
  90         },
  91         {
  92             "file" => "kernel/configs.ko",
  93             "exec" => "scripts/extract-ikconfig",
  94             "test" => "scripts/extract-ikconfig",
  95         },
  96         {
  97             "file" => "kernel/configs.o",
  98             "exec" => "scripts/extract-ikconfig",
  99             "test" => "scripts/extract-ikconfig",
 100         },
 101 );
 102
 103 sub read_config {
 104     foreach my $conf (@searchconfigs) {
 105         my $file = $conf->{"file"};
 106
 107         next if ( ! -f "$file");
 108
 109         if (defined($conf->{"test"})) {
 110             `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
 111             next if ($?);
 112         }
 113
 114         my $exec = $conf->{"exec"};
 115
 116         print STDERR "using config: '$file'\n";
 117
 118         open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
 119         my @x = <$infile>;
 120         close $infile;
 121         return @x;
 122     }
 123     die "No config file found";
 124 }
 125
 126 my @config_file = read_config;
 127
 128 # Parse options
 129 my $localmodconfig = 0;
 130 my $localyesconfig = 0;
 131
 132 GetOptions("localmodconfig" => \$localmodconfig,
 133            "localyesconfig" => \$localyesconfig);
 134
 135 # Get the build source and top level Kconfig file (passed in)
 136 my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
 137 my $kconfig = $ARGV[1];
 138 my $lsmod_file = $ENV{'LSMOD'};
 139
 140 my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
 141 chomp @makefiles;
 142
 143 my %depends;
 144 my %selects;
 145 my %prompts;
 146 my %objects;
 147 my $var;
 148 my $iflevel = 0;
 149 my @ifdeps;
 150
 151 # prevent recursion
 152 my %read_kconfigs;
 153
 154 sub read_kconfig {
 155     my ($kconfig) = @_;
 156
 157     my $state = "NONE";
 158     my $config;
 159
 160     my $cont = 0;
 161     my $line;
 162
 163     my $source = "$ksource/$kconfig";
 164     my $last_source = "";
 165
 166     # Check for any environment variables used
 167     while ($source =~ /\$(\w+)/ && $last_source ne $source) {
 168         my $env = $1;
 169         $last_source = $source;
 170         $source =~ s/\$$env/$ENV{$env}/;
 171     }
 172
 173     open(my $kinfile, '<', $source) || die "Can't open $kconfig";
 174     while (<$kinfile>) {
 175         chomp;
 176
 177         # Make sure that lines ending with \ continue
 178         if ($cont) {
 179             $_ = $line . " " . $_;
 180         }
 181
 182         if (s/\\$//) {
 183             $cont = 1;
 184             $line = $_;
 185             next;
 186         }
 187
 188         $cont = 0;
 189
 190         # collect any Kconfig sources
 191         if (/^source\s*"(.*)"/) {
 192             my $kconfig = $1;
 193             # prevent reading twice.
 194             if (!defined($read_kconfigs{$kconfig})) {
 195                 $read_kconfigs{$kconfig} = 1;
 196                 read_kconfig($kconfig);
 197             }
 198             next;
 199         }
 200
 201         # configs found
 202         if (/^\s*(menu)?config\s+(\S+)\s*$/) {
 203             $state = "NEW";
 204             $config = $2;
 205
 206             # Add depends for 'if' nesting
 207             for (my $i = 0; $i < $iflevel; $i++) {
 208                 if ($i) {
 209                     $depends{$config} .= " " . $ifdeps[$i];
 210                 } else {
 211                     $depends{$config} = $ifdeps[$i];
 212                 }
 213                 $state = "DEP";
 214             }
 215
 216         # collect the depends for the config
 217         } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
 218             $state = "DEP";
 219             $depends{$config} = $1;
 220         } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
 221             $depends{$config} .= " " . $1;
 222         } elsif ($state eq "DEP" && /^\s*def(_(bool|tristate)|ault)\s+(\S.*)$/) {
 223             my $dep = $3;
 224             if ($dep !~ /^\s*(y|m|n)\s*$/) {
 225                 $dep =~ s/.*\sif\s+//;
 226                 $depends{$config} .= " " . $dep;
 227                 dprint "Added default depends $dep to $config\n";
 228             }
 229
 230         # Get the configs that select this config
 231         } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
 232             my $conf = $1;
 233             if (defined($selects{$conf})) {
 234                 $selects{$conf} .= " " . $config;
 235             } else {
 236                 $selects{$conf} = $config;
 237             }
 238
 239         # configs without prompts must be selected
 240         } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
 241             # note if the config has a prompt
 242             $prompts{$config} = 1;
 243
 244         # Check for if statements
 245         } elsif (/^if\s+(.*\S)\s*$/) {
 246             my $deps = $1;
 247             # remove beginning and ending non text
 248             $deps =~ s/^[^a-zA-Z0-9_]*//;
 249             $deps =~ s/[^a-zA-Z0-9_]*$//;
 250
 251             my @deps = split /[^a-zA-Z0-9_]+/, $deps;
 252
 253             $ifdeps[$iflevel++] = join ':', @deps;
 254
 255         } elsif (/^endif/) {
 256
 257             $iflevel-- if ($iflevel);
 258
 259         # stop on "help"
 260         } elsif (/^\s*help\s*$/) {
 261             $state = "NONE";
 262         }
 263     }
 264     close($kinfile);
 265 }
 266
 267 if ($kconfig) {
 268     read_kconfig($kconfig);
 269 }
 270
 271 # Makefiles can use variables to define their dependencies
 272 sub convert_vars {
 273     my ($line, %vars) = @_;
 274
 275     my $process = "";
 276
 277     while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
 278         my $start = $1;
 279         my $variable = $2;
 280         my $var = $3;
 281
 282         if (defined($vars{$var})) {
 283             $process .= $start . $vars{$var};
 284         } else {
 285             $process .= $start . $variable;
 286         }
 287     }
 288
 289     $process .= $line;
 290
 291     return $process;
 292 }
 293
 294 # Read all Makefiles to map the configs to the objects
 295 foreach my $makefile (@makefiles) {
 296
 297     my $line = "";
 298     my %make_vars;
 299
 300     open(my $infile, '<', $makefile) || die "Can't open $makefile";
 301     while (<$infile>) {
 302         # if this line ends with a backslash, continue
 303         chomp;
 304         if (/^(.*)\\$/) {
 305             $line .= $1;
 306             next;
 307         }
 308
 309         $line .= $_;
 310         $_ = $line;
 311         $line = "";
 312
 313         my $objs;
 314
 315         # Convert variables in a line (could define configs)
 316         $_ = convert_vars($_, %make_vars);
 317
 318         # collect objects after obj-$(CONFIG_FOO_BAR)
 319         if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
 320             $var = $1;
 321             $objs = $2;
 322
 323         # check if variables are set
 324         } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
 325             $make_vars{$1} = $2;
 326         }
 327         if (defined($objs)) {
 328             foreach my $obj (split /\s+/,$objs) {
 329                 $obj =~ s/-/_/g;
 330                 if ($obj =~ /(.*)\.o$/) {
 331                     # Objects may be enabled by more than one config.
 332                     # Store configs in an array.
 333                     my @arr;
 334
 335                     if (defined($objects{$1})) {
 336                         @arr = @{$objects{$1}};
 337                     }
 338
 339                     $arr[$#arr+1] = $var;
 340
 341                     # The objects have a hash mapping to a reference
 342                     # of an array of configs.
 343                     $objects{$1} = \@arr;
 344                 }
 345             }
 346         }
 347     }
 348     close($infile);
 349 }
 350
 351 my %modules;
 352 my $linfile;
 353
 354 if (defined($lsmod_file)) {
 355     if ( ! -f $lsmod_file) {
 356         if ( -f $ENV{'objtree'}."/".$lsmod_file) {
 357             $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
 358         } else {
 359                 die "$lsmod_file not found";
 360         }
 361     }
 362
 363     my $otype = ( -x $lsmod_file) ? '-|' : '<';
 364     open($linfile, $otype, $lsmod_file);
 365
 366 } else {
 367
 368     # see what modules are loaded on this system
 369     my $lsmod;
 370
 371     foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
 372         if ( -x "$dir/lsmod" ) {
 373             $lsmod = "$dir/lsmod";
 374             last;
 375         }
 376 }
 377     if (!defined($lsmod)) {
 378         # try just the path
 379         $lsmod = "lsmod";
 380     }
 381
 382     open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
 383 }
 384
 385 while (<$linfile>) {
 386         next if (/^Module/);  # Skip the first line.
 387         if (/^(\S+)/) {
 388                 $modules{$1} = 1;
 389         }
 390 }
 391 close ($linfile);
 392
 393 # add to the configs hash all configs that are needed to enable
 394 # a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
 395 # where we know we need bar.o so we add FOO to the list.
 396 my %configs;
 397 foreach my $module (keys(%modules)) {
 398     if (defined($objects{$module})) {
 399         my @arr = @{$objects{$module}};
 400         foreach my $conf (@arr) {
 401             $configs{$conf} = $module;
 402             dprint "$conf added by direct ($module)\n";
 403             if ($debugprint) {
 404                 my $c=$conf;
 405                 $c =~ s/^CONFIG_//;
 406                 if (defined($depends{$c})) {
 407                     dprint " deps = $depends{$c}\n";
 408                 } else {
 409                     dprint " no deps\n";
 410                 }
 411             }
 412         }
 413     } else {
 414         # Most likely, someone has a custom (binary?) module loaded.
 415         print STDERR "$module config not found!!\n";
 416     }
 417 }
 418
 419 # Read the current config, and see what is enabled. We want to
 420 # ignore configs that we would not enable anyway.
 421
 422 my %orig_configs;
 423 my $valid = "A-Za-z_0-9";
 424
 425 foreach my $line (@config_file) {
 426     $_ = $line;
 427
 428     if (/(CONFIG_[$valid]*)=(m|y)/) {
 429         $orig_configs{$1} = $2;
 430     }
 431 }
 432
 433 my $repeat = 1;
 434
 435 my $depconfig;
 436
 437 #
 438 # Note, we do not care about operands (like: &&, ||, !) we want to add any
 439 # config that is in the depend list of another config. This script does
 440 # not enable configs that are not already enabled. If we come across a
 441 # config A that depends on !B, we can still add B to the list of depends
 442 # to keep on. If A was on in the original config, B would not have been
 443 # and B would not be turned on by this script.
 444 #
 445 sub parse_config_depends
 446 {
 447     my ($p) = @_;
 448
 449     while ($p =~ /[$valid]/) {
 450
 451         if ($p =~ /^[^$valid]*([$valid]+)/) {
 452             my $conf = "CONFIG_" . $1;
 453
 454             $p =~ s/^[^$valid]*[$valid]+//;
 455
 456             # We only need to process if the depend config is a module
 457             if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
 458                 next;
 459             }
 460
 461             if (!defined($configs{$conf})) {
 462                 # We must make sure that this config has its
 463                 # dependencies met.
 464                 $repeat = 1; # do again
 465                 dprint "$conf selected by depend $depconfig\n";
 466                 $configs{$conf} = 1;
 467             }
 468         } else {
 469             die "this should never happen";
 470         }
 471     }
 472 }
 473
 474 # Select is treated a bit differently than depends. We call this
 475 # when a config has no prompt and requires another config to be
 476 # selected. We use to just select all configs that selected this
 477 # config, but found that that can balloon into enabling hundreds
 478 # of configs that we do not care about.
 479 #
 480 # The idea is we look at all the configs that select it. If one
 481 # is already in our list of configs to enable, then there's nothing
 482 # else to do. If there isn't, we pick the first config that was
 483 # enabled in the orignal config and use that.
 484 sub parse_config_selects
 485 {
 486     my ($config, $p) = @_;
 487
 488     my $next_config;
 489
 490     while ($p =~ /[$valid]/) {
 491
 492         if ($p =~ /^[^$valid]*([$valid]+)/) {
 493             my $conf = "CONFIG_" . $1;
 494
 495             $p =~ s/^[^$valid]*[$valid]+//;
 496
 497             # Make sure that this config exists in the current .config file
 498             if (!defined($orig_configs{$conf})) {
 499                 dprint "$conf not set for $config select\n";
 500                 next;
 501             }
 502
 503             # Check if something other than a module selects this config
 504             if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
 505                 dprint "$conf (non module) selects config, we are good\n";
 506                 # we are good with this
 507                 return;
 508             }
 509             if (defined($configs{$conf})) {
 510                 dprint "$conf selects $config so we are good\n";
 511                 # A set config selects this config, we are good
 512                 return;
 513             }
 514             # Set this config to be selected
 515             if (!defined($next_config)) {
 516                 $next_config = $conf;
 517             }
 518         } else {
 519             die "this should never happen";
 520         }
 521     }
 522
 523     # If no possible config selected this, then something happened.
 524     if (!defined($next_config)) {
 525         print STDERR "WARNING: $config is required, but nothing in the\n";
 526         print STDERR "  current config selects it.\n";
 527         return;
 528     }
 529
 530     # If we are here, then we found no config that is set and
 531     # selects this config. Repeat.
 532     $repeat = 1;
 533     # Make this config need to be selected
 534     $configs{$next_config} = 1;
 535     dprint "$next_config selected by select $config\n";
 536 }
 537
 538 my %process_selects;
 539
 540 # loop through all configs, select their dependencies.
 541 sub loop_depend {
 542     $repeat = 1;
 543
 544     while ($repeat) {
 545         $repeat = 0;
 546
 547       forloop:
 548         foreach my $config (keys %configs) {
 549
 550             # If this config is not a module, we do not need to process it
 551             if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
 552                 next forloop;
 553             }
 554
 555             $config =~ s/^CONFIG_//;
 556             $depconfig = $config;
 557
 558             if (defined($depends{$config})) {
 559                 # This config has dependencies. Make sure they are also included
 560                 parse_config_depends $depends{$config};
 561             }
 562
 563             # If the config has no prompt, then we need to check if a config
 564             # that is enabled selected it. Or if we need to enable one.
 565             if (!defined($prompts{$config}) && defined($selects{$config})) {
 566                 $process_selects{$config} = 1;
 567             }
 568         }
 569     }
 570 }
 571
 572 sub loop_select {
 573
 574     foreach my $config (keys %process_selects) {
 575         $config =~ s/^CONFIG_//;
 576
 577         dprint "Process select $config\n";
 578
 579         # config has no prompt and must be selected.
 580         parse_config_selects $config, $selects{$config};
 581     }
 582 }
 583
 584 while ($repeat) {
 585     # Get the first set of configs and their dependencies.
 586     loop_depend;
 587
 588     $repeat = 0;
 589
 590     # Now we need to see if we have to check selects;
 591     loop_select;
 592 }
 593
 594 my %setconfigs;
 595
 596 # Finally, read the .config file and turn off any module enabled that
 597 # we could not find a reason to keep enabled.
 598 foreach my $line (@config_file) {
 599     $_ = $line;
 600
 601     if (/CONFIG_IKCONFIG/) {
 602         if (/# CONFIG_IKCONFIG is not set/) {
 603             # enable IKCONFIG at least as a module
 604             print "CONFIG_IKCONFIG=m\n";
 605             # don't ask about PROC
 606             print "# CONFIG_IKCONFIG_PROC is not set\n";
 607         } else {
 608             print;
 609         }
 610         next;
 611     }
 612
 613     if (/^(CONFIG.*)=(m|y)/) {
 614         if (defined($configs{$1})) {
 615             if ($localyesconfig) {
 616                 $setconfigs{$1} = 'y';
 617                 print "$1=y\n";
 618                 next;
 619             } else {
 620                 $setconfigs{$1} = $2;
 621             }
 622         } elsif ($2 eq "m") {
 623             print "# $1 is not set\n";
 624             next;
 625         }
 626     }
 627     print;
 628 }
 629
 630 # Integrity check, make sure all modules that we want enabled do
 631 # indeed have their configs set.
 632 loop:
 633 foreach my $module (keys(%modules)) {
 634     if (defined($objects{$module})) {
 635         my @arr = @{$objects{$module}};
 636         foreach my $conf (@arr) {
 637             if (defined($setconfigs{$conf})) {
 638                 next loop;
 639             }
 640         }
 641         print STDERR "module $module did not have configs";
 642         foreach my $conf (@arr) {
 643             print STDERR " " , $conf;
 644         }
 645         print STDERR "\n";
 646     }
 647 }