gdb/testsuite/gdb.base/sigbpt.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 2004-2020 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Check that GDB can and only executes single instructions when
  19 # stepping through a sequence of breakpoints interleaved by a signal
  20 # handler.
  21
  22 # This test is known to tickle the following problems: kernel letting
  23 # the inferior execute both the system call, and the instruction
  24 # following, when single-stepping a system call; kernel failing to
  25 # propogate the single-step state when single-stepping the sigreturn
  26 # system call, instead resuming the inferior at full speed; GDB
  27 # doesn't know how to software single-step across a sigreturn
  28 # instruction.  Since the kernel problems can be "fixed" using
  29 # software single-step this is KFAILed rather than XFAILed.
  30
  31 if [target_info exists gdb,nosignals] {
  32     verbose "Skipping sigbpt.exp because of nosignals."
  33     continue
  34 }
  35
  36
  37 standard_testfile
  38
  39 if {[prepare_for_testing "failed to prepare" $testfile $srcfile debug]} {
  40     return -1
  41 }
  42
  43 #
  44 # Run to `main' where we begin our tests.
  45 #
  46
  47 if ![runto_main] then {
  48     fail "can't run to main"
  49     return 0
  50 }
  51
  52 # If we can examine what's at memory address 0, it is possible that we
  53 # could also execute it.  This could probably make us run away,
  54 # executing random code, which could have all sorts of ill effects,
  55 # especially on targets without an MMU.  Don't run the tests in that
  56 # case.
  57
  58 if { [is_address_zero_readable] } {
  59     untested "memory at address 0 is possibly executable"
  60     return
  61 }
  62
  63 gdb_test "break keeper"
  64
  65 # Run to bowler, and then single step until there's a SIGSEGV.  Record
  66 # the address of each single-step instruction (up to and including the
  67 # instruction that causes the SIGSEGV) in bowler_addrs, and the address
  68 # of the actual SIGSEGV in segv_addr.
  69 # Note: this test detects which signal is received.  Usually it is SIGSEGV
  70 # (and we use SIGSEGV in comments) but on Darwin it is SIGBUS.
  71
  72 set bowler_addrs bowler
  73 set segv_addr none
  74 gdb_test {display/i $pc}
  75 gdb_test "advance bowler" "bowler.*" "advance to the bowler"
  76 set test "stepping to fault"
  77 set signame "SIGSEGV"
  78 gdb_test_multiple "stepi" "$test" {
  79     -re "Program received signal (SIGBUS|SIGSEGV).*pc(\r\n| *) *=> (0x\[0-9a-f\]*).*$gdb_prompt $" {
  80         set signame $expect_out(1,string)
  81         set segv_addr $expect_out(3,string)
  82         pass "$test"
  83     }
  84     -re " .*pc(\r\n| *)=> (0x\[0-9a-f\]*).*bowler.*$gdb_prompt $" {
  85         set bowler_addrs [concat $expect_out(2,string) $bowler_addrs]
  86         send_gdb "stepi\n"
  87         exp_continue
  88     }
  89 }
  90
  91 # Now record the address of the instruction following the faulting
  92 # instruction in bowler_addrs.
  93
  94 set test "get insn after fault"
  95 gdb_test_multiple {x/2i $pc} "$test" {
  96     -re "=> (0x\[0-9a-f\]*).*bowler.*(0x\[0-9a-f\]*).*bowler.*$gdb_prompt $" {
  97         set bowler_addrs [concat $expect_out(2,string) $bowler_addrs]
  98         pass "$test"
  99     }
 100 }
 101
 102 # Procedures for returning the address of the instruction before, at
 103 # and after, the faulting instruction.
 104
 105 proc before_segv { } {
 106     global bowler_addrs
 107     return [lindex $bowler_addrs 2]
 108 }
 109
 110 proc at_segv { } {
 111     global bowler_addrs
 112     return [lindex $bowler_addrs 1]
 113 }
 114
 115 proc after_segv { } {
 116     global bowler_addrs
 117     return [lindex $bowler_addrs 0]
 118 }
 119
 120 # Check that the address table and SIGSEGV correspond.
 121
 122 set test "verify that ${signame} occurs at the last STEPI insn"
 123 if {[string compare $segv_addr [at_segv]] == 0} {
 124     pass "$test"
 125 } else {
 126     fail "$test ($segv_addr [at_segv])"
 127 }
 128
 129 # Check that the inferior is correctly single stepped all the way back
 130 # to a faulting instruction.
 131
 132 proc stepi_out { name args } {
 133     global gdb_prompt
 134     global signame
 135
 136     # Set SIGSEGV to pass+nostop and then run the inferior all the way
 137     # through to the signal handler.  With the handler is reached,
 138     # disable SIGSEGV, ensuring that further signals stop the
 139     # inferior.  Stops a SIGSEGV infinite loop when a broke system
 140     # keeps re-executing the faulting instruction.
 141     rerun_to_main
 142     gdb_test "handle ${signame} nostop print pass" ".*" "${name}; pass ${signame}"
 143     gdb_test "continue" "keeper.*" "${name}; continue to keeper"
 144     gdb_test "handle ${signame} stop print nopass" ".*" "${name}; nopass ${signame}"
 145
 146     # Insert all the breakpoints.  To avoid the need to step over
 147     # these instructions, this is delayed until after the keeper has
 148     # been reached.
 149     for {set i 0} {$i < [llength $args]} {incr i} {
 150         gdb_test "break [lindex $args $i]" "Breakpoint.*" \
 151             "${name}; set breakpoint $i of [llength $args]"
 152     }
 153
 154     # Single step our way out of the keeper, through the signal
 155     # trampoline, and back to the instruction that faulted.
 156     set test "${name}; stepi out of handler"
 157     gdb_test_multiple "stepi" "$test" {
 158         -re "Could not insert single-step breakpoint.*$gdb_prompt $" {
 159             setup_kfail gdb/8841 "sparc*-*-openbsd*"
 160             fail "$test (could not insert single-step breakpoint)"
 161         }
 162         -re "Cannot insert breakpoint.*Cannot access memory.*$gdb_prompt $" {
 163             setup_kfail gdb/8841 "nios2*-*-linux*"
 164             fail "$test (could not insert single-step breakpoint)"
 165         }
 166         -re "keeper.*$gdb_prompt $" {
 167             send_gdb "stepi\n"
 168             exp_continue
 169         }
 170         -re "signal handler.*$gdb_prompt $" {
 171             send_gdb "stepi\n"
 172             exp_continue
 173         }
 174         -re "Program received signal SIGSEGV.*$gdb_prompt $" {
 175             kfail gdb/8807 "$test (executed fault insn)"
 176         }
 177         -re "Breakpoint.*pc(\r\n| *)[at_segv] .*bowler.*$gdb_prompt $" {
 178             pass "$test (at breakpoint)"
 179         }
 180         -re "Breakpoint.*pc(\r\n| *)[after_segv] .*bowler.*$gdb_prompt $" {
 181             kfail gdb/8807 "$test (executed breakpoint)"
 182         }
 183         -re "pc(\r\n| *)[at_segv] .*bowler.*$gdb_prompt $" {
 184             pass "$test"
 185         }
 186         -re "pc(\r\n| *)[after_segv] .*bowler.*$gdb_prompt $" {
 187             kfail gdb/8807 "$test (skipped fault insn)"
 188         }
 189         -re "pc(\r\n| *)=> 0x\[a-z0-9\]* .*bowler.*$gdb_prompt $" {
 190             kfail gdb/8807 "$test (corrupt pc)"
 191         }
 192     }
 193
 194     # Clear any breakpoints
 195     for {set i 0} {$i < [llength $args]} {incr i} {
 196         gdb_test "clear [lindex $args $i]" "Deleted .*" \
 197             "${name}; clear breakpoint $i of [llength $args]"
 198     }
 199 }
 200
 201 # Let a signal handler exit, returning to a breakpoint instruction
 202 # inserted at the original fault instruction.  Check that the
 203 # breakpoint is hit, and that single stepping off that breakpoint
 204 # executes the underlying fault instruction causing a SIGSEGV.
 205
 206 proc cont_out { name args } {
 207     global gdb_prompt
 208     global signame
 209
 210     # Set SIGSEGV to pass+nostop and then run the inferior all the way
 211     # through to the signal handler.  With the handler is reached,
 212     # disable SIGSEGV, ensuring that further signals stop the
 213     # inferior.  Stops a SIGSEGV infinite loop when a broke system
 214     # keeps re-executing the faulting instruction.
 215     rerun_to_main
 216     gdb_test "handle ${signame} nostop print pass" ".*" "${name}; pass ${signame}"
 217     gdb_test "continue" "keeper.*" "${name}; continue to keeper"
 218     gdb_test "handle ${signame} stop print nopass" ".*" "${name}; nopass ${signame}"
 219
 220     # Insert all the breakpoints.  To avoid the need to step over
 221     # these instructions, this is delayed until after the keeper has
 222     # been reached.  Always set a breakpoint at the signal trampoline
 223     # instruction.
 224     set args [concat $args "*[at_segv]"]
 225     for {set i 0} {$i < [llength $args]} {incr i} {
 226         gdb_test "break [lindex $args $i]" "Breakpoint.*" \
 227             "${name}; set breakpoint $i  of [llength $args]"
 228     }
 229
 230     # Let the handler return, it should "appear to hit" the breakpoint
 231     # inserted at the faulting instruction.  Note that the breakpoint
 232     # instruction wasn't executed, rather the inferior was SIGTRAPed
 233     # with the PC at the breakpoint.
 234     gdb_test "continue" "Breakpoint.*pc(\r\n| *)=> [at_segv] .*" \
 235         "${name}; continue to breakpoint at fault"
 236
 237     # Now single step the faulted instrction at that breakpoint.
 238     gdb_test "stepi" \
 239         "Program received signal ${signame}.*pc(\r\n| *)=> [at_segv] .*" \
 240         "${name}; stepi fault"
 241
 242     # Clear any breakpoints
 243     for {set i 0} {$i < [llength $args]} {incr i} {
 244         gdb_test "clear [lindex $args $i]" "Deleted .*" \
 245             "${name}; clear breakpoint $i of [llength $args]"
 246     }
 247
 248 }
 249
 250
 251
 252 # Try to confuse DECR_PC_AFTER_BREAK architectures by scattering
 253 # breakpoints around the faulting address.  In all cases the inferior
 254 # should single-step out of the signal trampoline halting (but not
 255 # executing) the fault instruction.
 256
 257 stepi_out "stepi"
 258 stepi_out "stepi bp before segv" "*[before_segv]"
 259 stepi_out "stepi bp at segv" "*[at_segv]"
 260 stepi_out "stepi bp before and at segv" "*[at_segv]" "*[before_segv]"
 261
 262
 263 # Try to confuse DECR_PC_AFTER_BREAK architectures by scattering
 264 # breakpoints around the faulting address.  In all cases the inferior
 265 # should exit the signal trampoline halting at the breakpoint that
 266 # replaced the fault instruction.
 267 cont_out "cont"
 268 cont_out "cont bp after segv" "*[before_segv]"
 269 cont_out "cont bp before and after segv" "*[before_segv]" "*[after_segv]"