0998c1b531692e986d83c68309424699489034a8
[people/teissler/ipfire-2.x.git] / config / firewall / rules.pl
1 #!/usr/bin/perl -w
2 ###############################################################################
3 # #
4 # IPFire.org - A linux based firewall #
5 # Copyright (C) 2013 Alexander Marx <amarx@ipfire.org> #
6 # #
7 # This program is free software: you can redistribute it and/or modify #
8 # it under the terms of the GNU General Public License as published by #
9 # the Free Software Foundation, either version 3 of the License, or #
10 # (at your option) any later version. #
11 # #
12 # This program is distributed in the hope that it will be useful, #
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of #
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the #
15 # GNU General Public License for more details. #
16 # #
17 # You should have received a copy of the GNU General Public License #
18 # along with this program. If not, see <http://www.gnu.org/licenses/>. #
19 # #
20 ###############################################################################
21
22 use strict;
23
24 require '/var/ipfire/general-functions.pl';
25 require "${General::swroot}/lang.pl";
26 require "/usr/lib/firewall/firewall-lib.pl";
27
28 # Set to one to enable debugging mode.
29 my $DEBUG = 0;
30
31 my $IPTABLES = "iptables --wait";
32
33 # iptables chains
34 my $CHAIN_INPUT = "INPUTFW";
35 my $CHAIN_FORWARD = "FORWARDFW";
36 my $CHAIN_OUTPUT = "OUTGOINGFW";
37 my $CHAIN = $CHAIN_FORWARD;
38 my $CHAIN_NAT_SOURCE = "NAT_SOURCE";
39 my $CHAIN_NAT_DESTINATION = "NAT_DESTINATION";
40 my $CHAIN_MANGLE_NAT_DESTINATION_FIX = "NAT_DESTINATION";
41 my @VALID_CHAINS = ($CHAIN_INPUT, $CHAIN_FORWARD, $CHAIN_OUTPUT);
42
43 my @PROTOCOLS = ("tcp", "udp", "icmp", "igmp", "ah", "esp", "gre", "ipv6", "ipip");
44 my @PROTOCOLS_WITH_PORTS = ("tcp", "udp");
45
46 my @VALID_TARGETS = ("ACCEPT", "DROP", "REJECT");
47
48 my %fwdfwsettings=();
49 my %defaultNetworks=();
50 my %configfwdfw=();;
51 my %customgrp=();
52 my %configinputfw=();
53 my %configoutgoingfw=();
54 my %confignatfw=();
55 my %aliases=();
56 my @p2ps=();
57
58 my $configfwdfw = "${General::swroot}/firewall/config";
59 my $configinput = "${General::swroot}/firewall/input";
60 my $configoutgoing = "${General::swroot}/firewall/outgoing";
61 my $p2pfile = "${General::swroot}/firewall/p2protocols";
62 my $configgrp = "${General::swroot}/fwhosts/customgroups";
63 my $netsettings = "${General::swroot}/ethernet/settings";
64
65 &General::readhash("${General::swroot}/firewall/settings", \%fwdfwsettings);
66 &General::readhash("$netsettings", \%defaultNetworks);
67 &General::readhasharray($configfwdfw, \%configfwdfw);
68 &General::readhasharray($configinput, \%configinputfw);
69 &General::readhasharray($configoutgoing, \%configoutgoingfw);
70 &General::readhasharray($configgrp, \%customgrp);
71 &General::get_aliases(\%aliases);
72
73 my @log_limit_options = &make_log_limit_options();
74
75 # MAIN
76 &main();
77
78 sub main {
79 # Flush all chains.
80 &flush();
81
82 # Reload firewall rules.
83 &preparerules();
84
85 # Load P2P block rules.
86 &p2pblock();
87
88 # Reload firewall policy.
89 run("/usr/sbin/firewall-policy");
90 }
91
92 sub run {
93 # Executes or prints the given shell command.
94 my $command = shift;
95
96 if ($DEBUG) {
97 print "$command\n";
98 } else {
99 system "$command";
100
101 if ($?) {
102 print_error("ERROR: $command");
103 }
104 }
105 }
106
107 sub print_error {
108 my $message = shift;
109
110 print STDERR "$message\n";
111 }
112
113 sub print_rule {
114 my $hash = shift;
115
116 print "\nRULE:";
117
118 my $i = 0;
119 foreach (@$hash) {
120 printf(" %2d: %s", $i++, $_);
121 }
122 print "\n";
123 }
124
125 sub flush {
126 run("$IPTABLES -F $CHAIN_INPUT");
127 run("$IPTABLES -F $CHAIN_FORWARD");
128 run("$IPTABLES -F $CHAIN_OUTPUT");
129 run("$IPTABLES -t nat -F $CHAIN_NAT_SOURCE");
130 run("$IPTABLES -t nat -F $CHAIN_NAT_DESTINATION");
131 run("$IPTABLES -t mangle -F $CHAIN_MANGLE_NAT_DESTINATION_FIX");
132 }
133
134 sub preparerules {
135 if (! -z "${General::swroot}/firewall/config"){
136 &buildrules(\%configfwdfw);
137 }
138 if (! -z "${General::swroot}/firewall/input"){
139 &buildrules(\%configinputfw);
140 }
141 if (! -z "${General::swroot}/firewall/outgoing"){
142 &buildrules(\%configoutgoingfw);
143 }
144 }
145
146 sub buildrules {
147 my $hash = shift;
148
149 foreach my $key (sort {$a <=> $b} keys %$hash) {
150 # Skip disabled rules.
151 next unless ($$hash{$key}[2] eq 'ON');
152
153 if ($DEBUG) {
154 print_rule($$hash{$key});
155 }
156
157 # Check if the target is valid.
158 my $target = $$hash{$key}[0];
159 if (!$target ~~ @VALID_TARGETS) {
160 print_error("Invalid target '$target' for rule $key");
161 next;
162 }
163
164 # Check if the chain is valid.
165 my $chain = $$hash{$key}[1];
166 if (!$chain ~~ @VALID_CHAINS) {
167 print_error("Invalid chain '$chain' in rule $key");
168 next;
169 }
170
171 # Collect all sources.
172 my @sources = &get_addresses($hash, $key, "src");
173
174 # Collect all destinations.
175 my @destinations = &get_addresses($hash, $key, "tgt");
176
177 # Check if logging should be enabled.
178 my $LOG = ($$hash{$key}[17] eq 'ON');
179
180 # Check if NAT is enabled and initialize variables, that we use for that.
181 my $NAT = ($$hash{$key}[28] eq 'ON');
182 my $NAT_MODE;
183 if ($NAT) {
184 $NAT_MODE = uc($$hash{$key}[31]);
185 }
186
187 # Set up time constraints.
188 my @time_options = ();
189 if ($$hash{$key}[18] eq 'ON') {
190 push(@time_options, ("-m", "time"));
191
192 # Select all days of the week this match is active.
193 my @weekdays = ();
194 if ($$hash{$key}[19] ne '') {
195 push (@weekdays, "Mon");
196 }
197 if ($$hash{$key}[20] ne '') {
198 push (@weekdays, "Tue");
199 }
200 if ($$hash{$key}[21] ne '') {
201 push (@weekdays, "Wed");
202 }
203 if ($$hash{$key}[22] ne '') {
204 push (@weekdays, "Thu");
205 }
206 if ($$hash{$key}[23] ne '') {
207 push (@weekdays, "Fri");
208 }
209 if ($$hash{$key}[24] ne '') {
210 push (@weekdays, "Sat");
211 }
212 if ($$hash{$key}[25] ne '') {
213 push (@weekdays, "Sun");
214 }
215 if (@weekdays) {
216 push(@time_options, ("--weekdays", join(",", @weekdays)));
217 }
218
219 # Convert start time.
220 my $time_start = &format_time($$hash{$key}[26]);
221 if ($time_start) {
222 push(@time_options, ("--timestart", $time_start));
223 }
224
225 # Convert end time.
226 my $time_stop = &format_time($$hash{$key}[27]);
227 if ($time_stop) {
228 push(@time_options, ("--timestop", $time_stop));
229 }
230 }
231
232 # Check which protocols are used in this rule and so that we can
233 # later group rules by protocols.
234 my @protocols = &get_protocols($hash, $key);
235 if (!@protocols) {
236 print_error("Invalid protocol configuration for rule $key");
237 next;
238 }
239
240 foreach my $protocol (@protocols) {
241 # Check if the given protocol is supported.
242 if (($protocol ne "all") && (!$protocol ~~ @PROTOCOLS)) {
243 print_error("Protocol $protocol is not supported (rule $key)");
244 next;
245 }
246
247 # Prepare protocol options (like ICMP types, ports, etc...).
248 my @protocol_options = &get_protocol_options($hash, $key, $protocol);
249
250 # Check if this protocol knows ports.
251 my $protocol_has_ports = ($protocol ~~ @PROTOCOLS_WITH_PORTS);
252
253 foreach my $source (@sources) {
254 foreach my $destination (@destinations) {
255 # Skip invalid rules.
256 next if (!$source || !$destination || ($destination eq "none"));
257
258 # Array with iptables arguments.
259 my @options = ();
260
261 # Append protocol.
262 if ($protocol ne "all") {
263 push(@options, ("-p", $protocol));
264 push(@options, @protocol_options);
265 }
266
267 # Prepare source options.
268 my @source_options = ();
269 if ($source =~ /mac/) {
270 push(@source_options, $source);
271 } else {
272 push(@source_options, ("-s", $source));
273 }
274
275 # Prepare destination options.
276 my @destination_options = ("-d", $destination);
277
278 # Add time constraint options.
279 push(@options, @time_options);
280
281 # Process NAT rules.
282 if ($NAT) {
283 my $nat_address = &get_nat_address($$hash{$key}[29]);
284
285 # Skip NAT rules if the NAT address is unknown
286 # (i.e. no internet connection has been established, yet).
287 next unless ($nat_address);
288
289 # Destination NAT
290 if ($NAT_MODE eq "DNAT") {
291 # Make port-forwardings useable from the internal networks.
292 &add_dnat_mangle_rules($nat_address, @options);
293
294 my @nat_options = @options;
295 push(@nat_options, @source_options);
296 push(@nat_options, ("-d", $nat_address));
297
298 my ($dnat_address, $dnat_mask) = split("/", $destination);
299 @destination_options = ("-d", $dnat_address);
300
301 if ($protocol_has_ports) {
302 my $dnat_port = &get_dnat_target_port($hash, $key);
303
304 if ($dnat_port) {
305 $dnat_address .= ":$dnat_port";
306 }
307 }
308
309 if ($LOG) {
310 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options @log_limit_options -j LOG --log-prefix 'DNAT '");
311 }
312 run("$IPTABLES -t nat -A $CHAIN_NAT_DESTINATION @nat_options -j DNAT --to-destination $dnat_address");
313
314 # Source NAT
315 } elsif ($NAT_MODE eq "SNAT") {
316 my @nat_options = @options;
317
318 push(@nat_options, @source_options);
319 push(@nat_options, @destination_options);
320
321 if ($LOG) {
322 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options @log_limit_options -j LOG --log-prefix 'SNAT '");
323 }
324 run("$IPTABLES -t nat -A $CHAIN_NAT_SOURCE @nat_options -j SNAT --to-source $nat_address");
325 }
326 }
327
328 push(@options, @source_options);
329 push(@options, @destination_options);
330
331 # Insert firewall rule.
332 if ($LOG && !$NAT) {
333 run("$IPTABLES -A $chain @options @log_limit_options -j LOG");
334 }
335 run("$IPTABLES -A $chain @options -j $target");
336 }
337 }
338 }
339 }
340 }
341
342 sub get_external_interface() {
343 open(IFACE, "/var/ipfire/red/iface") or return "";
344 my $iface = <IFACE>;
345 close(IFACE);
346
347 return $iface;
348 }
349
350 sub get_external_address() {
351 open(ADDR, "/var/ipfire/red/local-ipaddress") or return "";
352 my $address = <ADDR>;
353 close(ADDR);
354
355 return $address;
356 }
357
358 sub get_alias {
359 my $id = shift;
360
361 foreach my $alias (sort keys %aliases) {
362 if ($id eq $alias) {
363 return $aliases{$alias};
364 }
365 }
366 }
367
368 sub get_nat_address {
369 my $zone = shift;
370
371 # Any static address of any zone.
372 if ($zone eq "RED" || $zone eq "GREEN" || $zone eq "ORANGE" || $zone eq "BLUE") {
373 return $defaultNetworks{$zone . "_ADDRESS"};
374
375 } elsif ($zone eq "Default IP") {
376 return &get_external_address();
377
378 } else {
379 return &get_alias($zone);
380 }
381
382 print_error("Could not find NAT address");
383 }
384
385 # Formats the given timestamp into the iptables format which is "hh:mm" UTC.
386 sub format_time {
387 my $val = shift;
388
389 # Convert the given time into minutes.
390 my $minutes = &time_convert_to_minutes($val);
391
392 # Move the timestamp into UTC.
393 $minutes += &time_utc_offset();
394
395 # Make sure $minutes is between 00:00 and 23:59.
396 if ($minutes < 0) {
397 $minutes += 1440;
398 }
399
400 if ($minutes > 1440) {
401 $minutes -= 1440;
402 }
403
404 # Format as hh:mm.
405 return sprintf("%02d:%02d", $minutes / 60, $minutes % 60);
406 }
407
408 # Calculates the offsets in minutes from the local timezone to UTC.
409 sub time_utc_offset {
410 my @localtime = localtime(time);
411 my @gmtime = gmtime(time);
412
413 return ($gmtime[2] * 60 + $gmtime[1] % 60) - ($localtime[2] * 60 + $localtime[1] % 60);
414 }
415
416 # Takes a timestamp like "14:00" and converts it into minutes since midnight.
417 sub time_convert_to_minutes {
418 my ($hrs, $min) = split(":", shift);
419
420 return ($hrs * 60) + $min;
421 }
422
423 sub p2pblock {
424 my $P2PSTRING = "";
425 my $DO;
426 open( FILE, "< $p2pfile" ) or die "Unable to read $p2pfile";
427 @p2ps = <FILE>;
428 close FILE;
429 my $CMD = "-m ipp2p";
430 foreach my $p2pentry (sort @p2ps) {
431 my @p2pline = split( /\;/, $p2pentry );
432 if ( $fwdfwsettings{'POLICY'} eq 'MODE1' ) {
433 $DO = "ACCEPT";
434 if ("$p2pline[2]" eq "on") {
435 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
436 }
437 }else {
438 $DO = "RETURN";
439 if ("$p2pline[2]" eq "off") {
440 $P2PSTRING = "$P2PSTRING --$p2pline[1]";
441 }
442 }
443 }
444
445 if($P2PSTRING) {
446 run("$IPTABLES -A FORWARDFW $CMD $P2PSTRING -j $DO");
447 }
448 }
449
450 sub get_addresses {
451 my $hash = shift;
452 my $key = shift;
453 my $type = shift;
454
455 my @addresses = ();
456 my $addr_type;
457 my $value;
458 my $group_name;
459
460 if ($type eq "src") {
461 $addr_type = $$hash{$key}[3];
462 $value = $$hash{$key}[4];
463
464 } elsif ($type eq "tgt") {
465 $addr_type = $$hash{$key}[5];
466 $value = $$hash{$key}[6];
467 }
468
469 if ($addr_type ~~ ["cust_grp_src", "cust_grp_tgt"]) {
470 foreach my $grp (sort {$a <=> $b} keys %customgrp) {
471 if ($customgrp{$grp}[0] eq $value) {
472 my @address = &get_address($customgrp{$grp}[3], $customgrp{$grp}[2], $type);
473
474 if (@address) {
475 push(@addresses, @address);
476 }
477 }
478 }
479 } else {
480 my @address = &get_address($addr_type, $value, $type);
481
482 if (@address) {
483 push(@addresses, @address);
484 }
485 }
486
487 return @addresses;
488 }
489
490 sub get_address {
491 my $key = shift;
492 my $value = shift;
493 my $type = shift;
494
495 my @ret = ();
496
497 # If the user manually typed an address, we just check if it is a MAC
498 # address. Otherwise, we assume that it is an IP address.
499 if ($key ~~ ["src_addr", "tgt_addr"]) {
500 if (&General::validmac($value)) {
501 push(@ret, "-m mac --mac-source $value");
502 } else {
503 push(@ret, $value);
504 }
505
506 # If a default network interface (GREEN, BLUE, etc.) is selected, we
507 # try to get the corresponding address of the network.
508 } elsif ($key ~~ ["std_net_src", "std_net_tgt", "Standard Network"]) {
509 my $external_interface = &get_external_interface();
510
511 my $network_address = &fwlib::get_std_net_ip($value, $external_interface);
512 if ($network_address) {
513 push(@ret, $network_address);
514 }
515
516 # Custom networks.
517 } elsif ($key ~~ ["cust_net_src", "cust_net_tgt", "Custom Network"]) {
518 my $network_address = &fwlib::get_net_ip($value);
519 if ($network_address) {
520 push(@ret, $network_address);
521 }
522
523 # Custom hosts.
524 } elsif ($key ~~ ["cust_host_src", "cust_host_tgt", "Custom Host"]) {
525 my $host_address = &fwlib::get_host_ip($value, $type);
526 if ($host_address) {
527 push(@ret, $host_address);
528 }
529
530 # OpenVPN networks.
531 } elsif ($key ~~ ["ovpn_net_src", "ovpn_net_tgt", "OpenVPN static network"]) {
532 my $network_address = &fwlib::get_ovpn_net_ip($value, 1);
533 if ($network_address) {
534 push(@ret, $network_address);
535 }
536
537 # OpenVPN hosts.
538 } elsif ($key ~~ ["ovpn_host_src", "ovpn_host_tgt", "OpenVPN static host"]) {
539 my $host_address = &fwlib::get_ovpn_host_ip($value, 33);
540 if ($host_address) {
541 push(@ret, $host_address);
542 }
543
544 # OpenVPN N2N.
545 } elsif ($key ~~ ["ovpn_n2n_src", "ovpn_n2n_tgt", "OpenVPN N-2-N"]) {
546 my $network_address = &fwlib::get_ovpn_n2n_ip($value, 11);
547 if ($network_address) {
548 push(@ret, $network_address);
549 }
550
551 # IPsec networks.
552 } elsif ($key ~~ ["ipsec_net_src", "ipsec_net_tgt", "IpSec Network"]) {
553 my $network_address = &fwlib::get_ipsec_net_ip($value, 11);
554 if ($network_address) {
555 push(@ret, $network_address);
556 }
557
558 # The firewall's own IP addresses.
559 } elsif ($key ~~ ["ipfire", "ipfire_src"]) {
560 # ALL
561 if ($value eq "ALL") {
562 push(@ret, "0/0");
563
564 # GREEN
565 } elsif ($value eq "GREEN") {
566 push(@ret, $defaultNetworks{"GREEN_ADDRESS"});
567
568 # BLUE
569 } elsif ($value eq "BLUE") {
570 push(@ret, $defaultNetworks{"BLUE_ADDRESS"});
571
572 # ORANGE
573 } elsif ($value eq "ORANGE") {
574 push(@ret, $defaultNetworks{"ORANGE_ADDRESS"});
575
576 # RED
577 } elsif ($value ~~ ["RED", "RED1"]) {
578 my $address = &get_external_address();
579 if ($address) {
580 push(@ret, $address);
581 }
582
583 # Aliases
584 } else {
585 my %alias = &get_alias($value);
586 if (%alias) {
587 push(@ret, $alias{"IPT"});
588 }
589 }
590
591 # If nothing was selected, we assume "any".
592 } else {
593 push(@ret, "0/0");
594 }
595
596 return @ret;
597 }
598
599 sub get_protocols {
600 my $hash = shift;
601 my $key = shift;
602
603 my $uses_source_ports = ($$hash{$key}[7] eq "ON");
604 my $uses_services = ($$hash{$key}[11] eq "ON");
605
606 my @protocols = ();
607
608 # Rules which don't have source ports or services (like ICMP, ESP, ...).
609 if (!$uses_source_ports && !$uses_services) {
610 push(@protocols, $$hash{$key}[8]);
611
612 # Rules which either use ports or services.
613 } elsif ($uses_source_ports || $uses_services) {
614 # Check if service group or service
615 if ($$hash{$key}[14] eq 'cust_srv') {
616 push(@protocols, &fwlib::get_srv_prot($$hash{$key}[15]));
617
618 } elsif($$hash{$key}[14] eq 'cust_srvgrp'){
619 my $protos = &fwlib::get_srvgrp_prot($$hash{$key}[15]);
620 push(@protocols, split(",", $protos));
621
622 } else {
623 # Fetch the protocol for this rule.
624 my $protocol = lc($$hash{$key}[8]);
625
626 # Fetch source and destination ports for this rule.
627 my $source_ports = $$hash{$key}[10];
628 my $destination_ports = $$hash{$key}[15];
629
630 # Check if ports are set for protocols which do not support ports.
631 if (!($protocol ~~ @PROTOCOLS_WITH_PORTS) && ($source_ports || $destination_ports)) {
632 print_error("$protocol does not support ports");
633 return ();
634 }
635
636 push(@protocols, $protocol);
637 }
638 }
639
640 # Remove all empty elements
641 @protocols = map { $_ ? $_ : () } @protocols;
642
643 # If no protocol has been defined, we assume "all".
644 if (!@protocols) {
645 push(@protocols, "all");
646 }
647
648 # Make all protocol names lowercase.
649 @protocols = map { lc } @protocols;
650
651 return @protocols;
652 }
653
654 sub get_protocol_options {
655 my $hash = shift;
656 my $key = shift;
657 my $protocol = shift;
658 my @options = ();
659
660 # Process source ports.
661 my $use_src_ports = ($$hash{$key}[7] eq "ON");
662 my $src_ports = $$hash{$key}[10];
663
664 if ($use_src_ports && $src_ports) {
665 push(@options, &format_ports($src_ports, "src"));
666 }
667
668 # Process destination ports.
669 my $use_dst_ports = ($$hash{$key}[11] eq "ON");
670 my $use_dnat = (($$hash{$key}[28] eq "ON") && ($$hash{$key}[31] eq "dnat"));
671
672 if ($use_dst_ports) {
673 my $dst_ports_mode = $$hash{$key}[14];
674 my $dst_ports = $$hash{$key}[15];
675
676 if (($dst_ports_mode eq "TGT_PORT") && $dst_ports) {
677 if ($use_dnat && $$hash{$key}[30]) {
678 $dst_ports = $$hash{$key}[30];
679 }
680 push(@options, &format_ports($dst_ports, "dst"));
681
682 } elsif ($dst_ports_mode eq "cust_srv") {
683 if ($protocol eq "ICMP") {
684 push(@options, ("--icmp-type", &fwlib::get_srv_port($dst_ports, 3, "ICMP")));
685 } else {
686 $dst_ports = &fwlib::get_srv_port($dst_ports, 1, uc($protocol));
687 push(@options, &format_ports($dst_ports, "dst"));
688 }
689
690 } elsif ($dst_ports_mode eq "cust_srvgrp") {
691 push(@options, &fwlib::get_srvgrp_port($dst_ports, uc($protocol)));
692 }
693 }
694
695 # Check if a single ICMP type is selected.
696 if (!$use_src_ports && !$use_dst_ports && $protocol eq "icmp") {
697 my $icmp_type = $$hash{$key}[9];
698
699 if (($icmp_type ne "All ICMP-Types") && $icmp_type) {
700 push(@options, ("--icmp-type", $icmp_type));
701 }
702 }
703
704 return @options;
705 }
706
707 sub format_ports {
708 my $ports = shift;
709 my $type = shift;
710
711 my $arg;
712 if ($type eq "src") {
713 $arg = "--sport";
714 } elsif ($type eq "dst") {
715 $arg = "--dport";
716 }
717
718 my @options = ();
719
720 if ($ports =~ /\|/) {
721 $ports =~ s/\|/,/g;
722 push(@options, ("-m", "multiport"));
723 }
724
725 if ($ports) {
726 push(@options, ($arg, $ports));
727 }
728
729 return @options;
730 }
731
732 sub get_dnat_target_port {
733 my $hash = shift;
734 my $key = shift;
735
736 if ($$hash{$key}[14] eq "TGT_PORT") {
737 my $port = $$hash{$key}[15];
738 my $external_port = $$hash{$key}[30];
739
740 if ($external_port && ($port ne $external_port)) {
741 return $$hash{$key}[15];
742 }
743 }
744 }
745
746 sub add_dnat_mangle_rules {
747 my $nat_address = shift;
748 my @options = @_;
749
750 my $mark = 0;
751 foreach my $zone ("GREEN", "BLUE", "ORANGE") {
752 $mark++;
753
754 # Skip rule if not all required information exists.
755 next unless (exists $defaultNetworks{$zone . "_NETADDRESS"});
756 next unless (exists $defaultNetworks{$zone . "_NETMASK"});
757
758 my @mangle_options = @options;
759
760 my $netaddress = $defaultNetworks{$zone . "_NETADDRESS"};
761 $netaddress .= "/" . $defaultNetworks{$zone . "_NETMASK"};
762
763 push(@mangle_options, ("-s", $netaddress, "-d", $nat_address));
764 push(@mangle_options, ("-j", "MARK", "--set-mark", $mark));
765
766 run("$IPTABLES -t mangle -A $CHAIN_MANGLE_NAT_DESTINATION_FIX @mangle_options");
767 }
768 }
769
770 sub make_log_limit_options {
771 my @options = ("-m", "limit");
772
773 # Maybe we should get this from the configuration.
774 my $limit = 10;
775
776 # We limit log messages to $limit messages per minute.
777 push(@options, ("--limit", "$limit/min"));
778
779 # And we allow bursts of 2x $limit.
780 push(@options, ("--limit-burst", $limit * 2));
781
782 return @options;
783 }