configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  27 # --without-PROGRAM version used.
  28 AC_DEFUN([GIT_ARG_SET_PATH],
  29 [AC_ARG_WITH([$1],
  30  [AS_HELP_STRING([--with-$1=PATH],
  31                  [provide PATH to $1])],
  32  [GIT_CONF_APPEND_PATH($1,$2)],[])
  33 ])# GIT_ARG_SET_PATH
  34 #
  35 # GIT_CONF_APPEND_PATH(PROGRAM)
  36 # ------------------------------
  37 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38 # Used by GIT_ARG_SET_PATH(PROGRAM)
  39 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  40 # --without-PROGRAM is used.
  41 AC_DEFUN([GIT_CONF_APPEND_PATH],
  42 [PROGRAM=m4_toupper($1); \
  43 if test "$withval" = "no"; then \
  44         if test -n "$2"; then \
  45                 m4_toupper($1)_PATH=$withval; \
  46                 AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                 GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49         else \
  50                 AC_MSG_ERROR([You cannot use git without $1]); \
  51         fi; \
  52 else \
  53         if test "$withval" = "yes"; then \
  54                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55         else \
  56                 m4_toupper($1)_PATH=$withval; \
  57                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59         fi; \
  60 fi; \
  61 ]) # GIT_CONF_APPEND_PATH
  62 #
  63 # GIT_PARSE_WITH(PACKAGE)
  64 # -----------------------
  65 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  66 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69 AC_DEFUN([GIT_PARSE_WITH],
  70 [PACKAGE=m4_toupper($1); \
  71 if test "$withval" = "no"; then \
  72         m4_toupper(NO_$1)=YesPlease; \
  73 elif test "$withval" = "yes"; then \
  74         m4_toupper(NO_$1)=; \
  75 else \
  76         m4_toupper(NO_$1)=; \
  77         m4_toupper($1)DIR=$withval; \
  78         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80 fi \
  81 ])# GIT_PARSE_WITH
  82 #
  83 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84 # ---------------------
  85 # Set VAR to the value specied by --with-WITHNAME.
  86 # No verification of arguments is performed, but warnings are issued
  87 # if either 'yes' or 'no' is specified.
  88 # HELP_TEXT is presented when --help is called.
  89 # This is a direct way to allow setting variables in the Makefile.
  90 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91 [AC_ARG_WITH([$1],
  92  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93  if test -n "$withval"; then \
  94   if test "$withval" = "yes" -o "$withval" = "no"; then \
  95     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                      [a value for $1 ($2).  Maybe you do...?]); \
  97   fi; \
  98   \
  99   AC_MSG_NOTICE([Setting $2 to $withval]); \
 100   GIT_CONF_APPEND_LINE($2=$withval); \
 101  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103 dnl
 104 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105 dnl -----------------------------------------
 106 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108 dnl -Wall), it does not work.  By looking for function definition in
 109 dnl libraries, this problem can be worked around.
 110 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111   AC_SEARCH_LIBS([$1],,
 112   [$2],[$3])
 113 ],[$3])])
 114
 115 dnl
 116 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117 dnl -----------------------------
 118 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119 dnl tests that may want to take user settings into account.
 120 AC_DEFUN([GIT_STASH_FLAGS],[
 121 if test -n "$1"; then
 122    old_CPPFLAGS="$CPPFLAGS"
 123    old_LDFLAGS="$LDFLAGS"
 124    CPPFLAGS="-I$1/include $CPPFLAGS"
 125    LDFLAGS="-L$1/$lib $LDFLAGS"
 126 fi
 127 ])
 128
 129 dnl
 130 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131 dnl -----------------------------
 132 dnl Restore the stashed *FLAGS values.
 133 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134 if test -n "$1"; then
 135    CPPFLAGS="$old_CPPFLAGS"
 136    LDFLAGS="$old_LDFLAGS"
 137 fi
 138 ])
 139
 140 ## Site configuration related to programs (before tests)
 141 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 142 #
 143 # Set lib to alternative name of lib directory (e.g. lib64)
 144 AC_ARG_WITH([lib],
 145  [AS_HELP_STRING([--with-lib=ARG],
 146                  [ARG specifies alternative name for lib directory])],
 147  [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149 else \
 150         lib=$withval; \
 151         AC_MSG_NOTICE([Setting lib to '$lib']); \
 152         GIT_CONF_APPEND_LINE(lib=$withval); \
 153 fi; \
 154 ],[])
 155
 156 if test -z "$lib"; then
 157    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158    lib=lib
 159 fi
 160
 161 AC_ARG_ENABLE([pthreads],
 162  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164   [The default if FLAGS is not specified is to try first -pthread]
 165   [and then -lpthread.]
 166   [--without-pthreads will disable threading.])],
 167 [
 168 if test "x$enableval" = "xyes"; then
 169    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170 elif test "x$enableval" != "xno"; then
 171    PTHREAD_CFLAGS=$enableval
 172    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173 else
 174    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175    NO_PTHREADS=YesPlease
 176    USER_NOPTHREAD=1
 177 fi],
 178 [
 179    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180 ])
 181
 182 # Define option to enable JavaScript minification
 183 AC_ARG_ENABLE([jsmin],
 184 [AS_HELP_STRING([--enable-jsmin=PATH],
 185   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186 [
 187   JSMIN=$enableval;
 188   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189   GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190 ])
 191
 192 # Define option to enable CSS minification
 193 AC_ARG_ENABLE([cssmin],
 194 [AS_HELP_STRING([--enable-cssmin=PATH],
 195   [PATH is the name of a CSS minifier or the absolute path to one.])],
 196 [
 197   CSSMIN=$enableval;
 198   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199   GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200 ])
 201
 202 ## Site configuration (override autodetection)
 203 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 204 AC_MSG_NOTICE([CHECKS for site configuration])
 205 #
 206 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207 # tests.  These tests take up a significant amount of the total test time
 208 # but are not needed unless you plan to talk to SVN repos.
 209 #
 210 # Define PPC_SHA1 environment variable when running make to make use of
 211 # a bundled SHA1 routine optimized for PowerPC.
 212 #
 213 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214 # This also implies BLK_SHA1.
 215 #
 216 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217 # /foo/bar/include and /foo/bar/lib directories.
 218 AC_ARG_WITH(openssl,
 219 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221 GIT_PARSE_WITH(openssl))
 222 #
 223 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 224 # git-http-push are not built, and you cannot use http:// and https://
 225 # transports.
 226 #
 227 # Define CURLDIR=/foo/bar if your curl header and library files are in
 228 # /foo/bar/include and /foo/bar/lib directories.
 229 AC_ARG_WITH(curl,
 230 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232 GIT_PARSE_WITH(curl))
 233 #
 234 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235 # not built, and you cannot push using http:// and https:// transports.
 236 #
 237 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 238 # /foo/bar/include and /foo/bar/lib directories.
 239 AC_ARG_WITH(expat,
 240 AS_HELP_STRING([--with-expat],
 241 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243 GIT_PARSE_WITH(expat))
 244 #
 245 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246 # installed in /sw, but don't want GIT to link against any libraries
 247 # installed there.  If defined you may specify your own (or Fink's)
 248 # include directories and library directories by defining CFLAGS
 249 # and LDFLAGS appropriately.
 250 #
 251 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252 # have DarwinPorts installed in /opt/local, but don't want GIT to
 253 # link against any libraries installed there.  If defined you may
 254 # specify your own (or DarwinPort's) include directories and
 255 # library directories by defining CFLAGS and LDFLAGS appropriately.
 256 #
 257 # Define NO_MMAP if you want to avoid mmap.
 258 #
 259 # Define NO_ICONV if your libc does not properly support iconv.
 260 AC_ARG_WITH(iconv,
 261 AS_HELP_STRING([--without-iconv],
 262 [if your architecture doesn't properly support iconv])
 263 AS_HELP_STRING([--with-iconv=PATH],
 264 [PATH is prefix for libiconv library and headers])
 265 AS_HELP_STRING([],
 266 [used only if you need linking with libiconv]),
 267 GIT_PARSE_WITH(iconv))
 268
 269 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 270 #
 271 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 272 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274 # randomly break unless your underlying filesystem supports those sub-second
 275 # times (my ext3 doesn't).
 276 #
 277 # Define USE_STDEV below if you want git to care about the underlying device
 278 # change being considered an inode change from the update-index perspective.
 279
 280 #
 281 # Allow user to set ETC_GITCONFIG variable
 282 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                         Use VALUE instead of /etc/gitconfig as the
 284                         global git configuration file.
 285                         If VALUE is not fully qualified it will be interpretted
 286                         as a path relative to the computed prefix at runtime.)
 287
 288 #
 289 # Allow user to set the default pager
 290 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 291                         Use VALUE as the fall-back pager instead of 'less'.
 292                         This is used by things like 'git log' when the user
 293                         does not specify a pager to use through alternate
 294                         methods. eg: /usr/bin/pager)
 295 #
 296 # Allow user to set the default editor
 297 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 298                         Use VALUE as the fall-back editor instead of 'vi'.
 299                         This is used by things like 'git commit' when the user
 300                         does not specify a preferred editor through other
 301                         methods. eg: /usr/bin/editor)
 302
 303 #
 304 # Define SHELL_PATH to provide path to shell.
 305 GIT_ARG_SET_PATH(shell)
 306 #
 307 # Define PERL_PATH to provide path to Perl.
 308 GIT_ARG_SET_PATH(perl)
 309 #
 310 # Define PYTHON_PATH to provide path to Python.
 311 GIT_ARG_SET_PATH(python, allow-without)
 312 #
 313 # Define ZLIB_PATH to provide path to zlib.
 314 GIT_ARG_SET_PATH(zlib)
 315 #
 316 # Declare the with-tcltk/without-tcltk options.
 317 AC_ARG_WITH(tcltk,
 318 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 319 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 320 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 321 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 322 GIT_PARSE_WITH(tcltk))
 323 #
 324
 325
 326 ## Checks for programs.
 327 AC_MSG_NOTICE([CHECKS for programs])
 328 #
 329 AC_PROG_CC([cc gcc])
 330 AC_C_INLINE
 331 case $ac_cv_c_inline in
 332   inline | yes | no)    ;;
 333   *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 334 esac
 335
 336 # which switch to pass runtime path to dynamic libraries to the linker
 337 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 338    SAVE_LDFLAGS="${LDFLAGS}"
 339    LDFLAGS="${SAVE_LDFLAGS} -R /"
 340    AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 341    LDFLAGS="${SAVE_LDFLAGS}"
 342 ])
 343 if test "$git_cv_ld_dashr" = "yes"; then
 344    AC_SUBST(CC_LD_DYNPATH, [-R])
 345 else
 346    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 347       SAVE_LDFLAGS="${LDFLAGS}"
 348       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 349       AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 350       LDFLAGS="${SAVE_LDFLAGS}"
 351    ])
 352    if test "$git_cv_ld_wl_rpath" = "yes"; then
 353       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 354    else
 355       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 356          SAVE_LDFLAGS="${LDFLAGS}"
 357          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 358          AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 359          LDFLAGS="${SAVE_LDFLAGS}"
 360       ])
 361       if test "$git_cv_ld_rpath" = "yes"; then
 362          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 363       else
 364          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 365       fi
 366    fi
 367 fi
 368 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 369 AC_CHECK_TOOLS(AR, [gar ar], :)
 370 AC_CHECK_PROGS(TAR, [gtar tar])
 371 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 372 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 373 # or will be empty otherwise.
 374 if test -z "$NO_TCLTK"; then
 375   if test "$with_tcltk" = ""; then
 376   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 377     TCLTK_PATH=wish
 378     AC_SUBST(TCLTK_PATH)
 379   elif test "$with_tcltk" = "yes"; then
 380   # Tcl/Tk check requested.
 381     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 382   else
 383     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 384     TCLTK_PATH="$with_tcltk"
 385     AC_SUBST(TCLTK_PATH)
 386   fi
 387 fi
 388 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 389 if test -n "$ASCIIDOC"; then
 390         AC_MSG_CHECKING([for asciidoc version])
 391         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 392         case "${asciidoc_version}" in
 393         asciidoc' '8*)
 394                 ASCIIDOC8=YesPlease
 395                 AC_MSG_RESULT([${asciidoc_version} > 7])
 396                 ;;
 397         asciidoc' '7*)
 398                 ASCIIDOC8=
 399                 AC_MSG_RESULT([${asciidoc_version}])
 400                 ;;
 401         *)
 402                 ASCIIDOC8=
 403                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 404                 ;;
 405         esac
 406 fi
 407 AC_SUBST(ASCIIDOC8)
 408
 409
 410 ## Checks for libraries.
 411 AC_MSG_NOTICE([CHECKS for libraries])
 412 #
 413 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 414 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 415
 416 GIT_STASH_FLAGS($OPENSSLDIR)
 417
 418 AC_CHECK_LIB([crypto], [SHA1_Init],
 419 [NEEDS_SSL_WITH_CRYPTO=],
 420 [AC_CHECK_LIB([ssl], [SHA1_Init],
 421  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 422  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 423
 424 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 425
 426 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 427 AC_SUBST(NO_OPENSSL)
 428
 429 #
 430 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 431 # git-http-push are not built, and you cannot use http:// and https://
 432 # transports.
 433
 434 GIT_STASH_FLAGS($CURLDIR)
 435
 436 AC_CHECK_LIB([curl], [curl_global_init],
 437 [NO_CURL=],
 438 [NO_CURL=YesPlease])
 439
 440 GIT_UNSTASH_FLAGS($CURLDIR)
 441
 442 AC_SUBST(NO_CURL)
 443
 444 #
 445 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 446 # not built, and you cannot push using http:// and https:// transports.
 447
 448 GIT_STASH_FLAGS($EXPATDIR)
 449
 450 AC_CHECK_LIB([expat], [XML_ParserCreate],
 451 [NO_EXPAT=],
 452 [NO_EXPAT=YesPlease])
 453
 454 GIT_UNSTASH_FLAGS($EXPATDIR)
 455
 456 AC_SUBST(NO_EXPAT)
 457
 458 #
 459 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 460 # some Solaris installations).
 461 # Define NO_ICONV if neither libc nor libiconv support iconv.
 462
 463 if test -z "$NO_ICONV"; then
 464
 465 GIT_STASH_FLAGS($ICONVDIR)
 466
 467 AC_DEFUN([ICONVTEST_SRC], [
 468 #include <iconv.h>
 469
 470 int main(void)
 471 {
 472         iconv_open("", "");
 473         return 0;
 474 }
 475 ])
 476
 477 if test -n "$ICONVDIR"; then
 478    lib_order="-liconv -lc"
 479 else
 480    lib_order="-lc -liconv"
 481 fi
 482
 483 NO_ICONV=YesPlease
 484
 485 for l in $lib_order; do
 486     if test "$l" = "-liconv"; then
 487        NEEDS_LIBICONV=YesPlease
 488     else
 489        NEEDS_LIBICONV=
 490     fi
 491
 492     old_LIBS="$LIBS"
 493     LIBS="$LIBS $l"
 494     AC_MSG_CHECKING([for iconv in $l])
 495     AC_LINK_IFELSE(ICONVTEST_SRC,
 496         [AC_MSG_RESULT([yes])
 497         NO_ICONV=
 498         break],
 499         [AC_MSG_RESULT([no])])
 500     LIBS="$old_LIBS"
 501 done
 502
 503 #in case of break
 504 LIBS="$old_LIBS"
 505
 506 GIT_UNSTASH_FLAGS($ICONVDIR)
 507
 508 AC_SUBST(NEEDS_LIBICONV)
 509 AC_SUBST(NO_ICONV)
 510
 511 if test -n "$NO_ICONV"; then
 512     NEEDS_LIBICONV=
 513 fi
 514
 515 fi
 516
 517 #
 518 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 519
 520 GIT_STASH_FLAGS($ZLIB_PATH)
 521
 522 AC_DEFUN([ZLIBTEST_SRC], [
 523 #include <zlib.h>
 524
 525 int main(void)
 526 {
 527         deflateBound(0, 0);
 528         return 0;
 529 }
 530 ])
 531 AC_MSG_CHECKING([for deflateBound in -lz])
 532 old_LIBS="$LIBS"
 533 LIBS="$LIBS -lz"
 534 AC_LINK_IFELSE(ZLIBTEST_SRC,
 535         [AC_MSG_RESULT([yes])],
 536         [AC_MSG_RESULT([no])
 537         NO_DEFLATE_BOUND=yes])
 538 LIBS="$old_LIBS"
 539
 540 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 541
 542 AC_SUBST(NO_DEFLATE_BOUND)
 543
 544 #
 545 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 546 # Patrick Mauritz).
 547 AC_CHECK_LIB([c], [socket],
 548 [NEEDS_SOCKET=],
 549 [NEEDS_SOCKET=YesPlease])
 550 AC_SUBST(NEEDS_SOCKET)
 551 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 552
 553 #
 554 # The next few tests will define NEEDS_RESOLV if linking with
 555 # libresolv provides some of the functions we would normally get
 556 # from libc.
 557 NEEDS_RESOLV=
 558 AC_SUBST(NEEDS_RESOLV)
 559 #
 560 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 561 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 562 NO_INET_NTOP=
 563 AC_SUBST(NO_INET_NTOP)
 564 AC_CHECK_FUNC([inet_ntop],
 565         [],
 566     [AC_CHECK_LIB([resolv], [inet_ntop],
 567             [NEEDS_RESOLV=YesPlease],
 568         [NO_INET_NTOP=YesPlease])
 569 ])
 570 #
 571 # Define NO_INET_PTON if linking with -lresolv is not enough.
 572 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 573 NO_INET_PTON=
 574 AC_SUBST(NO_INET_PTON)
 575 AC_CHECK_FUNC([inet_pton],
 576         [],
 577     [AC_CHECK_LIB([resolv], [inet_pton],
 578             [NEEDS_RESOLV=YesPlease],
 579         [NO_INET_PTON=YesPlease])
 580 ])
 581 #
 582 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 583 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 584 NO_HSTRERROR=
 585 AC_CHECK_FUNC([hstrerror],
 586         [],
 587     [AC_CHECK_LIB([resolv], [hstrerror],
 588             [NEEDS_RESOLV=YesPlease],
 589         [NO_HSTRERROR=YesPlease])
 590 ])
 591 AC_SUBST(NO_HSTRERROR)
 592 #
 593 # If any of the above tests determined that -lresolv is needed at
 594 # build-time, also set it here for remaining configure-time checks.
 595 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 596
 597 AC_CHECK_LIB([c], [basename],
 598 [NEEDS_LIBGEN=],
 599 [NEEDS_LIBGEN=YesPlease])
 600 AC_SUBST(NEEDS_LIBGEN)
 601 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 602
 603 ## Checks for header files.
 604 AC_MSG_NOTICE([CHECKS for header files])
 605 #
 606 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 607 AC_CHECK_HEADER([sys/select.h],
 608 [NO_SYS_SELECT_H=],
 609 [NO_SYS_SELECT_H=UnfortunatelyYes])
 610 AC_SUBST(NO_SYS_SELECT_H)
 611 #
 612 # Define OLD_ICONV if your library has an old iconv(), where the second
 613 # (input buffer pointer) parameter is declared with type (const char **).
 614 AC_DEFUN([OLDICONVTEST_SRC], [[
 615 #include <iconv.h>
 616
 617 extern size_t iconv(iconv_t cd,
 618                     char **inbuf, size_t *inbytesleft,
 619                     char **outbuf, size_t *outbytesleft);
 620
 621 int main(void)
 622 {
 623         return 0;
 624 }
 625 ]])
 626
 627 GIT_STASH_FLAGS($ICONVDIR)
 628
 629 AC_MSG_CHECKING([for old iconv()])
 630 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 631         [AC_MSG_RESULT([no])],
 632         [AC_MSG_RESULT([yes])
 633         OLD_ICONV=UnfortunatelyYes])
 634
 635 GIT_UNSTASH_FLAGS($ICONVDIR)
 636
 637 AC_SUBST(OLD_ICONV)
 638
 639 ## Checks for typedefs, structures, and compiler characteristics.
 640 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 641 #
 642 TYPE_SOCKLEN_T
 643 case $ac_cv_type_socklen_t in
 644   yes)  ;;
 645   *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 646 esac
 647
 648 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 649 AC_CHECK_MEMBER(struct dirent.d_ino,
 650 [NO_D_INO_IN_DIRENT=],
 651 [NO_D_INO_IN_DIRENT=YesPlease],
 652 [#include <dirent.h>])
 653 AC_SUBST(NO_D_INO_IN_DIRENT)
 654 #
 655 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 656 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 657 AC_CHECK_MEMBER(struct dirent.d_type,
 658 [NO_D_TYPE_IN_DIRENT=],
 659 [NO_D_TYPE_IN_DIRENT=YesPlease],
 660 [#include <dirent.h>])
 661 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 662 #
 663 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 664 # sockaddr_storage.
 665 AC_CHECK_TYPE(struct sockaddr_storage,
 666 [NO_SOCKADDR_STORAGE=],
 667 [NO_SOCKADDR_STORAGE=YesPlease],[
 668 #include <sys/types.h>
 669 #include <sys/socket.h>
 670 ])
 671 AC_SUBST(NO_SOCKADDR_STORAGE)
 672 #
 673 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 674 AC_CHECK_TYPE([struct addrinfo],[
 675  GIT_CHECK_FUNC([getaddrinfo],
 676   [NO_IPV6=],
 677   [NO_IPV6=YesPlease])
 678 ],[NO_IPV6=YesPlease],[
 679 #include <sys/types.h>
 680 #include <sys/socket.h>
 681 #include <netdb.h>
 682 ])
 683 AC_SUBST(NO_IPV6)
 684 #
 685 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 686 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 687 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 688 # some C compilers supported these specifiers prior to C99 as an extension.
 689 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 690  [ac_cv_c_c99_format],
 691 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 692 AC_RUN_IFELSE(
 693         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 694                 [[char buf[64];
 695                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 696                   return 1;
 697                 else if (strcmp(buf, "12345"))
 698                   return 2;]])],
 699         [ac_cv_c_c99_format=yes],
 700         [ac_cv_c_c99_format=no])
 701 ])
 702 if test $ac_cv_c_c99_format = no; then
 703         NO_C99_FORMAT=YesPlease
 704 else
 705         NO_C99_FORMAT=
 706 fi
 707 AC_SUBST(NO_C99_FORMAT)
 708 #
 709 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 710 # when attempting to read from an fopen'ed directory.
 711 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 712  [ac_cv_fread_reads_directories],
 713 [
 714 AC_RUN_IFELSE(
 715         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 716                 [[char c;
 717                 FILE *f = fopen(".", "r");
 718                 return f && fread(&c, 1, 1, f)]])],
 719         [ac_cv_fread_reads_directories=no],
 720         [ac_cv_fread_reads_directories=yes])
 721 ])
 722 if test $ac_cv_fread_reads_directories = yes; then
 723         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 724 else
 725         FREAD_READS_DIRECTORIES=
 726 fi
 727 AC_SUBST(FREAD_READS_DIRECTORIES)
 728 #
 729 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 730 # or vsnprintf() return -1 instead of number of characters which would
 731 # have been written to the final string if enough space had been available.
 732 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 733  [ac_cv_snprintf_returns_bogus],
 734 [
 735 AC_RUN_IFELSE(
 736         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 737                 #include "stdarg.h"
 738
 739                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 740                 {
 741                   int ret;
 742                   va_list ap;
 743                   va_start(ap, format);
 744                   ret = vsnprintf(str, maxsize, format, ap);
 745                   va_end(ap);
 746                   return ret;
 747                 }],
 748                 [[char buf[6];
 749                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 750                       || strcmp(buf, "12")) return 1;
 751                   if (snprintf(buf, 3, "%s", "12345") != 5
 752                       || strcmp(buf, "12")) return 1]])],
 753         [ac_cv_snprintf_returns_bogus=no],
 754         [ac_cv_snprintf_returns_bogus=yes])
 755 ])
 756 if test $ac_cv_snprintf_returns_bogus = yes; then
 757         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 758 else
 759         SNPRINTF_RETURNS_BOGUS=
 760 fi
 761 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 762
 763
 764 ## Checks for library functions.
 765 ## (in default C library and libraries checked by AC_CHECK_LIB)
 766 AC_MSG_NOTICE([CHECKS for library functions])
 767 #
 768 # Define NO_LIBGEN_H if you don't have libgen.h.
 769 AC_CHECK_HEADER([libgen.h],
 770 [NO_LIBGEN_H=],
 771 [NO_LIBGEN_H=YesPlease])
 772 AC_SUBST(NO_LIBGEN_H)
 773 #
 774 # Define HAVE_PATHS_H if you have paths.h.
 775 AC_CHECK_HEADER([paths.h],
 776 [HAVE_PATHS_H=YesPlease],
 777 [HAVE_PATHS_H=])
 778 AC_SUBST(HAVE_PATHS_H)
 779 #
 780 # Define NO_STRCASESTR if you don't have strcasestr.
 781 GIT_CHECK_FUNC(strcasestr,
 782 [NO_STRCASESTR=],
 783 [NO_STRCASESTR=YesPlease])
 784 AC_SUBST(NO_STRCASESTR)
 785 #
 786 # Define NO_MEMMEM if you don't have memmem.
 787 GIT_CHECK_FUNC(memmem,
 788 [NO_MEMMEM=],
 789 [NO_MEMMEM=YesPlease])
 790 AC_SUBST(NO_MEMMEM)
 791 #
 792 # Define NO_STRLCPY if you don't have strlcpy.
 793 GIT_CHECK_FUNC(strlcpy,
 794 [NO_STRLCPY=],
 795 [NO_STRLCPY=YesPlease])
 796 AC_SUBST(NO_STRLCPY)
 797 #
 798 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 799 AC_CHECK_TYPE(uintmax_t,
 800 [NO_UINTMAX_T=],
 801 [NO_UINTMAX_T=YesPlease],[
 802 #include <inttypes.h>
 803 ])
 804 AC_SUBST(NO_UINTMAX_T)
 805 #
 806 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 807 GIT_CHECK_FUNC(strtoumax,
 808 [NO_STRTOUMAX=],
 809 [NO_STRTOUMAX=YesPlease])
 810 AC_SUBST(NO_STRTOUMAX)
 811 #
 812 # Define NO_SETENV if you don't have setenv in the C library.
 813 GIT_CHECK_FUNC(setenv,
 814 [NO_SETENV=],
 815 [NO_SETENV=YesPlease])
 816 AC_SUBST(NO_SETENV)
 817 #
 818 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 819 GIT_CHECK_FUNC(unsetenv,
 820 [NO_UNSETENV=],
 821 [NO_UNSETENV=YesPlease])
 822 AC_SUBST(NO_UNSETENV)
 823 #
 824 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 825 GIT_CHECK_FUNC(mkdtemp,
 826 [NO_MKDTEMP=],
 827 [NO_MKDTEMP=YesPlease])
 828 AC_SUBST(NO_MKDTEMP)
 829 #
 830 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 831 GIT_CHECK_FUNC(mkstemps,
 832 [NO_MKSTEMPS=],
 833 [NO_MKSTEMPS=YesPlease])
 834 AC_SUBST(NO_MKSTEMPS)
 835 #
 836 #
 837 # Define NO_MMAP if you want to avoid mmap.
 838 #
 839 # Define NO_ICONV if your libc does not properly support iconv.
 840
 841
 842 ## Other checks.
 843 # Define USE_PIC if you need the main git objects to be built with -fPIC
 844 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 845 #
 846 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 847 # Enable it on Windows.  By default, symrefs are still used.
 848 #
 849 # Define NO_PTHREADS if we do not have pthreads.
 850 #
 851 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
 852 AC_DEFUN([PTHREADTEST_SRC], [
 853 #include <pthread.h>
 854
 855 int main(void)
 856 {
 857         pthread_mutex_t test_mutex;
 858         int retcode = 0;
 859         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 860         retcode |= pthread_mutex_lock(&test_mutex);
 861         retcode |= pthread_mutex_unlock(&test_mutex);
 862         return retcode;
 863 }
 864 ])
 865
 866 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 867 dnl   [[#include <pthread.h>]],
 868 dnl   [[pthread_mutex_t test_mutex;]]
 869 dnl )])
 870
 871 NO_PTHREADS=UnfortunatelyYes
 872 PTHREAD_LIBS=
 873
 874 if test -n "$USER_NOPTHREAD"; then
 875    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 876 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 877 # -D_REENTRANT' or some such.
 878 elif test -z "$PTHREAD_CFLAGS"; then
 879   threads_found=no
 880   for opt in -mt -pthread -lpthread; do
 881      old_CFLAGS="$CFLAGS"
 882      CFLAGS="$opt $CFLAGS"
 883      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 884      AC_LINK_IFELSE(PTHREADTEST_SRC,
 885         [AC_MSG_RESULT([yes])
 886                 NO_PTHREADS=
 887                 PTHREAD_LIBS="$opt"
 888                 PTHREAD_CFLAGS="$opt"
 889                 threads_found=yes
 890                 break
 891         ],
 892         [AC_MSG_RESULT([no])])
 893       CFLAGS="$old_CFLAGS"
 894   done
 895   if test $threads_found != yes; then
 896     AC_CHECK_LIB([pthread], [pthread_create],
 897         [PTHREAD_LIBS="-lpthread"],
 898         [NO_PTHREADS=UnfortunatelyYes])
 899   fi
 900 else
 901   old_CFLAGS="$CFLAGS"
 902   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 903   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 904   AC_LINK_IFELSE(PTHREADTEST_SRC,
 905         [AC_MSG_RESULT([yes])
 906                 NO_PTHREADS=
 907                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
 908         ],
 909         [AC_MSG_RESULT([no])])
 910
 911   CFLAGS="$old_CFLAGS"
 912 fi
 913
 914 CFLAGS="$old_CFLAGS"
 915
 916 AC_SUBST(PTHREAD_CFLAGS)
 917 AC_SUBST(PTHREAD_LIBS)
 918 AC_SUBST(NO_PTHREADS)
 919
 920 ## Output files
 921 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 922 AC_OUTPUT
 923
 924
 925 ## Cleanup
 926 rm -f "${config_append}"