gdb/testsuite/gdb.base/ena-dis-br.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 1997-2020 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 #
  19 # test running programs
  20 #
  21
  22 standard_testfile break.c break1.c
  23
  24 if {[prepare_for_testing "failed to prepare" ${testfile} \
  25          [list $srcfile $srcfile2] {debug nowarnings}]} {
  26     return -1
  27 }
  28
  29 set bp_location1 [gdb_get_line_number "set breakpoint 1 here"]
  30 set bp_location7 [gdb_get_line_number "set breakpoint 7 here"]
  31 set bp_location8 [gdb_get_line_number "set breakpoint 8 here" $srcfile2]
  32 set bp_location11 [gdb_get_line_number "set breakpoint 11 here"]
  33 set bp_location14 [gdb_get_line_number "set breakpoint 14 here" $srcfile2]
  34 set bp_location15 [gdb_get_line_number "set breakpoint 15 here" $srcfile2]
  35 set bp_location17 [gdb_get_line_number "set breakpoint 17 here" $srcfile2]
  36
  37 if ![runto_main] then { fail "enable/disable break tests suppressed" }
  38
  39 # Verify that we can set a breakpoint (the location is irrelevant),
  40 # then enable it (yes, it's already enabled by default), then hit it.
  41
  42 proc break_at { breakpoint where } {
  43     global gdb_prompt
  44     global expect_out
  45
  46     set test "break $breakpoint"
  47     set bp 0
  48     gdb_test_multiple "$test" "$test" {
  49         -re "Breakpoint (\[0-9\]*) at .*$where.*$gdb_prompt $" {
  50             set bp $expect_out(1,string)
  51             pass "$test"
  52         }
  53     }
  54     return $bp
  55 }
  56
  57 set bp [break_at "marker1" " line $bp_location15"]
  58
  59 gdb_test_no_output "enable $bp" "enable break marker1"
  60
  61 gdb_test "info break $bp" \
  62     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+keep\[ \t\]+y.*" \
  63     "info break marker1 before hitting breakpoint"
  64
  65 # See the comments in condbreak.exp for "run until breakpoint at
  66 # marker1" for an explanation of the xfail below.
  67 set test "continue to break marker1"
  68 gdb_test_multiple "continue" "$test" {
  69     -re "Breakpoint \[0-9\]*, marker1.*$gdb_prompt $" {
  70         pass "$test"
  71     }
  72     -re "Breakpoint \[0-9\]*, $hex in marker1.*$gdb_prompt $" {
  73         xfail "$test"
  74     }
  75 }
  76
  77 gdb_test_no_output "delete $bp" "delete break marker1"
  78
  79 # Verify that we can set a breakpoint to be self-disabling after the
  80 # first time it triggers.
  81 set bp [break_at "marker2" " line $bp_location8"]
  82
  83 gdb_test_no_output "enable once $bp" "enable once break marker2"
  84
  85 gdb_test "info break $bp" \
  86     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+dis\[ \t\]+y.*" \
  87     "info auto-disabled break marker2 before hitting breakpoint"
  88
  89 # See the comments in condbreak.exp for "run until breakpoint at
  90 # marker1" for an explanation of the xfail below.
  91 set test "continue to auto-disabled break marker2"
  92 gdb_test_multiple "continue" "$test" {
  93     -re "Breakpoint \[0-9\]*, marker2.*$gdb_prompt $" {
  94         pass "$test"
  95     }
  96     -re "Breakpoint \[0-9\]*, $hex in marker2.*$gdb_prompt $" {
  97         xfail "$test"
  98     }
  99 }
 100
 101 gdb_test "info break $bp" \
 102     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+dis\[ \t\]+n.*" \
 103     "info auto-disabled break marker2 after hitting breakpoint"
 104
 105 # Verify that we don't stop at a disabled breakpoint.
 106 gdb_continue_to_end "no stop"
 107 rerun_to_main
 108 gdb_continue_to_end "no stop at auto-disabled break marker2"
 109
 110 # Verify that we can set a breakpoint to be self-deleting after the
 111 # first time it triggers.
 112 if ![runto_main] then {
 113     fail "enable/disable break tests suppressed"
 114 }
 115
 116 set bp [break_at "marker3" " line $bp_location17"]
 117
 118 gdb_test_no_output "enable del $bp" "enable del break marker3"
 119
 120 gdb_test "info break $bp" \
 121     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+del\[ \t\]+y.*" \
 122     "info auto-deleted break marker2"
 123
 124 gdb_test "continue" \
 125     ".*marker3 .*:$bp_location17.*" \
 126     "continue to auto-deleted break marker3"
 127
 128 gdb_test "info break $bp" \
 129     ".*No breakpoint or watchpoint matching.*" \
 130     "info auto-deleted break marker3"
 131
 132 # Verify that we can set a breakpoint and manually disable it (we've
 133 # already proven that disabled bp's don't trigger).
 134
 135 set bp [break_at "marker4" " line $bp_location14.*"]
 136
 137 gdb_test_no_output "disable $bp" "disable break marker4"
 138
 139 gdb_test "info break $bp" \
 140     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+keep\[ \t\]+n.*" \
 141     "info break marker4"
 142
 143 if ![runto_main] then {
 144     fail "enable/disable break tests suppressed"
 145 }
 146
 147 # Test enable count by stopping at a location until it is disabled
 148 # and passes through.
 149
 150 set bp [break_at $bp_location7 "line $bp_location7"]
 151
 152 set bp2 [break_at marker1 " line $bp_location15"]
 153
 154 gdb_test "enable count" \
 155     "Argument required \\(hit count\\)\\." \
 156     "enable count missing arguments"
 157
 158 gdb_test "enable count 2" \
 159     "Argument required \\(one or more breakpoint numbers\\)\\." \
 160     "enable count missing breakpoint number"
 161
 162 gdb_test_no_output "enable count 2 $bp" "disable break with count"
 163
 164 gdb_test "continue" \
 165     ".*factorial .*:$bp_location7.*" \
 166     "continue from enable count, first time"
 167
 168 gdb_test "continue" \
 169     ".*factorial .*:$bp_location7.*" \
 170     "continue from enable count, second time"
 171
 172 gdb_test "continue" \
 173     ".*marker1 .*:$bp_location15.*" \
 174     "continue through enable count, now disabled"
 175
 176 # Verify that we can set a breakpoint with an ignore count N, which
 177 # should cause the next N triggers of the bp to be ignored.  (This is
 178 # a flavor of enablement/disablement, after all.)
 179
 180 if ![runto_main] then {
 181     fail "enable/disable break tests suppressed"
 182 }
 183
 184 set bp [break_at "marker1" " line $bp_location15.*"]
 185
 186 # Verify that an ignore of a non-existent breakpoint is gracefully
 187 # handled.
 188
 189 gdb_test "ignore 999 2" \
 190     "No breakpoint number 999..*" \
 191     "ignore non-existent break"
 192
 193 # Verify that a missing ignore count is gracefully handled.
 194
 195 gdb_test "ignore $bp" \
 196     "Second argument .specified ignore-count. is missing..*" \
 197     "ignore break with missing ignore count"
 198
 199 # Verify that a negative or zero ignore count is handled gracefully
 200 # (they both are treated the same).
 201
 202 gdb_test "ignore $bp -1" \
 203     "Will stop next time breakpoint \[0-9\]* is reached..*" \
 204     "ignore break marker1 -1"
 205
 206 gdb_test "ignore $bp 0" \
 207     "Will stop next time breakpoint \[0-9\]* is reached..*" \
 208     "ignore break marker1 0"
 209
 210 gdb_test "ignore $bp 1" \
 211     "Will ignore next crossing of breakpoint \[0-9\]*.*" \
 212     "ignore break marker1 1"
 213
 214 gdb_test "info break $bp" \
 215     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+keep\[ \t\]+y.*ignore next 1 hits.*" \
 216     "info ignored break marker1"
 217
 218 gdb_continue_to_end "no stop at ignored break marker1"
 219 rerun_to_main
 220
 221 # See the comments in condbreak.exp for "run until breakpoint at marker1"
 222 # for an explanation of the xfail below.
 223 set test "continue to break marker1, 2nd time"
 224 gdb_test_multiple "continue" "$test" {
 225     -re "Breakpoint \[0-9\]*, marker1.*$gdb_prompt $" {
 226         pass "continue to break marker1, 2nd time"
 227     }
 228     -re "Breakpoint \[0-9\]*, $hex in marker1.*$gdb_prompt $" {
 229         xfail "continue to break marker1, 2nd time"
 230     }
 231 }
 232
 233 # Verify that we can specify both an ignore count and an auto-delete.
 234
 235 if ![runto_main] then {
 236     fail "enable/disable break tests suppressed"
 237 }
 238
 239 set bp [break_at marker1 " line $bp_location15.*"]
 240
 241 gdb_test "ignore $bp 1" \
 242     "Will ignore next crossing of breakpoint \[0-9\]*.*" \
 243     "ignore break marker1"
 244
 245 gdb_test_no_output "enable del $bp" "enable del break marker1"
 246
 247 gdb_test "info break $bp" \
 248     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+del\[ \t\]+y.*ignore next 1 hits.*" \
 249     "info break marker1 after hitting breakpoint"
 250
 251 gdb_continue_to_end "no stop at ignored & auto-deleted break marker1"
 252 rerun_to_main
 253
 254 gdb_test "continue" \
 255     ".*marker1 .*:$bp_location15.*" \
 256     "continue to ignored & auto-deleted break marker1"
 257
 258 # Verify that a disabled breakpoint's ignore count isn't updated when
 259 # the bp is encountered.
 260
 261 if ![runto_main] then {
 262     fail "enable/disable break tests suppressed"
 263 }
 264
 265 set bp [break_at marker1 " line $bp_location15"]
 266
 267 gdb_test "ignore $bp 10" \
 268     "Will ignore next 10 crossings of breakpoint \[0-9\]*.*" \
 269     "ignore break marker1 10"
 270
 271 gdb_test_no_output "disable $bp" "disable break marker1"
 272
 273 gdb_continue_to_end "no stop at ignored & disabled break marker1"
 274 rerun_to_main
 275
 276 gdb_test "info break $bp" \
 277     "\[0-9\]*\[ \t\]+breakpoint\[ \t\]+keep\[ \t\]+n.*ignore next 10 hits.*" \
 278     "info ignored & disabled break marker1"
 279
 280 # Verify that GDB correctly handles the "continue" command with an argument,
 281 # which is an ignore count to set on the currently stopped-at breakpoint.
 282 # (Also verify that GDB gracefully handles the case where the inferior
 283 # isn't stopped at a breakpoint.)
 284 #
 285 if ![runto_main] then { fail "enable/disable break tests suppressed" }
 286
 287 gdb_test "break $bp_location1" \
 288     "Breakpoint \[0-9\]*.*, line $bp_location1.*" \
 289     "prepare to continue with ignore count"
 290
 291 gdb_test "continue 2" \
 292     "Will ignore next crossing of breakpoint \[0-9\]*.  Continuing..*" \
 293     "continue with ignore count"
 294
 295 gdb_test "next" ".*$bp_location11\[ \t\]*marker1.*" \
 296     "step after continue with ignore count"
 297
 298 set test "continue with ignore count, not stopped at bpt"
 299 gdb_test_multiple "continue 2" "$test" {
 300     -re "Not stopped at any breakpoint; argument ignored.*$gdb_prompt $" {
 301         pass "$test"
 302     }
 303     -re "No breakpoint number -1.*$gdb_prompt $" {
 304         kfail gdb/1689 "$test"
 305     }
 306 }
 307
 308 # Verify that GDB correctly handles the "enable/disable" command
 309 # with arguments, that include multiple locations.
 310 #
 311 if ![runto_main] then { fail "enable/disable break tests suppressed" }
 312
 313 set b1 0
 314 set b2 0
 315 set b3 0
 316 set b4 0
 317 set b1 [break_at main ""]
 318 set b2 [break_at main ""]
 319 set b3 [break_at main ""]
 320 set b4 [break_at main ""]
 321
 322 # Perform tests for disable/enable commands on multiple
 323 # locations and breakpoints.
 324 #
 325 # WHAT - the command to test (disable/enable).
 326 #
 327 # Note: tests involving location ranges (and more) are found in
 328 # gdb.cp/ena-dis-br-range.exp.
 329 #
 330 proc test_ena_dis_br { what } {
 331     global b1
 332     global b2
 333     global b3
 334     global b4
 335     global gdb_prompt
 336
 337     # OPPOS    - the command opposite to WHAT.
 338     # WHAT_RES - whether breakpoints are expected to end
 339     #            up enabled or disabled.
 340     # OPPOS_RES- same as WHAT_RES but opposite.
 341     # P1/P2    - proc to call (pass/fail).  Must be
 342     #            opposites.
 343     # Set variable values for disable command.
 344     set oppos "enable"
 345     set oppos_res "y"
 346     set what_res "n"
 347     set p1 "pass"
 348     set p2 "fail"
 349
 350     if { "$what" == "enable" } {
 351         # Set varibale values for enable command.
 352         set oppos "disable"
 353         set oppos_res "n"
 354         set what_res "y"
 355         set p1 "fail"
 356         set p2 "pass"
 357     }
 358
 359     # Now enable(disable) $b.1 $b2.1.
 360     gdb_test_no_output "$what $b1.1 $b2.1" "$what \$b1.1 \$b2.1"
 361     set test1 "${what}d \$b1.1 and \$b2.1"
 362
 363     # Now $b1.1 and $b2.1 should be enabled(disabled).
 364     gdb_test_multiple "info break" "$test1" {
 365        -re "(${b1}.1)(\[^\n\r\]*)( n.*)(${b2}.1)(\[^\n\r\]*)( n.*)$gdb_prompt $" {
 366            $p1 "$test1"
 367        }
 368        -re ".*$gdb_prompt $" {
 369            $p2 "$test1"
 370        }
 371     }
 372
 373     # Now enable(disable) $b1 fooo.1, it should give error on fooo.
 374     gdb_test "$what $b1 fooo.1" \
 375        "Bad breakpoint number 'fooo\\.1'" \
 376        "$what \$b1 fooo.1"
 377
 378     # $b1 should be enabled(disabled).
 379     gdb_test "info break" \
 380        "(${b1})(\[^\n\r]*)( $what_res.*)" \
 381        "${what}d \$b1"
 382
 383     gdb_test_no_output "$oppos $b3" "$oppos \$b3"
 384     gdb_test_no_output "$what $b4 $b3.1" "$what \$b4 \$b3.1"
 385     set test1 "${what}d \$b4 and \$b3.1,remain ${oppos}d \$b3"
 386
 387     # Now $b4 $b3.1 should be enabled(disabled) and
 388     # $b3 should remain disabled(enabled).
 389     gdb_test_multiple "info break" "$test1" {
 390        -re "(${b3})(\[^\n\r]*)( $oppos_res.*)(${b3}.1)(\[^\n\r\]*)( n.*)(${b4})(\[^\n\r\]*)( $what_res.*)$gdb_prompt $" {
 391            $p1 "$test1"
 392        }
 393        -re "(${b3})(\[^\n\r]*)( $oppos_res.*)(${b4})(\[^\n\r\]*)( $what_res.*)$gdb_prompt $" {
 394            $p2 "$test1"
 395        }
 396     }
 397
 398     # Now enable(disable) '$b4.1 fooobaar'.  This should error on
 399     # fooobaar.
 400     gdb_test "$what $b4.1 fooobaar" \
 401        "Bad breakpoint number 'fooobaar'" \
 402        "$what \$b4.1 fooobar"
 403     set test1 "${what}d \$b4.1"
 404
 405     # $b4.1 should be enabled(disabled).
 406     gdb_test_multiple "info break" "$test1" {
 407         -re "(${b4}.1)(\[^\n\r\]*)( n.*)$gdb_prompt $" {
 408            $p1 "$test1"
 409        }
 410        -re ".*$gdb_prompt $" {
 411            $p2 "$test1"
 412        }
 413     }
 414 }
 415
 416 test_ena_dis_br "disable"
 417 test_ena_dis_br "enable"
 418
 419 gdb_exit
 420 return 0