libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 # If they didn't specify --enable-shared, don't generate shared libs.
 195 case "${enable_shared}" in
 196   yes) shared=yes ;;
 197   no) shared=no ;;
 198   "") shared=no ;;
 199   *) shared=yes ;;
 200 esac
 201 if [[ "${shared}" = "yes" ]]; then
 202   case "${host}" in
 203     *-*-cygwin*)        ;;
 204     alpha*-*-linux*)    PICFLAG=-fPIC ;;
 205     arm*-*-*)           PICFLAG=-fPIC ;;
 206     hppa*-*-*)          PICFLAG=-fPIC ;;
 207     i370-*-*)           PICFLAG=-fPIC ;;
 208     ia64-*-*)           PICFLAG=-fpic ;;
 209     i[[34567]]86-*-* | x86_64-*-*)
 210                         PICFLAG=-fpic ;;
 211     m68k-*-*)           PICFLAG=-fpic ;;
 212     mips*-*-linux*)     PICFLAG=-fPIC ;;
 213     powerpc*-*-aix*)    ;;
 214     powerpc*-*-*)       PICFLAG=-fPIC ;;
 215     sparc*-*-*)         case "${CFLAGS}" in
 216                           *-fpic* ) PICFLAG=-fpic ;;
 217                           * ) PICFLAG=-fPIC ;;
 218                         esac ;;
 219     s390*-*-*)          PICFLAG=-fpic ;;
 220     sh*-*-*)            PICFLAG=-fPIC ;;
 221   esac
 222 fi
 223 AC_SUBST(PICFLAG)
 224
 225 echo "# Warning: this fragment is automatically generated" > temp-frag
 226
 227 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 228   echo "Appending ${frag} to xhost-mkfrag"
 229   echo "# Following fragment copied from ${frag}" >> temp-frag
 230   cat ${frag} >> temp-frag
 231 fi
 232
 233 # record if we want to build shared libs.
 234 if [[ "${shared}" = "yes" ]]; then
 235   echo enable_shared = yes >> temp-frag
 236 else
 237   echo enable_shared = no >> temp-frag
 238 fi
 239
 240 frag=xhost-mkfrag
 241 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 242
 243 host_makefile_frag=${frag}
 244 AC_SUBST_FILE(host_makefile_frag)
 245
 246 # It's OK to check for header files.  Although the compiler may not be
 247 # able to link anything, it had better be able to at least compile
 248 # something.
 249 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 250 AC_HEADER_SYS_WAIT
 251 AC_HEADER_TIME
 252
 253 libiberty_AC_DECLARE_ERRNO
 254
 255 # Determine the size of an int for struct fibnode.
 256 AC_CHECK_SIZEOF([int])
 257
 258 # Look for a 64-bit type.
 259 AC_MSG_CHECKING([for a 64-bit type])
 260 AC_CACHE_VAL(liberty_cv_uint64,
 261 [AC_TRY_COMPILE(
 262 [#ifdef HAVE_STDINT_H
 263 #include <stdint.h>
 264 #endif],
 265 [extern uint64_t foo;],
 266 liberty_cv_uint64=uint64_t,
 267 [AC_TRY_COMPILE(
 268 [#ifdef HAVE_LIMITS_H
 269 #include <limits.h>
 270 #endif
 271 #ifndef CHAR_BIT
 272 #define CHAR_BIT 8
 273 #endif],
 274 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 275 liberty_cv_uint64="unsigned long",
 276 [AC_TRY_COMPILE(
 277 [#ifdef HAVE_LIMITS_H
 278 #include <limits.h>
 279 #endif
 280 #ifndef CHAR_BIT
 281 #define CHAR_BIT 8
 282 #endif],
 283 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 284 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 285 AC_MSG_RESULT($liberty_cv_uint64)
 286 if test "$liberty_cv_uint64" != none; then
 287   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 288                      [Define to an unsigned 64-bit type available in the compiler.])
 289 fi
 290
 291 AC_TYPE_INTPTR_T
 292 AC_TYPE_UINTPTR_T
 293 AC_TYPE_SSIZE_T
 294
 295 # Given the above check, we always have uintptr_t or a fallback
 296 # definition.  So define HAVE_UINTPTR_T in case any imported code
 297 # relies on it.
 298 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 299
 300 AC_TYPE_PID_T
 301
 302 # This is the list of functions which libiberty will provide if they
 303 # are not available on the host.
 304
 305 funcs="asprintf"
 306 funcs="$funcs atexit"
 307 funcs="$funcs basename"
 308 funcs="$funcs bcmp"
 309 funcs="$funcs bcopy"
 310 funcs="$funcs bsearch"
 311 funcs="$funcs bzero"
 312 funcs="$funcs calloc"
 313 funcs="$funcs clock"
 314 funcs="$funcs ffs"
 315 funcs="$funcs getcwd"
 316 funcs="$funcs getpagesize"
 317 funcs="$funcs gettimeofday"
 318 funcs="$funcs index"
 319 funcs="$funcs insque"
 320 funcs="$funcs memchr"
 321 funcs="$funcs memcmp"
 322 funcs="$funcs memcpy"
 323 funcs="$funcs memmem"
 324 funcs="$funcs memmove"
 325 funcs="$funcs mempcpy"
 326 funcs="$funcs memset"
 327 funcs="$funcs mkstemps"
 328 funcs="$funcs putenv"
 329 funcs="$funcs random"
 330 funcs="$funcs rename"
 331 funcs="$funcs rindex"
 332 funcs="$funcs setenv"
 333 funcs="$funcs snprintf"
 334 funcs="$funcs sigsetmask"
 335 funcs="$funcs stpcpy"
 336 funcs="$funcs stpncpy"
 337 funcs="$funcs strcasecmp"
 338 funcs="$funcs strchr"
 339 funcs="$funcs strdup"
 340 funcs="$funcs strncasecmp"
 341 funcs="$funcs strndup"
 342 funcs="$funcs strrchr"
 343 funcs="$funcs strstr"
 344 funcs="$funcs strtod"
 345 funcs="$funcs strtol"
 346 funcs="$funcs strtoul"
 347 funcs="$funcs strverscmp"
 348 funcs="$funcs tmpnam"
 349 funcs="$funcs vasprintf"
 350 funcs="$funcs vfprintf"
 351 funcs="$funcs vprintf"
 352 funcs="$funcs vsnprintf"
 353 funcs="$funcs vsprintf"
 354 funcs="$funcs waitpid"
 355 funcs="$funcs setproctitle"
 356
 357 # Also in the old function.def file: alloca, vfork, getopt.
 358
 359 vars="sys_errlist sys_nerr sys_siglist"
 360
 361 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 362  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 363  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 364  sysmp table times wait3 wait4"
 365
 366 # These are neither executed nor required, but they help keep
 367 # autoheader happy without adding a bunch of text to acconfig.h.
 368 if test "x" = "y"; then
 369   AC_CHECK_FUNCS(asprintf atexit \
 370     basename bcmp bcopy bsearch bzero \
 371     calloc canonicalize_file_name clock \
 372     dup3 \
 373     ffs __fsetlocking \
 374     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 375     index insque \
 376     memchr memcmp memcpy memmem memmove memset mkstemps \
 377     on_exit \
 378     psignal pstat_getdynamic pstat_getstatic putenv \
 379     random realpath rename rindex \
 380     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 381      stpcpy stpncpy strcasecmp strchr strdup \
 382      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
 383      strtoul strverscmp sysconf sysctl sysmp \
 384     table times tmpnam \
 385     vasprintf vfprintf vprintf vsprintf \
 386     wait3 wait4 waitpid)
 387   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 388   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 389   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 390   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 391 fi
 392
 393 # For each of these functions, if the host does not provide the
 394 # function we want to put FN.o in LIBOBJS, and if the host does
 395 # provide the function, we want to define HAVE_FN in config.h.
 396
 397 setobjs=
 398 CHECK=
 399 target_header_dir=
 400 if test -n "${with_target_subdir}"; then
 401
 402   # We are being configured as a target library.  AC_REPLACE_FUNCS
 403   # may not work correctly, because the compiler may not be able to
 404   # link executables.  Note that we may still be being configured
 405   # native.
 406
 407   # If we are being configured for newlib, we know which functions
 408   # newlib provide and which ones we will be expected to provide.
 409
 410   if test "x${with_newlib}" = "xyes"; then
 411     AC_LIBOBJ([asprintf])
 412     AC_LIBOBJ([basename])
 413     AC_LIBOBJ([insque])
 414     AC_LIBOBJ([random])
 415     AC_LIBOBJ([strdup])
 416     AC_LIBOBJ([vasprintf])
 417
 418     for f in $funcs; do
 419       case "$f" in
 420         asprintf | basename | insque | random | strdup | vasprintf)
 421           ;;
 422         *)
 423           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 424           AC_DEFINE_UNQUOTED($n)
 425           ;;
 426       esac
 427     done
 428
 429     # newlib doesnt provide any of the variables in $vars, so we
 430     # dont have to check them here.
 431
 432     # Of the functions in $checkfuncs, newlib only has strerror.
 433     AC_DEFINE(HAVE_STRERROR)
 434
 435     setobjs=yes
 436
 437   fi
 438
 439   # If we are being configured for Mingw, we know which functions
 440   # Mingw provides and which ones we will be expected to provide.
 441
 442   case "${host}" in
 443   *-*-mingw*)
 444     AC_LIBOBJ([asprintf])
 445     AC_LIBOBJ([basename])
 446     AC_LIBOBJ([bcmp])
 447     AC_LIBOBJ([bcopy])
 448     AC_LIBOBJ([bzero])
 449     AC_LIBOBJ([clock])
 450     AC_LIBOBJ([ffs])
 451     AC_LIBOBJ([getpagesize])
 452     AC_LIBOBJ([index])
 453     AC_LIBOBJ([insque])
 454     AC_LIBOBJ([mempcpy])
 455     AC_LIBOBJ([mkstemps])
 456     AC_LIBOBJ([random])
 457     AC_LIBOBJ([rindex])
 458     AC_LIBOBJ([sigsetmask])
 459     AC_LIBOBJ([stpcpy])
 460     AC_LIBOBJ([stpncpy])
 461     AC_LIBOBJ([strndup])
 462     AC_LIBOBJ([strverscmp])
 463     AC_LIBOBJ([vasprintf])
 464     AC_LIBOBJ([waitpid])
 465
 466     for f in $funcs; do
 467       case "$f" in
 468         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 469           ;;
 470         *)
 471           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 472           AC_DEFINE_UNQUOTED($n)
 473           ;;
 474       esac
 475     done
 476
 477     # Mingw doesnt provide any of the variables in $vars, so we
 478     # dont have to check them here.
 479
 480     # Of the functions in $checkfuncs, Mingw only has strerror.
 481     AC_DEFINE(HAVE_STRERROR)
 482
 483     setobjs=yes
 484     ;;
 485
 486   *-*-msdosdjgpp)
 487     AC_LIBOBJ([vasprintf])
 488     AC_LIBOBJ([vsnprintf])
 489     AC_LIBOBJ([snprintf])
 490     AC_LIBOBJ([asprintf])
 491
 492     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 493              getcwd getpagesize getrusage gettimeofday \
 494              index insque memchr memcmp memcpy memmove memset psignal \
 495              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 496              strchr strdup strerror strncasecmp strrchr strstr strtod \
 497              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 498              vsprintf waitpid
 499     do
 500       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 501       AC_DEFINE_UNQUOTED($n)
 502     done
 503
 504
 505     setobjs=yes
 506     ;;
 507
 508   esac
 509
 510   # We may wish to install the target headers somewhere.
 511   AC_ARG_ENABLE(install-libiberty,
 512   [  --enable-install-libiberty       Install headers for end users],
 513   enable_install_libiberty=$enableval,
 514   enable_install_libiberty=no)dnl
 515
 516   # Option parsed, now set things appropriately.
 517   case x"$enable_install_libiberty" in
 518     xyes|x)
 519       target_header_dir=libiberty
 520       ;;
 521     xno)
 522       target_header_dir=
 523       ;;
 524     *)
 525       # This could be sanity-checked in various ways...
 526       target_header_dir="${enable_install_libiberty}"
 527       ;;
 528   esac
 529
 530
 531 else
 532
 533    # Not a target library, so we set things up to run the test suite.
 534    CHECK=really-check
 535
 536 fi
 537
 538 AC_SUBST(CHECK)
 539 AC_SUBST(target_header_dir)
 540
 541 case "${host}" in
 542   *-*-cygwin* | *-*-mingw*)
 543     AC_DEFINE(HAVE_SYS_ERRLIST)
 544     AC_DEFINE(HAVE_SYS_NERR)
 545     ;;
 546 esac
 547
 548 if test -z "${setobjs}"; then
 549   case "${host}" in
 550
 551   *-*-vxworks*)
 552     # Handle VxWorks configuration specially, since on VxWorks the
 553     # libraries are actually on the target board, not in the file
 554     # system.
 555     AC_LIBOBJ([basename])
 556     AC_LIBOBJ([getpagesize])
 557     AC_LIBOBJ([insque])
 558     AC_LIBOBJ([random])
 559     AC_LIBOBJ([strcasecmp])
 560     AC_LIBOBJ([strncasecmp])
 561     AC_LIBOBJ([strdup])
 562     AC_LIBOBJ([vfork])
 563     AC_LIBOBJ([waitpid])
 564     AC_LIBOBJ([vasprintf])
 565     for f in $funcs; do
 566       case "$f" in
 567         basename | getpagesize | insque | random | strcasecmp)
 568           ;;
 569         strncasecmp | strdup | vfork | waitpid | vasprintf)
 570           ;;
 571         *)
 572           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 573           AC_DEFINE_UNQUOTED($n)
 574           ;;
 575       esac
 576     done
 577
 578     # VxWorks doesn't provide any of the variables in $vars, so we
 579     # don't have to check them here.
 580
 581     # Of the functions in $checkfuncs, VxWorks only has strerror.
 582     AC_DEFINE(HAVE_STRERROR)
 583
 584     setobjs=yes
 585     ;;
 586
 587   esac
 588 fi
 589
 590 if test -z "${setobjs}"; then
 591
 592   case "${host}" in
 593
 594   *-*-mingw32*)
 595     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 596     # macros, so the test below won't find them.
 597     libiberty_cv_var_sys_nerr=yes
 598     libiberty_cv_var_sys_errlist=yes
 599     ;;
 600
 601   *-*-msdosdjgpp*)
 602     # vfork and fork are stubs.
 603     ac_cv_func_vfork_works=no
 604     ;;
 605
 606   *-*-uwin*)
 607     # Under some versions of uwin, vfork is notoriously buggy and the test
 608     # can hang configure; on other versions, vfork exists just as a stub.
 609     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 610     ac_cv_func_vfork_works=no
 611     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 612     # macros (actually, these are imported from a DLL, but the end effect
 613     # is the same), so the test below won't find them.
 614     libiberty_cv_var_sys_nerr=yes
 615     libiberty_cv_var_sys_errlist=yes
 616     ;;
 617
 618   *-*-*vms*)
 619     # Under VMS, vfork works very different than on Unix. The standard test
 620     # won't work, and it isn't easily adaptable. It makes more sense to
 621     # just force it.
 622     ac_cv_func_vfork_works=yes
 623     ;;
 624
 625   esac
 626
 627   # We haven't set the list of objects yet.  Use the standard autoconf
 628   # tests.  This will only work if the compiler works.
 629   AC_ISC_POSIX
 630   AC_REPLACE_FUNCS($funcs)
 631   libiberty_AC_FUNC_C_ALLOCA
 632   AC_FUNC_FORK
 633   if test $ac_cv_func_vfork_works = no; then
 634     AC_LIBOBJ([vfork])
 635   fi
 636   # We only need _doprnt if we might use it to implement v*printf.
 637   if test $ac_cv_func_vprintf != yes \
 638      || test $ac_cv_func_vfprintf != yes \
 639      || test $ac_cv_func_vsprintf != yes; then
 640     AC_REPLACE_FUNCS(_doprnt)
 641   else
 642     AC_CHECK_FUNCS(_doprnt)
 643   fi
 644
 645   for v in $vars; do
 646     AC_MSG_CHECKING([for $v])
 647     AC_CACHE_VAL(libiberty_cv_var_$v,
 648       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 649                       [eval "libiberty_cv_var_$v=yes"],
 650                       [eval "libiberty_cv_var_$v=no"])])
 651     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 652       AC_MSG_RESULT(yes)
 653       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 654       AC_DEFINE_UNQUOTED($n)
 655     else
 656       AC_MSG_RESULT(no)
 657     fi
 658   done
 659
 660   # special check for _system_configuration because AIX <4.3.2 do not
 661   # contain the `physmem' member.
 662   AC_MSG_CHECKING([for external symbol _system_configuration])
 663   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 664                         [[double x = _system_configuration.physmem;]])],
 665     [AC_MSG_RESULT([yes])
 666     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 667               [Define if you have the _system_configuration variable.])],
 668     [AC_MSG_RESULT([no])])
 669
 670   AC_CHECK_FUNCS($checkfuncs)
 671   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 672   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 673   AC_CHECK_DECLS([strverscmp])
 674   libiberty_NEED_DECLARATION(canonicalize_file_name)
 675 fi
 676
 677 # Figure out which version of pexecute to use.
 678 case "${host}" in
 679      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 680      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 681      *-*-msdos*)                pexecute=pex-msdos  ;;
 682      *)                         pexecute=pex-unix   ;;
 683 esac
 684 AC_SUBST(pexecute)
 685
 686 libiberty_AC_FUNC_STRNCMP
 687
 688 # Install a library built with a cross compiler in $(tooldir) rather
 689 # than $(libdir).
 690 if test -z "${with_cross_host}"; then
 691   INSTALL_DEST=libdir
 692 else
 693   INSTALL_DEST=tooldir
 694 fi
 695 AC_SUBST(INSTALL_DEST)
 696
 697 m4_pattern_allow(LIBOBJS)
 698 L=""
 699 for l in x $LIBOBJS; do
 700   case $l in
 701     x) ;;
 702     *) L="$L ./$l" ;;
 703   esac
 704 done
 705 LIBOBJS="$L"
 706
 707 dnl Required by html and install-html
 708 AC_SUBST(datarootdir)
 709 AC_SUBST(docdir)
 710 AC_SUBST(htmldir)
 711
 712 # We need multilib support, but only if configuring for the target.
 713 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 714 AC_CONFIG_COMMANDS([default],
 715   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 716 if test -n "$CONFIG_FILES"; then
 717   if test -n "${with_target_subdir}"; then
 718     # FIXME: We shouldn't need to set ac_file
 719     ac_file=Makefile
 720     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 721     . ${libiberty_topdir}/config-ml.in
 722   fi
 723 fi]],
 724 [[srcdir=${srcdir}
 725 host=${host}
 726 target=${target}
 727 with_target_subdir=${with_target_subdir}
 728 with_multisubdir=${with_multisubdir}
 729 ac_configure_args="--enable-multilib ${ac_configure_args}"
 730 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 731 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 732 libiberty_topdir=${libiberty_topdir}
 733 ]])
 734 AC_OUTPUT