proto/bgp/config.Y

   1 /*
   2  *      BIRD -- Border Gateway Protocol Configuration
   3  *
   4  *      (c) 2000 Martin Mares <mj@ucw.cz>
   5  *
   6  *      Can be freely distributed and used under the terms of the GNU GPL.
   7  */
   8
   9 CF_HDR
  10
  11 #include "proto/bgp/bgp.h"
  12
  13 CF_DEFINES
  14
  15 #define BGP_CFG ((struct bgp_config *) this_proto)
  16 #define BGP_CC ((struct bgp_channel_config *) this_channel)
  17
  18 CF_DECLS
  19
  20 CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY, KEEPALIVE,
  21         MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT, PATH, METRIC, ERROR,
  22         START, DELAY, FORGET, WAIT, ENABLE, DISABLE, AFTER, BGP_PATH,
  23         BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN, BGP_NEXT_HOP, BGP_ATOMIC_AGGR,
  24         BGP_AGGREGATOR, BGP_COMMUNITY, BGP_EXT_COMMUNITY, BGP_LARGE_COMMUNITY,
  25         SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT, CLUSTER, ID, AS4, ADVERTISE,
  26         IPV4, CAPABILITIES, LIMIT, PASSIVE, PREFER, OLDER, MISSING, LLADDR,
  27         DROP, IGNORE, ROUTE, REFRESH, INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID,
  28         BGP_CLUSTER_LIST, IGP, TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL,
  29         SECURITY, DETERMINISTIC, SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX,
  30         GRACEFUL, RESTART, AWARE, CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY,
  31         STRICT, BIND, CONFEDERATION, MEMBER, MULTICAST, FLOW4, FLOW6, LONG,
  32         LIVED, STALE, IMPORT, IBGP, EBGP, MANDATORY, INTERNAL, EXTERNAL,
  33         DYNAMIC, RANGE, NAME, DIGITS, BGP_AIGP, AIGP, ORIGINATE, COST)
  34
  35 %type <i> bgp_nh
  36 %type <i32> bgp_afi
  37
  38 CF_KEYWORDS(CEASE, PREFIX, LIMIT, HIT, ADMINISTRATIVE, SHUTDOWN, RESET, PEER,
  39         CONFIGURATION, CHANGE, DECONFIGURED, CONNECTION, REJECTED, COLLISION,
  40         OUT, OF, RESOURCES)
  41
  42 %type<i> bgp_cease_mask bgp_cease_list bgp_cease_flag
  43
  44 CF_GRAMMAR
  45
  46 proto: bgp_proto '}'  ;
  47
  48 bgp_proto_start: proto_start BGP {
  49      this_proto = proto_config_new(&proto_bgp, $1);
  50      BGP_CFG->local_port = BGP_PORT;
  51      BGP_CFG->remote_port = BGP_PORT;
  52      BGP_CFG->multihop = -1;    /* undefined */
  53      BGP_CFG->hold_time = 240;
  54      BGP_CFG->initial_hold_time = 240;
  55      BGP_CFG->compare_path_lengths = 1;
  56      BGP_CFG->igp_metric = 1;
  57      BGP_CFG->connect_delay_time = 5;
  58      BGP_CFG->connect_retry_time = 120;
  59      BGP_CFG->error_amnesia_time = 300;
  60      BGP_CFG->error_delay_time_min = 60;
  61      BGP_CFG->error_delay_time_max = 300;
  62      BGP_CFG->enable_refresh = 1;
  63      BGP_CFG->enable_as4 = 1;
  64      BGP_CFG->capabilities = 2;
  65      BGP_CFG->interpret_communities = 1;
  66      BGP_CFG->default_local_pref = 100;
  67      BGP_CFG->gr_mode = BGP_GR_AWARE;
  68      BGP_CFG->gr_time = 120;
  69      BGP_CFG->llgr_mode = -1;
  70      BGP_CFG->llgr_time = 3600;
  71      BGP_CFG->setkey = 1;
  72      BGP_CFG->dynamic_name = "dynbgp";
  73      BGP_CFG->check_link = -1;
  74    }
  75  ;
  76
  77 bgp_loc_opts:
  78    /* empty */
  79  | bgp_loc_opts PORT expr { BGP_CFG->local_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  80  | bgp_loc_opts AS expr { BGP_CFG->local_as = $3; }
  81  ;
  82
  83 bgp_nbr_opts:
  84    /* empty */
  85  | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  86  | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
  87  | bgp_nbr_opts INTERNAL { BGP_CFG->peer_type = BGP_PT_INTERNAL; }
  88  | bgp_nbr_opts EXTERNAL { BGP_CFG->peer_type = BGP_PT_EXTERNAL; }
  89  ;
  90
  91 bgp_cease_mask:
  92    /* true -> all except connection collision */
  93    bool { $$ = $1 ? ~(1 << 7) : 0; }
  94  | '{' bgp_cease_list '}' { $$ = $2; }
  95  ;
  96
  97 bgp_cease_list:
  98    bgp_cease_flag
  99  | bgp_cease_list ',' bgp_cease_flag { $$ = $1 | $3; }
 100  ;
 101
 102 bgp_cease_flag:
 103    CEASE                        { $$ = 1 << 0; }
 104  | PREFIX LIMIT HIT             { $$ = 1 << 1; }
 105  | ADMINISTRATIVE SHUTDOWN      { $$ = 1 << 2; }
 106  | PEER DECONFIGURED            { $$ = 1 << 3; }
 107  | ADMINISTRATIVE RESET         { $$ = 1 << 4; }
 108  | CONNECTION REJECTED          { $$ = 1 << 5; }
 109  | CONFIGURATION CHANGE         { $$ = 1 << 6; }
 110  | CONNECTION COLLISION         { $$ = 1 << 7; }
 111  | OUT OF RESOURCES             { $$ = 1 << 8; }
 112  ;
 113
 114 bgp_proto:
 115    bgp_proto_start proto_name '{'
 116  | bgp_proto proto_item ';'
 117  | bgp_proto bgp_proto_channel ';'
 118  | bgp_proto LOCAL bgp_loc_opts ';'
 119  | bgp_proto LOCAL ipa ipa_scope bgp_loc_opts ';' {
 120      BGP_CFG->local_ip = $3;
 121      if ($4) BGP_CFG->iface = $4;
 122    }
 123  | bgp_proto NEIGHBOR bgp_nbr_opts ';'
 124  | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
 125      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 126        cf_error("Only one neighbor per BGP instance is allowed");
 127      BGP_CFG->remote_ip = $3;
 128      if ($4) BGP_CFG->iface = $4;
 129    }
 130  | bgp_proto NEIGHBOR RANGE net_ip bgp_nbr_opts ';' {
 131      if (ipa_nonzero(BGP_CFG->remote_ip) || BGP_CFG->remote_range)
 132        cf_error("Only one neighbor per BGP instance is allowed");
 133      net_addr *n = cfg_alloc($4.length);
 134      net_copy(n, &($4));
 135      BGP_CFG->remote_range = n;
 136    }
 137  | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
 138  | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
 139  | bgp_proto RR CLIENT bool ';' { BGP_CFG->rr_client = $4; }
 140  | bgp_proto RS CLIENT bool ';' { BGP_CFG->rs_client = $4; }
 141  | bgp_proto CONFEDERATION expr ';' { BGP_CFG->confederation = $3; }
 142  | bgp_proto CONFEDERATION MEMBER bool ';' { BGP_CFG->confederation_member = $4; }
 143  | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
 144  | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
 145  | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
 146  | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
 147  | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
 148  | bgp_proto DYNAMIC NAME text ';' {
 149      if (strchr($4, '%')) cf_error("Forbidden character '%%' in dynamic name");
 150      if (strlen($4) > (SYM_MAX_LEN - 16)) cf_error("Dynamic name too long");
 151      BGP_CFG->dynamic_name = $4;
 152    }
 153  | bgp_proto DYNAMIC NAME DIGITS expr ';' { BGP_CFG->dynamic_name_digits = $5; if ($5>10) cf_error("Dynamic name digits must be at most 10"); }
 154  | bgp_proto STRICT BIND bool ';' { BGP_CFG->strict_bind = $4; }
 155  | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
 156  | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
 157  | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
 158  | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
 159  | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
 160  | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
 161  | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
 162  | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->local_ip = $4; }
 163  | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
 164  | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
 165  | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
 166  | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
 167  | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
 168  | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
 169  | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
 170  | bgp_proto DISABLE AFTER CEASE bgp_cease_mask ';' { BGP_CFG->disable_after_cease = $5; }
 171  | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
 172  | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
 173  | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
 174  | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
 175  | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
 176  | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
 177  | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
 178  | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
 179  | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
 180  | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
 181  | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
 182  | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
 183  | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
 184  | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
 185  | bgp_proto LONG LIVED GRACEFUL RESTART bool ';' { BGP_CFG->llgr_mode = $6; }
 186  | bgp_proto LONG LIVED GRACEFUL RESTART AWARE ';' { BGP_CFG->llgr_mode = BGP_LLGR_AWARE; }
 187  | bgp_proto LONG LIVED STALE TIME expr ';' { BGP_CFG->llgr_time = $6; }
 188  | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
 189  | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
 190  | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
 191  | bgp_proto BFD GRACEFUL ';' { BGP_CFG->bfd = BGP_BFD_GRACEFUL; cf_check_bfd(1); }
 192  ;
 193
 194 bgp_afi:
 195    IPV4                 { $$ = BGP_AF_IPV4; }
 196  | IPV6                 { $$ = BGP_AF_IPV6; }
 197  | IPV4 MULTICAST       { $$ = BGP_AF_IPV4_MC; }
 198  | IPV6 MULTICAST       { $$ = BGP_AF_IPV6_MC; }
 199  | IPV4 MPLS            { $$ = BGP_AF_IPV4_MPLS; }
 200  | IPV6 MPLS            { $$ = BGP_AF_IPV6_MPLS; }
 201  | VPN4 MPLS            { $$ = BGP_AF_VPN4_MPLS; }
 202  | VPN6 MPLS            { $$ = BGP_AF_VPN6_MPLS; }
 203  | VPN4 MULTICAST       { $$ = BGP_AF_VPN4_MC; }
 204  | VPN6 MULTICAST       { $$ = BGP_AF_VPN6_MC; }
 205  | FLOW4                { $$ = BGP_AF_FLOW4; }
 206  | FLOW6                { $$ = BGP_AF_FLOW6; }
 207  ;
 208
 209 bgp_channel_start: bgp_afi
 210 {
 211   const struct bgp_af_desc *desc = bgp_get_af_desc($1);
 212
 213   if (!desc)
 214     cf_error("Unknown AFI/SAFI");
 215
 216   this_channel = channel_config_get(&channel_bgp, desc->name, desc->net, this_proto);
 217
 218   /* New channel */
 219   if (!BGP_CC->desc)
 220   {
 221     BGP_CC->c.in_filter = FILTER_UNDEF;
 222     BGP_CC->c.out_filter = FILTER_UNDEF;
 223     BGP_CC->c.ra_mode = RA_UNDEF;
 224     BGP_CC->afi = $1;
 225     BGP_CC->desc = desc;
 226     BGP_CC->next_hop_keep = 0xff; /* undefined */
 227     BGP_CC->gr_able = 0xff;     /* undefined */
 228     BGP_CC->llgr_able = 0xff;   /* undefined */
 229     BGP_CC->llgr_time = ~0U;    /* undefined */
 230     BGP_CC->aigp = 0xff;        /* undefined */
 231   }
 232 };
 233
 234 bgp_nh:
 235    bool { $$ = $1; }
 236  | IBGP { $$ = NH_IBGP; }
 237  | EBGP { $$ = NH_EBGP; }
 238
 239 bgp_channel_item:
 240    channel_item
 241  | NEXT HOP ADDRESS ipa { BGP_CC->next_hop_addr = $4; }
 242  | NEXT HOP SELF bgp_nh { BGP_CC->next_hop_self = $4; }
 243  | NEXT HOP KEEP bgp_nh { BGP_CC->next_hop_keep = $4; }
 244  | MANDATORY bool { BGP_CC->mandatory = $2; }
 245  | MISSING LLADDR SELF { BGP_CC->missing_lladdr = MLL_SELF; }
 246  | MISSING LLADDR DROP { BGP_CC->missing_lladdr = MLL_DROP; }
 247  | MISSING LLADDR IGNORE { BGP_CC->missing_lladdr = MLL_IGNORE; }
 248  | GATEWAY DIRECT { BGP_CC->gw_mode = GW_DIRECT; }
 249  | GATEWAY RECURSIVE { BGP_CC->gw_mode = GW_RECURSIVE; }
 250  | SECONDARY bool { BGP_CC->secondary = $2; }
 251  | GRACEFUL RESTART bool { BGP_CC->gr_able = $3; }
 252  | LONG LIVED GRACEFUL RESTART bool { BGP_CC->llgr_able = $5; }
 253  | LONG LIVED STALE TIME expr { BGP_CC->llgr_time = $5; }
 254  | EXTENDED NEXT HOP bool { BGP_CC->ext_next_hop = $4; }
 255  | ADD PATHS RX { BGP_CC->add_path = BGP_ADD_PATH_RX; }
 256  | ADD PATHS TX { BGP_CC->add_path = BGP_ADD_PATH_TX; }
 257  | ADD PATHS bool { BGP_CC->add_path = $3 ? BGP_ADD_PATH_FULL : 0; }
 258  | IMPORT TABLE bool { BGP_CC->import_table = $3; }
 259  | EXPORT TABLE bool { BGP_CC->export_table = $3; }
 260  | AIGP bool { BGP_CC->aigp = $2; BGP_CC->aigp_originate = 0; }
 261  | AIGP ORIGINATE { BGP_CC->aigp = 1; BGP_CC->aigp_originate = 1; }
 262  | COST expr { BGP_CC->cost = $2; if ($2 < 1) cf_error("Cost must be positive"); }
 263  | IGP TABLE rtable {
 264     if (BGP_CC->desc->no_igp)
 265       cf_error("IGP table not allowed here");
 266
 267     if ($3->addr_type == NET_IP4)
 268       BGP_CC->igp_table_ip4 = $3;
 269     else if ($3->addr_type == NET_IP6)
 270       BGP_CC->igp_table_ip6 = $3;
 271     else
 272       cf_error("Mismatched IGP table type");
 273    }
 274  ;
 275
 276 bgp_channel_opts:
 277    /* empty */
 278  | bgp_channel_opts bgp_channel_item ';'
 279  ;
 280
 281 bgp_channel_opt_list:
 282    /* empty */
 283  | '{' bgp_channel_opts '}'
 284  ;
 285
 286 bgp_channel_end:
 287 {
 288   if (!this_channel->table)
 289     cf_error("Routing table not specified");
 290
 291   this_channel = NULL;
 292 };
 293
 294 bgp_proto_channel: bgp_channel_start bgp_channel_opt_list bgp_channel_end;
 295
 296
 297 dynamic_attr: BGP_ORIGIN
 298         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(PROTOCOL_BGP, BA_ORIGIN)); } ;
 299 dynamic_attr: BGP_PATH
 300         { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(PROTOCOL_BGP, BA_AS_PATH)); } ;
 301 dynamic_attr: BGP_NEXT_HOP
 302         { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(PROTOCOL_BGP, BA_NEXT_HOP)); } ;
 303 dynamic_attr: BGP_MED
 304         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_MULTI_EXIT_DISC)); } ;
 305 dynamic_attr: BGP_LOCAL_PREF
 306         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(PROTOCOL_BGP, BA_LOCAL_PREF)); } ;
 307 dynamic_attr: BGP_ATOMIC_AGGR
 308         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_ATOMIC_AGGR)); } ;
 309 dynamic_attr: BGP_AGGREGATOR
 310         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AGGREGATOR)); } ;
 311 dynamic_attr: BGP_COMMUNITY
 312         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_COMMUNITY)); } ;
 313 dynamic_attr: BGP_ORIGINATOR_ID
 314         { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(PROTOCOL_BGP, BA_ORIGINATOR_ID)); } ;
 315 dynamic_attr: BGP_CLUSTER_LIST
 316         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(PROTOCOL_BGP, BA_CLUSTER_LIST)); } ;
 317 dynamic_attr: BGP_EXT_COMMUNITY
 318         { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(PROTOCOL_BGP, BA_EXT_COMMUNITY)); } ;
 319 dynamic_attr: BGP_AIGP
 320         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(PROTOCOL_BGP, BA_AIGP)); } ;
 321 dynamic_attr: BGP_LARGE_COMMUNITY
 322         { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(PROTOCOL_BGP, BA_LARGE_COMMUNITY)); } ;
 323
 324
 325
 326 CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
 327
 328 CF_CODE
 329
 330 CF_END