config/cloog.m4

   1 # This file is part of GCC.
   2 #
   3 # GCC is free software; you can redistribute it and/or modify it under
   4 # the terms of the GNU General Public License as published by the Free
   5 # Software Foundation; either version 3, or (at your option) any later
   6 # version.
   7 #
   8 # GCC is distributed in the hope that it will be useful, but WITHOUT
   9 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  10 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  11 # for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16 #
  17 # Contributed by Andreas Simbuerger <simbuerg@fim.uni-passau.de>
  18
  19 # CLOOG_INIT_FLAGS ()
  20 # -------------------------
  21 # Provide configure switches for CLooG support.
  22 # Initialize clooglibs/clooginc according to the user input.
  23 AC_DEFUN([CLOOG_INIT_FLAGS],
  24 [
  25   AC_ARG_WITH(cloog,
  26     [AS_HELP_STRING(
  27       [--with-cloog=PATH],
  28       [Specify prefix directory for the installed CLooG-PPL package.
  29        Equivalent to --with-cloog-include=PATH/include
  30        plus --with-cloog-lib=PATH/lib])])
  31   AC_ARG_WITH([cloog-include],
  32     [AS_HELP_STRING(
  33       [--with-cloog-include=PATH],
  34       [Specify directory for installed CLooG include files])])
  35   AC_ARG_WITH([cloog-lib],
  36     [AS_HELP_STRING(
  37       [--with-cloog-lib=PATH],
  38       [Specify the directory for the installed CLooG library])])
  39
  40   AC_ARG_ENABLE(cloog-version-check,
  41     [AS_HELP_STRING(
  42       [--disable-cloog-version-check],
  43       [disable check for CLooG version])],
  44     ENABLE_CLOOG_CHECK=$enableval,
  45     ENABLE_CLOOG_CHECK=yes)
  46
  47   # Initialize clooglibs and clooginc.
  48   case $with_cloog in
  49     no)
  50       clooglibs=
  51       clooginc=
  52       ;;
  53     "" | yes)
  54       ;;
  55     *)
  56       clooglibs="-L$with_cloog/lib"
  57       clooginc="-I$with_cloog/include"
  58       ;;
  59   esac
  60   if test "x${with_cloog_include}" != x ; then
  61     clooginc="-I$with_cloog_include"
  62   fi
  63   if test "x${with_cloog_lib}" != x; then
  64     clooglibs="-L$with_cloog_lib"
  65   fi
  66   dnl If no --with-cloog flag was specified and there is in-tree ClooG
  67   dnl source, set up flags to use that.
  68   if test "x${clooginc}" == x && test "x${clooglibs}" == x \
  69      && test -d ${srcdir}/cloog; then
  70      echo FooBar
  71      clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
  72      clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include -I'${srcdir}'/cloog/include '
  73   fi
  74
  75   clooginc="-DCLOOG_INT_GMP ${clooginc}"
  76   clooglibs="${clooglibs} -lcloog-isl ${isllibs}"
  77
  78   dnl Flags needed for CLOOG
  79   AC_SUBST(clooglibs)
  80   AC_SUBST(clooginc)
  81 ]
  82 )
  83
  84 # CLOOG_REQUESTED (ACTION-IF-REQUESTED, ACTION-IF-NOT)
  85 # ----------------------------------------------------
  86 # Provide actions for failed CLooG detection.
  87 AC_DEFUN([CLOOG_REQUESTED],
  88 [
  89   AC_REQUIRE([CLOOG_INIT_FLAGS])
  90
  91   if test "x${with_cloog}" = xno; then
  92     $2
  93   elif test "x${with_cloog}" != x \
  94     || test "x${with_cloog_include}" != x \
  95     || test "x${with_cloog_lib}" != x ; then
  96     $1
  97   else
  98     $2
  99   fi
 100 ]
 101 )
 102
 103 # _CLOOG_CHECK_CT_PROG(MAJOR, MINOR, REVISION)
 104 # --------------------------------------------
 105 # Helper for verifying CLooG's compile time version.
 106 m4_define([_CLOOG_CHECK_CT_PROG],[AC_LANG_PROGRAM(
 107   [#include "cloog/version.h"],
 108   [#if CLOOG_VERSION_MAJOR != $1 \
 109     || CLOOG_VERSION_MINOR != $2 \
 110     || CLOOG_VERSION_REVISION < $3
 111     choke me
 112    #endif])])
 113
 114 # CLOOG_CHECK_VERSION CLOOG_CHECK_VERSION (MAJOR, MINOR, REVISION)
 115 # ----------------------------------------------------------------
 116 # Test the found CLooG to be exact of version MAJOR.MINOR and at least
 117 # REVISION.
 118 AC_DEFUN([CLOOG_CHECK_VERSION],
 119 [
 120   AC_REQUIRE([CLOOG_INIT_FLAGS])
 121
 122   if test "${ENABLE_CLOOG_CHECK}" = yes ; then
 123     _cloog_saved_CFLAGS=$CFLAGS
 124     _cloog_saved_LDFLAGS=$LDFLAGS
 125
 126     CFLAGS="${_cloog_saved_CFLAGS} ${clooginc} ${islinc} ${gmpinc}"
 127     LDFLAGS="${_cloog_saved_LDFLAGS} ${clooglibs} ${isllibs} ${gmplib}"
 128
 129     AC_CACHE_CHECK([for version $1.$2.$3 of CLooG],
 130       [gcc_cv_cloog],
 131       [AC_COMPILE_IFELSE([_CLOOG_CHECK_CT_PROG($1,$2,$3)],
 132         [gcc_cv_cloog=yes],
 133         [gcc_cv_cloog=no])])
 134
 135     CFLAGS=$_cloog_saved_CFLAGS
 136     LDFLAGS=$_cloog_saved_LDFLAGS
 137   fi
 138 ]
 139 )
 140
 141 # CLOOG_IF_FAILED (ACTION-IF-FAILED)
 142 # ----------------------------------
 143 # Executes ACTION-IF-FAILED, if GRAPHITE was requested and
 144 # the checks failed.
 145 AC_DEFUN([CLOOG_IF_FAILED],
 146 [
 147   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
 148
 149   if test "${gcc_cv_cloog}" = no ; then
 150     clooglibs=
 151     clooginc=
 152   fi
 153
 154   if test "${graphite_requested}" = yes \
 155     && test "x${clooglibs}" = x \
 156     && test "x${clooginc}" = x ; then
 157     $1
 158   fi
 159 ]
 160 )