configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([memcheck],
  28   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  29   [],
  30   [enable_memcheck=yes]
  31 )
  32
  33 AC_ARG_ENABLE([pthreads],
  34   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  35   [],
  36   [enable_pthreads=try]
  37 )
  38
  39 AC_ARG_ENABLE([libssh],
  40   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  41   [],
  42   [enable_libssh=try]
  43 )
  44
  45 AC_ARG_ENABLE([mpls-kernel],
  46   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  47   [],
  48   [enable_mpls_kernel=try]
  49 )
  50
  51 AC_ARG_WITH([protocols],
  52   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  53   [],
  54   [with_protocols="all"]
  55 )
  56
  57 AC_ARG_WITH([sysconfig],
  58   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  59 )
  60
  61 AC_ARG_WITH([runtimedir],
  62   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  63   [runstatedir="$with_runtimedir"]
  64 )
  65
  66 AC_ARG_WITH([iproutedir],
  67   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  68   [given_iproutedir="yes"]
  69 )
  70
  71 AC_ARG_VAR([FLEX], [location of the Flex program])
  72 AC_ARG_VAR([BISON], [location of the Bison program])
  73 AC_ARG_VAR([M4], [location of the M4 program])
  74
  75
  76 if test "$srcdir" = . ; then
  77   # Building in current directory => create obj directory holding all objects
  78   objdir=obj
  79 else
  80   # Building in separate directory
  81   objdir=.
  82 fi
  83
  84 exedir=.
  85
  86 AC_SUBST([objdir])
  87 AC_SUBST([exedir])
  88 AC_SUBST([srcdir])
  89
  90 # Workaround for older Autoconfs that do not define runstatedir
  91 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
  92 AC_SUBST([runstatedir])
  93
  94 CONFIG_FILE="\$(sysconfdir)/bird.conf"
  95 AC_SUBST([CONFIG_FILE])
  96
  97 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
  98 AC_SUBST([CONTROL_SOCKET])
  99
 100 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 101   [],
 102   [AC_MSG_ERROR([Function clock_gettime not available.])]
 103 )
 104
 105 AC_CANONICAL_HOST
 106
 107 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 108 if test "$ac_test_CFLAGS" != set ; then
 109   bird_cflags_default=yes
 110 fi
 111
 112 AC_PROG_CC
 113 AC_PROG_CC_C99
 114 if test -z "$GCC" ; then
 115   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 116 fi
 117
 118 BIRD_CHECK_THREAD_LOCAL
 119 if test "$bird_cv_thread_local" = yes ; then
 120   AC_DEFINE([HAVE_THREAD_LOCAL], [1], [Define to 1 if _Thread_local is available])
 121 fi
 122
 123 if test "$enable_pthreads" != no ; then
 124   BIRD_CHECK_PTHREADS
 125
 126   if test "$bird_cv_lib_pthreads" = yes ; then
 127     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 128     CFLAGS="$CFLAGS -pthread"
 129     LDFLAGS="$LDFLAGS -pthread"
 130     proto_bfd=bfd
 131   elif test "$enable_pthreads" = yes ; then
 132     AC_MSG_ERROR([POSIX threads not available.])
 133   fi
 134
 135   if test "$enable_pthreads" = try ; then
 136     enable_pthreads="$bird_cv_lib_pthreads"
 137   fi
 138 fi
 139
 140 if test "$bird_cflags_default" = yes ; then
 141   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 142   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 143   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 144   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 145
 146   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 147   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 148   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 149   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
 150   BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
 151 fi
 152
 153 if test "$enable_debug" = no; then
 154   BIRD_CHECK_LTO
 155 fi
 156
 157 if test "$bird_cv_c_lto" = yes; then
 158   CFLAGS="$CFLAGS -flto"
 159   LDFLAGS="$LDFLAGS -flto=4"
 160 fi
 161
 162 AC_MSG_CHECKING([CFLAGS])
 163 AC_MSG_RESULT([$CFLAGS])
 164
 165 AC_PROG_CPP
 166 AC_PROG_INSTALL
 167 AC_PROG_RANLIB
 168 AC_CHECK_PROG([FLEX], [flex], [flex])
 169 AC_CHECK_PROG([BISON], [bison], [bison])
 170 AC_CHECK_PROGS([M4], [gm4 m4])
 171
 172 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 173 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 174 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 175
 176 AC_MSG_CHECKING([bison version])
 177 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 178 AC_MSG_RESULT([$BISON_VERSION])
 179 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 180   M4FLAGS="$M4FLAGS -s"
 181 fi
 182
 183 if test "$bird_bison_enhanced_error" = yes; then
 184   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 185 fi
 186
 187 AC_SUBST([M4FLAGS])
 188 AC_SUBST([BISONFLAGS])
 189
 190 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 191   [],
 192   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 193 )
 194
 195 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 196   if test -f $with_sysconfig ; then
 197     sysdesc=$with_sysconfig
 198   else
 199     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 200     if ! test -f $sysdesc ; then
 201       sysdesc=$sysdesc.h
 202     fi
 203   fi
 204 elif test -f sysconfig.h ; then
 205   sysdesc=sysconfig
 206 else
 207   case "$host_os" in
 208     linux*)
 209       sysdesc=linux
 210       default_iproutedir="/etc/iproute2"
 211       ;;
 212     freebsd*)
 213       sysdesc=bsd
 214       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 215       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 216       ;;
 217     kfreebsd*)
 218       sysdesc=bsd
 219       ;;
 220     netbsd*)
 221       sysdesc=bsd
 222       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 223       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 224       ;;
 225     openbsd*)
 226       sysdesc=bsd
 227       ;;
 228     dragonfly*)
 229       sysdesc=bsd
 230       ;;
 231     *)
 232       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 233       ;;
 234     esac
 235     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 236 fi
 237 AC_MSG_CHECKING([which OS configuration should we use])
 238 AC_MSG_RESULT([$sysdesc])
 239 if ! test -f $sysdesc ; then
 240   AC_MSG_ERROR([The system configuration file is missing.])
 241 fi
 242 sysname=`echo $sysdesc | sed 's/\.h$//'`
 243 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 244
 245 AC_MSG_CHECKING([system-dependent directories])
 246 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 247 AC_MSG_RESULT([$sysdep_dirs])
 248 AC_SUBST([sysdep_dirs])
 249
 250 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 251
 252 if test -n "$given_iproutedir"
 253 then iproutedir=$with_iproutedir
 254 else iproutedir=$default_iproutedir
 255 fi
 256
 257 AC_SUBST([iproutedir])
 258
 259 DAEMON_LIBS=
 260 AC_SUBST(DAEMON_LIBS)
 261
 262 if test "$enable_libssh" != no ; then
 263   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 264   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 265
 266   if test "$fail" != yes ; then
 267     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 268     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 269     proto_rpki=rpki
 270     enable_libssh=yes
 271   else
 272     if test "$enable_libssh" = yes ; then
 273       AC_MSG_ERROR([LibSSH not available.])
 274     else
 275       enable_libssh=no
 276     fi
 277   fi
 278 fi
 279
 280 if test "$enable_mpls_kernel" != no ; then
 281   BIRD_CHECK_MPLS_KERNEL
 282
 283   if test "$bird_cv_mpls_kernel" = yes ; then
 284     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 285   elif test "$enable_mpls_kernel" = yes ; then
 286     AC_MSG_ERROR([Kernel MPLS support not found.])
 287   fi
 288
 289   if test "$enable_mpls_kernel" = try ; then
 290     enable_mpls_kernel="$bird_cv_mpls_kernel"
 291   fi
 292 fi
 293
 294 all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
 295
 296 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 297
 298 if test "$with_protocols" = all ; then
 299   with_protocols="$all_protocols"
 300 fi
 301
 302 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 303 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 304 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 305 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 306 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 307 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 308 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 309 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 310 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 311 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 312
 313 AC_MSG_CHECKING([protocols])
 314 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 315 if test "$protocols" = no ; then protocols= ; fi
 316 for a in $protocols ; do
 317   if ! test -f $srcdir/proto/$a/Makefile ; then
 318     AC_MSG_RESULT([failed])
 319     AC_MSG_ERROR([Requested protocol $a not found])
 320   fi
 321   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 322 done
 323 AC_MSG_RESULT([ok])
 324 AC_SUBST([protocols])
 325
 326 case $sysdesc in
 327   */linux*)
 328     AC_CHECK_HEADER([linux/rtnetlink.h],
 329       [],
 330       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 331       [
 332         dnl Some older versions of Linux kernel headers require these includes
 333         #include <asm/types.h>
 334         #include <sys/socket.h>
 335       ]
 336     )
 337     ;;
 338 esac
 339
 340 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 341 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 342
 343 AC_C_BIGENDIAN(
 344   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 345   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 346   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 347 )
 348
 349 BIRD_CHECK_ANDROID_GLOB
 350 if test "$bird_cv_lib_glob" = no ; then
 351   AC_MSG_ERROR([glob.h not found.])
 352 elif test "$bird_cv_lib_glob" != yes ; then
 353   LIBS="$LIBS $bird_cv_lib_glob"
 354 fi
 355
 356 BIRD_CHECK_ANDROID_LOG
 357 if test "$bird_cv_lib_log" = no ; then
 358   AC_MSG_ERROR([don't know how to link syslog.])
 359 elif test "$bird_cv_lib_log" != yes ; then
 360   LIBS="$LIBS $bird_cv_lib_log"
 361 fi
 362
 363 if test "$enable_debug" = yes ; then
 364   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 365   LDFLAGS="$LDFLAGS -rdynamic"
 366   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 367
 368   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 369   BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
 370
 371   AC_CHECK_HEADER([execinfo.h],
 372     [
 373       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 374       AC_SEARCH_LIBS([backtrace], [execinfo],
 375         [],
 376         [AC_MSG_ERROR([Function backtrace not available.])]
 377       )
 378     ]
 379   )
 380
 381   if test "$enable_memcheck" = yes ; then
 382     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 383     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 384       AC_CHECK_LIB([efence], [malloc])
 385     fi
 386   fi
 387 else
 388   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 389   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_implicit_fallthrough], [-Wno-implicit-fallthrough])
 390 fi
 391
 392 CLIENT=birdcl
 393 CLIENT_LIBS=
 394 if test "$enable_client" = yes ; then
 395   CLIENT="$CLIENT birdc"
 396   BASE_LIBS="$LIBS"
 397   LIBS=""
 398
 399   AC_CHECK_HEADERS([curses.h],
 400     [],
 401     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 402     [AC_INCLUDES_DEFAULT]
 403   )
 404
 405   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 406     [TINFO_LIBS="$LIBS"; LIBS=""],
 407     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 408   )
 409
 410   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 411     [],
 412     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 413     [AC_INCLUDES_DEFAULT]
 414   )
 415
 416   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 417     [READLINE_LIBS="$LIBS"; LIBS=""],
 418     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 419     [$TINFO_LIBS]
 420   )
 421
 422   AC_CHECK_LIB([readline], [rl_crlf],
 423     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 424     [],
 425     [$TINFO_LIBS]
 426   )
 427
 428   AC_CHECK_LIB([readline], [rl_ding],
 429     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 430     [],
 431     [$TINFO_LIBS]
 432   )
 433
 434   LIBS="$BASE_LIBS"
 435   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 436 fi
 437 AC_SUBST([CLIENT])
 438 AC_SUBST([CLIENT_LIBS])
 439
 440 mkdir -p $objdir/sysdep
 441 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 442 AC_CONFIG_FILES([Makefile:Makefile.in])
 443 AC_OUTPUT
 444
 445 AC_MSG_RESULT()
 446 AC_MSG_RESULT([BIRD was configured with the following options:])
 447 AC_MSG_RESULT([        Source directory:        $srcdir])
 448 AC_MSG_RESULT([        Object directory:        $objdir])
 449 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 450 AC_MSG_RESULT([        System configuration:    $sysdesc])
 451 AC_MSG_RESULT([        Debugging:               $enable_debug])
 452 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 453 AC_MSG_RESULT([        Routing protocols:       $protocols])
 454 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 455 AC_MSG_RESULT([        Client:                  $enable_client])
 456
 457 rm -f $objdir/.*-stamp