proto/bgp/config.Y

   1 /*
   2  *      BIRD -- Border Gateway Protocol Configuration
   3  *
   4  *      (c) 2000 Martin Mares <mj@ucw.cz>
   5  *
   6  *      Can be freely distributed and used under the terms of the GNU GPL.
   7  */
   8
   9 CF_HDR
  10
  11 #include "proto/bgp/bgp.h"
  12
  13 CF_DEFINES
  14
  15 #define BGP_CFG ((struct bgp_config *) this_proto)
  16 #define BGP_CC ((struct bgp_channel_config *) this_channel)
  17
  18 CF_DECLS
  19
  20 CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY, KEEPALIVE,
  21         MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT, PATH, METRIC, ERROR,
  22         START, DELAY, FORGET, WAIT, ENABLE, DISABLE, AFTER, BGP_PATH,
  23         BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN, BGP_NEXT_HOP, BGP_ATOMIC_AGGR,
  24         BGP_AGGREGATOR, BGP_COMMUNITY, BGP_EXT_COMMUNITY, BGP_LARGE_COMMUNITY,
  25         SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT, CLUSTER, ID, AS4, ADVERTISE,
  26         IPV4, CAPABILITIES, LIMIT, PASSIVE, PREFER, OLDER, MISSING, LLADDR,
  27         DROP, IGNORE, ROUTE, REFRESH, INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID,
  28         BGP_CLUSTER_LIST, IGP, TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL,
  29         SECURITY, DETERMINISTIC, SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX,
  30         GRACEFUL, RESTART, AWARE, CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY,
  31         STRICT, BIND, CONFEDERATION, MEMBER, MULTICAST, FLOW4, FLOW6, LONG,
  32         LIVED, STALE)
  33
  34 %type <i32> bgp_afi
  35
  36 CF_KEYWORDS(CEASE, PREFIX, LIMIT, HIT, ADMINISTRATIVE, SHUTDOWN, RESET, PEER,
  37         CONFIGURATION, CHANGE, DECONFIGURED, CONNECTION, REJECTED, COLLISION,
  38         OUT, OF, RESOURCES)
  39
  40 %type<i> bgp_cease_mask bgp_cease_list bgp_cease_flag
  41
  42 CF_GRAMMAR
  43
  44 proto: bgp_proto '}'  ;
  45
  46 bgp_proto_start: proto_start BGP {
  47      this_proto = proto_config_new(&proto_bgp, $1);
  48      BGP_CFG->local_port = BGP_PORT;
  49      BGP_CFG->remote_port = BGP_PORT;
  50      BGP_CFG->multihop = -1;    /* undefined */
  51      BGP_CFG->hold_time = 240;
  52      BGP_CFG->initial_hold_time = 240;
  53      BGP_CFG->compare_path_lengths = 1;
  54      BGP_CFG->igp_metric = 1;
  55      BGP_CFG->connect_delay_time = 5;
  56      BGP_CFG->connect_retry_time = 120;
  57      BGP_CFG->error_amnesia_time = 300;
  58      BGP_CFG->error_delay_time_min = 60;
  59      BGP_CFG->error_delay_time_max = 300;
  60      BGP_CFG->enable_refresh = 1;
  61      BGP_CFG->enable_as4 = 1;
  62      BGP_CFG->capabilities = 2;
  63      BGP_CFG->interpret_communities = 1;
  64      BGP_CFG->default_local_pref = 100;
  65      BGP_CFG->gr_mode = BGP_GR_AWARE;
  66      BGP_CFG->gr_time = 120;
  67      BGP_CFG->llgr_mode = -1;
  68      BGP_CFG->llgr_time = 3600;
  69      BGP_CFG->setkey = 1;
  70      BGP_CFG->check_link = -1;
  71    }
  72  ;
  73
  74 bgp_loc_opts:
  75    /* empty */
  76  | bgp_loc_opts PORT expr { BGP_CFG->local_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  77  | bgp_loc_opts AS expr { BGP_CFG->local_as = $3; }
  78  ;
  79
  80 bgp_nbr_opts:
  81    /* empty */
  82  | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  83  | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
  84  ;
  85
  86 bgp_cease_mask:
  87    /* true -> all except connection collision */
  88    bool { $$ = $1 ? ~(1 << 7) : 0; }
  89  | '{' bgp_cease_list '}' { $$ = $2; }
  90  ;
  91
  92 bgp_cease_list:
  93    bgp_cease_flag
  94  | bgp_cease_list ',' bgp_cease_flag { $$ = $1 | $3; }
  95  ;
  96
  97 bgp_cease_flag:
  98    CEASE                        { $$ = 1 << 0; }
  99  | PREFIX LIMIT HIT             { $$ = 1 << 1; }
 100  | ADMINISTRATIVE SHUTDOWN      { $$ = 1 << 2; }
 101  | PEER DECONFIGURED            { $$ = 1 << 3; }
 102  | ADMINISTRATIVE RESET         { $$ = 1 << 4; }
 103  | CONNECTION REJECTED          { $$ = 1 << 5; }
 104  | CONFIGURATION CHANGE         { $$ = 1 << 6; }
 105  | CONNECTION COLLISION         { $$ = 1 << 7; }
 106  | OUT OF RESOURCES             { $$ = 1 << 8; }
 107  ;
 108
 109 bgp_proto:
 110    bgp_proto_start proto_name '{'
 111  | bgp_proto proto_item ';'
 112  | bgp_proto bgp_proto_channel ';'
 113  | bgp_proto LOCAL bgp_loc_opts ';'
 114  | bgp_proto LOCAL ipa ipa_scope bgp_loc_opts ';' {
 115      BGP_CFG->local_ip = $3;
 116      if ($4) BGP_CFG->iface = $4;
 117    }
 118  | bgp_proto NEIGHBOR bgp_nbr_opts ';'
 119  | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
 120      if (ipa_nonzero(BGP_CFG->remote_ip))
 121        cf_error("Only one neighbor per BGP instance is allowed");
 122      BGP_CFG->remote_ip = $3;
 123      if ($4) BGP_CFG->iface = $4;
 124    }
 125  | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
 126  | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
 127  | bgp_proto RR CLIENT bool ';' { BGP_CFG->rr_client = $4; }
 128  | bgp_proto RS CLIENT bool ';' { BGP_CFG->rs_client = $4; }
 129  | bgp_proto CONFEDERATION expr ';' { BGP_CFG->confederation = $3; }
 130  | bgp_proto CONFEDERATION MEMBER bool ';' { BGP_CFG->confederation_member = $4; }
 131  | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
 132  | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
 133  | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
 134  | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
 135  | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
 136  | bgp_proto STRICT BIND bool ';' { BGP_CFG->strict_bind = $4; }
 137  | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
 138  | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
 139  | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
 140  | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
 141  | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
 142  | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
 143  | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
 144  | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->local_ip = $4; }
 145  | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
 146  | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
 147  | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
 148  | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
 149  | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
 150  | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
 151  | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
 152  | bgp_proto DISABLE AFTER CEASE bgp_cease_mask ';' { BGP_CFG->disable_after_cease = $5; }
 153  | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
 154  | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
 155  | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
 156  | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
 157  | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
 158  | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
 159  | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
 160  | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
 161  | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
 162  | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
 163  | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
 164  | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
 165  | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
 166  | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
 167  | bgp_proto LONG LIVED GRACEFUL RESTART bool ';' { BGP_CFG->llgr_mode = $6; }
 168  | bgp_proto LONG LIVED GRACEFUL RESTART AWARE ';' { BGP_CFG->llgr_mode = BGP_LLGR_AWARE; }
 169  | bgp_proto LONG LIVED STALE TIME expr ';' { BGP_CFG->llgr_time = $6; }
 170  | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
 171  | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
 172  | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
 173  | bgp_proto BFD GRACEFUL ';' { BGP_CFG->bfd = BGP_BFD_GRACEFUL; cf_check_bfd(1); }
 174  ;
 175
 176 bgp_afi:
 177    IPV4                 { $$ = BGP_AF_IPV4; }
 178  | IPV6                 { $$ = BGP_AF_IPV6; }
 179  | IPV4 MULTICAST       { $$ = BGP_AF_IPV4_MC; }
 180  | IPV6 MULTICAST       { $$ = BGP_AF_IPV6_MC; }
 181  | IPV4 MPLS            { $$ = BGP_AF_IPV4_MPLS; }
 182  | IPV6 MPLS            { $$ = BGP_AF_IPV6_MPLS; }
 183  | VPN4 MPLS            { $$ = BGP_AF_VPN4_MPLS; }
 184  | VPN6 MPLS            { $$ = BGP_AF_VPN6_MPLS; }
 185  | VPN4 MULTICAST       { $$ = BGP_AF_VPN4_MC; }
 186  | VPN6 MULTICAST       { $$ = BGP_AF_VPN6_MC; }
 187  | FLOW4                { $$ = BGP_AF_FLOW4; }
 188  | FLOW6                { $$ = BGP_AF_FLOW6; }
 189  ;
 190
 191 bgp_channel_start: bgp_afi
 192 {
 193   const struct bgp_af_desc *desc = bgp_get_af_desc($1);
 194
 195   if (!desc)
 196     cf_error("Unknown AFI/SAFI");
 197
 198   this_channel = channel_config_get(&channel_bgp, desc->name, desc->net, this_proto);
 199
 200   /* New channel */
 201   if (!BGP_CC->desc)
 202   {
 203     BGP_CC->c.in_filter = FILTER_UNDEF;
 204     BGP_CC->c.out_filter = FILTER_UNDEF;
 205     BGP_CC->c.ra_mode = RA_UNDEF;
 206     BGP_CC->afi = $1;
 207     BGP_CC->desc = desc;
 208     BGP_CC->gr_able = 0xff;     /* undefined */
 209     BGP_CC->llgr_able = 0xff;   /* undefined */
 210     BGP_CC->llgr_time = ~0U;    /* undefined */
 211   }
 212 };
 213
 214 bgp_channel_item:
 215    channel_item
 216  | NEXT HOP ADDRESS ipa { BGP_CC->next_hop_addr = $4; }
 217  | NEXT HOP SELF { BGP_CC->next_hop_self = 1; BGP_CC->next_hop_keep = 0; }
 218  | NEXT HOP KEEP { BGP_CC->next_hop_keep = 1; BGP_CC->next_hop_self = 0; }
 219  | MISSING LLADDR SELF { BGP_CC->missing_lladdr = MLL_SELF; }
 220  | MISSING LLADDR DROP { BGP_CC->missing_lladdr = MLL_DROP; }
 221  | MISSING LLADDR IGNORE { BGP_CC->missing_lladdr = MLL_IGNORE; }
 222  | GATEWAY DIRECT { BGP_CC->gw_mode = GW_DIRECT; }
 223  | GATEWAY RECURSIVE { BGP_CC->gw_mode = GW_RECURSIVE; }
 224  | SECONDARY bool { BGP_CC->secondary = $2; }
 225  | GRACEFUL RESTART bool { BGP_CC->gr_able = $3; }
 226  | LONG LIVED GRACEFUL RESTART bool { BGP_CC->llgr_able = $5; }
 227  | LONG LIVED STALE TIME expr { BGP_CC->llgr_time = $5; }
 228  | EXTENDED NEXT HOP bool { BGP_CC->ext_next_hop = $4; }
 229  | ADD PATHS RX { BGP_CC->add_path = BGP_ADD_PATH_RX; }
 230  | ADD PATHS TX { BGP_CC->add_path = BGP_ADD_PATH_TX; }
 231  | ADD PATHS bool { BGP_CC->add_path = $3 ? BGP_ADD_PATH_FULL : 0; }
 232  | IGP TABLE rtable {
 233     if (BGP_CC->desc->no_igp)
 234       cf_error("IGP table not allowed here");
 235
 236     if ($3->addr_type == NET_IP4)
 237       BGP_CC->igp_table_ip4 = $3;
 238     else if ($3->addr_type == NET_IP6)
 239       BGP_CC->igp_table_ip6 = $3;
 240     else
 241       cf_error("Mismatched IGP table type");
 242    }
 243  ;
 244
 245 bgp_channel_opts:
 246    /* empty */
 247  | bgp_channel_opts bgp_channel_item ';'
 248  ;
 249
 250 bgp_channel_opt_list:
 251    /* empty */
 252  | '{' bgp_channel_opts '}'
 253  ;
 254
 255 bgp_channel_end:
 256 {
 257   if (!this_channel->table)
 258     cf_error("Routing table not specified");
 259
 260   this_channel = NULL;
 261 };
 262
 263 bgp_proto_channel: bgp_channel_start bgp_channel_opt_list bgp_channel_end;
 264
 265
 266 dynamic_attr: BGP_ORIGIN
 267         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(PROTOCOL_BGP, BA_ORIGIN)); } ;
 268 dynamic_attr: BGP_PATH
 269         { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(PROTOCOL_BGP, BA_AS_PATH)); } ;
 270 dynamic_attr: BGP_NEXT_HOP
 271         { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(PROTOCOL_BGP, BA_NEXT_HOP)); } ;
 272 dynamic_attr: BGP_MED
 273         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_MULTI_EXIT_DISC)); } ;
 274 dynamic_attr: BGP_LOCAL_PREF
 275         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_LOCAL_PREF)); } ;
 276 dynamic_attr: BGP_ATOMIC_AGGR
 277         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_ATOMIC_AGGR)); } ;
 278 dynamic_attr: BGP_AGGREGATOR
 279         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_AGGREGATOR)); } ;
 280 dynamic_attr: BGP_COMMUNITY
 281         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_COMMUNITY)); } ;
 282 dynamic_attr: BGP_ORIGINATOR_ID
 283         { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(PROTOCOL_BGP, BA_ORIGINATOR_ID)); } ;
 284 dynamic_attr: BGP_CLUSTER_LIST
 285         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_CLUSTER_LIST)); } ;
 286 dynamic_attr: BGP_EXT_COMMUNITY
 287         { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(PROTOCOL_BGP, BA_EXT_COMMUNITY)); } ;
 288 dynamic_attr: BGP_LARGE_COMMUNITY
 289         { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(PROTOCOL_BGP, BA_LARGE_COMMUNITY)); } ;
 290
 291
 292
 293 CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
 294
 295 CF_CODE
 296
 297 CF_END