configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specified by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 #
 245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 246 # /foo/bar/include and /foo/bar/lib directories.
 247 AC_ARG_WITH(openssl,
 248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 249 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 250 GIT_PARSE_WITH([openssl]))
 251
 252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 253 # commands such as log and grep offer runtime options to use
 254 # Perl-compatible regular expressions instead of standard or extended
 255 # POSIX regular expressions. Only libpcre version 2 is supported.
 256 #
 257 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
 258 # /foo/bar/include and /foo/bar/lib directories.
 259 #
 260
 261 AC_ARG_WITH(libpcre1,
 262 AS_HELP_STRING([--with-libpcre1],[DEPRECATED]),
 263     AC_MSG_ERROR([support for --with-libpcre1 has been removed. Use --with-libpcre2!])
 264     )
 265
 266 AC_ARG_WITH(libpcre,
 267 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
 268     if test "$withval" = "no"; then
 269         USE_LIBPCRE2=
 270     elif test "$withval" = "yes"; then
 271         USE_LIBPCRE2=YesPlease
 272     else
 273         USE_LIBPCRE2=YesPlease
 274         LIBPCREDIR=$withval
 275         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 276         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 277         dnl it yet.
 278         GIT_CONF_SUBST([LIBPCREDIR])
 279     fi)
 280
 281 AC_ARG_WITH(libpcre2,
 282 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
 283 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 284     if test -n "$USE_LIBPCRE2"; then
 285         AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
 286     fi
 287
 288     if test "$withval" = "no"; then
 289         USE_LIBPCRE2=
 290     elif test "$withval" = "yes"; then
 291         USE_LIBPCRE2=YesPlease
 292     else
 293         USE_LIBPCRE2=YesPlease
 294         LIBPCREDIR=$withval
 295         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 296         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 297         dnl it yet.
 298         GIT_CONF_SUBST([LIBPCREDIR])
 299     fi)
 300 #
 301 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 302 AC_FUNC_ALLOCA
 303 case $ac_cv_working_alloca_h in
 304     yes)    HAVE_ALLOCA_H=YesPlease;;
 305     *)      HAVE_ALLOCA_H='';;
 306 esac
 307 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 308 #
 309 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 310 # git-http-push are not built, and you cannot use http:// and https://
 311 # transports.
 312 #
 313 # Define CURLDIR=/foo/bar if your curl header and library files are in
 314 # /foo/bar/include and /foo/bar/lib directories.
 315 AC_ARG_WITH(curl,
 316 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 317 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 318 GIT_PARSE_WITH(curl))
 319 #
 320 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 321 # not built, and you cannot push using http:// and https:// transports.
 322 #
 323 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 324 # /foo/bar/include and /foo/bar/lib directories.
 325 AC_ARG_WITH(expat,
 326 AS_HELP_STRING([--with-expat],
 327 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 328 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 329 GIT_PARSE_WITH(expat))
 330 #
 331 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 332 # installed in /sw, but don't want GIT to link against any libraries
 333 # installed there.  If defined you may specify your own (or Fink's)
 334 # include directories and library directories by defining CFLAGS
 335 # and LDFLAGS appropriately.
 336 #
 337 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 338 # have DarwinPorts installed in /opt/local, but don't want GIT to
 339 # link against any libraries installed there.  If defined you may
 340 # specify your own (or DarwinPort's) include directories and
 341 # library directories by defining CFLAGS and LDFLAGS appropriately.
 342 #
 343 # Define NO_MMAP if you want to avoid mmap.
 344 #
 345 # Define NO_ICONV if your libc does not properly support iconv.
 346 AC_ARG_WITH(iconv,
 347 AS_HELP_STRING([--without-iconv],
 348 [if your architecture doesn't properly support iconv])
 349 AS_HELP_STRING([--with-iconv=PATH],
 350 [PATH is prefix for libiconv library and headers])
 351 AS_HELP_STRING([],
 352 [used only if you need linking with libiconv]),
 353 GIT_PARSE_WITH(iconv))
 354
 355 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 356 #
 357 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 358 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 359 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 360 # randomly break unless your underlying filesystem supports those sub-second
 361 # times (my ext3 doesn't).
 362 #
 363 # Define USE_STDEV below if you want git to care about the underlying device
 364 # change being considered an inode change from the update-index perspective.
 365
 366 #
 367 # Allow user to set ETC_GITCONFIG variable
 368 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 369                         Use VALUE instead of /etc/gitconfig as the
 370                         global git configuration file.
 371                         If VALUE is not fully qualified it will be interpreted
 372                         as a path relative to the computed prefix at runtime.)
 373
 374 #
 375 # Allow user to set ETC_GITATTRIBUTES variable
 376 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 377                         Use VALUE instead of /etc/gitattributes as the
 378                         global git attributes file.
 379                         If VALUE is not fully qualified it will be interpreted
 380                         as a path relative to the computed prefix at runtime.)
 381
 382 #
 383 # Allow user to set the default pager
 384 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 385                         Use VALUE as the fall-back pager instead of 'less'.
 386                         This is used by things like 'git log' when the user
 387                         does not specify a pager to use through alternate
 388                         methods. eg: /usr/bin/pager)
 389 #
 390 # Allow user to set the default editor
 391 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 392                         Use VALUE as the fall-back editor instead of 'vi'.
 393                         This is used by things like 'git commit' when the user
 394                         does not specify a preferred editor through other
 395                         methods. eg: /usr/bin/editor)
 396
 397 #
 398 # Define SHELL_PATH to provide path to shell.
 399 GIT_ARG_SET_PATH(shell)
 400 #
 401 # Define PERL_PATH to provide path to Perl.
 402 GIT_ARG_SET_PATH(perl)
 403 #
 404 # Define PYTHON_PATH to provide path to Python.
 405 GIT_ARG_SET_PATH(python, allow-without)
 406 #
 407 # Define ZLIB_PATH to provide path to zlib.
 408 GIT_ARG_SET_PATH(zlib)
 409 #
 410 # Declare the with-tcltk/without-tcltk options.
 411 AC_ARG_WITH(tcltk,
 412 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 413 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 414 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 415 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 416 GIT_PARSE_WITH(tcltk))
 417 #
 418
 419
 420 ## Checks for programs.
 421 AC_MSG_NOTICE([CHECKS for programs])
 422 #
 423 AC_PROG_CC([cc gcc])
 424 AC_C_INLINE
 425 case $ac_cv_c_inline in
 426   inline | yes | no) INLINE='';;
 427   *)                 INLINE=$ac_cv_c_inline ;;
 428 esac
 429 GIT_CONF_SUBST([INLINE])
 430
 431 # which switch to pass runtime path to dynamic libraries to the linker
 432 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 433    SAVE_LDFLAGS="${LDFLAGS}"
 434    LDFLAGS="${SAVE_LDFLAGS} -R /"
 435    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 436    LDFLAGS="${SAVE_LDFLAGS}"
 437 ])
 438 if test "$git_cv_ld_dashr" = "yes"; then
 439    CC_LD_DYNPATH=-R
 440 else
 441    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 442       SAVE_LDFLAGS="${LDFLAGS}"
 443       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 444       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 445       LDFLAGS="${SAVE_LDFLAGS}"
 446    ])
 447    if test "$git_cv_ld_wl_rpath" = "yes"; then
 448       CC_LD_DYNPATH=-Wl,-rpath,
 449    else
 450       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 451          SAVE_LDFLAGS="${LDFLAGS}"
 452          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 453          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 454          LDFLAGS="${SAVE_LDFLAGS}"
 455       ])
 456       if test "$git_cv_ld_rpath" = "yes"; then
 457          CC_LD_DYNPATH=-rpath
 458       else
 459          AC_CACHE_CHECK([if linker supports -Wl,+b,], git_cv_ld_wl_b, [
 460             SAVE_LDFLAGS="${LDFLAGS}"
 461             LDFLAGS="${SAVE_LDFLAGS} -Wl,+b,/"
 462             AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_b=yes], [git_cv_ld_wl_b=no])
 463             LDFLAGS="${SAVE_LDFLAGS}"
 464          ])
 465          if test "$git_cv_ld_wl_b" = "yes"; then
 466             CC_LD_DYNPATH=-Wl,+b,
 467           else
 468              CC_LD_DYNPATH=
 469              AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 470           fi
 471       fi
 472    fi
 473 fi
 474 GIT_CONF_SUBST([CC_LD_DYNPATH])
 475 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 476 AC_CHECK_TOOLS(AR, [gar ar], :)
 477 AC_CHECK_PROGS(TAR, [gtar tar])
 478 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 479 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 480 # or will be empty otherwise.
 481 if test -n "$NO_TCLTK"; then
 482   TCLTK_PATH=
 483 else
 484   if test "$with_tcltk" = ""; then
 485   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 486     TCLTK_PATH=wish
 487   elif test "$with_tcltk" = "yes"; then
 488   # Tcl/Tk check requested.
 489     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 490   else
 491     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 492     TCLTK_PATH="$with_tcltk"
 493   fi
 494 fi
 495 GIT_CONF_SUBST([TCLTK_PATH])
 496 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 497 if test -n "$ASCIIDOC"; then
 498         AC_MSG_CHECKING([for asciidoc version])
 499         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 500         case "${asciidoc_version}" in
 501         asciidoc' '8*)
 502                 AC_MSG_RESULT([${asciidoc_version}])
 503                 ;;
 504         *)
 505                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 506                 ;;
 507         esac
 508 fi
 509
 510 if grep -a ascii configure.ac >/dev/null; then
 511   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
 512   SANE_TEXT_GREP=-a
 513 else
 514   SANE_TEXT_GREP=
 515 fi
 516 GIT_CONF_SUBST([SANE_TEXT_GREP])
 517
 518 ## Checks for libraries.
 519 AC_MSG_NOTICE([CHECKS for libraries])
 520 #
 521 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 522 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 523
 524 GIT_STASH_FLAGS($OPENSSLDIR)
 525
 526 AC_CHECK_LIB([crypto], [SHA1_Init],
 527 [NEEDS_SSL_WITH_CRYPTO=],
 528 [AC_CHECK_LIB([ssl], [SHA1_Init],
 529  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 530  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 531
 532 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 533
 534 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 535 GIT_CONF_SUBST([NO_OPENSSL])
 536
 537 #
 538 # Handle the USE_LIBPCRE options potentially set above.
 539 #
 540
 541 if test -n "$USE_LIBPCRE2"; then
 542
 543 GIT_STASH_FLAGS($LIBPCREDIR)
 544
 545 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
 546 [USE_LIBPCRE2=YesPlease],
 547 [USE_LIBPCRE2=])
 548
 549 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 550
 551 GIT_CONF_SUBST([USE_LIBPCRE2])
 552
 553 fi
 554
 555 #
 556 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 557 # git-http-push are not built, and you cannot use http:// and https://
 558 # transports.
 559
 560 GIT_STASH_FLAGS($CURLDIR)
 561
 562 AC_CHECK_LIB([curl], [curl_global_init],
 563 [NO_CURL=],
 564 [NO_CURL=YesPlease])
 565
 566 GIT_UNSTASH_FLAGS($CURLDIR)
 567
 568 GIT_CONF_SUBST([NO_CURL])
 569
 570 if test -z "$NO_CURL"; then
 571
 572 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 573 [curl-config],
 574 [no])
 575
 576 if test $CURL_CONFIG != no; then
 577     GIT_CONF_SUBST([CURL_CONFIG])
 578
 579     if test -z "$CURL_CONFIG_OPTS"; then
 580         CURL_CONFIG_OPTS="--libs"
 581     fi
 582
 583     CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
 584     AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
 585     GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
 586 fi
 587
 588 fi
 589
 590
 591 #
 592 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 593 # not built, and you cannot push using http:// and https:// transports.
 594
 595 GIT_STASH_FLAGS($EXPATDIR)
 596
 597 AC_CHECK_LIB([expat], [XML_ParserCreate],
 598 [NO_EXPAT=],
 599 [NO_EXPAT=YesPlease])
 600
 601 GIT_UNSTASH_FLAGS($EXPATDIR)
 602
 603 GIT_CONF_SUBST([NO_EXPAT])
 604
 605 #
 606 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 607 # some Solaris installations).
 608 # Define NO_ICONV if neither libc nor libiconv support iconv.
 609
 610 if test -z "$NO_ICONV"; then
 611
 612 GIT_STASH_FLAGS($ICONVDIR)
 613
 614 AC_DEFUN([ICONVTEST_SRC],
 615 [AC_LANG_PROGRAM([#include <iconv.h>],
 616  [iconv_open("", "");])])
 617
 618 if test -n "$ICONVDIR"; then
 619    lib_order="-liconv -lc"
 620 else
 621    lib_order="-lc -liconv"
 622 fi
 623
 624 NO_ICONV=YesPlease
 625
 626 for l in $lib_order; do
 627     if test "$l" = "-liconv"; then
 628        NEEDS_LIBICONV=YesPlease
 629     else
 630        NEEDS_LIBICONV=
 631     fi
 632
 633     old_LIBS="$LIBS"
 634     LIBS="$LIBS $l"
 635     AC_MSG_CHECKING([for iconv in $l])
 636     AC_LINK_IFELSE([ICONVTEST_SRC],
 637         [AC_MSG_RESULT([yes])
 638         NO_ICONV=
 639         break],
 640         [AC_MSG_RESULT([no])])
 641     LIBS="$old_LIBS"
 642 done
 643
 644 #in case of break
 645 LIBS="$old_LIBS"
 646
 647 GIT_UNSTASH_FLAGS($ICONVDIR)
 648
 649 GIT_CONF_SUBST([NEEDS_LIBICONV])
 650 GIT_CONF_SUBST([NO_ICONV])
 651
 652 if test -n "$NO_ICONV"; then
 653     NEEDS_LIBICONV=
 654 fi
 655
 656 fi
 657
 658 #
 659 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 660
 661 GIT_STASH_FLAGS($ZLIB_PATH)
 662
 663 AC_DEFUN([ZLIBTEST_SRC], [
 664 AC_LANG_PROGRAM([#include <zlib.h>],
 665  [deflateBound(0, 0);])])
 666 AC_MSG_CHECKING([for deflateBound in -lz])
 667 old_LIBS="$LIBS"
 668 LIBS="$LIBS -lz"
 669 AC_LINK_IFELSE([ZLIBTEST_SRC],
 670         [AC_MSG_RESULT([yes])],
 671         [AC_MSG_RESULT([no])
 672         NO_DEFLATE_BOUND=yes])
 673 LIBS="$old_LIBS"
 674
 675 AC_DEFUN([ZLIBTEST_UNCOMPRESS2_SRC], [
 676 AC_LANG_PROGRAM([#include <zlib.h>],
 677  [uncompress2(NULL,NULL,NULL,NULL);])])
 678 AC_MSG_CHECKING([for uncompress2 in -lz])
 679 old_LIBS="$LIBS"
 680 LIBS="$LIBS -lz"
 681 AC_LINK_IFELSE([ZLIBTEST_UNCOMPRESS2_SRC],
 682         [AC_MSG_RESULT([yes])],
 683         [AC_MSG_RESULT([no])
 684         NO_UNCOMPRESS2=yes])
 685 LIBS="$old_LIBS"
 686
 687 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 688
 689 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 690 GIT_CONF_SUBST([NO_UNCOMPRESS2])
 691
 692 #
 693 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 694 # Patrick Mauritz).
 695 AC_CHECK_LIB([c], [socket],
 696 [NEEDS_SOCKET=],
 697 [NEEDS_SOCKET=YesPlease])
 698 GIT_CONF_SUBST([NEEDS_SOCKET])
 699 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 700
 701 #
 702 # The next few tests will define NEEDS_RESOLV if linking with
 703 # libresolv provides some of the functions we would normally get
 704 # from libc.
 705 NEEDS_RESOLV=
 706 #
 707 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 708 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 709 NO_INET_NTOP=
 710 AC_CHECK_FUNC([inet_ntop],
 711     [],
 712     [AC_CHECK_LIB([resolv], [inet_ntop],
 713         [NEEDS_RESOLV=YesPlease],
 714         [NO_INET_NTOP=YesPlease])
 715 ])
 716 GIT_CONF_SUBST([NO_INET_NTOP])
 717 #
 718 # Define NO_INET_PTON if linking with -lresolv is not enough.
 719 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 720 NO_INET_PTON=
 721 AC_CHECK_FUNC([inet_pton],
 722     [],
 723     [AC_CHECK_LIB([resolv], [inet_pton],
 724         [NEEDS_RESOLV=YesPlease],
 725         [NO_INET_PTON=YesPlease])
 726 ])
 727 GIT_CONF_SUBST([NO_INET_PTON])
 728 #
 729 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 730 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 731 NO_HSTRERROR=
 732 AC_CHECK_FUNC([hstrerror],
 733     [],
 734     [AC_CHECK_LIB([resolv], [hstrerror],
 735         [NEEDS_RESOLV=YesPlease],
 736         [NO_HSTRERROR=YesPlease])
 737 ])
 738 GIT_CONF_SUBST([NO_HSTRERROR])
 739
 740 dnl This must go after all the possible places for its initialization,
 741 dnl in the AC_CHECK_FUNC invocations above.
 742 GIT_CONF_SUBST([NEEDS_RESOLV])
 743 #
 744 # If any of the above tests determined that -lresolv is needed at
 745 # build-time, also set it here for remaining configure-time checks.
 746 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 747
 748 AC_CHECK_LIB([c], [basename],
 749 [NEEDS_LIBGEN=],
 750 [NEEDS_LIBGEN=YesPlease])
 751 GIT_CONF_SUBST([NEEDS_LIBGEN])
 752 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 753
 754 AC_DEFUN([LIBINTL_SRC], [
 755 AC_LANG_PROGRAM([[
 756 #include <libintl.h>
 757 ]],[[
 758 char *msg = gettext("test");
 759 ]])])
 760
 761 AC_MSG_CHECKING([if libc contains libintl])
 762 AC_LINK_IFELSE([LIBINTL_SRC],
 763         [AC_MSG_RESULT([yes])
 764         LIBC_CONTAINS_LIBINTL=YesPlease],
 765         [AC_MSG_RESULT([no])
 766         LIBC_CONTAINS_LIBINTL=])
 767 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 768
 769 #
 770 # Define NO_GETTEXT if you don't want Git output to be translated.
 771 # A translated Git requires GNU libintl or another gettext implementation
 772 AC_CHECK_HEADER([libintl.h],
 773 [NO_GETTEXT=],
 774 [NO_GETTEXT=YesPlease])
 775 GIT_CONF_SUBST([NO_GETTEXT])
 776
 777 if test -z "$NO_GETTEXT"; then
 778     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 779 fi
 780
 781 ## Checks for header files.
 782 AC_MSG_NOTICE([CHECKS for header files])
 783 #
 784 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 785 AC_CHECK_HEADER([sys/select.h],
 786 [NO_SYS_SELECT_H=],
 787 [NO_SYS_SELECT_H=UnfortunatelyYes])
 788 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 789 #
 790 # Define NO_POLL_H if you don't have poll.h
 791 AC_CHECK_HEADER([poll.h],
 792 [NO_POLL_H=],
 793 [NO_POLL_H=UnfortunatelyYes])
 794 GIT_CONF_SUBST([NO_POLL_H])
 795 #
 796 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 797 AC_CHECK_HEADER([sys/poll.h],
 798 [NO_SYS_POLL_H=],
 799 [NO_SYS_POLL_H=UnfortunatelyYes])
 800 GIT_CONF_SUBST([NO_SYS_POLL_H])
 801 #
 802 # Define NO_INTTYPES_H if you don't have inttypes.h
 803 AC_CHECK_HEADER([inttypes.h],
 804 [NO_INTTYPES_H=],
 805 [NO_INTTYPES_H=UnfortunatelyYes])
 806 GIT_CONF_SUBST([NO_INTTYPES_H])
 807 #
 808 # Define OLD_ICONV if your library has an old iconv(), where the second
 809 # (input buffer pointer) parameter is declared with type (const char **).
 810 AC_DEFUN([OLDICONVTEST_SRC], [
 811 AC_LANG_PROGRAM([[
 812 #include <iconv.h>
 813
 814 extern size_t iconv(iconv_t cd,
 815                     char **inbuf, size_t *inbytesleft,
 816                     char **outbuf, size_t *outbytesleft);
 817 ]], [])])
 818
 819 GIT_STASH_FLAGS($ICONVDIR)
 820
 821 AC_MSG_CHECKING([for old iconv()])
 822 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 823         [AC_MSG_RESULT([no])],
 824         [AC_MSG_RESULT([yes])
 825         AC_DEFINE(HAVE_OLD_ICONV, 1)
 826         OLD_ICONV=UnfortunatelyYes])
 827
 828 GIT_UNSTASH_FLAGS($ICONVDIR)
 829
 830 GIT_CONF_SUBST([OLD_ICONV])
 831
 832 #
 833 # Define ICONV_OMITS_BOM if you are on a system which
 834 # iconv omits bom for utf-{16,32}
 835 if test -z "$NO_ICONV"; then
 836 AC_CACHE_CHECK([whether iconv omits bom for utf-16 and utf-32],
 837  [ac_cv_iconv_omits_bom],
 838 [
 839 old_LIBS="$LIBS"
 840 if test -n "$NEEDS_LIBICONV"; then
 841         LIBS="$LIBS -liconv"
 842 fi
 843
 844 AC_RUN_IFELSE(
 845         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 846         #include <iconv.h>
 847         #ifdef HAVE_OLD_ICONV
 848         typedef const char *iconv_ibp;
 849         #else
 850         typedef char *iconv_ibp;
 851         #endif
 852         ],
 853         [[
 854         int v;
 855         iconv_t conv;
 856         char in[] = "a"; iconv_ibp pin = in;
 857         char out[20] = ""; char *pout = out;
 858         size_t isz = sizeof in;
 859         size_t osz = sizeof out;
 860
 861         conv = iconv_open("UTF-16", "UTF-8");
 862         iconv(conv, &pin, &isz, &pout, &osz);
 863         iconv_close(conv);
 864         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 865         return v != 0xfe + 0xff;
 866         ]])],
 867         [ac_cv_iconv_omits_bom=no],
 868         [ac_cv_iconv_omits_bom=yes])
 869
 870 LIBS="$old_LIBS"
 871 ])
 872 if test "x$ac_cv_iconv_omits_bom" = xyes; then
 873         ICONV_OMITS_BOM=Yes
 874 else
 875         ICONV_OMITS_BOM=
 876 fi
 877 GIT_CONF_SUBST([ICONV_OMITS_BOM])
 878 fi
 879
 880 ## Checks for typedefs, structures, and compiler characteristics.
 881 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 882 #
 883 TYPE_SOCKLEN_T
 884 case $ac_cv_type_socklen_t in
 885   yes)  SOCKLEN_T='';;
 886   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 887 esac
 888 GIT_CONF_SUBST([SOCKLEN_T])
 889
 890 #
 891 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 892 AC_CHECK_TYPES([struct itimerval],
 893 [NO_STRUCT_ITIMERVAL=],
 894 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 895 [#include <sys/time.h>])
 896 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 897 #
 898 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 899 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 900 # stat.st_mtimespec.tv_nsec exists.
 901 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 902 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 903 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 904         USE_ST_TIMESPEC=YesPlease
 905         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 906 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 907         NO_NSEC=YesPlease
 908         GIT_CONF_SUBST([NO_NSEC])
 909 fi
 910 #
 911 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 912 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 913 AC_CHECK_MEMBER(struct dirent.d_type,
 914 [NO_D_TYPE_IN_DIRENT=],
 915 [NO_D_TYPE_IN_DIRENT=YesPlease],
 916 [#include <dirent.h>])
 917 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 918 #
 919 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 920 # in the C library.
 921 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 922 [NO_GECOS_IN_PWENT=],
 923 [NO_GECOS_IN_PWENT=YesPlease],
 924 [#include <pwd.h>])
 925 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 926 #
 927 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 928 # sockaddr_storage.
 929 AC_CHECK_TYPE(struct sockaddr_storage,
 930 [NO_SOCKADDR_STORAGE=],
 931 [NO_SOCKADDR_STORAGE=YesPlease],[
 932 #include <sys/types.h>
 933 #include <sys/socket.h>
 934 ])
 935 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 936 #
 937 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 938 AC_CHECK_TYPE([struct addrinfo],[
 939  GIT_CHECK_FUNC([getaddrinfo],
 940   [NO_IPV6=],
 941   [NO_IPV6=YesPlease])
 942 ],[NO_IPV6=YesPlease],[
 943 #include <sys/types.h>
 944 #include <sys/socket.h>
 945 #include <netdb.h>
 946 ])
 947 GIT_CONF_SUBST([NO_IPV6])
 948 #
 949 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 950 # feature.
 951 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 952  [ac_cv_c_regex_with_reg_startend], [
 953 AC_EGREP_CPP(yippeeyeswehaveit,
 954         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 955 #include <regex.h>
 956 ],
 957 [#ifdef REG_STARTEND
 958 yippeeyeswehaveit
 959 #endif
 960 ]),
 961         [ac_cv_c_regex_with_reg_startend=yes],
 962         [ac_cv_c_regex_with_reg_startend=no])
 963 ])
 964 if test $ac_cv_c_regex_with_reg_startend = yes; then
 965         NO_REGEX=
 966 else
 967         NO_REGEX=YesPlease
 968 fi
 969 GIT_CONF_SUBST([NO_REGEX])
 970 #
 971 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 972 # when attempting to read from an fopen'ed directory.
 973 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 974  [ac_cv_fread_reads_directories],
 975 [
 976 AC_RUN_IFELSE(
 977         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 978                 [[
 979                 FILE *f = fopen(".", "r");
 980                 return f != NULL;]])],
 981         [ac_cv_fread_reads_directories=no],
 982         [ac_cv_fread_reads_directories=yes])
 983 ])
 984 if test $ac_cv_fread_reads_directories = yes; then
 985         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 986 else
 987         FREAD_READS_DIRECTORIES=
 988 fi
 989 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 990 #
 991 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 992 # or vsnprintf() return -1 instead of number of characters which would
 993 # have been written to the final string if enough space had been available.
 994 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 995  [ac_cv_snprintf_returns_bogus],
 996 [
 997 AC_RUN_IFELSE(
 998         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 999                 #include "stdarg.h"
1000
1001                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
1002                 {
1003                   int ret;
1004                   va_list ap;
1005                   va_start(ap, format);
1006                   ret = vsnprintf(str, maxsize, format, ap);
1007                   va_end(ap);
1008                   return ret;
1009                 }],
1010                 [[char buf[6];
1011                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
1012                       || strcmp(buf, "12")) return 1;
1013                   if (snprintf(buf, 3, "%s", "12345") != 5
1014                       || strcmp(buf, "12")) return 1]])],
1015         [ac_cv_snprintf_returns_bogus=no],
1016         [ac_cv_snprintf_returns_bogus=yes])
1017 ])
1018 if test $ac_cv_snprintf_returns_bogus = yes; then
1019         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
1020 else
1021         SNPRINTF_RETURNS_BOGUS=
1022 fi
1023 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
1024 #
1025 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
1026 # bits in mode values.
1027 AC_CACHE_CHECK([whether the platform uses typical file type bits],
1028  [ac_cv_sane_mode_bits], [
1029 AC_EGREP_CPP(yippeeyeswehaveit,
1030         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1031 [#if S_IFMT == 0170000 && \
1032         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
1033         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
1034         S_IFIFO == 0010000 && S_IFSOCK == 0140000
1035 yippeeyeswehaveit
1036 #endif
1037 ]),
1038         [ac_cv_sane_mode_bits=yes],
1039         [ac_cv_sane_mode_bits=no])
1040 ])
1041 if test $ac_cv_sane_mode_bits = yes; then
1042         NEEDS_MODE_TRANSLATION=
1043 else
1044         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
1045 fi
1046 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1047
1048
1049 ## Checks for library functions.
1050 ## (in default C library and libraries checked by AC_CHECK_LIB)
1051 AC_MSG_NOTICE([CHECKS for library functions])
1052 #
1053 # Define NO_LIBGEN_H if you don't have libgen.h.
1054 AC_CHECK_HEADER([libgen.h],
1055 [NO_LIBGEN_H=],
1056 [NO_LIBGEN_H=YesPlease])
1057 GIT_CONF_SUBST([NO_LIBGEN_H])
1058 #
1059 # Define HAVE_PATHS_H if you have paths.h.
1060 AC_CHECK_HEADER([paths.h],
1061 [HAVE_PATHS_H=YesPlease],
1062 [HAVE_PATHS_H=])
1063 GIT_CONF_SUBST([HAVE_PATHS_H])
1064 #
1065 # Define HAVE_LIBCHARSET_H if have libcharset.h
1066 AC_CHECK_HEADER([libcharset.h],
1067 [HAVE_LIBCHARSET_H=YesPlease],
1068 [HAVE_LIBCHARSET_H=])
1069 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1070 #
1071 # Define HAVE_STRINGS_H if you have strings.h
1072 AC_CHECK_HEADER([strings.h],
1073 [HAVE_STRINGS_H=YesPlease],
1074 [HAVE_STRINGS_H=])
1075 GIT_CONF_SUBST([HAVE_STRINGS_H])
1076 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1077 # and libcharset does
1078 CHARSET_LIB=
1079 AC_CHECK_LIB([iconv], [locale_charset],
1080        [CHARSET_LIB=-liconv],
1081        [AC_CHECK_LIB([charset], [locale_charset],
1082                      [CHARSET_LIB=-lcharset])])
1083 GIT_CONF_SUBST([CHARSET_LIB])
1084 #
1085 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1086 GIT_CHECK_FUNC(clock_gettime,
1087         [HAVE_CLOCK_GETTIME=YesPlease],
1088         [HAVE_CLOCK_GETTIME=])
1089 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1090
1091 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1092 AC_LANG_PROGRAM([[
1093 #include <time.h>
1094 clockid_t id = CLOCK_MONOTONIC;
1095 ]])])
1096
1097 #
1098 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1099 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1100 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1101         [AC_MSG_RESULT([yes])
1102         HAVE_CLOCK_MONOTONIC=YesPlease],
1103         [AC_MSG_RESULT([no])
1104         HAVE_CLOCK_MONOTONIC=])
1105 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1106 #
1107 # Define NO_SETITIMER if you don't have setitimer.
1108 GIT_CHECK_FUNC(setitimer,
1109 [NO_SETITIMER=],
1110 [NO_SETITIMER=YesPlease])
1111 GIT_CONF_SUBST([NO_SETITIMER])
1112 #
1113 # Define NO_STRCASESTR if you don't have strcasestr.
1114 GIT_CHECK_FUNC(strcasestr,
1115 [NO_STRCASESTR=],
1116 [NO_STRCASESTR=YesPlease])
1117 GIT_CONF_SUBST([NO_STRCASESTR])
1118 #
1119 # Define NO_MEMMEM if you don't have memmem.
1120 GIT_CHECK_FUNC(memmem,
1121 [NO_MEMMEM=],
1122 [NO_MEMMEM=YesPlease])
1123 GIT_CONF_SUBST([NO_MEMMEM])
1124 #
1125 # Define NO_STRLCPY if you don't have strlcpy.
1126 GIT_CHECK_FUNC(strlcpy,
1127 [NO_STRLCPY=],
1128 [NO_STRLCPY=YesPlease])
1129 GIT_CONF_SUBST([NO_STRLCPY])
1130 #
1131 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1132 AC_CHECK_TYPE(uintmax_t,
1133 [NO_UINTMAX_T=],
1134 [NO_UINTMAX_T=YesPlease],[
1135 #include <inttypes.h>
1136 ])
1137 GIT_CONF_SUBST([NO_UINTMAX_T])
1138 #
1139 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1140 GIT_CHECK_FUNC(strtoumax,
1141 [NO_STRTOUMAX=],
1142 [NO_STRTOUMAX=YesPlease])
1143 GIT_CONF_SUBST([NO_STRTOUMAX])
1144 #
1145 # Define NO_SETENV if you don't have setenv in the C library.
1146 GIT_CHECK_FUNC(setenv,
1147 [NO_SETENV=],
1148 [NO_SETENV=YesPlease])
1149 GIT_CONF_SUBST([NO_SETENV])
1150 #
1151 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1152 GIT_CHECK_FUNC(unsetenv,
1153 [NO_UNSETENV=],
1154 [NO_UNSETENV=YesPlease])
1155 GIT_CONF_SUBST([NO_UNSETENV])
1156 #
1157 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1158 GIT_CHECK_FUNC(mkdtemp,
1159 [NO_MKDTEMP=],
1160 [NO_MKDTEMP=YesPlease])
1161 GIT_CONF_SUBST([NO_MKDTEMP])
1162 #
1163 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1164 GIT_CHECK_FUNC(initgroups,
1165 [NO_INITGROUPS=],
1166 [NO_INITGROUPS=YesPlease])
1167 GIT_CONF_SUBST([NO_INITGROUPS])
1168 #
1169 # Define HAVE_GETDELIM if you have getdelim in the C library.
1170 GIT_CHECK_FUNC(getdelim,
1171 [HAVE_GETDELIM=YesPlease],
1172 [HAVE_GETDELIM=])
1173 GIT_CONF_SUBST([HAVE_GETDELIM])
1174 #
1175 #
1176 # Define NO_MMAP if you want to avoid mmap.
1177 #
1178 # Define NO_ICONV if your libc does not properly support iconv.
1179
1180 AC_DEFUN([BSD_SYSCTL_SRC], [
1181 AC_LANG_PROGRAM([[
1182 #include <stddef.h>
1183 #include <sys/types.h>
1184 #include <sys/sysctl.h>
1185 ]],[[
1186 int val, mib[2];
1187 size_t len;
1188 mib[0] = CTL_HW;
1189 mib[1] = 1;
1190 len = sizeof(val);
1191 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1192 ]])])
1193
1194 #
1195 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1196 AC_MSG_CHECKING([for BSD sysctl])
1197 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1198         [AC_MSG_RESULT([yes])
1199         HAVE_BSD_SYSCTL=YesPlease],
1200         [AC_MSG_RESULT([no])
1201         HAVE_BSD_SYSCTL=])
1202 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1203
1204 ## Other checks.
1205 # Define USE_PIC if you need the main git objects to be built with -fPIC
1206 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1207 #
1208 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1209 # Enable it on Windows.  By default, symrefs are still used.
1210 #
1211 # Define NO_PTHREADS if we do not have pthreads.
1212 #
1213 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1214 AC_DEFUN([PTHREADTEST_SRC], [
1215 AC_LANG_PROGRAM([[
1216 #include <pthread.h>
1217 static void *noop(void *ignore) { return ignore; }
1218 ]], [[
1219         pthread_mutex_t test_mutex;
1220         pthread_key_t test_key;
1221         pthread_t th;
1222         int retcode = 0;
1223         void *ret = (void *)0;
1224         retcode |= pthread_key_create(&test_key, (void *)0);
1225         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1226         retcode |= pthread_mutex_lock(&test_mutex);
1227         retcode |= pthread_mutex_unlock(&test_mutex);
1228         retcode |= pthread_create(&th, ret, noop, ret);
1229         retcode |= pthread_join(th, &ret);
1230         return retcode;
1231 ]])])
1232
1233 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1234 dnl   [[#include <pthread.h>]],
1235 dnl   [[pthread_mutex_t test_mutex;]]
1236 dnl )])
1237
1238 NO_PTHREADS=UnfortunatelyYes
1239 PTHREAD_LIBS=
1240
1241 if test -n "$USER_NOPTHREAD"; then
1242    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1243 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1244 # -D_REENTRANT' or some such.
1245 elif test -z "$PTHREAD_CFLAGS"; then
1246   threads_found=no
1247   # Attempt to compile and link some code using pthreads to determine
1248   # required linker flags. The order is somewhat important here: We
1249   # first try it without any extra flags, to catch systems where
1250   # pthreads are part of the C library, then go on testing various other
1251   # flags. We do so to avoid false positives. For example, on Mac OS X
1252   # pthreads are part of the C library; moreover, the compiler allows us
1253   # to add "-mt" to the CFLAGS (although it will do nothing except
1254   # trigger a warning about an unused flag). Hence if we checked for
1255   # "-mt" before "" we would end up picking it. But unfortunately this
1256   # would then trigger compiler warnings on every single file we compile.
1257   for opt in "" -mt -pthread -lpthread; do
1258      old_CFLAGS="$CFLAGS"
1259      old_LIBS="$LIBS"
1260      case "$opt" in
1261         -l*)  LIBS="$opt $LIBS" ;;
1262         *)    CFLAGS="$opt $CFLAGS" ;;
1263      esac
1264
1265      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1266      AC_LINK_IFELSE([PTHREADTEST_SRC],
1267         [AC_MSG_RESULT([yes])
1268                 NO_PTHREADS=
1269                 PTHREAD_LIBS="$opt"
1270                 PTHREAD_CFLAGS="$opt"
1271                 threads_found=yes
1272                 break
1273         ],
1274         [AC_MSG_RESULT([no])])
1275       CFLAGS="$old_CFLAGS"
1276       LIBS="$old_LIBS"
1277   done
1278   if test $threads_found != yes; then
1279     AC_CHECK_LIB([pthread], [pthread_create],
1280         [PTHREAD_LIBS="-lpthread"],
1281         [NO_PTHREADS=UnfortunatelyYes])
1282   fi
1283 else
1284   old_CFLAGS="$CFLAGS"
1285   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1286   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1287   AC_LINK_IFELSE([PTHREADTEST_SRC],
1288         [AC_MSG_RESULT([yes])
1289                 NO_PTHREADS=
1290                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1291         ],
1292         [AC_MSG_RESULT([no])])
1293
1294   CFLAGS="$old_CFLAGS"
1295 fi
1296
1297 CFLAGS="$old_CFLAGS"
1298
1299 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1300 GIT_CONF_SUBST([PTHREAD_LIBS])
1301 GIT_CONF_SUBST([NO_PTHREADS])
1302
1303 ## Output files
1304 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1305 AC_OUTPUT