configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_WARN([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49
  50
  51 ## Site configuration
  52 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  53 #
  54 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
  55 # tests.  These tests take up a significant amount of the total test time
  56 # but are not needed unless you plan to talk to SVN repos.
  57 #
  58 # Define MOZILLA_SHA1 environment variable when running make to make use of
  59 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61 # choice) has very fast version optimized for i586.
  62 #
  63 # Define PPC_SHA1 environment variable when running make to make use of
  64 # a bundled SHA1 routine optimized for PowerPC.
  65 #
  66 # Define ARM_SHA1 environment variable when running make to make use of
  67 # a bundled SHA1 routine optimized for ARM.
  68 #
  69 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70 # This also implies MOZILLA_SHA1.
  71 #
  72 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  73 # git-http-push are not built, and you cannot use http:// and https://
  74 # transports.
  75 #
  76 # Define CURLDIR=/foo/bar if your curl header and library files are in
  77 # /foo/bar/include and /foo/bar/lib directories.
  78 #
  79 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80 # not built, and you cannot push using http:// and https:// transports.
  81 #
  82 # Define NO_MMAP if you want to avoid mmap.
  83 #
  84 # Define SHELL_PATH to provide path to shell.
  85 GIT_ARG_SET_PATH(shell)
  86 #
  87 # Define PERL_PATH to provide path to Perl.
  88 GIT_ARG_SET_PATH(perl)
  89 #
  90 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
  91 # Define PYTHON_PATH to provide path to Python.
  92 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
  93 AS_HELP_STRING([--no-python], [don't use python scripts])],
  94  [if test "$withval" = "no"; then \
  95     NO_PYTHON=YesPlease; \
  96   elif test "$withval" != "yes"; then \
  97     PYTHON_PATH=$withval; \
  98   fi; \
  99  ])
 100 AC_SUBST(NO_PYTHON)
 101 AC_SUBST(PYTHON_PATH)
 102 #
 103 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 104 # Define COLLISION_CHECK below if you believe that SHA1's
 105 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 106 # sufficient guarantee that no collisions between objects will ever happen.
 107 #
 108 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 109 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 110 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 111 # randomly break unless your underlying filesystem supports those sub-second
 112 # times (my ext3 doesn't).
 113 #
 114 # Define USE_STDEV below if you want git to care about the underlying device
 115 # change being considered an inode change from the update-cache perspective.
 116
 117
 118 ## Checks for programs.
 119 AC_MSG_NOTICE([CHECKS for programs])
 120 #
 121 AC_PROG_CC
 122 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 123 AC_CHECK_TOOL(AR, ar, :)
 124 AC_CHECK_PROGS(TAR, [gtar tar])
 125 #
 126 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 127 # Define PYTHON_PATH to provide path to Python.
 128 if test -z "$NO_PYTHON"; then
 129         AC_PATH_PROGS(PYTHON_PATH, [python2.4 python2.3 python2 python])
 130         if test -n "$PYTHON_PATH"; then
 131                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 132         else
 133                 GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 134         fi
 135 else
 136         GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 137 fi
 138
 139
 140 ## Checks for libraries.
 141 AC_MSG_NOTICE([CHECKS for libraries])
 142 #
 143 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 144 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 145 AC_CHECK_LIB([ssl], [SHA1_Init],[],
 146 [AC_CHECK_LIB([crypto], [SHA1_INIT],
 147  [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
 148  [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
 149 #
 150 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 151 # git-http-push are not built, and you cannot use http:// and https://
 152 # transports.
 153 AC_CHECK_LIB([curl], [curl_global_init],[],
 154 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
 155 #
 156 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 157 # not built, and you cannot push using http:// and https:// transports.
 158 AC_CHECK_LIB([expat], [XML_ParserCreate],[],
 159 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
 160 #
 161 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 162 AC_CHECK_LIB([c], [iconv],[],
 163 [AC_CHECK_LIB([iconv],[iconv],
 164  [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
 165 #
 166 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 167 # Patrick Mauritz).
 168 AC_CHECK_LIB([c], [socket],[],
 169 [AC_CHECK_LIB([socket],[socket],
 170  [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
 171
 172
 173 ## Checks for header files.
 174
 175
 176 ## Checks for typedefs, structures, and compiler characteristics.
 177 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 178 #
 179 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 180 AC_CHECK_MEMBER(struct dirent.d_ino,[],
 181 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 182 [#include <dirent.h>])
 183 #
 184 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 185 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 186 AC_CHECK_MEMBER(struct dirent.d_type,[],
 187 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 188 [#include <dirent.h>])
 189 #
 190 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 191 # sockaddr_storage.
 192 AC_CHECK_TYPE(struct sockaddr_storage,[],
 193 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 194 [#include <netinet/in.h>])
 195 #
 196 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 197 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 198 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 199 # some C compilers supported these specifiers prior to C99 as an extension.
 200 AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 201  ac_cv_c_c99_format,
 202 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 203 AC_RUN_IFELSE(
 204         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 205                 [[char buf[64];
 206                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 207                   exit(1);
 208                 else if (strcmp(buf, "12345"))
 209                   exit(2);]])],
 210         [ac_cv_c_c99_format=yes],
 211         [ac_cv_c_c99_format=no])
 212 ])
 213 if test $ac_cv_c_c99_format = no; then
 214         GIT_CONF_APPEND_LINE(NO_C99_FORMAT=YesPlease)
 215 fi
 216
 217
 218 ## Checks for library functions.
 219 ## (in default C library and libraries checked by AC_CHECK_LIB)
 220 AC_MSG_NOTICE([CHECKS for library functions])
 221 #
 222 # Define NO_STRCASESTR if you don't have strcasestr.
 223 AC_CHECK_FUNC(strcasestr,[],
 224 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 225 #
 226 # Define NO_STRLCPY if you don't have strlcpy.
 227 AC_CHECK_FUNC(strlcpy,[],
 228 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 229 #
 230 # Define NO_SETENV if you don't have setenv in the C library.
 231 AC_CHECK_FUNC(setenv,[],
 232 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 233 #
 234 # Define NO_MMAP if you want to avoid mmap.
 235 #
 236 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 237 #
 238 # Define NO_ICONV if your libc does not properly support iconv.
 239
 240
 241 ## Other checks.
 242 # Define USE_PIC if you need the main git objects to be built with -fPIC
 243 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 244 #
 245 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 246 # Enable it on Windows.  By default, symrefs are still used.
 247 #
 248 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 249 #
 250 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 251 # a missing newline at the end of the file.
 252
 253
 254 ## Output files
 255 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 256 AC_OUTPUT
 257
 258
 259 ## Cleanup
 260 rm -f "${config_append}"