proto/bgp/config.Y

   1 /*
   2  *      BIRD -- Border Gateway Protocol Configuration
   3  *
   4  *      (c) 2000 Martin Mares <mj@ucw.cz>
   5  *
   6  *      Can be freely distributed and used under the terms of the GNU GPL.
   7  */
   8
   9 CF_HDR
  10
  11 #include "proto/bgp/bgp.h"
  12
  13 CF_DEFINES
  14
  15 #define BGP_CFG ((struct bgp_config *) this_proto)
  16 #define BGP_CC ((struct bgp_channel_config *) this_channel)
  17
  18 CF_DECLS
  19
  20 CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY, KEEPALIVE,
  21         MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT, PATH, METRIC, ERROR,
  22         START, DELAY, FORGET, WAIT, ENABLE, DISABLE, AFTER, BGP_PATH,
  23         BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN, BGP_NEXT_HOP, BGP_ATOMIC_AGGR,
  24         BGP_AGGREGATOR, BGP_COMMUNITY, BGP_EXT_COMMUNITY, BGP_LARGE_COMMUNITY,
  25         SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT, CLUSTER, ID, AS4, ADVERTISE,
  26         IPV4, CAPABILITIES, LIMIT, PASSIVE, PREFER, OLDER, MISSING, LLADDR,
  27         DROP, IGNORE, ROUTE, REFRESH, INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID,
  28         BGP_CLUSTER_LIST, IGP, TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL,
  29         SECURITY, DETERMINISTIC, SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX,
  30         GRACEFUL, RESTART, AWARE, CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY,
  31         STRICT, BIND, CONFEDERATION, MEMBER, MULTICAST, FLOW4, FLOW6, LONG,
  32         LIVED, STALE, IMPORT, IBGP, EBGP, MANDATORY, INTERNAL, EXTERNAL, SETS,
  33         DYNAMIC, RANGE, NAME, DIGITS, BGP_AIGP, AIGP, ORIGINATE, COST)
  34
  35 %type <i> bgp_nh
  36 %type <i32> bgp_afi
  37
  38 CF_KEYWORDS(CEASE, PREFIX, LIMIT, HIT, ADMINISTRATIVE, SHUTDOWN, RESET, PEER,
  39         CONFIGURATION, CHANGE, DECONFIGURED, CONNECTION, REJECTED, COLLISION,
  40         OUT, OF, RESOURCES)
  41
  42 %type<i> bgp_cease_mask bgp_cease_list bgp_cease_flag
  43
  44 CF_GRAMMAR
  45
  46 proto: bgp_proto '}'  ;
  47
  48 bgp_proto_start: proto_start BGP {
  49      this_proto = proto_config_new(&proto_bgp, $1);
  50      BGP_CFG->local_port = BGP_PORT;
  51      BGP_CFG->remote_port = BGP_PORT;
  52      BGP_CFG->multihop = -1;    /* undefined */
  53      BGP_CFG->hold_time = 240;
  54      BGP_CFG->initial_hold_time = 240;
  55      BGP_CFG->compare_path_lengths = 1;
  56      BGP_CFG->igp_metric = 1;
  57      BGP_CFG->connect_delay_time = 5;
  58      BGP_CFG->connect_retry_time = 120;
  59      BGP_CFG->error_amnesia_time = 300;
  60      BGP_CFG->error_delay_time_min = 60;
  61      BGP_CFG->error_delay_time_max = 300;
  62      BGP_CFG->enable_refresh = 1;
  63      BGP_CFG->enable_as4 = 1;
  64      BGP_CFG->capabilities = 2;
  65      BGP_CFG->interpret_communities = 1;
  66      BGP_CFG->allow_as_sets = 1;
  67      BGP_CFG->default_local_pref = 100;
  68      BGP_CFG->gr_mode = BGP_GR_AWARE;
  69      BGP_CFG->gr_time = 120;
  70      BGP_CFG->llgr_mode = -1;
  71      BGP_CFG->llgr_time = 3600;
  72      BGP_CFG->setkey = 1;
  73      BGP_CFG->dynamic_name = "dynbgp";
  74      BGP_CFG->check_link = -1;
  75    }
  76  ;
  77
  78 bgp_loc_opts:
  79    /* empty */
  80  | bgp_loc_opts PORT expr { BGP_CFG->local_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  81  | bgp_loc_opts AS expr { BGP_CFG->local_as = $3; }
  82  ;
  83
  84 bgp_nbr_opts:
  85    /* empty */
  86  | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  87  | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
  88  | bgp_nbr_opts INTERNAL { BGP_CFG->peer_type = BGP_PT_INTERNAL; }
  89  | bgp_nbr_opts EXTERNAL { BGP_CFG->peer_type = BGP_PT_EXTERNAL; }
  90  ;
  91
  92 bgp_cease_mask:
  93    /* true -> all except connection collision */
  94    bool { $$ = $1 ? ~(1 << 7) : 0; }
  95  | '{' bgp_cease_list '}' { $$ = $2; }
  96  ;
  97
  98 bgp_cease_list:
  99    bgp_cease_flag
 100  | bgp_cease_list ',' bgp_cease_flag { $$ = $1 | $3; }
 101  ;
 102
 103 bgp_cease_flag:
 104    CEASE                        { $$ = 1 << 0; }
 105  | PREFIX LIMIT HIT             { $$ = 1 << 1; }
 106  | ADMINISTRATIVE SHUTDOWN      { $$ = 1 << 2; }
 107  | PEER DECONFIGURED            { $$ = 1 << 3; }
 108  | ADMINISTRATIVE RESET         { $$ = 1 << 4; }
 109  | CONNECTION REJECTED          { $$ = 1 << 5; }
 110  | CONFIGURATION CHANGE         { $$ = 1 << 6; }
 111  | CONNECTION COLLISION         { $$ = 1 << 7; }
 112  | OUT OF RESOURCES             { $$ = 1 << 8; }
 113  ;
 114
 115 bgp_proto:
 116    bgp_proto_start proto_name '{'
 117  | bgp_proto proto_item ';'
 118  | bgp_proto bgp_proto_channel ';'
 119  | bgp_proto LOCAL bgp_loc_opts ';'
 120  | bgp_proto LOCAL ipa ipa_scope bgp_loc_opts ';' {
 121      BGP_CFG->local_ip = $3;
 122      if ($4) BGP_CFG->iface = $4;
 123    }
 124  | bgp_proto NEIGHBOR bgp_nbr_opts ';'
 125  | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
 126      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 127        cf_error("Only one neighbor per BGP instance is allowed");
 128      BGP_CFG->remote_ip = $3;
 129      if ($4) BGP_CFG->iface = $4;
 130    }
 131  | bgp_proto NEIGHBOR RANGE net_ip bgp_nbr_opts ';' {
 132      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 133        cf_error("Only one neighbor per BGP instance is allowed");
 134      net_addr *n = cfg_alloc($4.length);
 135      net_copy(n, &($4));
 136      BGP_CFG->remote_range = n;
 137    }
 138  | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
 139  | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
 140  | bgp_proto RR CLIENT bool ';' { BGP_CFG->rr_client = $4; }
 141  | bgp_proto RS CLIENT bool ';' { BGP_CFG->rs_client = $4; }
 142  | bgp_proto CONFEDERATION expr ';' { BGP_CFG->confederation = $3; }
 143  | bgp_proto CONFEDERATION MEMBER bool ';' { BGP_CFG->confederation_member = $4; }
 144  | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
 145  | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
 146  | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
 147  | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
 148  | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
 149  | bgp_proto DYNAMIC NAME text ';' {
 150      if (strchr($4, '%')) cf_error("Forbidden character '%%' in dynamic name");
 151      if (strlen($4) > (SYM_MAX_LEN - 16)) cf_error("Dynamic name too long");
 152      BGP_CFG->dynamic_name = $4;
 153    }
 154  | bgp_proto DYNAMIC NAME DIGITS expr ';' { BGP_CFG->dynamic_name_digits = $5; if ($5>10) cf_error("Dynamic name digits must be at most 10"); }
 155  | bgp_proto STRICT BIND bool ';' { BGP_CFG->strict_bind = $4; }
 156  | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
 157  | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
 158  | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
 159  | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
 160  | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
 161  | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
 162  | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
 163  | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->local_ip = $4; }
 164  | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
 165  | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
 166  | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
 167  | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
 168  | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
 169  | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
 170  | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
 171  | bgp_proto DISABLE AFTER CEASE bgp_cease_mask ';' { BGP_CFG->disable_after_cease = $5; }
 172  | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
 173  | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
 174  | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
 175  | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
 176  | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
 177  | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
 178  | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
 179  | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
 180  | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
 181  | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
 182  | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
 183  | bgp_proto ALLOW AS SETS bool ';' { BGP_CFG->allow_as_sets = $5; }
 184  | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
 185  | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
 186  | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
 187  | bgp_proto LONG LIVED GRACEFUL RESTART bool ';' { BGP_CFG->llgr_mode = $6; }
 188  | bgp_proto LONG LIVED GRACEFUL RESTART AWARE ';' { BGP_CFG->llgr_mode = BGP_LLGR_AWARE; }
 189  | bgp_proto LONG LIVED STALE TIME expr ';' { BGP_CFG->llgr_time = $6; }
 190  | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
 191  | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
 192  | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
 193  | bgp_proto BFD GRACEFUL ';' { BGP_CFG->bfd = BGP_BFD_GRACEFUL; cf_check_bfd(1); }
 194  ;
 195
 196 bgp_afi:
 197    IPV4                 { $$ = BGP_AF_IPV4; }
 198  | IPV6                 { $$ = BGP_AF_IPV6; }
 199  | IPV4 MULTICAST       { $$ = BGP_AF_IPV4_MC; }
 200  | IPV6 MULTICAST       { $$ = BGP_AF_IPV6_MC; }
 201  | IPV4 MPLS            { $$ = BGP_AF_IPV4_MPLS; }
 202  | IPV6 MPLS            { $$ = BGP_AF_IPV6_MPLS; }
 203  | VPN4 MPLS            { $$ = BGP_AF_VPN4_MPLS; }
 204  | VPN6 MPLS            { $$ = BGP_AF_VPN6_MPLS; }
 205  | VPN4 MULTICAST       { $$ = BGP_AF_VPN4_MC; }
 206  | VPN6 MULTICAST       { $$ = BGP_AF_VPN6_MC; }
 207  | FLOW4                { $$ = BGP_AF_FLOW4; }
 208  | FLOW6                { $$ = BGP_AF_FLOW6; }
 209  ;
 210
 211 bgp_channel_start: bgp_afi
 212 {
 213   const struct bgp_af_desc *desc = bgp_get_af_desc($1);
 214
 215   if (!desc)
 216     cf_error("Unknown AFI/SAFI");
 217
 218   this_channel = channel_config_get(&channel_bgp, desc->name, desc->net, this_proto);
 219
 220   /* New channel */
 221   if (!BGP_CC->desc)
 222   {
 223     BGP_CC->c.in_filter = FILTER_UNDEF;
 224     BGP_CC->c.out_filter = FILTER_UNDEF;
 225     BGP_CC->c.ra_mode = RA_UNDEF;
 226     BGP_CC->afi = $1;
 227     BGP_CC->desc = desc;
 228     BGP_CC->next_hop_keep = 0xff; /* undefined */
 229     BGP_CC->gr_able = 0xff;     /* undefined */
 230     BGP_CC->llgr_able = 0xff;   /* undefined */
 231     BGP_CC->llgr_time = ~0U;    /* undefined */
 232     BGP_CC->aigp = 0xff;        /* undefined */
 233   }
 234 };
 235
 236 bgp_nh:
 237    bool { $$ = $1; }
 238  | IBGP { $$ = NH_IBGP; }
 239  | EBGP { $$ = NH_EBGP; }
 240
 241 bgp_channel_item:
 242    channel_item
 243  | NEXT HOP ADDRESS ipa { BGP_CC->next_hop_addr = $4; }
 244  | NEXT HOP SELF bgp_nh { BGP_CC->next_hop_self = $4; }
 245  | NEXT HOP KEEP bgp_nh { BGP_CC->next_hop_keep = $4; }
 246  | MANDATORY bool { BGP_CC->mandatory = $2; }
 247  | MISSING LLADDR SELF { BGP_CC->missing_lladdr = MLL_SELF; }
 248  | MISSING LLADDR DROP { BGP_CC->missing_lladdr = MLL_DROP; }
 249  | MISSING LLADDR IGNORE { BGP_CC->missing_lladdr = MLL_IGNORE; }
 250  | GATEWAY DIRECT { BGP_CC->gw_mode = GW_DIRECT; }
 251  | GATEWAY RECURSIVE { BGP_CC->gw_mode = GW_RECURSIVE; }
 252  | SECONDARY bool { BGP_CC->secondary = $2; }
 253  | GRACEFUL RESTART bool { BGP_CC->gr_able = $3; }
 254  | LONG LIVED GRACEFUL RESTART bool { BGP_CC->llgr_able = $5; }
 255  | LONG LIVED STALE TIME expr { BGP_CC->llgr_time = $5; }
 256  | EXTENDED NEXT HOP bool { BGP_CC->ext_next_hop = $4; }
 257  | ADD PATHS RX { BGP_CC->add_path = BGP_ADD_PATH_RX; }
 258  | ADD PATHS TX { BGP_CC->add_path = BGP_ADD_PATH_TX; }
 259  | ADD PATHS bool { BGP_CC->add_path = $3 ? BGP_ADD_PATH_FULL : 0; }
 260  | IMPORT TABLE bool { BGP_CC->import_table = $3; }
 261  | EXPORT TABLE bool { BGP_CC->export_table = $3; }
 262  | AIGP bool { BGP_CC->aigp = $2; BGP_CC->aigp_originate = 0; }
 263  | AIGP ORIGINATE { BGP_CC->aigp = 1; BGP_CC->aigp_originate = 1; }
 264  | COST expr { BGP_CC->cost = $2; if ($2 < 1) cf_error("Cost must be positive"); }
 265  | IGP TABLE rtable {
 266     if (BGP_CC->desc->no_igp)
 267       cf_error("IGP table not allowed here");
 268
 269     if ($3->addr_type == NET_IP4)
 270       BGP_CC->igp_table_ip4 = $3;
 271     else if ($3->addr_type == NET_IP6)
 272       BGP_CC->igp_table_ip6 = $3;
 273     else
 274       cf_error("Mismatched IGP table type");
 275    }
 276  ;
 277
 278 bgp_channel_opts:
 279    /* empty */
 280  | bgp_channel_opts bgp_channel_item ';'
 281  ;
 282
 283 bgp_channel_opt_list:
 284    /* empty */
 285  | '{' bgp_channel_opts '}'
 286  ;
 287
 288 bgp_channel_end:
 289 {
 290   if (!this_channel->table)
 291     cf_error("Routing table not specified");
 292
 293   this_channel = NULL;
 294 };
 295
 296 bgp_proto_channel: bgp_channel_start bgp_channel_opt_list bgp_channel_end;
 297
 298
 299 dynamic_attr: BGP_ORIGIN
 300         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(PROTOCOL_BGP, BA_ORIGIN)); } ;
 301 dynamic_attr: BGP_PATH
 302         { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(PROTOCOL_BGP, BA_AS_PATH)); } ;
 303 dynamic_attr: BGP_NEXT_HOP
 304         { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(PROTOCOL_BGP, BA_NEXT_HOP)); } ;
 305 dynamic_attr: BGP_MED
 306         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_MULTI_EXIT_DISC)); } ;
 307 dynamic_attr: BGP_LOCAL_PREF
 308         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_LOCAL_PREF)); } ;
 309 dynamic_attr: BGP_ATOMIC_AGGR
 310         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_ATOMIC_AGGR)); } ;
 311 dynamic_attr: BGP_AGGREGATOR
 312         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AGGREGATOR)); } ;
 313 dynamic_attr: BGP_COMMUNITY
 314         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_COMMUNITY)); } ;
 315 dynamic_attr: BGP_ORIGINATOR_ID
 316         { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(PROTOCOL_BGP, BA_ORIGINATOR_ID)); } ;
 317 dynamic_attr: BGP_CLUSTER_LIST
 318         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_CLUSTER_LIST)); } ;
 319 dynamic_attr: BGP_EXT_COMMUNITY
 320         { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(PROTOCOL_BGP, BA_EXT_COMMUNITY)); } ;
 321 dynamic_attr: BGP_AIGP
 322         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AIGP)); } ;
 323 dynamic_attr: BGP_LARGE_COMMUNITY
 324         { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(PROTOCOL_BGP, BA_LARGE_COMMUNITY)); } ;
 325
 326
 327
 328 CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
 329
 330 CF_CODE
 331
 332 CF_END