config/firewall/rules.pl

   1 #!/usr/bin/perl -w
   2 ###############################################################################
   3 #                                                                             #
   4 # IPFire.org - A linux based firewall                                         #
   5 # Copyright (C) 2007-2020  IPFire Team  <info@ipfire.org>                     #
   6 #                                                                             #
   7 # This program is free software: you can redistribute it and/or modify        #
   8 # it under the terms of the GNU General Public License as published by        #
   9 # the Free Software Foundation, either version 3 of the License, or           #
  10 # (at your option) any later version.                                         #
  11 #                                                                             #
  12 # This program is distributed in the hope that it will be useful,             #
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  15 # GNU General Public License for more details.                                #
  16 #                                                                             #
  17 # You should have received a copy of the GNU General Public License           #
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  19 #                                                                             #
  20 ###############################################################################
  21
  22 use strict;
  23 use experimental 'smartmatch';
  24
  25 require '/var/ipfire/general-functions.pl';
  26 require "${General::swroot}/lang.pl";
  27 require "/usr/lib/firewall/firewall-lib.pl";
  28 require "${General::swroot}/location-functions.pl";
  29 require "${General::swroot}/ipblocklist-functions.pl";
  30
  31 # Set to one to enable debugging mode.
  32 my $DEBUG = 0;
  33
  34 my $IPTABLES = "iptables --wait";
  35 my $IPSET = "ipset";
  36
  37 # iptables chains
  38 my $CHAIN_INPUT           = "INPUTFW";
  39 my $CHAIN_FORWARD         = "FORWARDFW";
  40 my $CHAIN_OUTPUT          = "OUTGOINGFW";
  41 my $CHAIN                 = $CHAIN_FORWARD;
  42 my $CHAIN_NAT_SOURCE      = "NAT_SOURCE";
  43 my $CHAIN_NAT_DESTINATION = "NAT_DESTINATION";
  44 my $CHAIN_MANGLE_NAT_DESTINATION_FIX = "NAT_DESTINATION";
  45 my @VALID_CHAINS          = ($CHAIN_INPUT, $CHAIN_FORWARD, $CHAIN_OUTPUT);
  46 my @ANY_ADDRESSES         = ("0.0.0.0/0.0.0.0", "0.0.0.0/0", "0/0");
  47
  48 my @PROTOCOLS = ("tcp", "udp", "icmp", "igmp", "ah", "esp", "gre", "ipv6", "ipip");
  49 my @PROTOCOLS_WITH_PORTS = ("tcp", "udp");
  50
  51 my @VALID_TARGETS = ("ACCEPT", "DROP", "REJECT");
  52
  53 my @PRIVATE_NETWORKS = (
  54         "10.0.0.0/8",
  55         "172.16.0.0/12",
  56         "192.168.0.0/16",
  57         "100.64.0.0/10",
  58 );
  59
  60 # MARK masks
  61 my $NAT_MASK = 0x0f000000;
  62
  63 # Country code, which is used to mark hostile networks.
  64 my $HOSTILE_CCODE = "XD";
  65
  66 my %fwdfwsettings=();
  67 my %fwoptions = ();
  68 my %defaultNetworks=();
  69 my %configfwdfw=();;
  70 my %customgrp=();
  71 my %configinputfw=();
  72 my %configoutgoingfw=();
  73 my %confignatfw=();
  74 my %locationsettings = (
  75         "LOCATIONBLOCK_ENABLED" => "off"
  76 );
  77 my %blocklistsettings= (
  78         "ENABLE" => "off",
  79 );
  80
  81 my %ipset_loaded_sets = ();
  82 my @ipset_used_sets = ();
  83
  84 my $configfwdfw         = "${General::swroot}/firewall/config";
  85 my $configinput     = "${General::swroot}/firewall/input";
  86 my $configoutgoing  = "${General::swroot}/firewall/outgoing";
  87 my $locationfile                = "${General::swroot}/firewall/locationblock";
  88 my $configgrp           = "${General::swroot}/fwhosts/customgroups";
  89 my $netsettings         = "${General::swroot}/ethernet/settings";
  90 my $blocklistfile   = "${General::swroot}/ipblocklist/settings";
  91
  92 &General::readhash("${General::swroot}/firewall/settings", \%fwdfwsettings);
  93 &General::readhash("${General::swroot}/optionsfw/settings", \%fwoptions);
  94 &General::readhash("$netsettings", \%defaultNetworks);
  95 &General::readhasharray($configfwdfw, \%configfwdfw);
  96 &General::readhasharray($configinput, \%configinputfw);
  97 &General::readhasharray($configoutgoing, \%configoutgoingfw);
  98 &General::readhasharray($configgrp, \%customgrp);
  99
 100 # Check if the location settings file exists
 101 if (-e "$locationfile") {
 102         # Read settings file
 103         &General::readhash("$locationfile", \%locationsettings);
 104 }
 105
 106 # Check if the ipblocklist settings file exits.
 107 if (-e "$blocklistfile") {
 108         # Read-in settings file.
 109         &General::readhash("$blocklistfile", \%blocklistsettings);
 110 }
 111
 112 # Get all available locations.
 113 my @locations = &Location::Functions::get_locations();
 114
 115 # Get all supported blocklists.
 116 my @blocklists = &IPblocklist::get_blocklists();
 117
 118 # Name or the RED interface.
 119 my $RED_DEV = &General::get_red_interface();
 120
 121 my @log_limit_options = &make_log_limit_options();
 122
 123 my $POLICY_INPUT_ALLOWED   = 0;
 124 my $POLICY_FORWARD_ALLOWED = ($fwdfwsettings{"POLICY"} eq "MODE2");
 125 my $POLICY_OUTPUT_ALLOWED  = ($fwdfwsettings{"POLICY1"} eq "MODE2");
 126
 127 my $POLICY_INPUT_ACTION    = $fwoptions{"FWPOLICY2"};
 128 my $POLICY_FORWARD_ACTION  = $fwoptions{"FWPOLICY"};
 129 my $POLICY_OUTPUT_ACTION   = $fwoptions{"FWPOLICY1"};
 130
 131 #workaround to suppress a warning when a variable is used only once
 132 my @dummy = ( $Location::Functions::ipset_db_directory );
 133 undef (@dummy);
 134
 135 # MAIN
 136 &main();
 137
 138 sub main {
 139         # Get currently used ipset sets.
 140         @ipset_used_sets = &ipset_get_sets();
 141
 142         # Flush all chains.
 143         &flush();
 144
 145         # Prepare firewall rules.
 146         if (! -z  "${General::swroot}/firewall/input"){
 147                 &buildrules(\%configinputfw);
 148         }
 149         if (! -z  "${General::swroot}/firewall/outgoing"){
 150                 &buildrules(\%configoutgoingfw);
 151         }
 152         if (! -z  "${General::swroot}/firewall/config"){
 153                 &buildrules(\%configfwdfw);
 154         }
 155
 156         # Load Location block rules.
 157         &locationblock();
 158
 159         # Load rules to block hostile networks.
 160         &drop_hostile_networks();
 161
 162         # Handle ipblocklist.
 163         &ipblocklist();
 164
 165         # Reload firewall policy.
 166         run("/usr/sbin/firewall-policy");
 167
 168         # Cleanup not longer needed ipset sets.
 169         &ipset_cleanup();
 170
 171         #Reload firewall.local if present
 172         if ( -f '/etc/sysconfig/firewall.local'){
 173                 run("/etc/sysconfig/firewall.local reload");
 174         }
 175 }
 176
 177 sub run {
 178         # Executes or prints the given shell command.
 179         my $command = shift;
 180
 181         if ($DEBUG) {
 182                 print "$command\n";
 183         } else {
 184                 system "$command";
 185
 186                 if ($?) {
 187                         print_error("ERROR: $command");
 188                 }
 189         }
 190 }
 191
 192 sub print_error {
 193         my $message = shift;
 194
 195         print STDERR "$message\n";
 196 }
 197
 198 sub print_rule {
 199         my $hash = shift;
 200
 201         print "\nRULE:";
 202
 203         my $i = 0;
 204         foreach (@$hash) {
 205                 printf("  %2d: %s", $i++, $_);
 206         }
 207         print "\n";
 208 }
 209
 210 sub count_elements {
 211         my $hash = shift;
 212
 213         return scalar @$hash;
 214 }
 215
 216 sub flush {
 217         run("$IPTABLES -F $CHAIN_INPUT");
 218         run("$IPTABLES -F $CHAIN_FORWARD");
 219         run("$IPTABLES -F $CHAIN_OUTPUT");
 220         run("$IPTABLES -t nat -F $CHAIN_NAT_SOURCE");
 221         run("$IPTABLES -t nat -F $CHAIN_NAT_DESTINATION");
 222         run("$IPTABLES -t mangle -F $CHAIN_MANGLE_NAT_DESTINATION_FIX");
 223 }
 224
 225 sub buildrules {
 226         my $hash = shift;
 227
 228         # Search for targets that need to be specially handled when adding
 229         # forwarding rules. Additional rules will automatically get inserted
 230         # into the INPUT/OUTPUT chains for these targets.
 231         my @special_input_targets = ();
 232         if (!$POLICY_FORWARD_ALLOWED) {
 233                 push(@special_input_targets, "ACCEPT");
 234         }
 235
 236         if ($POLICY_INPUT_ACTION eq "DROP") {
 237                 push(@special_input_targets, ("ACCEPT", "REJECT"));
 238         } elsif ($POLICY_INPUT_ACTION eq "REJECT") {
 239                 push(@special_input_targets, ("ACCEPT", "DROP"));
 240         }
 241
 242         my @special_output_targets = ();
 243         if ($POLICY_OUTPUT_ALLOWED) {
 244                 push(@special_output_targets, ("DROP", "REJECT"));
 245         } else {
 246                 push(@special_output_targets, "ACCEPT");
 247
 248                 if ($POLICY_OUTPUT_ACTION eq "DROP") {
 249                         push(@special_output_targets, ("ACCEPT", "REJECT"));
 250                 } elsif ($POLICY_OUTPUT_ACTION eq "REJECT") {
 251                         push(@special_output_targets, ("ACCEPT", "DROP"));
 252                 }
 253         }
 254
 255         foreach my $key (sort {$a <=> $b} keys %$hash) {
 256                 # Skip disabled rules.
 257                 next unless ($$hash{$key}[2] eq 'ON');
 258
 259                 # Count number of elements in this line
 260                 my $elements = &count_elements($$hash{$key});
 261
 262                 if ($DEBUG) {
 263                         print_rule($$hash{$key});
 264                 }
 265
 266                 # Check if the target is valid.
 267                 my $target = $$hash{$key}[0];
 268                 if (!$target ~~ @VALID_TARGETS) {
 269                         print_error("Invalid target '$target' for rule $key");
 270                         next;
 271                 }
 272
 273                 # Check if the chain is valid.
 274                 my $chain = $$hash{$key}[1];
 275                 if (!$chain ~~ @VALID_CHAINS) {
 276                         print_error("Invalid chain '$chain' in rule $key");
 277                         next;
 278                 }
 279
 280                 # Collect all sources.
 281                 my @sources = &fwlib::get_addresses($hash, $key, "src");
 282
 283                 # Collect all destinations.
 284                 my @destinations = &fwlib::get_addresses($hash, $key, "tgt");
 285
 286                 # True if the destination is the firewall itself.
 287                 my $destination_is_firewall = ($$hash{$key}[5] eq "ipfire");
 288
 289                 # Check if logging should be enabled.
 290                 my $LOG = ($$hash{$key}[17] eq 'ON');
 291
 292                 # Check if NAT is enabled and initialize variables, that we use for that.
 293                 my $NAT = ($$hash{$key}[28] eq 'ON');
 294                 my $NAT_MODE;
 295                 if ($NAT) {
 296                         $NAT_MODE = uc($$hash{$key}[31]);
 297                 }
 298
 299                 # Set up time constraints.
 300                 my @time_options = ();
 301                 if ($$hash{$key}[18] eq 'ON') {
 302                         push(@time_options, ("-m", "time"));
 303
 304                         # Select all days of the week this match is active.
 305                         my @weekdays = ();
 306                         if ($$hash{$key}[19] ne '') {
 307                                 push (@weekdays, "Mon");
 308                         }
 309                         if ($$hash{$key}[20] ne '') {
 310                                 push (@weekdays, "Tue");
 311                         }
 312                         if ($$hash{$key}[21] ne '') {
 313                                 push (@weekdays, "Wed");
 314                         }
 315                         if ($$hash{$key}[22] ne '') {
 316                                 push (@weekdays, "Thu");
 317                         }
 318                         if ($$hash{$key}[23] ne '') {
 319                                 push (@weekdays, "Fri");
 320                         }
 321                         if ($$hash{$key}[24] ne '') {
 322                                 push (@weekdays, "Sat");
 323                         }
 324                         if ($$hash{$key}[25] ne '') {
 325                                 push (@weekdays, "Sun");
 326                         }
 327                         if (@weekdays) {
 328                                 push(@time_options, ("--weekdays", join(",", @weekdays)));
 329                         }
 330
 331                         # Convert start time.
 332                         my $time_start = &format_time($$hash{$key}[26]);
 333                         if ($time_start) {
 334                                 push(@time_options, ("--timestart", $time_start));
 335                         }
 336
 337                         # Convert end time.
 338                         my $time_stop = &format_time($$hash{$key}[27]);
 339                         if ($time_stop) {
 340                                 push(@time_options, ("--timestop", $time_stop));
 341                         }
 342                 }
 343
 344                 # Concurrent connection limit
 345                 my @ratelimit_options = ();
 346
 347                 if (($elements ge 34) && ($$hash{$key}[32] eq 'ON')) {
 348                         my $conn_limit = $$hash{$key}[33];
 349
 350                         if ($conn_limit ge 1) {
 351                                 push(@ratelimit_options, ("-m", "connlimit"));
 352
 353                                 # Use the the entire source IP address
 354                                 push(@ratelimit_options, "--connlimit-saddr");
 355                                 push(@ratelimit_options, ("--connlimit-mask", "32"));
 356
 357                                 # Apply the limit
 358                                 push(@ratelimit_options, ("--connlimit-upto", $conn_limit));
 359                         }
 360                 }
 361
 362                 # Ratelimit
 363                 if (($elements ge 37) && ($$hash{$key}[34] eq 'ON')) {
 364                         my $rate_limit = "$$hash{$key}[35]/$$hash{$key}[36]";
 365
 366                         if ($rate_limit) {
 367                                 push(@ratelimit_options, ("-m", "limit"));
 368                                 push(@ratelimit_options, ("--limit", $rate_limit));
 369                         }
 370                 }
 371
 372                 # Check which protocols are used in this rule and so that we can
 373                 # later group rules by protocols.
 374                 my @protocols = &get_protocols($hash, $key);
 375                 if (!@protocols) {
 376                         print_error("Invalid protocol configuration for rule $key");
 377                         next;
 378                 }
 379
 380                 foreach my $protocol (@protocols) {
 381                         # Check if the given protocol is supported.
 382                         if (($protocol ne "all") && (!$protocol ~~ @PROTOCOLS)) {
 383                                 print_error("Protocol $protocol is not supported (rule $key)");
 384                                 next;
 385                         }
 386
 387                         # Prepare protocol options (like ICMP types, ports, etc...).
 388                         my @protocol_options = &get_protocol_options($hash, $key, $protocol, 0);
 389
 390                         # Check if this protocol knows ports.
 391                         my $protocol_has_ports = ($protocol ~~ @PROTOCOLS_WITH_PORTS);
 392
 393                         foreach my $src (@sources) {
 394                                 # Skip invalid source.
 395                                 next unless (defined $src);
 396                                 next unless ($src);
 397
 398                                 # Sanitize source.
 399                                 my $source = @$src[0];
 400                                 if ($source ~~ @ANY_ADDRESSES) {
 401                                         $source = "";
 402                                 }
 403
 404                                 my $source_intf = @$src[1];
 405
 406                                 foreach my $dst (@destinations) {
 407                                         # Skip invalid rules.
 408                                         next unless (defined $dst);
 409                                         next if (!$dst || ($dst eq "none"));
 410
 411                                         # Sanitize destination.
 412                                         my $destination = @$dst[0];
 413                                         if ($destination ~~ @ANY_ADDRESSES) {
 414                                                 $destination = "";
 415                                         }
 416
 417                                         my $destination_intf = @$dst[1];
 418
 419                                         # Array with iptables arguments.
 420                                         my @options = ();
 421
 422                                         # Append protocol.
 423                                         if ($protocol ne "all") {
 424                                                 push(@options, @protocol_options);
 425                                         }
 426
 427                                         # Prepare source options.
 428                                         my @source_options = ();
 429                                         if ($source =~ /mac/) {
 430                                                 push(@source_options, $source);
 431                                         } elsif ($source =~ /-m set/) {
 432                                                 # Split given arguments into single chunks to
 433                                                 # obtain the set name.
 434                                                 my ($a, $b, $c, $loc_src, $e) = split(/ /, $source);
 435
 436                                                 # Call function to load the networks list for this country.
 437                                                 &ipset_restore($loc_src);
 438
 439                                                 push(@source_options, $source);
 440                                         } elsif($source) {
 441                                                 push(@source_options, ("-s", $source));
 442                                         }
 443
 444                                         # Prepare destination options.
 445                                         my @destination_options = ();
 446                                         if ($destination =~ /-m set/) {
 447                                                 # Split given arguments into single chunks to
 448                                                 # obtain the set name.
 449                                                 my ($a, $b, $c, $loc_dst, $e) = split(/ /, $destination);
 450
 451                                                 # Call function to load the networks list for this country.
 452                                                 &ipset_restore($loc_dst);
 453
 454                                                 push(@destination_options,  $destination);
 455                                         } elsif ($destination) {
 456                                                 push(@destination_options, ("-d", $destination));
 457                                         }
 458
 459                                         # Add source and destination interface to the filter rules.
 460                                         # These are supposed to help filtering forged packets that originate
 461                                         # from BLUE with an IP address from GREEN for instance.
 462                                         my @source_intf_options = ();
 463                                         if ($source_intf) {
 464                                                 push(@source_intf_options, ("-i", $source_intf));
 465                                         }
 466
 467                                         my @destination_intf_options = ();
 468                                         if ($destination_intf) {
 469                                                 push(@destination_intf_options, ("-o", $destination_intf));
 470                                         }
 471
 472                                         # Add time constraint options.
 473                                         push(@options, @time_options);
 474
 475                                         # Add ratelimiting option
 476                                         push(@options, @ratelimit_options);
 477
 478                                         my $firewall_is_in_source_subnet = 1;
 479                                         if ($source) {
 480                                                 $firewall_is_in_source_subnet = &firewall_is_in_subnet($source);
 481                                         }
 482
 483                                         my $firewall_is_in_destination_subnet = 1;
 484                                         if ($destination) {
 485                                                 $firewall_is_in_destination_subnet = &firewall_is_in_subnet($destination);
 486                                         }
 487
 488                                         # Process NAT rules.
 489                                         if ($NAT) {
 490                                                 my $nat_address = &fwlib::get_nat_address($$hash{$key}[29], $source);
 491
 492                                                 # Skip NAT rules if the NAT address is unknown
 493                                                 # (i.e. no internet connection has been established, yet).
 494                                                 next unless ($nat_address);
 495
 496                                                 # Destination NAT
 497                                                 if ($NAT_MODE eq "DNAT") {
 498                                                         my @nat_options = ();
 499                                                         if ($protocol ne "all") {
 500                                                                 my @nat_protocol_options = &get_protocol_options($hash, $key, $protocol, 1);
 501                                                                 push(@nat_options, @nat_protocol_options);
 502                                                         }
 503
 504                                                         # Add time options.
 505                                                         push(@nat_options, @time_options);
 506
 507                                                         # Determine if a REDIRECT rule should be created.
 508                                                         my $use_redirect = ($destination_is_firewall && !$destination && $protocol_has_ports);
 509
 510                                                         # Make port-forwardings useable from the internal networks.
 511                                                         if (!$use_redirect) {
 512                                                                 my @internal_addresses = &fwlib::get_internal_firewall_ip_addresses(1);
 513                                                                 unless ($nat_address ~~ @internal_addresses) {
 514                                                                         &add_dnat_mangle_rules($nat_address, $source_intf, @nat_options);
 515                                                                 }
 516                                                         }
 517
 518                                                         # Add source options.
 519                                                         push(@nat_options, @source_options);
 520
 521                                                         # Add NAT address.
 522                                                         if (!$use_redirect) {
 523                                                                 push(@nat_options, ("-d", $nat_address));
 524                                                         }
 525
 526                                                         my $dnat_port;
 527                                                         if ($protocol_has_ports) {
 528                                                                 $dnat_port = &get_dnat_target_port($hash, $key);
 529                                                         }
 530
 531                                                         my @nat_action_options = ();
 532
 533                                                         # Use iptables REDIRECT
 534                                                         if ($use_redirect) {
 535                                                                 push(@nat_action_options, ("-j", "REDIRECT"));
 536
 537                                                                 # Redirect to specified port if one has given.
 538                                                                 if ($dnat_port) {
 539                                                                         push(@nat_action_options, ("--to-ports", $dnat_port));
 540                                                                 }
 541
 542                                                         # Use iptables DNAT
 543                                                         } else {
 544                                                                 if ($destination_is_firewall && !$destination) {
 545                                                                         $destination = &fwlib::get_external_address();
 546                                                                 }
 547                                                                 next unless ($destination);
 548
 549                                                                 my ($dnat_address, $dnat_mask) = split("/", $destination);
 550                                                                 @destination_options = ("-d", $dnat_address);
 551
 552                                                                 if ($protocol_has_ports) {
 553                                                                         my $dnat_port = &get_dnat_target_port($hash, $key);
 554
 555                                                                         if ($dnat_port) {
 556                                                                                 $dnat_address .= ":$dnat_port";
 557                                                                         }
 558                                                                 }
 559
 560                                                                 push(@nat_action_options, ("-j", "DNAT", "--to-destination", $dnat_address));
 561                                                         }
 562
 563                                                         if ($LOG) {
 564                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @log_limit_options -j LOG --log-prefix 'DNAT '");
 565                                                         }
 566                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @nat_action_options");
 567
 568                                                 # Source NAT
 569                                                 } elsif ($NAT_MODE eq "SNAT") {
 570                                                         my @snat_options = ( "-m", "policy", "--dir", "out", "--pol", "none" );
 571                                                         my @nat_options = @options;
 572
 573                                                         # Get addresses for the configured firewall interfaces.
 574                                                         my @local_addresses = &fwlib::get_internal_firewall_ip_addresses(1);
 575
 576                                                         # Check if the nat_address is one of the local addresses.
 577                                                         foreach my $local_address (@local_addresses) {
 578                                                                 if ($nat_address eq $local_address) {
 579                                                                         # Clear SNAT options.
 580                                                                         @snat_options = ();
 581
 582                                                                         # Finish loop.
 583                                                                         last;
 584                                                                 }
 585                                                         }
 586
 587                                                         push(@nat_options, @destination_intf_options);
 588                                                         push(@nat_options, @source_options);
 589                                                         push(@nat_options, @destination_options);
 590
 591                                                         if ($LOG) {
 592                                                                 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @snat_options @log_limit_options -j LOG --log-prefix 'SNAT '");
 593                                                         }
 594                                                         run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @snat_options -j SNAT --to-source $nat_address");
 595                                                 }
 596                                         }
 597
 598                                         push(@options, @source_options);
 599                                         push(@options, @destination_options);
 600
 601                                         # Insert firewall rule.
 602                                         if ($LOG) {
 603                                                 run("$IPTABLES -A $chain @options @source_intf_options @destination_intf_options @log_limit_options -j LOG --log-prefix '$chain '");
 604                                         }
 605                                         run("$IPTABLES -A $chain @options @source_intf_options @destination_intf_options -j $target");
 606
 607                                         # Handle forwarding rules and add corresponding rules for firewall access.
 608                                         if ($chain eq $CHAIN_FORWARD) {
 609                                                 # If the firewall is part of the destination subnet and access to the destination network
 610                                                 # is granted/forbidden for any network that the firewall itself is part of, we grant/forbid access
 611                                                 # for the firewall, too.
 612                                                 if ($firewall_is_in_destination_subnet && ($target ~~ @special_input_targets)) {
 613                                                         if ($LOG) {
 614                                                                 run("$IPTABLES -A $CHAIN_INPUT @options @source_intf_options @log_limit_options -j LOG --log-prefix '$CHAIN_INPUT '");
 615                                                         }
 616                                                         run("$IPTABLES -A $CHAIN_INPUT @options @source_intf_options -j $target");
 617                                                 }
 618
 619                                                 # Likewise.
 620                                                 if ($firewall_is_in_source_subnet && ($target ~~ @special_output_targets)) {
 621                                                         if ($LOG) {
 622                                                                 run("$IPTABLES -A $CHAIN_OUTPUT @options @destination_intf_options @log_limit_options -j LOG --log-prefix '$CHAIN_OUTPUT '");
 623                                                         }
 624                                                         run("$IPTABLES -A $CHAIN_OUTPUT @options @destination_intf_options -j $target");
 625                                                 }
 626                                         }
 627                                 }
 628                         }
 629                 }
 630         }
 631 }
 632
 633 # Formats the given timestamp into the iptables format which is "hh:mm" UTC.
 634 sub format_time {
 635         my $val = shift;
 636
 637         # Convert the given time into minutes.
 638         my $minutes = &time_convert_to_minutes($val);
 639
 640         # Move the timestamp into UTC.
 641         $minutes += &time_utc_offset();
 642
 643         # Make sure $minutes is between 00:00 and 23:59.
 644         if ($minutes < 0) {
 645                 $minutes += 1440;
 646         }
 647
 648         if ($minutes > 1440) {
 649                 $minutes -= 1440;
 650         }
 651
 652         # Format as hh:mm.
 653         return sprintf("%02d:%02d", $minutes / 60, $minutes % 60);
 654 }
 655
 656 # Calculates the offsets in minutes from the local timezone to UTC.
 657 sub time_utc_offset {
 658         my @localtime = localtime(time);
 659         my @gmtime = gmtime(time);
 660
 661         return ($gmtime[2] * 60 + $gmtime[1] % 60) - ($localtime[2] * 60 + $localtime[1] % 60);
 662 }
 663
 664 # Takes a timestamp like "14:00" and converts it into minutes since midnight.
 665 sub time_convert_to_minutes {
 666         my ($hrs, $min) = split(":", shift);
 667
 668         return ($hrs * 60) + $min;
 669 }
 670
 671 sub locationblock {
 672         # Flush LOCATIONBLOCK chain.
 673         run("$IPTABLES -F LOCATIONBLOCK");
 674
 675         # If location blocking is not enabled, we are finished here.
 676         if ($locationsettings{'LOCATIONBLOCK_ENABLED'} ne "on") {
 677                 # Exit submodule. Process remaining script.
 678                 return;
 679         }
 680
 681         # Only check the RED interface, which is ppp0 in case of RED_TYPE being
 682         # set to "PPPOE", and red0 in case of RED_TYPE not being empty otherwise.
 683         if ($defaultNetworks{'RED_TYPE'} eq "PPPOE") {
 684                 run("$IPTABLES -A LOCATIONBLOCK ! -i ppp0 -j RETURN");
 685         } elsif ($defaultNetworks{'RED_DEV'} ne "") {
 686                 run("$IPTABLES -A LOCATIONBLOCK ! -i $defaultNetworks{'RED_DEV'} -j RETURN");
 687         }
 688
 689         # Do not check any private address space
 690         foreach my $network (@PRIVATE_NETWORKS) {
 691                 run("$IPTABLES -A LOCATIONBLOCK -s $network -j RETURN");
 692         }
 693
 694         # Loop through all supported locations and
 695         # create iptables rules, if blocking for this country
 696         # is enabled.
 697         foreach my $location (@locations) {
 698                 if(exists $locationsettings{$location} && $locationsettings{$location} eq "on") {
 699                         # Call function to load the networks list for this country.
 700                         &ipset_restore($location);
 701
 702                         # Call iptables and create rule to use the loaded ipset list.
 703                         run("$IPTABLES -A LOCATIONBLOCK -m set --match-set $location src -j DROP");
 704                 }
 705         }
 706 }
 707
 708 sub drop_hostile_networks () {
 709         # Flush the HOSTILE firewall chain.
 710         run("$IPTABLES -F HOSTILE");
 711
 712         # If dropping hostile networks is not enabled, we are finished here.
 713         if ($fwoptions{'DROPHOSTILE'} ne "on") {
 714                 # Exit function.
 715                 return;
 716         }
 717
 718         # Exit if there is no red interface.
 719         return unless($RED_DEV);
 720
 721         # Call function to load the network list of hostile networks.
 722         &ipset_restore($HOSTILE_CCODE);
 723
 724         # Check traffic in incoming/outgoing direction and drop if it matches
 725         run("$IPTABLES -A HOSTILE -i $RED_DEV -m set --match-set $HOSTILE_CCODE src -j HOSTILE_DROP");
 726         run("$IPTABLES -A HOSTILE -o $RED_DEV -m set --match-set $HOSTILE_CCODE dst -j HOSTILE_DROP");
 727 }
 728
 729 sub ipblocklist () {
 730         # Flush the ipblocklist chains.
 731         run("$IPTABLES -F BLOCKLISTIN");
 732         run("$IPTABLES -F BLOCKLISTOUT");
 733
 734         # Loop through the array of blocklists.
 735         foreach my $blocklist (@blocklists) {
 736                 # Check if the blocklist feature and the current processed blocklist is enabled.
 737                 if(($blocklistsettings{'ENABLE'} eq "on") && ($blocklistsettings{$blocklist}) && ($blocklistsettings{$blocklist} eq "on")) {
 738                         # Call function to load the blocklist.
 739                         &ipset_restore($blocklist);
 740
 741                         # Call function to check if the corresponding iptables drop chain already has been created.
 742                         if(&firewall_chain_exists("${blocklist}_DROP")) {
 743                                 # Create iptables chain.
 744                                 run("$IPTABLES -N ${blocklist}_DROP");
 745
 746                                 # Check if logging is enabled.
 747                                 if($blocklistsettings{'LOGGING'} eq "on") {
 748                                         # Create logging rule.
 749                                         run("$IPTABLES -A ${blocklist}_DROP -j LOG -m limit --limit 10/second --log-prefix \"BLKLST_$blocklist\" ");
 750                                 }
 751
 752                                 # Create Drop rule.
 753                                 run("$IPTABLES -A ${blocklist}_DROP -j DROP");
 754                         }
 755
 756                         # Add the rules to check against the set
 757                         run("$IPTABLES -A BLOCKLISTIN -p ALL -i $RED_DEV -m set --match-set $blocklist src -j ${blocklist}_DROP");
 758                         run("$IPTABLES -A BLOCKLISTOUT -p ALL -o $RED_DEV -m set --match-set $blocklist dst -j ${blocklist}_DROP");
 759
 760                 # IP blocklist or the blocklist is disabled.
 761                 } else {
 762                         # Check if the blocklist related iptables drop chain exits.
 763                         unless(&firewall_chain_exists("${blocklist}_DROP")) {
 764                                 # Flush the chain.
 765                                 run("$IPTABLES -F ${blocklist}_DROP");
 766
 767                                 # Drop the chain.
 768                                 run("$IPTABLES -X ${blocklist}_DROP");
 769                         }
 770                 }
 771         }
 772 }
 773
 774 sub get_protocols {
 775         my $hash = shift;
 776         my $key = shift;
 777
 778         my $uses_source_ports = ($$hash{$key}[7] eq "ON");
 779         my $uses_services = ($$hash{$key}[11] eq "ON");
 780
 781         my @protocols = ();
 782
 783         # Rules which don't have source ports or services (like ICMP, ESP, ...).
 784         if (!$uses_source_ports && !$uses_services) {
 785                 push(@protocols, $$hash{$key}[8]);
 786
 787         # Rules which either use ports or services.
 788         } elsif ($uses_source_ports || $uses_services) {
 789                 # Check if service group or service
 790                 if ($$hash{$key}[14] eq 'cust_srv') {
 791                         push(@protocols, &fwlib::get_srv_prot($$hash{$key}[15]));
 792
 793                 } elsif($$hash{$key}[14] eq 'cust_srvgrp'){
 794                         my $protos = &fwlib::get_srvgrp_prot($$hash{$key}[15]);
 795                         push(@protocols, split(",", $protos));
 796
 797                 } else {
 798                         # Fetch the protocol for this rule.
 799                         my $protocol = lc($$hash{$key}[8]);
 800
 801                         # Fetch source and destination ports for this rule.
 802                         my $source_ports = $$hash{$key}[10];
 803                         my $destination_ports = $$hash{$key}[15];
 804
 805                         # Check if ports are set for protocols which do not support ports.
 806                         if (!($protocol ~~ @PROTOCOLS_WITH_PORTS) && ($source_ports || $destination_ports)) {
 807                                 print_error("$protocol does not support ports");
 808                                 return ();
 809                         }
 810
 811                         push(@protocols, $protocol);
 812                 }
 813         }
 814
 815         # Remove all empty elements
 816         @protocols = map { $_ ? $_ : () } @protocols;
 817
 818         # If no protocol has been defined, we assume "all".
 819         if (!@protocols) {
 820                 push(@protocols, "all");
 821         }
 822
 823         # Make all protocol names lowercase.
 824         @protocols = map { lc } @protocols;
 825
 826         return @protocols;
 827 }
 828
 829 sub get_protocol_options {
 830         my $hash = shift;
 831         my $key  = shift;
 832         my $protocol = shift;
 833         my $nat_options_wanted = shift;
 834         my @options = ();
 835
 836         # Nothing to do if no protocol is specified.
 837         if ($protocol eq "all") {
 838                 return @options;
 839         } else {
 840                 push(@options, ("-p", $protocol));
 841         }
 842
 843         if ($protocol ~~ @PROTOCOLS_WITH_PORTS) {
 844                 # Process source ports.
 845                 my $use_src_ports = ($$hash{$key}[7] eq "ON");
 846                 my $src_ports     = $$hash{$key}[10];
 847
 848                 if ($use_src_ports && $src_ports) {
 849                         push(@options, &format_ports($src_ports, "src"));
 850                 }
 851
 852                 # Process destination ports.
 853                 my $use_dst_ports  = ($$hash{$key}[11] eq "ON");
 854                 my $use_dnat       = (($$hash{$key}[28] eq "ON") && ($$hash{$key}[31] eq "dnat"));
 855
 856                 if ($use_dst_ports) {
 857                         my $dst_ports_mode = $$hash{$key}[14];
 858                         my $dst_ports      = $$hash{$key}[15];
 859
 860                         if (($dst_ports_mode eq "TGT_PORT") && $dst_ports) {
 861                                 if ($nat_options_wanted && $use_dnat && $$hash{$key}[30]) {
 862                                         $dst_ports = $$hash{$key}[30];
 863                                 }
 864                                 push(@options, &format_ports($dst_ports, "dst"));
 865
 866                         } elsif ($dst_ports_mode eq "cust_srv") {
 867                                 if ($protocol eq "ICMP") {
 868                                         push(@options, ("--icmp-type", &fwlib::get_srv_port($dst_ports, 3, "ICMP")));
 869                                 } else {
 870                                         $dst_ports = &fwlib::get_srv_port($dst_ports, 1, uc($protocol));
 871                                         push(@options, &format_ports($dst_ports, "dst"));
 872                                 }
 873
 874                         } elsif ($dst_ports_mode eq "cust_srvgrp") {
 875                                 push(@options, &fwlib::get_srvgrp_port($dst_ports, uc($protocol)));
 876                         }
 877                 }
 878         }
 879
 880         # Check if a single ICMP type is selected.
 881         if ($protocol eq "icmp") {
 882                 my $icmp_type = $$hash{$key}[9];
 883
 884                 if (($icmp_type ne "All ICMP-Types") && $icmp_type) {
 885                         push(@options, ("--icmp-type", $icmp_type));
 886                 }
 887         }
 888
 889         return @options;
 890 }
 891
 892 sub format_ports {
 893         my $ports = shift;
 894         my $type = shift;
 895
 896         my $arg;
 897         if ($type eq "src") {
 898                 $arg = "--sport";
 899         } elsif ($type eq "dst") {
 900                 $arg = "--dport";
 901         }
 902
 903         my @options = ();
 904
 905         if ($ports =~ /\|/) {
 906                 $ports =~ s/\|/,/g;
 907                 push(@options, ("-m", "multiport"));
 908         }
 909
 910         if ($ports) {
 911                 push(@options, ($arg, $ports));
 912         }
 913
 914         return @options;
 915 }
 916
 917 sub get_dnat_target_port {
 918         my $hash = shift;
 919         my $key  = shift;
 920
 921         if ($$hash{$key}[14] eq "TGT_PORT") {
 922                 my $port = $$hash{$key}[15];
 923                 my $external_port = $$hash{$key}[30];
 924
 925                 if ($external_port && ($port ne $external_port)) {
 926                         return $$hash{$key}[15];
 927                 }
 928         }
 929 }
 930
 931 sub add_dnat_mangle_rules {
 932         my $nat_address = shift;
 933         my $interface = shift;
 934         my @options = @_;
 935
 936         my $mark = 0x01000000;
 937         foreach my $zone ("GREEN", "BLUE", "ORANGE") {
 938                 # Skip rule if not all required information exists.
 939                 next unless (exists $defaultNetworks{$zone . "_NETADDRESS"});
 940                 next unless (exists $defaultNetworks{$zone . "_NETMASK"});
 941
 942                 next if ($interface && $interface ne $defaultNetworks{$zone . "_DEV"});
 943
 944                 my @mangle_options = @options;
 945
 946                 my $netaddress = $defaultNetworks{$zone . "_NETADDRESS"};
 947                 $netaddress .= "/" . $defaultNetworks{$zone . "_NETMASK"};
 948
 949                 push(@mangle_options, ("-s", $netaddress, "-d", $nat_address));
 950                 push(@mangle_options, ("-j", "MARK", "--set-xmark", "$mark/$NAT_MASK"));
 951
 952                 run("$IPTABLES -t mangle -A $CHAIN_MANGLE_NAT_DESTINATION_FIX @mangle_options");
 953
 954                 $mark <<= 1;
 955         }
 956 }
 957
 958 sub make_log_limit_options {
 959         my @options = ("-m", "limit");
 960
 961         # Maybe we should get this from the configuration.
 962         my $limit = 10;
 963
 964         # We limit log messages to $limit messages per second.
 965         push(@options, ("--limit", "$limit/second"));
 966
 967         # And we allow bursts of 2x $limit.
 968         push(@options, ("--limit-burst", $limit * 2));
 969
 970         return @options;
 971 }
 972
 973 sub firewall_is_in_subnet {
 974         my $subnet = shift;
 975
 976         # ORANGE is missing here, because nothing may ever access
 977         # the firewall from this network.
 978         my $address = &fwlib::get_internal_firewall_ip_address($subnet, 0);
 979
 980         if ($address) {
 981                 return 1;
 982         }
 983
 984         return 0;
 985 }
 986
 987 sub firewall_chain_exists ($) {
 988         my ($chain) = @_;
 989
 990         my $ret = &General::system("iptables", "--wait", "-n", "-L", "$chain");
 991
 992         return $ret;
 993 }
 994
 995 sub ipset_get_sets () {
 996         my @sets;
 997
 998         # Get all currently used ipset lists and store them in an array.
 999         my @output = `$IPSET -n list`;
1000
1001         # Loop through the temporary array.
1002         foreach my $set (@output) {
1003                 # Remove any newlines.
1004                 chomp($set);
1005
1006                 # Add the set the array of used sets.
1007                 push(@sets, $set);
1008         }
1009
1010         # Display used sets in debug mode.
1011         if($DEBUG) {
1012                 print "Used ipset sets:\n";
1013                 print "@sets\n\n";
1014         }
1015
1016         # Return the array of sets.
1017         return @sets;
1018 }
1019
1020 sub ipset_restore ($) {
1021         my ($set) = @_;
1022
1023         # Empty variable to store the db file, which should be
1024         # restored by ipset.
1025         my $db_file;
1026
1027         # Check if the set already has been loaded.
1028         if($ipset_loaded_sets{$set}) {
1029                 # It already has been loaded - so there is nothing to do.
1030                 return;
1031         }
1032
1033         # Check if the given set name is a country code.
1034         if($set ~~ @locations) {
1035                 # Libloc adds the IP type (v4 or v6) as part of the set and file name.
1036                 my $loc_set = "$set" . "v4";
1037
1038                 # The bare filename equals the set name.
1039                 my $filename = $loc_set;
1040
1041                 # Libloc uses "ipset" as file extension.
1042                 my $file_extension = "ipset";
1043
1044                 # Generate full path and filename for the ipset db file.
1045                 my $db_file = "$Location::Functions::ipset_db_directory/$filename.$file_extension";
1046
1047                 # Call function to restore/load the set.
1048                 &ipset_call_restore($db_file);
1049
1050                 # Check if the set is already loaded (has been used before).
1051                 if ($set ~~ @ipset_used_sets) {
1052                         # The sets contains the IP type (v4 or v6) as part of the name.
1053                         # The firewall rules matches against sets without that extension. So we safely
1054                         # can swap or rename the sets to use the new ones.
1055                         run("$IPSET swap $loc_set $set");
1056                 } else {
1057                         # If the set is not loaded, we have to rename it to proper use it.
1058                         run("$IPSET rename $loc_set $set");
1059                 }
1060
1061         # Check if the given set name is a blocklist.
1062         } elsif ($set ~~ @blocklists) {
1063                 # Get the database file for the given blocklist.
1064                 my $db_file = &IPblocklist::get_ipset_db_file($set);
1065
1066                 # Call function to restore/load the set.
1067                 &ipset_call_restore($db_file);
1068         }
1069
1070         # Store the restored set to the hash to prevent from loading it again.
1071         $ipset_loaded_sets{$set} = "1";
1072 }
1073
1074 sub ipset_call_restore ($) {
1075         my ($file) = @_;
1076
1077         # Check if the requested file exists.
1078         if (-f $file) {
1079                 # Run ipset and restore the given set.
1080                 run("$IPSET restore -f $file");
1081         }
1082 }
1083
1084 sub ipset_cleanup () {
1085         # Reload the array of used sets.
1086         @ipset_used_sets = &ipset_get_sets();
1087
1088         # Loop through the array of used sets.
1089         foreach my $set (@ipset_used_sets) {
1090                 # Check if this set is still in use.
1091                 #
1092                 # In this case an entry in the loaded sets hash exists.
1093                 unless($ipset_loaded_sets{$set}) {
1094                         # Entry does not exist, so this set is not longer
1095                         # used and can be destroyed.
1096                         run("$IPSET destroy $set");
1097                 }
1098         }
1099 }