]> git.ipfire.org Git - thirdparty/git.git/blob - git-svn.perl
perl: bump the required Perl version to 5.8 from 5.6.[21]
[thirdparty/git.git] / git-svn.perl
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use 5.008;
5 use warnings;
6 use strict;
7 use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11 $VERSION = '@@GIT_VERSION@@';
12
13 # From which subdir have we been invoked?
14 my $cmd_dir_prefix = eval {
15 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
16 } || '';
17
18 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
19 $ENV{GIT_DIR} ||= '.git';
20 $Git::SVN::default_repo_id = 'svn';
21 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
22 $Git::SVN::Ra::_log_window_size = 100;
23 $Git::SVN::_minimize_url = 'unset';
24
25 if (! exists $ENV{SVN_SSH}) {
26 if (exists $ENV{GIT_SSH}) {
27 $ENV{SVN_SSH} = $ENV{GIT_SSH};
28 if ($^O eq 'msys') {
29 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
30 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
31 }
32 }
33 }
34
35 $Git::SVN::Log::TZ = $ENV{TZ};
36 $ENV{TZ} = 'UTC';
37 $| = 1; # unbuffer STDOUT
38
39 sub fatal (@) { print STDERR "@_\n"; exit 1 }
40 sub _req_svn {
41 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
42 require SVN::Ra;
43 require SVN::Delta;
44 if ($SVN::Core::VERSION lt '1.1.0') {
45 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
46 }
47 }
48 my $can_compress = eval { require Compress::Zlib; 1};
49 push @Git::SVN::Ra::ISA, 'SVN::Ra';
50 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
51 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
52 use Carp qw/croak/;
53 use Digest::MD5;
54 use IO::File qw//;
55 use File::Basename qw/dirname basename/;
56 use File::Path qw/mkpath/;
57 use File::Spec;
58 use File::Find;
59 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
60 use IPC::Open3;
61 use Git;
62
63 BEGIN {
64 # import functions from Git into our packages, en masse
65 no strict 'refs';
66 foreach (qw/command command_oneline command_noisy command_output_pipe
67 command_input_pipe command_close_pipe
68 command_bidi_pipe command_close_bidi_pipe/) {
69 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
70 Git::SVN::Migration Git::SVN::Log Git::SVN),
71 __PACKAGE__) {
72 *{"${package}::$_"} = \&{"Git::$_"};
73 }
74 }
75 }
76
77 my ($SVN);
78
79 $sha1 = qr/[a-f\d]{40}/;
80 $sha1_short = qr/[a-f\d]{4,40}/;
81 my ($_stdin, $_help, $_edit,
82 $_message, $_file, $_branch_dest,
83 $_template, $_shared,
84 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
85 $_merge, $_strategy, $_dry_run, $_local,
86 $_prefix, $_no_checkout, $_url, $_verbose,
87 $_git_format, $_commit_url, $_tag);
88 $Git::SVN::_follow_parent = 1;
89 $_q ||= 0;
90 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
91 'config-dir=s' => \$Git::SVN::Ra::config_dir,
92 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
93 'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
94 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
95 'authors-file|A=s' => \$_authors,
96 'authors-prog=s' => \$_authors_prog,
97 'repack:i' => \$Git::SVN::_repack,
98 'noMetadata' => \$Git::SVN::_no_metadata,
99 'useSvmProps' => \$Git::SVN::_use_svm_props,
100 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
101 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
102 'no-checkout' => \$_no_checkout,
103 'quiet|q+' => \$_q,
104 'repack-flags|repack-args|repack-opts=s' =>
105 \$Git::SVN::_repack_flags,
106 'use-log-author' => \$Git::SVN::_use_log_author,
107 'add-author-from' => \$Git::SVN::_add_author_from,
108 'localtime' => \$Git::SVN::_localtime,
109 %remote_opts );
110
111 my ($_trunk, @_tags, @_branches, $_stdlayout);
112 my %icv;
113 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
114 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
115 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
116 'stdlayout|s' => \$_stdlayout,
117 'minimize-url|m!' => \$Git::SVN::_minimize_url,
118 'no-metadata' => sub { $icv{noMetadata} = 1 },
119 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
120 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
121 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
122 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
123 %remote_opts );
124 my %cmt_opts = ( 'edit|e' => \$_edit,
125 'rmdir' => \$SVN::Git::Editor::_rmdir,
126 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
127 'l=i' => \$SVN::Git::Editor::_rename_limit,
128 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
129 );
130
131 my %cmd = (
132 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
133 { 'revision|r=s' => \$_revision,
134 'fetch-all|all' => \$_fetch_all,
135 'parent|p' => \$_fetch_parent,
136 %fc_opts } ],
137 clone => [ \&cmd_clone, "Initialize and fetch revisions",
138 { 'revision|r=s' => \$_revision,
139 %fc_opts, %init_opts } ],
140 init => [ \&cmd_init, "Initialize a repo for tracking" .
141 " (requires URL argument)",
142 \%init_opts ],
143 'multi-init' => [ \&cmd_multi_init,
144 "Deprecated alias for ".
145 "'$0 init -T<trunk> -b<branches> -t<tags>'",
146 \%init_opts ],
147 dcommit => [ \&cmd_dcommit,
148 'Commit several diffs to merge with upstream',
149 { 'merge|m|M' => \$_merge,
150 'strategy|s=s' => \$_strategy,
151 'verbose|v' => \$_verbose,
152 'dry-run|n' => \$_dry_run,
153 'fetch-all|all' => \$_fetch_all,
154 'commit-url=s' => \$_commit_url,
155 'revision|r=i' => \$_revision,
156 'no-rebase' => \$_no_rebase,
157 %cmt_opts, %fc_opts } ],
158 branch => [ \&cmd_branch,
159 'Create a branch in the SVN repository',
160 { 'message|m=s' => \$_message,
161 'destination|d=s' => \$_branch_dest,
162 'dry-run|n' => \$_dry_run,
163 'tag|t' => \$_tag,
164 'username=s' => \$Git::SVN::Prompt::_username,
165 'commit-url=s' => \$_commit_url } ],
166 tag => [ sub { $_tag = 1; cmd_branch(@_) },
167 'Create a tag in the SVN repository',
168 { 'message|m=s' => \$_message,
169 'destination|d=s' => \$_branch_dest,
170 'dry-run|n' => \$_dry_run,
171 'username=s' => \$Git::SVN::Prompt::_username,
172 'commit-url=s' => \$_commit_url } ],
173 'set-tree' => [ \&cmd_set_tree,
174 "Set an SVN repository to a git tree-ish",
175 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
176 'create-ignore' => [ \&cmd_create_ignore,
177 'Create a .gitignore per svn:ignore',
178 { 'revision|r=i' => \$_revision
179 } ],
180 'mkdirs' => [ \&cmd_mkdirs ,
181 "recreate empty directories after a checkout",
182 { 'revision|r=i' => \$_revision } ],
183 'propget' => [ \&cmd_propget,
184 'Print the value of a property on a file or directory',
185 { 'revision|r=i' => \$_revision } ],
186 'proplist' => [ \&cmd_proplist,
187 'List all properties of a file or directory',
188 { 'revision|r=i' => \$_revision } ],
189 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
190 { 'revision|r=i' => \$_revision
191 } ],
192 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
193 { 'revision|r=i' => \$_revision
194 } ],
195 'multi-fetch' => [ \&cmd_multi_fetch,
196 "Deprecated alias for $0 fetch --all",
197 { 'revision|r=s' => \$_revision, %fc_opts } ],
198 'migrate' => [ sub { },
199 # no-op, we automatically run this anyways,
200 'Migrate configuration/metadata/layout from
201 previous versions of git-svn',
202 { 'minimize' => \$Git::SVN::Migration::_minimize,
203 %remote_opts } ],
204 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
205 { 'limit=i' => \$Git::SVN::Log::limit,
206 'revision|r=s' => \$_revision,
207 'verbose|v' => \$Git::SVN::Log::verbose,
208 'incremental' => \$Git::SVN::Log::incremental,
209 'oneline' => \$Git::SVN::Log::oneline,
210 'show-commit' => \$Git::SVN::Log::show_commit,
211 'non-recursive' => \$Git::SVN::Log::non_recursive,
212 'authors-file|A=s' => \$_authors,
213 'color' => \$Git::SVN::Log::color,
214 'pager=s' => \$Git::SVN::Log::pager
215 } ],
216 'find-rev' => [ \&cmd_find_rev,
217 "Translate between SVN revision numbers and tree-ish",
218 {} ],
219 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
220 { 'merge|m|M' => \$_merge,
221 'verbose|v' => \$_verbose,
222 'strategy|s=s' => \$_strategy,
223 'local|l' => \$_local,
224 'fetch-all|all' => \$_fetch_all,
225 'dry-run|n' => \$_dry_run,
226 %fc_opts } ],
227 'commit-diff' => [ \&cmd_commit_diff,
228 'Commit a diff between two trees',
229 { 'message|m=s' => \$_message,
230 'file|F=s' => \$_file,
231 'revision|r=s' => \$_revision,
232 %cmt_opts } ],
233 'info' => [ \&cmd_info,
234 "Show info about the latest SVN revision
235 on the current branch",
236 { 'url' => \$_url, } ],
237 'blame' => [ \&Git::SVN::Log::cmd_blame,
238 "Show what revision and author last modified each line of a file",
239 { 'git-format' => \$_git_format } ],
240 'reset' => [ \&cmd_reset,
241 "Undo fetches back to the specified SVN revision",
242 { 'revision|r=s' => \$_revision,
243 'parent|p' => \$_fetch_parent } ],
244 'gc' => [ \&cmd_gc,
245 "Compress unhandled.log files in .git/svn and remove " .
246 "index files in .git/svn",
247 {} ],
248 );
249
250 my $cmd;
251 for (my $i = 0; $i < @ARGV; $i++) {
252 if (defined $cmd{$ARGV[$i]}) {
253 $cmd = $ARGV[$i];
254 splice @ARGV, $i, 1;
255 last;
256 } elsif ($ARGV[$i] eq 'help') {
257 $cmd = $ARGV[$i+1];
258 usage(0);
259 }
260 };
261
262 # make sure we're always running at the top-level working directory
263 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
264 unless (-d $ENV{GIT_DIR}) {
265 if ($git_dir_user_set) {
266 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
267 "but it is not a directory\n";
268 }
269 my $git_dir = delete $ENV{GIT_DIR};
270 my $cdup = undef;
271 git_cmd_try {
272 $cdup = command_oneline(qw/rev-parse --show-cdup/);
273 $git_dir = '.' unless ($cdup);
274 chomp $cdup if ($cdup);
275 $cdup = "." unless ($cdup && length $cdup);
276 } "Already at toplevel, but $git_dir not found\n";
277 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
278 unless (-d $git_dir) {
279 die "$git_dir still not found after going to ",
280 "'$cdup'\n";
281 }
282 $ENV{GIT_DIR} = $git_dir;
283 }
284 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
285 }
286
287 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
288
289 read_git_config(\%opts);
290 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
291 Getopt::Long::Configure('pass_through');
292 }
293 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
294 'minimize-connections' => \$Git::SVN::Migration::_minimize,
295 'id|i=s' => \$Git::SVN::default_ref_id,
296 'svn-remote|remote|R=s' => sub {
297 $Git::SVN::no_reuse_existing = 1;
298 $Git::SVN::default_repo_id = $_[1] });
299 exit 1 if (!$rv && $cmd && $cmd ne 'log');
300
301 usage(0) if $_help;
302 version() if $_version;
303 usage(1) unless defined $cmd;
304 load_authors() if $_authors;
305 if (defined $_authors_prog) {
306 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
307 }
308
309 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
310 Git::SVN::Migration::migration_check();
311 }
312 Git::SVN::init_vars();
313 eval {
314 Git::SVN::verify_remotes_sanity();
315 $cmd{$cmd}->[0]->(@ARGV);
316 };
317 fatal $@ if $@;
318 post_fetch_checkout();
319 exit 0;
320
321 ####################### primary functions ######################
322 sub usage {
323 my $exit = shift || 0;
324 my $fd = $exit ? \*STDERR : \*STDOUT;
325 print $fd <<"";
326 git-svn - bidirectional operations between a single Subversion tree and git
327 Usage: git svn <command> [options] [arguments]\n
328
329 print $fd "Available commands:\n" unless $cmd;
330
331 foreach (sort keys %cmd) {
332 next if $cmd && $cmd ne $_;
333 next if /^multi-/; # don't show deprecated commands
334 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
335 foreach (sort keys %{$cmd{$_}->[2]}) {
336 # mixed-case options are for .git/config only
337 next if /[A-Z]/ && /^[a-z]+$/i;
338 # prints out arguments as they should be passed:
339 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
340 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
341 "--$_" : "-$_" }
342 split /\|/,$_)," $x\n";
343 }
344 }
345 print $fd <<"";
346 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
347 arbitrary identifier if you're tracking multiple SVN branches/repositories in
348 one git repository and want to keep them separate. See git-svn(1) for more
349 information.
350
351 exit $exit;
352 }
353
354 sub version {
355 ::_req_svn();
356 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
357 exit 0;
358 }
359
360 sub do_git_init_db {
361 unless (-d $ENV{GIT_DIR}) {
362 my @init_db = ('init');
363 push @init_db, "--template=$_template" if defined $_template;
364 if (defined $_shared) {
365 if ($_shared =~ /[a-z]/) {
366 push @init_db, "--shared=$_shared";
367 } else {
368 push @init_db, "--shared";
369 }
370 }
371 command_noisy(@init_db);
372 $_repository = Git->repository(Repository => ".git");
373 }
374 my $set;
375 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
376 foreach my $i (keys %icv) {
377 die "'$set' and '$i' cannot both be set\n" if $set;
378 next unless defined $icv{$i};
379 command_noisy('config', "$pfx.$i", $icv{$i});
380 $set = $i;
381 }
382 my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
383 command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
384 if defined $$ignore_regex;
385 }
386
387 sub init_subdir {
388 my $repo_path = shift or return;
389 mkpath([$repo_path]) unless -d $repo_path;
390 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
391 $ENV{GIT_DIR} = '.git';
392 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
393 }
394
395 sub cmd_clone {
396 my ($url, $path) = @_;
397 if (!defined $path &&
398 (defined $_trunk || @_branches || @_tags ||
399 defined $_stdlayout) &&
400 $url !~ m#^[a-z\+]+://#) {
401 $path = $url;
402 }
403 $path = basename($url) if !defined $path || !length $path;
404 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
405 cmd_init($url, $path);
406 command_oneline('config', 'svn.authorsfile', $authors_absolute)
407 if $_authors;
408 Git::SVN::fetch_all($Git::SVN::default_repo_id);
409 }
410
411 sub cmd_init {
412 if (defined $_stdlayout) {
413 $_trunk = 'trunk' if (!defined $_trunk);
414 @_tags = 'tags' if (! @_tags);
415 @_branches = 'branches' if (! @_branches);
416 }
417 if (defined $_trunk || @_branches || @_tags) {
418 return cmd_multi_init(@_);
419 }
420 my $url = shift or die "SVN repository location required ",
421 "as a command-line argument\n";
422 $url = canonicalize_url($url);
423 init_subdir(@_);
424 do_git_init_db();
425
426 if ($Git::SVN::_minimize_url eq 'unset') {
427 $Git::SVN::_minimize_url = 0;
428 }
429
430 Git::SVN->init($url);
431 }
432
433 sub cmd_fetch {
434 if (grep /^\d+=./, @_) {
435 die "'<rev>=<commit>' fetch arguments are ",
436 "no longer supported.\n";
437 }
438 my ($remote) = @_;
439 if (@_ > 1) {
440 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
441 }
442 $Git::SVN::no_reuse_existing = undef;
443 if ($_fetch_parent) {
444 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
445 unless ($gs) {
446 die "Unable to determine upstream SVN information from ",
447 "working tree history\n";
448 }
449 # just fetch, don't checkout.
450 $_no_checkout = 'true';
451 $_fetch_all ? $gs->fetch_all : $gs->fetch;
452 } elsif ($_fetch_all) {
453 cmd_multi_fetch();
454 } else {
455 $remote ||= $Git::SVN::default_repo_id;
456 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
457 }
458 }
459
460 sub cmd_set_tree {
461 my (@commits) = @_;
462 if ($_stdin || !@commits) {
463 print "Reading from stdin...\n";
464 @commits = ();
465 while (<STDIN>) {
466 if (/\b($sha1_short)\b/o) {
467 unshift @commits, $1;
468 }
469 }
470 }
471 my @revs;
472 foreach my $c (@commits) {
473 my @tmp = command('rev-parse',$c);
474 if (scalar @tmp == 1) {
475 push @revs, $tmp[0];
476 } elsif (scalar @tmp > 1) {
477 push @revs, reverse(command('rev-list',@tmp));
478 } else {
479 fatal "Failed to rev-parse $c";
480 }
481 }
482 my $gs = Git::SVN->new;
483 my ($r_last, $cmt_last) = $gs->last_rev_commit;
484 $gs->fetch;
485 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
486 fatal "There are new revisions that were fetched ",
487 "and need to be merged (or acknowledged) ",
488 "before committing.\nlast rev: $r_last\n",
489 " current: $gs->{last_rev}";
490 }
491 $gs->set_tree($_) foreach @revs;
492 print "Done committing ",scalar @revs," revisions to SVN\n";
493 unlink $gs->{index};
494 }
495
496 sub cmd_dcommit {
497 my $head = shift;
498 command_noisy(qw/update-index --refresh/);
499 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
500 'Cannot dcommit with a dirty index. Commit your changes first, '
501 . "or stash them with `git stash'.\n";
502 $head ||= 'HEAD';
503
504 my $old_head;
505 if ($head ne 'HEAD') {
506 $old_head = eval {
507 command_oneline([qw/symbolic-ref -q HEAD/])
508 };
509 if ($old_head) {
510 $old_head =~ s{^refs/heads/}{};
511 } else {
512 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
513 }
514 command(['checkout', $head], STDERR => 0);
515 }
516
517 my @refs;
518 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
519 unless ($gs) {
520 die "Unable to determine upstream SVN information from ",
521 "$head history.\nPerhaps the repository is empty.";
522 }
523
524 if (defined $_commit_url) {
525 $url = $_commit_url;
526 } else {
527 $url = eval { command_oneline('config', '--get',
528 "svn-remote.$gs->{repo_id}.commiturl") };
529 if (!$url) {
530 $url = $gs->full_url
531 }
532 }
533
534 my $last_rev = $_revision if defined $_revision;
535 if ($url) {
536 print "Committing to $url ...\n";
537 }
538 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
539 if ($_no_rebase && scalar(@$linear_refs) > 1) {
540 warn "Attempting to commit more than one change while ",
541 "--no-rebase is enabled.\n",
542 "If these changes depend on each other, re-running ",
543 "without --no-rebase may be required."
544 }
545 my $expect_url = $url;
546 Git::SVN::remove_username($expect_url);
547 while (1) {
548 my $d = shift @$linear_refs or last;
549 unless (defined $last_rev) {
550 (undef, $last_rev, undef) = cmt_metadata("$d~1");
551 unless (defined $last_rev) {
552 fatal "Unable to extract revision information ",
553 "from commit $d~1";
554 }
555 }
556 if ($_dry_run) {
557 print "diff-tree $d~1 $d\n";
558 } else {
559 my $cmt_rev;
560 my %ed_opts = ( r => $last_rev,
561 log => get_commit_entry($d)->{log},
562 ra => Git::SVN::Ra->new($url),
563 config => SVN::Core::config_get_config(
564 $Git::SVN::Ra::config_dir
565 ),
566 tree_a => "$d~1",
567 tree_b => $d,
568 editor_cb => sub {
569 print "Committed r$_[0]\n";
570 $cmt_rev = $_[0];
571 },
572 svn_path => '');
573 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
574 print "No changes\n$d~1 == $d\n";
575 } elsif ($parents->{$d} && @{$parents->{$d}}) {
576 $gs->{inject_parents_dcommit}->{$cmt_rev} =
577 $parents->{$d};
578 }
579 $_fetch_all ? $gs->fetch_all : $gs->fetch;
580 $last_rev = $cmt_rev;
581 next if $_no_rebase;
582
583 # we always want to rebase against the current HEAD,
584 # not any head that was passed to us
585 my @diff = command('diff-tree', $d,
586 $gs->refname, '--');
587 my @finish;
588 if (@diff) {
589 @finish = rebase_cmd();
590 print STDERR "W: $d and ", $gs->refname,
591 " differ, using @finish:\n",
592 join("\n", @diff), "\n";
593 } else {
594 print "No changes between current HEAD and ",
595 $gs->refname,
596 "\nResetting to the latest ",
597 $gs->refname, "\n";
598 @finish = qw/reset --mixed/;
599 }
600 command_noisy(@finish, $gs->refname);
601 if (@diff) {
602 @refs = ();
603 my ($url_, $rev_, $uuid_, $gs_) =
604 working_head_info('HEAD', \@refs);
605 my ($linear_refs_, $parents_) =
606 linearize_history($gs_, \@refs);
607 if (scalar(@$linear_refs) !=
608 scalar(@$linear_refs_)) {
609 fatal "# of revisions changed ",
610 "\nbefore:\n",
611 join("\n", @$linear_refs),
612 "\n\nafter:\n",
613 join("\n", @$linear_refs_), "\n",
614 'If you are attempting to commit ',
615 "merges, try running:\n\t",
616 'git rebase --interactive',
617 '--preserve-merges ',
618 $gs->refname,
619 "\nBefore dcommitting";
620 }
621 if ($url_ ne $expect_url) {
622 if ($url_ eq $gs->metadata_url) {
623 print
624 "Accepting rewritten URL:",
625 " $url_\n";
626 } else {
627 fatal
628 "URL mismatch after rebase:",
629 " $url_ != $expect_url";
630 }
631 }
632 if ($uuid_ ne $uuid) {
633 fatal "uuid mismatch after rebase: ",
634 "$uuid_ != $uuid";
635 }
636 # remap parents
637 my (%p, @l, $i);
638 for ($i = 0; $i < scalar @$linear_refs; $i++) {
639 my $new = $linear_refs_->[$i] or next;
640 $p{$new} =
641 $parents->{$linear_refs->[$i]};
642 push @l, $new;
643 }
644 $parents = \%p;
645 $linear_refs = \@l;
646 }
647 }
648 }
649
650 if ($old_head) {
651 my $new_head = command_oneline(qw/rev-parse HEAD/);
652 my $new_is_symbolic = eval {
653 command_oneline(qw/symbolic-ref -q HEAD/);
654 };
655 if ($new_is_symbolic) {
656 print "dcommitted the branch ", $head, "\n";
657 } else {
658 print "dcommitted on a detached HEAD because you gave ",
659 "a revision argument.\n",
660 "The rewritten commit is: ", $new_head, "\n";
661 }
662 command(['checkout', $old_head], STDERR => 0);
663 }
664
665 unlink $gs->{index};
666 }
667
668 sub cmd_branch {
669 my ($branch_name, $head) = @_;
670
671 unless (defined $branch_name && length $branch_name) {
672 die(($_tag ? "tag" : "branch") . " name required\n");
673 }
674 $head ||= 'HEAD';
675
676 my (undef, $rev, undef, $gs) = working_head_info($head);
677 my $src = $gs->full_url;
678
679 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
680 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
681 my $glob;
682 if ($#{$allglobs} == 0) {
683 $glob = $allglobs->[0];
684 } else {
685 unless(defined $_branch_dest) {
686 die "Multiple ",
687 $_tag ? "tag" : "branch",
688 " paths defined for Subversion repository.\n",
689 "You must specify where you want to create the ",
690 $_tag ? "tag" : "branch",
691 " with the --destination argument.\n";
692 }
693 foreach my $g (@{$allglobs}) {
694 # SVN::Git::Editor could probably be moved to Git.pm..
695 my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
696 if ($_branch_dest =~ /$re/) {
697 $glob = $g;
698 last;
699 }
700 }
701 unless (defined $glob) {
702 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
703 foreach my $g (@{$allglobs}) {
704 $g->{path}->{left} =~ /$dest_re/ or next;
705 if (defined $glob) {
706 die "Ambiguous destination: ",
707 $_branch_dest, "\nmatches both '",
708 $glob->{path}->{left}, "' and '",
709 $g->{path}->{left}, "'\n";
710 }
711 $glob = $g;
712 }
713 unless (defined $glob) {
714 die "Unknown ",
715 $_tag ? "tag" : "branch",
716 " destination $_branch_dest\n";
717 }
718 }
719 }
720 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
721 my $url;
722 if (defined $_commit_url) {
723 $url = $_commit_url;
724 } else {
725 $url = eval { command_oneline('config', '--get',
726 "svn-remote.$gs->{repo_id}.commiturl") };
727 if (!$url) {
728 $url = $remote->{url};
729 }
730 }
731 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
732
733 if ($dst =~ /^https:/ && $src =~ /^http:/) {
734 $src=~s/^http:/https:/;
735 }
736
737 ::_req_svn();
738
739 my $ctx = SVN::Client->new(
740 auth => Git::SVN::Ra::_auth_providers(),
741 log_msg => sub {
742 ${ $_[0] } = defined $_message
743 ? $_message
744 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
745 . $branch_name;
746 },
747 );
748
749 eval {
750 $ctx->ls($dst, 'HEAD', 0);
751 } and die "branch ${branch_name} already exists\n";
752
753 print "Copying ${src} at r${rev} to ${dst}...\n";
754 $ctx->copy($src, $rev, $dst)
755 unless $_dry_run;
756
757 $gs->fetch_all;
758 }
759
760 sub cmd_find_rev {
761 my $revision_or_hash = shift or die "SVN or git revision required ",
762 "as a command-line argument\n";
763 my $result;
764 if ($revision_or_hash =~ /^r\d+$/) {
765 my $head = shift;
766 $head ||= 'HEAD';
767 my @refs;
768 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
769 unless ($gs) {
770 die "Unable to determine upstream SVN information from ",
771 "$head history\n";
772 }
773 my $desired_revision = substr($revision_or_hash, 1);
774 $result = $gs->rev_map_get($desired_revision, $uuid);
775 } else {
776 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
777 $result = $rev;
778 }
779 print "$result\n" if $result;
780 }
781
782 sub cmd_rebase {
783 command_noisy(qw/update-index --refresh/);
784 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
785 unless ($gs) {
786 die "Unable to determine upstream SVN information from ",
787 "working tree history\n";
788 }
789 if ($_dry_run) {
790 print "Remote Branch: " . $gs->refname . "\n";
791 print "SVN URL: " . $url . "\n";
792 return;
793 }
794 if (command(qw/diff-index HEAD --/)) {
795 print STDERR "Cannot rebase with uncommited changes:\n";
796 command_noisy('status');
797 exit 1;
798 }
799 unless ($_local) {
800 # rebase will checkout for us, so no need to do it explicitly
801 $_no_checkout = 'true';
802 $_fetch_all ? $gs->fetch_all : $gs->fetch;
803 }
804 command_noisy(rebase_cmd(), $gs->refname);
805 $gs->mkemptydirs;
806 }
807
808 sub cmd_show_ignore {
809 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
810 $gs ||= Git::SVN->new;
811 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
812 $gs->prop_walk($gs->{path}, $r, sub {
813 my ($gs, $path, $props) = @_;
814 print STDOUT "\n# $path\n";
815 my $s = $props->{'svn:ignore'} or return;
816 $s =~ s/[\r\n]+/\n/g;
817 $s =~ s/^\n+//;
818 chomp $s;
819 $s =~ s#^#$path#gm;
820 print STDOUT "$s\n";
821 });
822 }
823
824 sub cmd_show_externals {
825 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
826 $gs ||= Git::SVN->new;
827 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
828 $gs->prop_walk($gs->{path}, $r, sub {
829 my ($gs, $path, $props) = @_;
830 print STDOUT "\n# $path\n";
831 my $s = $props->{'svn:externals'} or return;
832 $s =~ s/[\r\n]+/\n/g;
833 chomp $s;
834 $s =~ s#^#$path#gm;
835 print STDOUT "$s\n";
836 });
837 }
838
839 sub cmd_create_ignore {
840 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
841 $gs ||= Git::SVN->new;
842 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
843 $gs->prop_walk($gs->{path}, $r, sub {
844 my ($gs, $path, $props) = @_;
845 # $path is of the form /path/to/dir/
846 $path = '.' . $path;
847 # SVN can have attributes on empty directories,
848 # which git won't track
849 mkpath([$path]) unless -d $path;
850 my $ignore = $path . '.gitignore';
851 my $s = $props->{'svn:ignore'} or return;
852 open(GITIGNORE, '>', $ignore)
853 or fatal("Failed to open `$ignore' for writing: $!");
854 $s =~ s/[\r\n]+/\n/g;
855 $s =~ s/^\n+//;
856 chomp $s;
857 # Prefix all patterns so that the ignore doesn't apply
858 # to sub-directories.
859 $s =~ s#^#/#gm;
860 print GITIGNORE "$s\n";
861 close(GITIGNORE)
862 or fatal("Failed to close `$ignore': $!");
863 command_noisy('add', '-f', $ignore);
864 });
865 }
866
867 sub cmd_mkdirs {
868 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
869 $gs ||= Git::SVN->new;
870 $gs->mkemptydirs($_revision);
871 }
872
873 sub canonicalize_path {
874 my ($path) = @_;
875 my $dot_slash_added = 0;
876 if (substr($path, 0, 1) ne "/") {
877 $path = "./" . $path;
878 $dot_slash_added = 1;
879 }
880 # File::Spec->canonpath doesn't collapse x/../y into y (for a
881 # good reason), so let's do this manually.
882 $path =~ s#/+#/#g;
883 $path =~ s#/\.(?:/|$)#/#g;
884 $path =~ s#/[^/]+/\.\.##g;
885 $path =~ s#/$##g;
886 $path =~ s#^\./## if $dot_slash_added;
887 $path =~ s#^/##;
888 $path =~ s#^\.$##;
889 return $path;
890 }
891
892 sub canonicalize_url {
893 my ($url) = @_;
894 $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
895 return $url;
896 }
897
898 # get_svnprops(PATH)
899 # ------------------
900 # Helper for cmd_propget and cmd_proplist below.
901 sub get_svnprops {
902 my $path = shift;
903 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
904 $gs ||= Git::SVN->new;
905
906 # prefix THE PATH by the sub-directory from which the user
907 # invoked us.
908 $path = $cmd_dir_prefix . $path;
909 fatal("No such file or directory: $path") unless -e $path;
910 my $is_dir = -d $path ? 1 : 0;
911 $path = $gs->{path} . '/' . $path;
912
913 # canonicalize the path (otherwise libsvn will abort or fail to
914 # find the file)
915 $path = canonicalize_path($path);
916
917 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
918 my $props;
919 if ($is_dir) {
920 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
921 }
922 else {
923 (undef, $props) = $gs->ra->get_file($path, $r, undef);
924 }
925 return $props;
926 }
927
928 # cmd_propget (PROP, PATH)
929 # ------------------------
930 # Print the SVN property PROP for PATH.
931 sub cmd_propget {
932 my ($prop, $path) = @_;
933 $path = '.' if not defined $path;
934 usage(1) if not defined $prop;
935 my $props = get_svnprops($path);
936 if (not defined $props->{$prop}) {
937 fatal("`$path' does not have a `$prop' SVN property.");
938 }
939 print $props->{$prop} . "\n";
940 }
941
942 # cmd_proplist (PATH)
943 # -------------------
944 # Print the list of SVN properties for PATH.
945 sub cmd_proplist {
946 my $path = shift;
947 $path = '.' if not defined $path;
948 my $props = get_svnprops($path);
949 print "Properties on '$path':\n";
950 foreach (sort keys %{$props}) {
951 print " $_\n";
952 }
953 }
954
955 sub cmd_multi_init {
956 my $url = shift;
957 unless (defined $_trunk || @_branches || @_tags) {
958 usage(1);
959 }
960
961 $_prefix = '' unless defined $_prefix;
962 if (defined $url) {
963 $url = canonicalize_url($url);
964 init_subdir(@_);
965 }
966 do_git_init_db();
967 if (defined $_trunk) {
968 $_trunk =~ s#^/+##;
969 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
970 # try both old-style and new-style lookups:
971 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
972 unless ($gs_trunk) {
973 my ($trunk_url, $trunk_path) =
974 complete_svn_url($url, $_trunk);
975 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
976 undef, $trunk_ref);
977 }
978 }
979 return unless @_branches || @_tags;
980 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
981 foreach my $path (@_branches) {
982 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
983 }
984 foreach my $path (@_tags) {
985 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
986 }
987 }
988
989 sub cmd_multi_fetch {
990 $Git::SVN::no_reuse_existing = undef;
991 my $remotes = Git::SVN::read_all_remotes();
992 foreach my $repo_id (sort keys %$remotes) {
993 if ($remotes->{$repo_id}->{url}) {
994 Git::SVN::fetch_all($repo_id, $remotes);
995 }
996 }
997 }
998
999 # this command is special because it requires no metadata
1000 sub cmd_commit_diff {
1001 my ($ta, $tb, $url) = @_;
1002 my $usage = "Usage: $0 commit-diff -r<revision> ".
1003 "<tree-ish> <tree-ish> [<URL>]";
1004 fatal($usage) if (!defined $ta || !defined $tb);
1005 my $svn_path = '';
1006 if (!defined $url) {
1007 my $gs = eval { Git::SVN->new };
1008 if (!$gs) {
1009 fatal("Needed URL or usable git-svn --id in ",
1010 "the command-line\n", $usage);
1011 }
1012 $url = $gs->{url};
1013 $svn_path = $gs->{path};
1014 }
1015 unless (defined $_revision) {
1016 fatal("-r|--revision is a required argument\n", $usage);
1017 }
1018 if (defined $_message && defined $_file) {
1019 fatal("Both --message/-m and --file/-F specified ",
1020 "for the commit message.\n",
1021 "I have no idea what you mean");
1022 }
1023 if (defined $_file) {
1024 $_message = file_to_s($_file);
1025 } else {
1026 $_message ||= get_commit_entry($tb)->{log};
1027 }
1028 my $ra ||= Git::SVN::Ra->new($url);
1029 my $r = $_revision;
1030 if ($r eq 'HEAD') {
1031 $r = $ra->get_latest_revnum;
1032 } elsif ($r !~ /^\d+$/) {
1033 die "revision argument: $r not understood by git-svn\n";
1034 }
1035 my %ed_opts = ( r => $r,
1036 log => $_message,
1037 ra => $ra,
1038 tree_a => $ta,
1039 tree_b => $tb,
1040 editor_cb => sub { print "Committed r$_[0]\n" },
1041 svn_path => $svn_path );
1042 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1043 print "No changes\n$ta == $tb\n";
1044 }
1045 }
1046
1047 sub escape_uri_only {
1048 my ($uri) = @_;
1049 my @tmp;
1050 foreach (split m{/}, $uri) {
1051 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1052 push @tmp, $_;
1053 }
1054 join('/', @tmp);
1055 }
1056
1057 sub escape_url {
1058 my ($url) = @_;
1059 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1060 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1061 $url = "$scheme://$domain$uri";
1062 }
1063 $url;
1064 }
1065
1066 sub cmd_info {
1067 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1068 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1069 if (exists $_[1]) {
1070 die "Too many arguments specified\n";
1071 }
1072
1073 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1074
1075 if (!$file_type && !$diff_status) {
1076 print STDERR "svn: '$path' is not under version control\n";
1077 exit 1;
1078 }
1079
1080 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1081 unless ($gs) {
1082 die "Unable to determine upstream SVN information from ",
1083 "working tree history\n";
1084 }
1085
1086 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1087 $path = "." if $path eq "";
1088
1089 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1090
1091 if ($_url) {
1092 print escape_url($full_url), "\n";
1093 return;
1094 }
1095
1096 my $result = "Path: $path\n";
1097 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1098 $result .= "URL: " . escape_url($full_url) . "\n";
1099
1100 eval {
1101 my $repos_root = $gs->repos_root;
1102 Git::SVN::remove_username($repos_root);
1103 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1104 };
1105 if ($@) {
1106 $result .= "Repository Root: (offline)\n";
1107 }
1108 ::_req_svn();
1109 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1110 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1111 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1112
1113 $result .= "Node Kind: " .
1114 ($file_type eq "dir" ? "directory" : "file") . "\n";
1115
1116 my $schedule = $diff_status eq "A"
1117 ? "add"
1118 : ($diff_status eq "D" ? "delete" : "normal");
1119 $result .= "Schedule: $schedule\n";
1120
1121 if ($diff_status eq "A") {
1122 print $result, "\n";
1123 return;
1124 }
1125
1126 my ($lc_author, $lc_rev, $lc_date_utc);
1127 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1128 my $log = command_output_pipe(@args);
1129 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1130 while (<$log>) {
1131 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1132 $lc_author = $1;
1133 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1134 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1135 (undef, $lc_rev, undef) = ::extract_metadata($1);
1136 }
1137 }
1138 close $log;
1139
1140 Git::SVN::Log::set_local_timezone();
1141
1142 $result .= "Last Changed Author: $lc_author\n";
1143 $result .= "Last Changed Rev: $lc_rev\n";
1144 $result .= "Last Changed Date: " .
1145 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1146
1147 if ($file_type ne "dir") {
1148 my $text_last_updated_date =
1149 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1150 $result .=
1151 "Text Last Updated: " .
1152 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1153 "\n";
1154 my $checksum;
1155 if ($diff_status eq "D") {
1156 my ($fh, $ctx) =
1157 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1158 if ($file_type eq "link") {
1159 my $file_name = <$fh>;
1160 $checksum = md5sum("link $file_name");
1161 } else {
1162 $checksum = md5sum($fh);
1163 }
1164 command_close_pipe($fh, $ctx);
1165 } elsif ($file_type eq "link") {
1166 my $file_name =
1167 command(qw(cat-file blob), "HEAD:$path");
1168 $checksum =
1169 md5sum("link " . $file_name);
1170 } else {
1171 open FILE, "<", $path or die $!;
1172 $checksum = md5sum(\*FILE);
1173 close FILE or die $!;
1174 }
1175 $result .= "Checksum: " . $checksum . "\n";
1176 }
1177
1178 print $result, "\n";
1179 }
1180
1181 sub cmd_reset {
1182 my $target = shift || $_revision or die "SVN revision required\n";
1183 $target = $1 if $target =~ /^r(\d+)$/;
1184 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1185 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1186 unless ($gs) {
1187 die "Unable to determine upstream SVN information from ".
1188 "history\n";
1189 }
1190 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1191 die "Cannot find SVN revision $target\n" unless defined($c);
1192 $gs->rev_map_set($r, $c, 'reset', $uuid);
1193 print "r$r = $c ($gs->{ref_id})\n";
1194 }
1195
1196 sub cmd_gc {
1197 if (!$can_compress) {
1198 warn "Compress::Zlib could not be found; unhandled.log " .
1199 "files will not be compressed.\n";
1200 }
1201 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1202 }
1203
1204 ########################### utility functions #########################
1205
1206 sub rebase_cmd {
1207 my @cmd = qw/rebase/;
1208 push @cmd, '-v' if $_verbose;
1209 push @cmd, qw/--merge/ if $_merge;
1210 push @cmd, "--strategy=$_strategy" if $_strategy;
1211 @cmd;
1212 }
1213
1214 sub post_fetch_checkout {
1215 return if $_no_checkout;
1216 my $gs = $Git::SVN::_head or return;
1217 return if verify_ref('refs/heads/master^0');
1218
1219 # look for "trunk" ref if it exists
1220 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1221 my $fetch = $remote->{fetch};
1222 if ($fetch) {
1223 foreach my $p (keys %$fetch) {
1224 basename($fetch->{$p}) eq 'trunk' or next;
1225 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1226 last;
1227 }
1228 }
1229
1230 my $valid_head = verify_ref('HEAD^0');
1231 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1232 return if ($valid_head || !verify_ref('HEAD^0'));
1233
1234 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1235 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1236 return if -f $index;
1237
1238 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1239 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1240 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1241 print STDERR "Checked out HEAD:\n ",
1242 $gs->full_url, " r", $gs->last_rev, "\n";
1243 $gs->mkemptydirs($gs->last_rev);
1244 }
1245
1246 sub complete_svn_url {
1247 my ($url, $path) = @_;
1248 $path =~ s#/+$##;
1249 if ($path !~ m#^[a-z\+]+://#) {
1250 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1251 fatal("E: '$path' is not a complete URL ",
1252 "and a separate URL is not specified");
1253 }
1254 return ($url, $path);
1255 }
1256 return ($path, '');
1257 }
1258
1259 sub complete_url_ls_init {
1260 my ($ra, $repo_path, $switch, $pfx) = @_;
1261 unless ($repo_path) {
1262 print STDERR "W: $switch not specified\n";
1263 return;
1264 }
1265 $repo_path =~ s#/+$##;
1266 if ($repo_path =~ m#^[a-z\+]+://#) {
1267 $ra = Git::SVN::Ra->new($repo_path);
1268 $repo_path = '';
1269 } else {
1270 $repo_path =~ s#^/+##;
1271 unless ($ra) {
1272 fatal("E: '$repo_path' is not a complete URL ",
1273 "and a separate URL is not specified");
1274 }
1275 }
1276 my $url = $ra->{url};
1277 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1278 my $k = "svn-remote.$gs->{repo_id}.url";
1279 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1280 if ($orig_url && ($orig_url ne $gs->{url})) {
1281 die "$k already set: $orig_url\n",
1282 "wanted to set to: $gs->{url}\n";
1283 }
1284 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1285 my $remote_path = "$gs->{path}/$repo_path";
1286 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1287 $remote_path =~ s#/+#/#g;
1288 $remote_path =~ s#^/##g;
1289 $remote_path .= "/*" if $remote_path !~ /\*/;
1290 my ($n) = ($switch =~ /^--(\w+)/);
1291 if (length $pfx && $pfx !~ m#/$#) {
1292 die "--prefix='$pfx' must have a trailing slash '/'\n";
1293 }
1294 command_noisy('config',
1295 '--add',
1296 "svn-remote.$gs->{repo_id}.$n",
1297 "$remote_path:refs/remotes/$pfx*" .
1298 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1299 }
1300
1301 sub verify_ref {
1302 my ($ref) = @_;
1303 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1304 { STDERR => 0 }); };
1305 }
1306
1307 sub get_tree_from_treeish {
1308 my ($treeish) = @_;
1309 # $treeish can be a symbolic ref, too:
1310 my $type = command_oneline(qw/cat-file -t/, $treeish);
1311 my $expected;
1312 while ($type eq 'tag') {
1313 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1314 }
1315 if ($type eq 'commit') {
1316 $expected = (grep /^tree /, command(qw/cat-file commit/,
1317 $treeish))[0];
1318 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1319 die "Unable to get tree from $treeish\n" unless $expected;
1320 } elsif ($type eq 'tree') {
1321 $expected = $treeish;
1322 } else {
1323 die "$treeish is a $type, expected tree, tag or commit\n";
1324 }
1325 return $expected;
1326 }
1327
1328 sub get_commit_entry {
1329 my ($treeish) = shift;
1330 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1331 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1332 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1333 open my $log_fh, '>', $commit_editmsg or croak $!;
1334
1335 my $type = command_oneline(qw/cat-file -t/, $treeish);
1336 if ($type eq 'commit' || $type eq 'tag') {
1337 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1338 $type, $treeish);
1339 my $in_msg = 0;
1340 my $author;
1341 my $saw_from = 0;
1342 my $msgbuf = "";
1343 while (<$msg_fh>) {
1344 if (!$in_msg) {
1345 $in_msg = 1 if (/^\s*$/);
1346 $author = $1 if (/^author (.*>)/);
1347 } elsif (/^git-svn-id: /) {
1348 # skip this for now, we regenerate the
1349 # correct one on re-fetch anyways
1350 # TODO: set *:merge properties or like...
1351 } else {
1352 if (/^From:/ || /^Signed-off-by:/) {
1353 $saw_from = 1;
1354 }
1355 $msgbuf .= $_;
1356 }
1357 }
1358 $msgbuf =~ s/\s+$//s;
1359 if ($Git::SVN::_add_author_from && defined($author)
1360 && !$saw_from) {
1361 $msgbuf .= "\n\nFrom: $author";
1362 }
1363 print $log_fh $msgbuf or croak $!;
1364 command_close_pipe($msg_fh, $ctx);
1365 }
1366 close $log_fh or croak $!;
1367
1368 if ($_edit || ($type eq 'tree')) {
1369 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1370 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1371 }
1372 rename $commit_editmsg, $commit_msg or croak $!;
1373 {
1374 require Encode;
1375 # SVN requires messages to be UTF-8 when entering the repo
1376 local $/;
1377 open $log_fh, '<', $commit_msg or croak $!;
1378 binmode $log_fh;
1379 chomp($log_entry{log} = <$log_fh>);
1380
1381 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1382 my $msg = $log_entry{log};
1383
1384 eval { $msg = Encode::decode($enc, $msg, 1) };
1385 if ($@) {
1386 die "Could not decode as $enc:\n", $msg,
1387 "\nPerhaps you need to set i18n.commitencoding\n";
1388 }
1389
1390 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1391 die "Could not encode as UTF-8:\n$msg\n" if $@;
1392
1393 $log_entry{log} = $msg;
1394
1395 close $log_fh or croak $!;
1396 }
1397 unlink $commit_msg;
1398 \%log_entry;
1399 }
1400
1401 sub s_to_file {
1402 my ($str, $file, $mode) = @_;
1403 open my $fd,'>',$file or croak $!;
1404 print $fd $str,"\n" or croak $!;
1405 close $fd or croak $!;
1406 chmod ($mode &~ umask, $file) if (defined $mode);
1407 }
1408
1409 sub file_to_s {
1410 my $file = shift;
1411 open my $fd,'<',$file or croak "$!: file: $file\n";
1412 local $/;
1413 my $ret = <$fd>;
1414 close $fd or croak $!;
1415 $ret =~ s/\s*$//s;
1416 return $ret;
1417 }
1418
1419 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1420 sub load_authors {
1421 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1422 my $log = $cmd eq 'log';
1423 while (<$authors>) {
1424 chomp;
1425 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1426 my ($user, $name, $email) = ($1, $2, $3);
1427 if ($log) {
1428 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1429 } else {
1430 $users{$user} = [$name, $email];
1431 }
1432 }
1433 close $authors or croak $!;
1434 }
1435
1436 # convert GetOpt::Long specs for use by git-config
1437 sub read_git_config {
1438 my $opts = shift;
1439 my @config_only;
1440 foreach my $o (keys %$opts) {
1441 # if we have mixedCase and a long option-only, then
1442 # it's a config-only variable that we don't need for
1443 # the command-line.
1444 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1445 my $v = $opts->{$o};
1446 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1447 $key =~ s/-//g;
1448 my $arg = 'git config';
1449 $arg .= ' --int' if ($o =~ /[:=]i$/);
1450 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1451 if (ref $v eq 'ARRAY') {
1452 chomp(my @tmp = `$arg --get-all svn.$key`);
1453 @$v = @tmp if @tmp;
1454 } else {
1455 chomp(my $tmp = `$arg --get svn.$key`);
1456 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1457 $$v = $tmp;
1458 }
1459 }
1460 }
1461 delete @$opts{@config_only} if @config_only;
1462 }
1463
1464 sub extract_metadata {
1465 my $id = shift or return (undef, undef, undef);
1466 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1467 \s([a-f\d\-]+)$/ix);
1468 if (!defined $rev || !$uuid || !$url) {
1469 # some of the original repositories I made had
1470 # identifiers like this:
1471 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1472 }
1473 return ($url, $rev, $uuid);
1474 }
1475
1476 sub cmt_metadata {
1477 return extract_metadata((grep(/^git-svn-id: /,
1478 command(qw/cat-file commit/, shift)))[-1]);
1479 }
1480
1481 sub cmt_sha2rev_batch {
1482 my %s2r;
1483 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1484 my $list = shift;
1485
1486 foreach my $sha (@{$list}) {
1487 my $first = 1;
1488 my $size = 0;
1489 print $out $sha, "\n";
1490
1491 while (my $line = <$in>) {
1492 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1493 last;
1494 } elsif ($first &&
1495 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1496 $first = 0;
1497 $size = $1;
1498 next;
1499 } elsif ($line =~ /^(git-svn-id: )/) {
1500 my (undef, $rev, undef) =
1501 extract_metadata($line);
1502 $s2r{$sha} = $rev;
1503 }
1504
1505 $size -= length($line);
1506 last if ($size == 0);
1507 }
1508 }
1509
1510 command_close_bidi_pipe($pid, $in, $out, $ctx);
1511
1512 return \%s2r;
1513 }
1514
1515 sub working_head_info {
1516 my ($head, $refs) = @_;
1517 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1518 my ($fh, $ctx) = command_output_pipe(@args, $head);
1519 my $hash;
1520 my %max;
1521 while (<$fh>) {
1522 if ( m{^commit ($::sha1)$} ) {
1523 unshift @$refs, $hash if $hash and $refs;
1524 $hash = $1;
1525 next;
1526 }
1527 next unless s{^\s*(git-svn-id:)}{$1};
1528 my ($url, $rev, $uuid) = extract_metadata($_);
1529 if (defined $url && defined $rev) {
1530 next if $max{$url} and $max{$url} < $rev;
1531 if (my $gs = Git::SVN->find_by_url($url)) {
1532 my $c = $gs->rev_map_get($rev, $uuid);
1533 if ($c && $c eq $hash) {
1534 close $fh; # break the pipe
1535 return ($url, $rev, $uuid, $gs);
1536 } else {
1537 $max{$url} ||= $gs->rev_map_max;
1538 }
1539 }
1540 }
1541 }
1542 command_close_pipe($fh, $ctx);
1543 (undef, undef, undef, undef);
1544 }
1545
1546 sub read_commit_parents {
1547 my ($parents, $c) = @_;
1548 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1549 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1550 @{$parents->{$c}} = split(/ /, $p);
1551 }
1552
1553 sub linearize_history {
1554 my ($gs, $refs) = @_;
1555 my %parents;
1556 foreach my $c (@$refs) {
1557 read_commit_parents(\%parents, $c);
1558 }
1559
1560 my @linear_refs;
1561 my %skip = ();
1562 my $last_svn_commit = $gs->last_commit;
1563 foreach my $c (reverse @$refs) {
1564 next if $c eq $last_svn_commit;
1565 last if $skip{$c};
1566
1567 unshift @linear_refs, $c;
1568 $skip{$c} = 1;
1569
1570 # we only want the first parent to diff against for linear
1571 # history, we save the rest to inject when we finalize the
1572 # svn commit
1573 my $fp_a = verify_ref("$c~1");
1574 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1575 if (!$fp_a || !$fp_b) {
1576 die "Commit $c\n",
1577 "has no parent commit, and therefore ",
1578 "nothing to diff against.\n",
1579 "You should be working from a repository ",
1580 "originally created by git-svn\n";
1581 }
1582 if ($fp_a ne $fp_b) {
1583 die "$c~1 = $fp_a, however parsing commit $c ",
1584 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1585 }
1586
1587 foreach my $p (@{$parents{$c}}) {
1588 $skip{$p} = 1;
1589 }
1590 }
1591 (\@linear_refs, \%parents);
1592 }
1593
1594 sub find_file_type_and_diff_status {
1595 my ($path) = @_;
1596 return ('dir', '') if $path eq '';
1597
1598 my $diff_output =
1599 command_oneline(qw(diff --cached --name-status --), $path) || "";
1600 my $diff_status = (split(' ', $diff_output))[0] || "";
1601
1602 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1603
1604 return (undef, undef) if !$diff_status && !$ls_tree;
1605
1606 if ($diff_status eq "A") {
1607 return ("link", $diff_status) if -l $path;
1608 return ("dir", $diff_status) if -d $path;
1609 return ("file", $diff_status);
1610 }
1611
1612 my $mode = (split(' ', $ls_tree))[0] || "";
1613
1614 return ("link", $diff_status) if $mode eq "120000";
1615 return ("dir", $diff_status) if $mode eq "040000";
1616 return ("file", $diff_status);
1617 }
1618
1619 sub md5sum {
1620 my $arg = shift;
1621 my $ref = ref $arg;
1622 my $md5 = Digest::MD5->new();
1623 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1624 $md5->addfile($arg) or croak $!;
1625 } elsif ($ref eq 'SCALAR') {
1626 $md5->add($$arg) or croak $!;
1627 } elsif (!$ref) {
1628 $md5->add($arg) or croak $!;
1629 } else {
1630 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1631 }
1632 return $md5->hexdigest();
1633 }
1634
1635 sub gc_directory {
1636 if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1637 my $out_filename = $_ . ".gz";
1638 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1639 binmode $in_fh;
1640 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1641 die "Unable to open $out_filename: $!\n";
1642
1643 my $res;
1644 while ($res = sysread($in_fh, my $str, 1024)) {
1645 $gz->gzwrite($str) or
1646 die "Unable to write: ".$gz->gzerror()."!\n";
1647 }
1648 unlink $_ or die "unlink $File::Find::name: $!\n";
1649 } elsif (-f $_ && basename($_) eq "index") {
1650 unlink $_ or die "unlink $_: $!\n";
1651 }
1652 }
1653
1654 package Git::SVN;
1655 use strict;
1656 use warnings;
1657 use Fcntl qw/:DEFAULT :seek/;
1658 use constant rev_map_fmt => 'NH40';
1659 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1660 $_repack $_repack_flags $_use_svm_props $_head
1661 $_use_svnsync_props $no_reuse_existing $_minimize_url
1662 $_use_log_author $_add_author_from $_localtime/;
1663 use Carp qw/croak/;
1664 use File::Path qw/mkpath/;
1665 use File::Copy qw/copy/;
1666 use IPC::Open3;
1667 use Memoize; # core since 5.8.0, Jul 2002
1668 use Memoize::Storable;
1669
1670 my ($_gc_nr, $_gc_period);
1671
1672 # properties that we do not log:
1673 my %SKIP_PROP;
1674 BEGIN {
1675 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1676 svn:special svn:executable
1677 svn:entry:committed-rev
1678 svn:entry:last-author
1679 svn:entry:uuid
1680 svn:entry:committed-date/;
1681
1682 # some options are read globally, but can be overridden locally
1683 # per [svn-remote "..."] section. Command-line options will *NOT*
1684 # override options set in an [svn-remote "..."] section
1685 no strict 'refs';
1686 for my $option (qw/follow_parent no_metadata use_svm_props
1687 use_svnsync_props/) {
1688 my $key = $option;
1689 $key =~ tr/_//d;
1690 my $prop = "-$option";
1691 *$option = sub {
1692 my ($self) = @_;
1693 return $self->{$prop} if exists $self->{$prop};
1694 my $k = "svn-remote.$self->{repo_id}.$key";
1695 eval { command_oneline(qw/config --get/, $k) };
1696 if ($@) {
1697 $self->{$prop} = ${"Git::SVN::_$option"};
1698 } else {
1699 my $v = command_oneline(qw/config --bool/,$k);
1700 $self->{$prop} = $v eq 'false' ? 0 : 1;
1701 }
1702 return $self->{$prop};
1703 }
1704 }
1705 }
1706
1707
1708 my (%LOCKFILES, %INDEX_FILES);
1709 END {
1710 unlink keys %LOCKFILES if %LOCKFILES;
1711 unlink keys %INDEX_FILES if %INDEX_FILES;
1712 }
1713
1714 sub resolve_local_globs {
1715 my ($url, $fetch, $glob_spec) = @_;
1716 return unless defined $glob_spec;
1717 my $ref = $glob_spec->{ref};
1718 my $path = $glob_spec->{path};
1719 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1720 next unless m#^$ref->{regex}$#;
1721 my $p = $1;
1722 my $pathname = desanitize_refname($path->full_path($p));
1723 my $refname = desanitize_refname($ref->full_path($p));
1724 if (my $existing = $fetch->{$pathname}) {
1725 if ($existing ne $refname) {
1726 die "Refspec conflict:\n",
1727 "existing: $existing\n",
1728 " globbed: $refname\n";
1729 }
1730 my $u = (::cmt_metadata("$refname"))[0];
1731 $u =~ s!^\Q$url\E(/|$)!! or die
1732 "$refname: '$url' not found in '$u'\n";
1733 if ($pathname ne $u) {
1734 warn "W: Refspec glob conflict ",
1735 "(ref: $refname):\n",
1736 "expected path: $pathname\n",
1737 " real path: $u\n",
1738 "Continuing ahead with $u\n";
1739 next;
1740 }
1741 } else {
1742 $fetch->{$pathname} = $refname;
1743 }
1744 }
1745 }
1746
1747 sub parse_revision_argument {
1748 my ($base, $head) = @_;
1749 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1750 return ($base, $head);
1751 }
1752 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1753 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1754 return ($head, $head) if ($::_revision eq 'HEAD');
1755 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1756 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1757 die "revision argument: $::_revision not understood by git-svn\n";
1758 }
1759
1760 sub fetch_all {
1761 my ($repo_id, $remotes) = @_;
1762 if (ref $repo_id) {
1763 my $gs = $repo_id;
1764 $repo_id = undef;
1765 $repo_id = $gs->{repo_id};
1766 }
1767 $remotes ||= read_all_remotes();
1768 my $remote = $remotes->{$repo_id} or
1769 die "[svn-remote \"$repo_id\"] unknown\n";
1770 my $fetch = $remote->{fetch};
1771 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1772 my (@gs, @globs);
1773 my $ra = Git::SVN::Ra->new($url);
1774 my $uuid = $ra->get_uuid;
1775 my $head = $ra->get_latest_revnum;
1776
1777 # ignore errors, $head revision may not even exist anymore
1778 eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
1779 warn "W: $@\n" if $@;
1780
1781 my $base = defined $fetch ? $head : 0;
1782
1783 # read the max revs for wildcard expansion (branches/*, tags/*)
1784 foreach my $t (qw/branches tags/) {
1785 defined $remote->{$t} or next;
1786 push @globs, @{$remote->{$t}};
1787
1788 my $max_rev = eval { tmp_config(qw/--int --get/,
1789 "svn-remote.$repo_id.${t}-maxRev") };
1790 if (defined $max_rev && ($max_rev < $base)) {
1791 $base = $max_rev;
1792 } elsif (!defined $max_rev) {
1793 $base = 0;
1794 }
1795 }
1796
1797 if ($fetch) {
1798 foreach my $p (sort keys %$fetch) {
1799 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1800 my $lr = $gs->rev_map_max;
1801 if (defined $lr) {
1802 $base = $lr if ($lr < $base);
1803 }
1804 push @gs, $gs;
1805 }
1806 }
1807
1808 ($base, $head) = parse_revision_argument($base, $head);
1809 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1810 }
1811
1812 sub read_all_remotes {
1813 my $r = {};
1814 my $use_svm_props = eval { command_oneline(qw/config --bool
1815 svn.useSvmProps/) };
1816 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1817 my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1818 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1819 if (m!^(.+)\.fetch=$svn_refspec$!) {
1820 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1821 die("svn-remote.$remote: remote ref '$remote_ref' "
1822 . "must start with 'refs/'\n")
1823 unless $remote_ref =~ m{^refs/};
1824 $local_ref = uri_decode($local_ref);
1825 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1826 $r->{$remote}->{svm} = {} if $use_svm_props;
1827 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1828 $r->{$1}->{svm} = {};
1829 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1830 $r->{$1}->{url} = $2;
1831 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1832 my ($remote, $t, $local_ref, $remote_ref) =
1833 ($1, $2, $3, $4);
1834 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1835 . "must start with 'refs/'\n")
1836 unless $remote_ref =~ m{^refs/};
1837 $local_ref = uri_decode($local_ref);
1838 my $rs = {
1839 t => $t,
1840 remote => $remote,
1841 path => Git::SVN::GlobSpec->new($local_ref, 1),
1842 ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
1843 if (length($rs->{ref}->{right}) != 0) {
1844 die "The '*' glob character must be the last ",
1845 "character of '$remote_ref'\n";
1846 }
1847 push @{ $r->{$remote}->{$t} }, $rs;
1848 }
1849 }
1850
1851 map {
1852 if (defined $r->{$_}->{svm}) {
1853 my $svm;
1854 eval {
1855 my $section = "svn-remote.$_";
1856 $svm = {
1857 source => tmp_config('--get',
1858 "$section.svm-source"),
1859 replace => tmp_config('--get',
1860 "$section.svm-replace"),
1861 }
1862 };
1863 $r->{$_}->{svm} = $svm;
1864 }
1865 } keys %$r;
1866
1867 $r;
1868 }
1869
1870 sub init_vars {
1871 $_gc_nr = $_gc_period = 1000;
1872 if (defined $_repack || defined $_repack_flags) {
1873 warn "Repack options are obsolete; they have no effect.\n";
1874 }
1875 }
1876
1877 sub verify_remotes_sanity {
1878 return unless -d $ENV{GIT_DIR};
1879 my %seen;
1880 foreach (command(qw/config -l/)) {
1881 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1882 if ($seen{$1}) {
1883 die "Remote ref refs/remote/$1 is tracked by",
1884 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1885 "Please resolve this ambiguity in ",
1886 "your git configuration file before ",
1887 "continuing\n";
1888 }
1889 $seen{$1} = $_;
1890 }
1891 }
1892 }
1893
1894 sub find_existing_remote {
1895 my ($url, $remotes) = @_;
1896 return undef if $no_reuse_existing;
1897 my $existing;
1898 foreach my $repo_id (keys %$remotes) {
1899 my $u = $remotes->{$repo_id}->{url} or next;
1900 next if $u ne $url;
1901 $existing = $repo_id;
1902 last;
1903 }
1904 $existing;
1905 }
1906
1907 sub init_remote_config {
1908 my ($self, $url, $no_write) = @_;
1909 $url =~ s!/+$!!; # strip trailing slash
1910 my $r = read_all_remotes();
1911 my $existing = find_existing_remote($url, $r);
1912 if ($existing) {
1913 unless ($no_write) {
1914 print STDERR "Using existing ",
1915 "[svn-remote \"$existing\"]\n";
1916 }
1917 $self->{repo_id} = $existing;
1918 } elsif ($_minimize_url) {
1919 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1920 $existing = find_existing_remote($min_url, $r);
1921 if ($existing) {
1922 unless ($no_write) {
1923 print STDERR "Using existing ",
1924 "[svn-remote \"$existing\"]\n";
1925 }
1926 $self->{repo_id} = $existing;
1927 }
1928 if ($min_url ne $url) {
1929 unless ($no_write) {
1930 print STDERR "Using higher level of URL: ",
1931 "$url => $min_url\n";
1932 }
1933 my $old_path = $self->{path};
1934 $self->{path} = $url;
1935 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1936 if (length $old_path) {
1937 $self->{path} .= "/$old_path";
1938 }
1939 $url = $min_url;
1940 }
1941 }
1942 my $orig_url;
1943 if (!$existing) {
1944 # verify that we aren't overwriting anything:
1945 $orig_url = eval {
1946 command_oneline('config', '--get',
1947 "svn-remote.$self->{repo_id}.url")
1948 };
1949 if ($orig_url && ($orig_url ne $url)) {
1950 die "svn-remote.$self->{repo_id}.url already set: ",
1951 "$orig_url\nwanted to set to: $url\n";
1952 }
1953 }
1954 my ($xrepo_id, $xpath) = find_ref($self->refname);
1955 if (!$no_write && defined $xpath) {
1956 die "svn-remote.$xrepo_id.fetch already set to track ",
1957 "$xpath:", $self->refname, "\n";
1958 }
1959 unless ($no_write) {
1960 command_noisy('config',
1961 "svn-remote.$self->{repo_id}.url", $url);
1962 $self->{path} =~ s{^/}{};
1963 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1964 command_noisy('config', '--add',
1965 "svn-remote.$self->{repo_id}.fetch",
1966 "$self->{path}:".$self->refname);
1967 }
1968 $self->{url} = $url;
1969 }
1970
1971 sub find_by_url { # repos_root and, path are optional
1972 my ($class, $full_url, $repos_root, $path) = @_;
1973
1974 return undef unless defined $full_url;
1975 remove_username($full_url);
1976 remove_username($repos_root) if defined $repos_root;
1977 my $remotes = read_all_remotes();
1978 if (defined $full_url && defined $repos_root && !defined $path) {
1979 $path = $full_url;
1980 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1981 }
1982 foreach my $repo_id (keys %$remotes) {
1983 my $u = $remotes->{$repo_id}->{url} or next;
1984 remove_username($u);
1985 next if defined $repos_root && $repos_root ne $u;
1986
1987 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1988 foreach my $t (qw/branches tags/) {
1989 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1990 resolve_local_globs($u, $fetch, $globspec);
1991 }
1992 }
1993 my $p = $path;
1994 my $rwr = rewrite_root({repo_id => $repo_id});
1995 my $svm = $remotes->{$repo_id}->{svm}
1996 if defined $remotes->{$repo_id}->{svm};
1997 unless (defined $p) {
1998 $p = $full_url;
1999 my $z = $u;
2000 my $prefix = '';
2001 if ($rwr) {
2002 $z = $rwr;
2003 remove_username($z);
2004 } elsif (defined $svm) {
2005 $z = $svm->{source};
2006 $prefix = $svm->{replace};
2007 $prefix =~ s#^\Q$u\E(?:/|$)##;
2008 $prefix =~ s#/$##;
2009 }
2010 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
2011 }
2012 foreach my $f (keys %$fetch) {
2013 next if $f ne $p;
2014 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
2015 }
2016 }
2017 undef;
2018 }
2019
2020 sub init {
2021 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
2022 my $self = _new($class, $repo_id, $ref_id, $path);
2023 if (defined $url) {
2024 $self->init_remote_config($url, $no_write);
2025 }
2026 $self;
2027 }
2028
2029 sub find_ref {
2030 my ($ref_id) = @_;
2031 foreach (command(qw/config -l/)) {
2032 next unless m!^svn-remote\.(.+)\.fetch=
2033 \s*(.*?)\s*:\s*(.+?)\s*$!x;
2034 my ($repo_id, $path, $ref) = ($1, $2, $3);
2035 if ($ref eq $ref_id) {
2036 $path = '' if ($path =~ m#^\./?#);
2037 return ($repo_id, $path);
2038 }
2039 }
2040 (undef, undef, undef);
2041 }
2042
2043 sub new {
2044 my ($class, $ref_id, $repo_id, $path) = @_;
2045 if (defined $ref_id && !defined $repo_id && !defined $path) {
2046 ($repo_id, $path) = find_ref($ref_id);
2047 if (!defined $repo_id) {
2048 die "Could not find a \"svn-remote.*.fetch\" key ",
2049 "in the repository configuration matching: ",
2050 "$ref_id\n";
2051 }
2052 }
2053 my $self = _new($class, $repo_id, $ref_id, $path);
2054 if (!defined $self->{path} || !length $self->{path}) {
2055 my $fetch = command_oneline('config', '--get',
2056 "svn-remote.$repo_id.fetch",
2057 ":$ref_id\$") or
2058 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2059 "\":$ref_id\$\" in config\n";
2060 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2061 }
2062 $self->{path} =~ s{/+}{/}g;
2063 $self->{path} =~ s{\A/}{};
2064 $self->{path} =~ s{/\z}{};
2065 $self->{url} = command_oneline('config', '--get',
2066 "svn-remote.$repo_id.url") or
2067 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2068 $self->rebuild;
2069 $self;
2070 }
2071
2072 sub refname {
2073 my ($refname) = $_[0]->{ref_id} ;
2074
2075 # It cannot end with a slash /, we'll throw up on this because
2076 # SVN can't have directories with a slash in their name, either:
2077 if ($refname =~ m{/$}) {
2078 die "ref: '$refname' ends with a trailing slash, this is ",
2079 "not permitted by git nor Subversion\n";
2080 }
2081
2082 # It cannot have ASCII control character space, tilde ~, caret ^,
2083 # colon :, question-mark ?, asterisk *, space, or open bracket [
2084 # anywhere.
2085 #
2086 # Additionally, % must be escaped because it is used for escaping
2087 # and we want our escaped refname to be reversible
2088 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2089
2090 # no slash-separated component can begin with a dot .
2091 # /.* becomes /%2E*
2092 $refname =~ s{/\.}{/%2E}g;
2093
2094 # It cannot have two consecutive dots .. anywhere
2095 # .. becomes %2E%2E
2096 $refname =~ s{\.\.}{%2E%2E}g;
2097
2098 # trailing dots and .lock are not allowed
2099 # .$ becomes %2E and .lock becomes %2Elock
2100 $refname =~ s{\.(?=$|lock$)}{%2E};
2101
2102 # the sequence @{ is used to access the reflog
2103 # @{ becomes %40{
2104 $refname =~ s{\@\{}{%40\{}g;
2105
2106 return $refname;
2107 }
2108
2109 sub desanitize_refname {
2110 my ($refname) = @_;
2111 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2112 return $refname;
2113 }
2114
2115 sub svm_uuid {
2116 my ($self) = @_;
2117 return $self->{svm}->{uuid} if $self->svm;
2118 $self->ra;
2119 unless ($self->{svm}) {
2120 die "SVM UUID not cached, and reading remotely failed\n";
2121 }
2122 $self->{svm}->{uuid};
2123 }
2124
2125 sub svm {
2126 my ($self) = @_;
2127 return $self->{svm} if $self->{svm};
2128 my $svm;
2129 # see if we have it in our config, first:
2130 eval {
2131 my $section = "svn-remote.$self->{repo_id}";
2132 $svm = {
2133 source => tmp_config('--get', "$section.svm-source"),
2134 uuid => tmp_config('--get', "$section.svm-uuid"),
2135 replace => tmp_config('--get', "$section.svm-replace"),
2136 }
2137 };
2138 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2139 $self->{svm} = $svm;
2140 }
2141 $self->{svm};
2142 }
2143
2144 sub _set_svm_vars {
2145 my ($self, $ra) = @_;
2146 return $ra if $self->svm;
2147
2148 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2149 "(svm:source, svm:uuid) ",
2150 "from the following URLs:\n" );
2151 sub read_svm_props {
2152 my ($self, $ra, $path, $r) = @_;
2153 my $props = ($ra->get_dir($path, $r))[2];
2154 my $src = $props->{'svm:source'};
2155 my $uuid = $props->{'svm:uuid'};
2156 return undef if (!$src || !$uuid);
2157
2158 chomp($src, $uuid);
2159
2160 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2161 or die "doesn't look right - svm:uuid is '$uuid'\n";
2162
2163 # the '!' is used to mark the repos_root!/relative/path
2164 $src =~ s{/?!/?}{/};
2165 $src =~ s{/+$}{}; # no trailing slashes please
2166 # username is of no interest
2167 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2168
2169 my $replace = $ra->{url};
2170 $replace .= "/$path" if length $path;
2171
2172 my $section = "svn-remote.$self->{repo_id}";
2173 tmp_config("$section.svm-source", $src);
2174 tmp_config("$section.svm-replace", $replace);
2175 tmp_config("$section.svm-uuid", $uuid);
2176 $self->{svm} = {
2177 source => $src,
2178 uuid => $uuid,
2179 replace => $replace
2180 };
2181 }
2182
2183 my $r = $ra->get_latest_revnum;
2184 my $path = $self->{path};
2185 my %tried;
2186 while (length $path) {
2187 unless ($tried{"$self->{url}/$path"}) {
2188 return $ra if $self->read_svm_props($ra, $path, $r);
2189 $tried{"$self->{url}/$path"} = 1;
2190 }
2191 $path =~ s#/?[^/]+$##;
2192 }
2193 die "Path: '$path' should be ''\n" if $path ne '';
2194 return $ra if $self->read_svm_props($ra, $path, $r);
2195 $tried{"$self->{url}/$path"} = 1;
2196
2197 if ($ra->{repos_root} eq $self->{url}) {
2198 die @err, (map { " $_\n" } keys %tried), "\n";
2199 }
2200
2201 # nope, make sure we're connected to the repository root:
2202 my $ok;
2203 my @tried_b;
2204 $path = $ra->{svn_path};
2205 $ra = Git::SVN::Ra->new($ra->{repos_root});
2206 while (length $path) {
2207 unless ($tried{"$ra->{url}/$path"}) {
2208 $ok = $self->read_svm_props($ra, $path, $r);
2209 last if $ok;
2210 $tried{"$ra->{url}/$path"} = 1;
2211 }
2212 $path =~ s#/?[^/]+$##;
2213 }
2214 die "Path: '$path' should be ''\n" if $path ne '';
2215 $ok ||= $self->read_svm_props($ra, $path, $r);
2216 $tried{"$ra->{url}/$path"} = 1;
2217 if (!$ok) {
2218 die @err, (map { " $_\n" } keys %tried), "\n";
2219 }
2220 Git::SVN::Ra->new($self->{url});
2221 }
2222
2223 sub svnsync {
2224 my ($self) = @_;
2225 return $self->{svnsync} if $self->{svnsync};
2226
2227 if ($self->no_metadata) {
2228 die "Can't have both 'noMetadata' and ",
2229 "'useSvnsyncProps' options set!\n";
2230 }
2231 if ($self->rewrite_root) {
2232 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2233 "options set!\n";
2234 }
2235 if ($self->rewrite_uuid) {
2236 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
2237 "options set!\n";
2238 }
2239
2240 my $svnsync;
2241 # see if we have it in our config, first:
2242 eval {
2243 my $section = "svn-remote.$self->{repo_id}";
2244
2245 my $url = tmp_config('--get', "$section.svnsync-url");
2246 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2247 die "doesn't look right - svn:sync-from-url is '$url'\n";
2248
2249 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2250 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2251 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2252
2253 $svnsync = { url => $url, uuid => $uuid }
2254 };
2255 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2256 return $self->{svnsync} = $svnsync;
2257 }
2258
2259 my $err = "useSvnsyncProps set, but failed to read " .
2260 "svnsync property: svn:sync-from-";
2261 my $rp = $self->ra->rev_proplist(0);
2262
2263 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2264 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2265 die "doesn't look right - svn:sync-from-url is '$url'\n";
2266
2267 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2268 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2269 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2270
2271 my $section = "svn-remote.$self->{repo_id}";
2272 tmp_config('--add', "$section.svnsync-uuid", $uuid);
2273 tmp_config('--add', "$section.svnsync-url", $url);
2274 return $self->{svnsync} = { url => $url, uuid => $uuid };
2275 }
2276
2277 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2278 # remote lookup (useful for 'git svn log').
2279 sub ra_uuid {
2280 my ($self) = @_;
2281 unless ($self->{ra_uuid}) {
2282 my $key = "svn-remote.$self->{repo_id}.uuid";
2283 my $uuid = eval { tmp_config('--get', $key) };
2284 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2285 $self->{ra_uuid} = $uuid;
2286 } else {
2287 die "ra_uuid called without URL\n" unless $self->{url};
2288 $self->{ra_uuid} = $self->ra->get_uuid;
2289 tmp_config('--add', $key, $self->{ra_uuid});
2290 }
2291 }
2292 $self->{ra_uuid};
2293 }
2294
2295 sub _set_repos_root {
2296 my ($self, $repos_root) = @_;
2297 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2298 $repos_root ||= $self->ra->{repos_root};
2299 tmp_config($k, $repos_root);
2300 $repos_root;
2301 }
2302
2303 sub repos_root {
2304 my ($self) = @_;
2305 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2306 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2307 }
2308
2309 sub ra {
2310 my ($self) = shift;
2311 my $ra = Git::SVN::Ra->new($self->{url});
2312 $self->_set_repos_root($ra->{repos_root});
2313 if ($self->use_svm_props && !$self->{svm}) {
2314 if ($self->no_metadata) {
2315 die "Can't have both 'noMetadata' and ",
2316 "'useSvmProps' options set!\n";
2317 } elsif ($self->use_svnsync_props) {
2318 die "Can't have both 'useSvnsyncProps' and ",
2319 "'useSvmProps' options set!\n";
2320 }
2321 $ra = $self->_set_svm_vars($ra);
2322 $self->{-want_revprops} = 1;
2323 }
2324 $ra;
2325 }
2326
2327 # prop_walk(PATH, REV, SUB)
2328 # -------------------------
2329 # Recursively traverse PATH at revision REV and invoke SUB for each
2330 # directory that contains a SVN property. SUB will be invoked as
2331 # follows: &SUB(gs, path, props); where `gs' is this instance of
2332 # Git::SVN, `path' the path to the directory where the properties
2333 # `props' were found. The `path' will be relative to point of checkout,
2334 # that is, if url://repo/trunk is the current Git branch, and that
2335 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2336 # as `path' (note the trailing `/').
2337 sub prop_walk {
2338 my ($self, $path, $rev, $sub) = @_;
2339
2340 $path =~ s#^/##;
2341 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2342 $path =~ s#^/*#/#g;
2343 my $p = $path;
2344 # Strip the irrelevant part of the path.
2345 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2346 # Ensure the path is terminated by a `/'.
2347 $p =~ s#/*$#/#;
2348
2349 # The properties contain all the internal SVN stuff nobody
2350 # (usually) cares about.
2351 my $interesting_props = 0;
2352 foreach (keys %{$props}) {
2353 # If it doesn't start with `svn:', it must be a
2354 # user-defined property.
2355 ++$interesting_props and next if $_ !~ /^svn:/;
2356 # FIXME: Fragile, if SVN adds new public properties,
2357 # this needs to be updated.
2358 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2359 |eol-style|mime-type
2360 |externals|needs-lock)$/x;
2361 }
2362 &$sub($self, $p, $props) if $interesting_props;
2363
2364 foreach (sort keys %$dirent) {
2365 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2366 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2367 }
2368 }
2369
2370 sub last_rev { ($_[0]->last_rev_commit)[0] }
2371 sub last_commit { ($_[0]->last_rev_commit)[1] }
2372
2373 # returns the newest SVN revision number and newest commit SHA1
2374 sub last_rev_commit {
2375 my ($self) = @_;
2376 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2377 return ($self->{last_rev}, $self->{last_commit});
2378 }
2379 my $c = ::verify_ref($self->refname.'^0');
2380 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2381 my $rev = (::cmt_metadata($c))[1];
2382 if (defined $rev) {
2383 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2384 return ($rev, $c);
2385 }
2386 }
2387 my $map_path = $self->map_path;
2388 unless (-e $map_path) {
2389 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2390 return (undef, undef);
2391 }
2392 my ($rev, $commit) = $self->rev_map_max(1);
2393 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2394 return ($rev, $commit);
2395 }
2396
2397 sub get_fetch_range {
2398 my ($self, $min, $max) = @_;
2399 $max ||= $self->ra->get_latest_revnum;
2400 $min ||= $self->rev_map_max;
2401 (++$min, $max);
2402 }
2403
2404 sub tmp_config {
2405 my (@args) = @_;
2406 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2407 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2408 if (! -f $config && -f $old_def_config) {
2409 rename $old_def_config, $config or
2410 die "Failed rename $old_def_config => $config: $!\n";
2411 }
2412 my $old_config = $ENV{GIT_CONFIG};
2413 $ENV{GIT_CONFIG} = $config;
2414 $@ = undef;
2415 my @ret = eval {
2416 unless (-f $config) {
2417 mkfile($config);
2418 open my $fh, '>', $config or
2419 die "Can't open $config: $!\n";
2420 print $fh "; This file is used internally by ",
2421 "git-svn\n" or die
2422 "Couldn't write to $config: $!\n";
2423 print $fh "; You should not have to edit it\n" or
2424 die "Couldn't write to $config: $!\n";
2425 close $fh or die "Couldn't close $config: $!\n";
2426 }
2427 command('config', @args);
2428 };
2429 my $err = $@;
2430 if (defined $old_config) {
2431 $ENV{GIT_CONFIG} = $old_config;
2432 } else {
2433 delete $ENV{GIT_CONFIG};
2434 }
2435 die $err if $err;
2436 wantarray ? @ret : $ret[0];
2437 }
2438
2439 sub tmp_index_do {
2440 my ($self, $sub) = @_;
2441 my $old_index = $ENV{GIT_INDEX_FILE};
2442 $ENV{GIT_INDEX_FILE} = $self->{index};
2443 $@ = undef;
2444 my @ret = eval {
2445 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2446 mkpath([$dir]) unless -d $dir;
2447 &$sub;
2448 };
2449 my $err = $@;
2450 if (defined $old_index) {
2451 $ENV{GIT_INDEX_FILE} = $old_index;
2452 } else {
2453 delete $ENV{GIT_INDEX_FILE};
2454 }
2455 die $err if $err;
2456 wantarray ? @ret : $ret[0];
2457 }
2458
2459 sub assert_index_clean {
2460 my ($self, $treeish) = @_;
2461
2462 $self->tmp_index_do(sub {
2463 command_noisy('read-tree', $treeish) unless -e $self->{index};
2464 my $x = command_oneline('write-tree');
2465 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2466 /^tree ($::sha1)/mo);
2467 return if $y eq $x;
2468
2469 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2470 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2471 command_noisy('read-tree', $treeish);
2472 $x = command_oneline('write-tree');
2473 if ($y ne $x) {
2474 ::fatal "trees ($treeish) $y != $x\n",
2475 "Something is seriously wrong...";
2476 }
2477 });
2478 }
2479
2480 sub get_commit_parents {
2481 my ($self, $log_entry) = @_;
2482 my (%seen, @ret, @tmp);
2483 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2484 if (my $ip = $self->{inject_parents}) {
2485 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2486 push @tmp, $commit;
2487 }
2488 }
2489 if (my $cur = ::verify_ref($self->refname.'^0')) {
2490 push @tmp, $cur;
2491 }
2492 if (my $ipd = $self->{inject_parents_dcommit}) {
2493 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2494 push @tmp, @$commit;
2495 }
2496 }
2497 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2498 while (my $p = shift @tmp) {
2499 next if $seen{$p};
2500 $seen{$p} = 1;
2501 push @ret, $p;
2502 }
2503 @ret;
2504 }
2505
2506 sub rewrite_root {
2507 my ($self) = @_;
2508 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2509 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2510 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2511 if ($rwr) {
2512 $rwr =~ s#/+$##;
2513 if ($rwr !~ m#^[a-z\+]+://#) {
2514 die "$rwr is not a valid URL (key: $k)\n";
2515 }
2516 }
2517 $self->{-rewrite_root} = $rwr;
2518 }
2519
2520 sub rewrite_uuid {
2521 my ($self) = @_;
2522 return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
2523 my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
2524 my $rwid = eval { command_oneline(qw/config --get/, $k) };
2525 if ($rwid) {
2526 $rwid =~ s#/+$##;
2527 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
2528 die "$rwid is not a valid UUID (key: $k)\n";
2529 }
2530 }
2531 $self->{-rewrite_uuid} = $rwid;
2532 }
2533
2534 sub metadata_url {
2535 my ($self) = @_;
2536 ($self->rewrite_root || $self->{url}) .
2537 (length $self->{path} ? '/' . $self->{path} : '');
2538 }
2539
2540 sub full_url {
2541 my ($self) = @_;
2542 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2543 }
2544
2545
2546 sub set_commit_header_env {
2547 my ($log_entry) = @_;
2548 my %env;
2549 foreach my $ned (qw/NAME EMAIL DATE/) {
2550 foreach my $ac (qw/AUTHOR COMMITTER/) {
2551 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2552 }
2553 }
2554
2555 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2556 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2557 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2558
2559 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2560 ? $log_entry->{commit_name}
2561 : $log_entry->{name};
2562 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2563 ? $log_entry->{commit_email}
2564 : $log_entry->{email};
2565 \%env;
2566 }
2567
2568 sub restore_commit_header_env {
2569 my ($env) = @_;
2570 foreach my $ned (qw/NAME EMAIL DATE/) {
2571 foreach my $ac (qw/AUTHOR COMMITTER/) {
2572 my $k = "GIT_${ac}_${ned}";
2573 if (defined $env->{$k}) {
2574 $ENV{$k} = $env->{$k};
2575 } else {
2576 delete $ENV{$k};
2577 }
2578 }
2579 }
2580 }
2581
2582 sub gc {
2583 command_noisy('gc', '--auto');
2584 };
2585
2586 sub do_git_commit {
2587 my ($self, $log_entry) = @_;
2588 my $lr = $self->last_rev;
2589 if (defined $lr && $lr >= $log_entry->{revision}) {
2590 die "Last fetched revision of ", $self->refname,
2591 " was r$lr, but we are about to fetch: ",
2592 "r$log_entry->{revision}!\n";
2593 }
2594 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2595 croak "$log_entry->{revision} = $c already exists! ",
2596 "Why are we refetching it?\n";
2597 }
2598 my $old_env = set_commit_header_env($log_entry);
2599 my $tree = $log_entry->{tree};
2600 if (!defined $tree) {
2601 $tree = $self->tmp_index_do(sub {
2602 command_oneline('write-tree') });
2603 }
2604 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2605
2606 my @exec = ('git', 'commit-tree', $tree);
2607 foreach ($self->get_commit_parents($log_entry)) {
2608 push @exec, '-p', $_;
2609 }
2610 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2611 or croak $!;
2612 binmode $msg_fh;
2613
2614 # we always get UTF-8 from SVN, but we may want our commits in
2615 # a different encoding.
2616 if (my $enc = Git::config('i18n.commitencoding')) {
2617 require Encode;
2618 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2619 }
2620 print $msg_fh $log_entry->{log} or croak $!;
2621 restore_commit_header_env($old_env);
2622 unless ($self->no_metadata) {
2623 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2624 or croak $!;
2625 }
2626 $msg_fh->flush == 0 or croak $!;
2627 close $msg_fh or croak $!;
2628 chomp(my $commit = do { local $/; <$out_fh> });
2629 close $out_fh or croak $!;
2630 waitpid $pid, 0;
2631 croak $? if $?;
2632 if ($commit !~ /^$::sha1$/o) {
2633 die "Failed to commit, invalid sha1: $commit\n";
2634 }
2635
2636 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2637
2638 $self->{last_rev} = $log_entry->{revision};
2639 $self->{last_commit} = $commit;
2640 print "r$log_entry->{revision}" unless $::_q > 1;
2641 if (defined $log_entry->{svm_revision}) {
2642 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2643 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2644 0, $self->svm_uuid);
2645 }
2646 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2647 if (--$_gc_nr == 0) {
2648 $_gc_nr = $_gc_period;
2649 gc();
2650 }
2651 return $commit;
2652 }
2653
2654 sub match_paths {
2655 my ($self, $paths, $r) = @_;
2656 return 1 if $self->{path} eq '';
2657 if (my $path = $paths->{"/$self->{path}"}) {
2658 return ($path->{action} eq 'D') ? 0 : 1;
2659 }
2660 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2661 if (grep /$self->{path_regex}/, keys %$paths) {
2662 return 1;
2663 }
2664 my $c = '';
2665 foreach (split m#/#, $self->{path}) {
2666 $c .= "/$_";
2667 next unless ($paths->{$c} &&
2668 ($paths->{$c}->{action} =~ /^[AR]$/));
2669 if ($self->ra->check_path($self->{path}, $r) ==
2670 $SVN::Node::dir) {
2671 return 1;
2672 }
2673 }
2674 return 0;
2675 }
2676
2677 sub find_parent_branch {
2678 my ($self, $paths, $rev) = @_;
2679 return undef unless $self->follow_parent;
2680 unless (defined $paths) {
2681 my $err_handler = $SVN::Error::handler;
2682 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2683 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2684 sub { $paths = $_[0] });
2685 $SVN::Error::handler = $err_handler;
2686 }
2687 return undef unless defined $paths;
2688
2689 # look for a parent from another branch:
2690 my @b_path_components = split m#/#, $self->{path};
2691 my @a_path_components;
2692 my $i;
2693 while (@b_path_components) {
2694 $i = $paths->{'/'.join('/', @b_path_components)};
2695 last if $i && defined $i->{copyfrom_path};
2696 unshift(@a_path_components, pop(@b_path_components));
2697 }
2698 return undef unless defined $i && defined $i->{copyfrom_path};
2699 my $branch_from = $i->{copyfrom_path};
2700 if (@a_path_components) {
2701 print STDERR "branch_from: $branch_from => ";
2702 $branch_from .= '/'.join('/', @a_path_components);
2703 print STDERR $branch_from, "\n";
2704 }
2705 my $r = $i->{copyfrom_rev};
2706 my $repos_root = $self->ra->{repos_root};
2707 my $url = $self->ra->{url};
2708 my $new_url = $url . $branch_from;
2709 print STDERR "Found possible branch point: ",
2710 "$new_url => ", $self->full_url, ", $r\n"
2711 unless $::_q > 1;
2712 $branch_from =~ s#^/##;
2713 my $gs = $self->other_gs($new_url, $url,
2714 $branch_from, $r, $self->{ref_id});
2715 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2716 {
2717 my ($base, $head);
2718 if (!defined $r0 || !defined $parent) {
2719 ($base, $head) = parse_revision_argument(0, $r);
2720 } else {
2721 if ($r0 < $r) {
2722 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2723 0, 1, sub { $base = $_[1] - 1 });
2724 }
2725 }
2726 if (defined $base && $base <= $r) {
2727 $gs->fetch($base, $r);
2728 }
2729 ($r0, $parent) = $gs->find_rev_before($r, 1);
2730 }
2731 if (defined $r0 && defined $parent) {
2732 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2733 unless $::_q > 1;
2734 my $ed;
2735 if ($self->ra->can_do_switch) {
2736 $self->assert_index_clean($parent);
2737 print STDERR "Following parent with do_switch\n"
2738 unless $::_q > 1;
2739 # do_switch works with svn/trunk >= r22312, but that
2740 # is not included with SVN 1.4.3 (the latest version
2741 # at the moment), so we can't rely on it
2742 $self->{last_rev} = $r0;
2743 $self->{last_commit} = $parent;
2744 $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2745 $gs->ra->gs_do_switch($r0, $rev, $gs,
2746 $self->full_url, $ed)
2747 or die "SVN connection failed somewhere...\n";
2748 } elsif ($self->ra->trees_match($new_url, $r0,
2749 $self->full_url, $rev)) {
2750 print STDERR "Trees match:\n",
2751 " $new_url\@$r0\n",
2752 " ${\$self->full_url}\@$rev\n",
2753 "Following parent with no changes\n"
2754 unless $::_q > 1;
2755 $self->tmp_index_do(sub {
2756 command_noisy('read-tree', $parent);
2757 });
2758 $self->{last_commit} = $parent;
2759 } else {
2760 print STDERR "Following parent with do_update\n"
2761 unless $::_q > 1;
2762 $ed = SVN::Git::Fetcher->new($self);
2763 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2764 or die "SVN connection failed somewhere...\n";
2765 }
2766 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2767 return $self->make_log_entry($rev, [$parent], $ed);
2768 }
2769 return undef;
2770 }
2771
2772 sub do_fetch {
2773 my ($self, $paths, $rev) = @_;
2774 my $ed;
2775 my ($last_rev, @parents);
2776 if (my $lc = $self->last_commit) {
2777 # we can have a branch that was deleted, then re-added
2778 # under the same name but copied from another path, in
2779 # which case we'll have multiple parents (we don't
2780 # want to break the original ref, nor lose copypath info):
2781 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2782 push @{$log_entry->{parents}}, $lc;
2783 return $log_entry;
2784 }
2785 $ed = SVN::Git::Fetcher->new($self);
2786 $last_rev = $self->{last_rev};
2787 $ed->{c} = $lc;
2788 @parents = ($lc);
2789 } else {
2790 $last_rev = $rev;
2791 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2792 return $log_entry;
2793 }
2794 $ed = SVN::Git::Fetcher->new($self);
2795 }
2796 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2797 die "SVN connection failed somewhere...\n";
2798 }
2799 $self->make_log_entry($rev, \@parents, $ed);
2800 }
2801
2802 sub mkemptydirs {
2803 my ($self, $r) = @_;
2804
2805 sub scan {
2806 my ($r, $empty_dirs, $line) = @_;
2807 if (defined $r && $line =~ /^r(\d+)$/) {
2808 return 0 if $1 > $r;
2809 } elsif ($line =~ /^ \+empty_dir: (.+)$/) {
2810 $empty_dirs->{$1} = 1;
2811 } elsif ($line =~ /^ \-empty_dir: (.+)$/) {
2812 my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2813 delete @$empty_dirs{@d};
2814 }
2815 1; # continue
2816 };
2817
2818 my %empty_dirs = ();
2819 my $gz_file = "$self->{dir}/unhandled.log.gz";
2820 if (-f $gz_file) {
2821 if (!$can_compress) {
2822 warn "Compress::Zlib could not be found; ",
2823 "empty directories in $gz_file will not be read\n";
2824 } else {
2825 my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2826 die "Unable to open $gz_file: $!\n";
2827 my $line;
2828 while ($gz->gzreadline($line) > 0) {
2829 scan($r, \%empty_dirs, $line) or last;
2830 }
2831 $gz->gzclose;
2832 }
2833 }
2834
2835 if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2836 binmode $fh or croak "binmode: $!";
2837 while (<$fh>) {
2838 scan($r, \%empty_dirs, $_) or last;
2839 }
2840 close $fh;
2841 }
2842
2843 my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2844 foreach my $d (sort keys %empty_dirs) {
2845 $d = uri_decode($d);
2846 $d =~ s/$strip//;
2847 next unless length($d);
2848 next if -d $d;
2849 if (-e $d) {
2850 warn "$d exists but is not a directory\n";
2851 } else {
2852 print "creating empty directory: $d\n";
2853 mkpath([$d]);
2854 }
2855 }
2856 }
2857
2858 sub get_untracked {
2859 my ($self, $ed) = @_;
2860 my @out;
2861 my $h = $ed->{empty};
2862 foreach (sort keys %$h) {
2863 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2864 push @out, " $act: " . uri_encode($_);
2865 warn "W: $act: $_\n";
2866 }
2867 foreach my $t (qw/dir_prop file_prop/) {
2868 $h = $ed->{$t} or next;
2869 foreach my $path (sort keys %$h) {
2870 my $ppath = $path eq '' ? '.' : $path;
2871 foreach my $prop (sort keys %{$h->{$path}}) {
2872 next if $SKIP_PROP{$prop};
2873 my $v = $h->{$path}->{$prop};
2874 my $t_ppath_prop = "$t: " .
2875 uri_encode($ppath) . ' ' .
2876 uri_encode($prop);
2877 if (defined $v) {
2878 push @out, " +$t_ppath_prop " .
2879 uri_encode($v);
2880 } else {
2881 push @out, " -$t_ppath_prop";
2882 }
2883 }
2884 }
2885 }
2886 foreach my $t (qw/absent_file absent_directory/) {
2887 $h = $ed->{$t} or next;
2888 foreach my $parent (sort keys %$h) {
2889 foreach my $path (sort @{$h->{$parent}}) {
2890 push @out, " $t: " .
2891 uri_encode("$parent/$path");
2892 warn "W: $t: $parent/$path ",
2893 "Insufficient permissions?\n";
2894 }
2895 }
2896 }
2897 \@out;
2898 }
2899
2900 # parse_svn_date(DATE)
2901 # --------------------
2902 # Given a date (in UTC) from Subversion, return a string in the format
2903 # "<TZ Offset> <local date/time>" that Git will use.
2904 #
2905 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2906 # is true we'll convert it to the local timezone instead.
2907 sub parse_svn_date {
2908 my $date = shift || return '+0000 1970-01-01 00:00:00';
2909 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2910 (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2911 croak "Unable to parse date: $date\n";
2912 my $parsed_date; # Set next.
2913
2914 if ($Git::SVN::_localtime) {
2915 # Translate the Subversion datetime to an epoch time.
2916 # Begin by switching ourselves to $date's timezone, UTC.
2917 my $old_env_TZ = $ENV{TZ};
2918 $ENV{TZ} = 'UTC';
2919
2920 my $epoch_in_UTC =
2921 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2922
2923 # Determine our local timezone (including DST) at the
2924 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
2925 # value of TZ, if any, at the time we were run.
2926 if (defined $Git::SVN::Log::TZ) {
2927 $ENV{TZ} = $Git::SVN::Log::TZ;
2928 } else {
2929 delete $ENV{TZ};
2930 }
2931
2932 my $our_TZ =
2933 POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2934
2935 # This converts $epoch_in_UTC into our local timezone.
2936 my ($sec, $min, $hour, $mday, $mon, $year,
2937 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2938
2939 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2940 $our_TZ, $year + 1900, $mon + 1,
2941 $mday, $hour, $min, $sec);
2942
2943 # Reset us to the timezone in effect when we entered
2944 # this routine.
2945 if (defined $old_env_TZ) {
2946 $ENV{TZ} = $old_env_TZ;
2947 } else {
2948 delete $ENV{TZ};
2949 }
2950 } else {
2951 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2952 }
2953
2954 return $parsed_date;
2955 }
2956
2957 sub other_gs {
2958 my ($self, $new_url, $url,
2959 $branch_from, $r, $old_ref_id) = @_;
2960 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2961 unless ($gs) {
2962 my $ref_id = $old_ref_id;
2963 $ref_id =~ s/\@\d+-*$//;
2964 $ref_id .= "\@$r";
2965 # just grow a tail if we're not unique enough :x
2966 $ref_id .= '-' while find_ref($ref_id);
2967 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2968 if ($u =~ s#^\Q$url\E(/|$)##) {
2969 $p = $u;
2970 $u = $url;
2971 $repo_id = $self->{repo_id};
2972 }
2973 while (1) {
2974 # It is possible to tag two different subdirectories at
2975 # the same revision. If the url for an existing ref
2976 # does not match, we must either find a ref with a
2977 # matching url or create a new ref by growing a tail.
2978 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2979 my (undef, $max_commit) = $gs->rev_map_max(1);
2980 last if (!$max_commit);
2981 my ($url) = ::cmt_metadata($max_commit);
2982 last if ($url eq $gs->full_url);
2983 $ref_id .= '-';
2984 }
2985 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2986 }
2987 $gs
2988 }
2989
2990 sub call_authors_prog {
2991 my ($orig_author) = @_;
2992 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2993 my $author = `$::_authors_prog $orig_author`;
2994 if ($? != 0) {
2995 die "$::_authors_prog failed with exit code $?\n"
2996 }
2997 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2998 my ($name, $email) = ($1, $2);
2999 $email = undef if length $2 == 0;
3000 return [$name, $email];
3001 } else {
3002 die "Author: $orig_author: $::_authors_prog returned "
3003 . "invalid author format: $author\n";
3004 }
3005 }
3006
3007 sub check_author {
3008 my ($author) = @_;
3009 if (!defined $author || length $author == 0) {
3010 $author = '(no author)';
3011 }
3012 if (!defined $::users{$author}) {
3013 if (defined $::_authors_prog) {
3014 $::users{$author} = call_authors_prog($author);
3015 } elsif (defined $::_authors) {
3016 die "Author: $author not defined in $::_authors file\n";
3017 }
3018 }
3019 $author;
3020 }
3021
3022 sub find_extra_svk_parents {
3023 my ($self, $ed, $tickets, $parents) = @_;
3024 # aha! svk:merge property changed...
3025 my @tickets = split "\n", $tickets;
3026 my @known_parents;
3027 for my $ticket ( @tickets ) {
3028 my ($uuid, $path, $rev) = split /:/, $ticket;
3029 if ( $uuid eq $self->ra_uuid ) {
3030 my $url = $self->{url};
3031 my $repos_root = $url;
3032 my $branch_from = $path;
3033 $branch_from =~ s{^/}{};
3034 my $gs = $self->other_gs($repos_root."/".$branch_from,
3035 $url,
3036 $branch_from,
3037 $rev,
3038 $self->{ref_id});
3039 if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
3040 # wahey! we found it, but it might be
3041 # an old one (!)
3042 push @known_parents, [ $rev, $commit ];
3043 }
3044 }
3045 }
3046 # Ordering matters; highest-numbered commit merge tickets
3047 # first, as they may account for later merge ticket additions
3048 # or changes.
3049 @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
3050 for my $parent ( @known_parents ) {
3051 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
3052 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3053 my $new;
3054 while ( <$msg_fh> ) {
3055 $new=1;last;
3056 }
3057 command_close_pipe($msg_fh, $ctx);
3058 if ( $new ) {
3059 print STDERR
3060 "Found merge parent (svk:merge ticket): $parent\n";
3061 push @$parents, $parent;
3062 }
3063 }
3064 }
3065
3066 sub lookup_svn_merge {
3067 my $uuid = shift;
3068 my $url = shift;
3069 my $merge = shift;
3070
3071 my ($source, $revs) = split ":", $merge;
3072 my $path = $source;
3073 $path =~ s{^/}{};
3074 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3075 if ( !$gs ) {
3076 warn "Couldn't find revmap for $url$source\n";
3077 return;
3078 }
3079 my @ranges = split ",", $revs;
3080 my ($tip, $tip_commit);
3081 my @merged_commit_ranges;
3082 # find the tip
3083 for my $range ( @ranges ) {
3084 my ($bottom, $top) = split "-", $range;
3085 $top ||= $bottom;
3086 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
3087 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
3088
3089 unless ($top_commit and $bottom_commit) {
3090 warn "W:unknown path/rev in svn:mergeinfo "
3091 ."dirprop: $source:$range\n";
3092 next;
3093 }
3094
3095 push @merged_commit_ranges,
3096 "$bottom_commit^..$top_commit";
3097
3098 if ( !defined $tip or $top > $tip ) {
3099 $tip = $top;
3100 $tip_commit = $top_commit;
3101 }
3102 }
3103 return ($tip_commit, @merged_commit_ranges);
3104 }
3105
3106 sub _rev_list {
3107 my ($msg_fh, $ctx) = command_output_pipe(
3108 "rev-list", @_,
3109 );
3110 my @rv;
3111 while ( <$msg_fh> ) {
3112 chomp;
3113 push @rv, $_;
3114 }
3115 command_close_pipe($msg_fh, $ctx);
3116 @rv;
3117 }
3118
3119 sub check_cherry_pick {
3120 my $base = shift;
3121 my $tip = shift;
3122 my @ranges = @_;
3123 my %commits = map { $_ => 1 }
3124 _rev_list("--no-merges", $tip, "--not", $base);
3125 for my $range ( @ranges ) {
3126 delete @commits{_rev_list($range)};
3127 }
3128 for my $commit (keys %commits) {
3129 if (has_no_changes($commit)) {
3130 delete $commits{$commit};
3131 }
3132 }
3133 return (keys %commits);
3134 }
3135
3136 sub has_no_changes {
3137 my $commit = shift;
3138
3139 my @revs = split / /, command_oneline(
3140 qw(rev-list --parents -1 -m), $commit);
3141
3142 # Commits with no parents, e.g. the start of a partial branch,
3143 # have changes by definition.
3144 return 1 if (@revs < 2);
3145
3146 # Commits with multiple parents, e.g a merge, have no changes
3147 # by definition.
3148 return 0 if (@revs > 2);
3149
3150 return (command_oneline("rev-parse", "$commit^{tree}") eq
3151 command_oneline("rev-parse", "$commit~1^{tree}"));
3152 }
3153
3154 # The GIT_DIR environment variable is not always set until after the command
3155 # line arguments are processed, so we can't memoize in a BEGIN block.
3156 {
3157 my $memoized = 0;
3158
3159 sub memoize_svn_mergeinfo_functions {
3160 return if $memoized;
3161 $memoized = 1;
3162
3163 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
3164 mkpath([$cache_path]) unless -d $cache_path;
3165
3166 tie my %lookup_svn_merge_cache => 'Memoize::Storable',
3167 "$cache_path/lookup_svn_merge.db", 'nstore';
3168 memoize 'lookup_svn_merge',
3169 SCALAR_CACHE => 'FAULT',
3170 LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
3171 ;
3172
3173 tie my %check_cherry_pick_cache => 'Memoize::Storable',
3174 "$cache_path/check_cherry_pick.db", 'nstore';
3175 memoize 'check_cherry_pick',
3176 SCALAR_CACHE => 'FAULT',
3177 LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
3178 ;
3179
3180 tie my %has_no_changes_cache => 'Memoize::Storable',
3181 "$cache_path/has_no_changes.db", 'nstore';
3182 memoize 'has_no_changes',
3183 SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
3184 LIST_CACHE => 'FAULT',
3185 ;
3186 }
3187
3188 sub unmemoize_svn_mergeinfo_functions {
3189 return if not $memoized;
3190 $memoized = 0;
3191
3192 Memoize::unmemoize 'lookup_svn_merge';
3193 Memoize::unmemoize 'check_cherry_pick';
3194 Memoize::unmemoize 'has_no_changes';
3195 }
3196 }
3197
3198 END {
3199 # Force cache writeout explicitly instead of waiting for
3200 # global destruction to avoid segfault in Storable:
3201 # http://rt.cpan.org/Public/Bug/Display.html?id=36087
3202 unmemoize_svn_mergeinfo_functions();
3203 }
3204
3205 sub parents_exclude {
3206 my $parents = shift;
3207 my @commits = @_;
3208 return unless @commits;
3209
3210 my @excluded;
3211 my $excluded;
3212 do {
3213 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
3214 $excluded = command_oneline(@cmd);
3215 if ( $excluded ) {
3216 my @new;
3217 my $found;
3218 for my $commit ( @commits ) {
3219 if ( $commit eq $excluded ) {
3220 push @excluded, $commit;
3221 $found++;
3222 last;
3223 }
3224 else {
3225 push @new, $commit;
3226 }
3227 }
3228 die "saw commit '$excluded' in rev-list output, "
3229 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
3230 unless $found;
3231 @commits = @new;
3232 }
3233 }
3234 while ($excluded and @commits);
3235
3236 return @excluded;
3237 }
3238
3239
3240 # note: this function should only be called if the various dirprops
3241 # have actually changed
3242 sub find_extra_svn_parents {
3243 my ($self, $ed, $mergeinfo, $parents) = @_;
3244 # aha! svk:merge property changed...
3245
3246 memoize_svn_mergeinfo_functions();
3247
3248 # We first search for merged tips which are not in our
3249 # history. Then, we figure out which git revisions are in
3250 # that tip, but not this revision. If all of those revisions
3251 # are now marked as merge, we can add the tip as a parent.
3252 my @merges = split "\n", $mergeinfo;
3253 my @merge_tips;
3254 my $url = $self->{url};
3255 my $uuid = $self->ra_uuid;
3256 my %ranges;
3257 for my $merge ( @merges ) {
3258 my ($tip_commit, @ranges) =
3259 lookup_svn_merge( $uuid, $url, $merge );
3260 unless (!$tip_commit or
3261 grep { $_ eq $tip_commit } @$parents ) {
3262 push @merge_tips, $tip_commit;
3263 $ranges{$tip_commit} = \@ranges;
3264 } else {
3265 push @merge_tips, undef;
3266 }
3267 }
3268
3269 my %excluded = map { $_ => 1 }
3270 parents_exclude($parents, grep { defined } @merge_tips);
3271
3272 # check merge tips for new parents
3273 my @new_parents;
3274 for my $merge_tip ( @merge_tips ) {
3275 my $spec = shift @merges;
3276 next unless $merge_tip and $excluded{$merge_tip};
3277
3278 my $ranges = $ranges{$merge_tip};
3279
3280 # check out 'new' tips
3281 my $merge_base;
3282 eval {
3283 $merge_base = command_oneline(
3284 "merge-base",
3285 @$parents, $merge_tip,
3286 );
3287 };
3288 if ($@) {
3289 die "An error occurred during merge-base"
3290 unless $@->isa("Git::Error::Command");
3291
3292 warn "W: Cannot find common ancestor between ".
3293 "@$parents and $merge_tip. Ignoring merge info.\n";
3294 next;
3295 }
3296
3297 # double check that there are no missing non-merge commits
3298 my (@incomplete) = check_cherry_pick(
3299 $merge_base, $merge_tip,
3300 @$ranges,
3301 );
3302
3303 if ( @incomplete ) {
3304 warn "W:svn cherry-pick ignored ($spec) - missing "
3305 .@incomplete." commit(s) (eg $incomplete[0])\n";
3306 } else {
3307 warn
3308 "Found merge parent (svn:mergeinfo prop): ",
3309 $merge_tip, "\n";
3310 push @new_parents, $merge_tip;
3311 }
3312 }
3313
3314 # cater for merges which merge commits from multiple branches
3315 if ( @new_parents > 1 ) {
3316 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
3317 for ( my $j = 0; $j <= $#new_parents; $j++ ) {
3318 next if $i == $j;
3319 next unless $new_parents[$i];
3320 next unless $new_parents[$j];
3321 my $revs = command_oneline(
3322 "rev-list", "-1",
3323 "$new_parents[$i]..$new_parents[$j]",
3324 );
3325 if ( !$revs ) {
3326 undef($new_parents[$j]);
3327 }
3328 }
3329 }
3330 }
3331 push @$parents, grep { defined } @new_parents;
3332 }
3333
3334 sub make_log_entry {
3335 my ($self, $rev, $parents, $ed) = @_;
3336 my $untracked = $self->get_untracked($ed);
3337
3338 my @parents = @$parents;
3339 my $ps = $ed->{path_strip} || "";
3340 for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3341 my $props = $ed->{dir_prop}{$path};
3342 if ( $props->{"svk:merge"} ) {
3343 $self->find_extra_svk_parents
3344 ($ed, $props->{"svk:merge"}, \@parents);
3345 }
3346 if ( $props->{"svn:mergeinfo"} ) {
3347 $self->find_extra_svn_parents
3348 ($ed,
3349 $props->{"svn:mergeinfo"},
3350 \@parents);
3351 }
3352 }
3353
3354 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3355 print $un "r$rev\n" or croak $!;
3356 print $un $_, "\n" foreach @$untracked;
3357 my %log_entry = ( parents => \@parents, revision => $rev,
3358 log => '');
3359
3360 my $headrev;
3361 my $logged = delete $self->{logged_rev_props};
3362 if (!$logged || $self->{-want_revprops}) {
3363 my $rp = $self->ra->rev_proplist($rev);
3364 foreach (sort keys %$rp) {
3365 my $v = $rp->{$_};
3366 if (/^svn:(author|date|log)$/) {
3367 $log_entry{$1} = $v;
3368 } elsif ($_ eq 'svm:headrev') {
3369 $headrev = $v;
3370 } else {
3371 print $un " rev_prop: ", uri_encode($_), ' ',
3372 uri_encode($v), "\n";
3373 }
3374 }
3375 } else {
3376 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3377 }
3378 close $un or croak $!;
3379
3380 $log_entry{date} = parse_svn_date($log_entry{date});
3381 $log_entry{log} .= "\n";
3382 my $author = $log_entry{author} = check_author($log_entry{author});
3383 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3384 : ($author, undef);
3385
3386 my ($commit_name, $commit_email) = ($name, $email);
3387 if ($_use_log_author) {
3388 my $name_field;
3389 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3390 $name_field = $1;
3391 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3392 $name_field = $1;
3393 }
3394 if (!defined $name_field) {
3395 if (!defined $email) {
3396 $email = $name;
3397 }
3398 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3399 ($name, $email) = ($1, $2);
3400 } elsif ($name_field =~ /(.*)@/) {
3401 ($name, $email) = ($1, $name_field);
3402 } else {
3403 ($name, $email) = ($name_field, $name_field);
3404 }
3405 }
3406 if (defined $headrev && $self->use_svm_props) {
3407 if ($self->rewrite_root) {
3408 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3409 "options set!\n";
3410 }
3411 if ($self->rewrite_uuid) {
3412 die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
3413 "options set!\n";
3414 }
3415 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3416 # we don't want "SVM: initializing mirror for junk" ...
3417 return undef if $r == 0;
3418 my $svm = $self->svm;
3419 if ($uuid ne $svm->{uuid}) {
3420 die "UUID mismatch on SVM path:\n",
3421 "expected: $svm->{uuid}\n",
3422 " got: $uuid\n";
3423 }
3424 my $full_url = $self->full_url;
3425 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3426 die "Failed to replace '$svm->{replace}' with ",
3427 "'$svm->{source}' in $full_url\n";
3428 # throw away username for storing in records
3429 remove_username($full_url);
3430 $log_entry{metadata} = "$full_url\@$r $uuid";
3431 $log_entry{svm_revision} = $r;
3432 $email ||= "$author\@$uuid";
3433 $commit_email ||= "$author\@$uuid";
3434 } elsif ($self->use_svnsync_props) {
3435 my $full_url = $self->svnsync->{url};
3436 $full_url .= "/$self->{path}" if length $self->{path};
3437 remove_username($full_url);
3438 my $uuid = $self->svnsync->{uuid};
3439 $log_entry{metadata} = "$full_url\@$rev $uuid";
3440 $email ||= "$author\@$uuid";
3441 $commit_email ||= "$author\@$uuid";
3442 } else {
3443 my $url = $self->metadata_url;
3444 remove_username($url);
3445 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
3446 $log_entry{metadata} = "$url\@$rev " . $uuid;
3447 $email ||= "$author\@" . $uuid;
3448 $commit_email ||= "$author\@" . $uuid;
3449 }
3450 $log_entry{name} = $name;
3451 $log_entry{email} = $email;
3452 $log_entry{commit_name} = $commit_name;
3453 $log_entry{commit_email} = $commit_email;
3454 \%log_entry;
3455 }
3456
3457 sub fetch {
3458 my ($self, $min_rev, $max_rev, @parents) = @_;
3459 my ($last_rev, $last_commit) = $self->last_rev_commit;
3460 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3461 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3462 }
3463
3464 sub set_tree_cb {
3465 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3466 $self->{inject_parents} = { $rev => $tree };
3467 $self->fetch(undef, undef);
3468 }
3469
3470 sub set_tree {
3471 my ($self, $tree) = (shift, shift);
3472 my $log_entry = ::get_commit_entry($tree);
3473 unless ($self->{last_rev}) {
3474 ::fatal("Must have an existing revision to commit");
3475 }
3476 my %ed_opts = ( r => $self->{last_rev},
3477 log => $log_entry->{log},
3478 ra => $self->ra,
3479 tree_a => $self->{last_commit},
3480 tree_b => $tree,
3481 editor_cb => sub {
3482 $self->set_tree_cb($log_entry, $tree, @_) },
3483 svn_path => $self->{path} );
3484 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3485 print "No changes\nr$self->{last_rev} = $tree\n";
3486 }
3487 }
3488
3489 sub rebuild_from_rev_db {
3490 my ($self, $path) = @_;
3491 my $r = -1;
3492 open my $fh, '<', $path or croak "open: $!";
3493 binmode $fh or croak "binmode: $!";
3494 while (<$fh>) {
3495 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3496 chomp($_);
3497 ++$r;
3498 next if $_ eq ('0' x 40);
3499 $self->rev_map_set($r, $_);
3500 print "r$r = $_\n";
3501 }
3502 close $fh or croak "close: $!";
3503 unlink $path or croak "unlink: $!";
3504 }
3505
3506 sub rebuild {
3507 my ($self) = @_;
3508 my $map_path = $self->map_path;
3509 my $partial = (-e $map_path && ! -z $map_path);
3510 return unless ::verify_ref($self->refname.'^0');
3511 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3512 my $rev_db = $self->rev_db_path;
3513 $self->rebuild_from_rev_db($rev_db);
3514 if ($self->use_svm_props) {
3515 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3516 $self->rebuild_from_rev_db($svm_rev_db);
3517 }
3518 $self->unlink_rev_db_symlink;
3519 return;
3520 }
3521 print "Rebuilding $map_path ...\n" if (!$partial);
3522 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3523 (undef, undef));
3524 my ($log, $ctx) =
3525 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3526 ($head ? "$head.." : "") . $self->refname,
3527 '--');
3528 my $metadata_url = $self->metadata_url;
3529 remove_username($metadata_url);
3530 my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
3531 my $c;
3532 while (<$log>) {
3533 if ( m{^commit ($::sha1)$} ) {
3534 $c = $1;
3535 next;
3536 }
3537 next unless s{^\s*(git-svn-id:)}{$1};
3538 my ($url, $rev, $uuid) = ::extract_metadata($_);
3539 remove_username($url);
3540
3541 # ignore merges (from set-tree)
3542 next if (!defined $rev || !$uuid);
3543
3544 # if we merged or otherwise started elsewhere, this is
3545 # how we break out of it
3546 if (($uuid ne $svn_uuid) ||
3547 ($metadata_url && $url && ($url ne $metadata_url))) {
3548 next;
3549 }
3550 if ($partial && $head) {
3551 print "Partial-rebuilding $map_path ...\n";
3552 print "Currently at $base_rev = $head\n";
3553 $head = undef;
3554 }
3555
3556 $self->rev_map_set($rev, $c);
3557 print "r$rev = $c\n";
3558 }
3559 command_close_pipe($log, $ctx);
3560 print "Done rebuilding $map_path\n" if (!$partial || !$head);
3561 my $rev_db_path = $self->rev_db_path;
3562 if (-f $self->rev_db_path) {
3563 unlink $self->rev_db_path or croak "unlink: $!";
3564 }
3565 $self->unlink_rev_db_symlink;
3566 }
3567
3568 # rev_map:
3569 # Tie::File seems to be prone to offset errors if revisions get sparse,
3570 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3571 # one of my favorite modules is out :< Next up would be one of the DBM
3572 # modules, but I'm not sure which is most portable...
3573 #
3574 # This is the replacement for the rev_db format, which was too big
3575 # and inefficient for large repositories with a lot of sparse history
3576 # (mainly tags)
3577 #
3578 # The format is this:
3579 # - 24 bytes for every record,
3580 # * 4 bytes for the integer representing an SVN revision number
3581 # * 20 bytes representing the sha1 of a git commit
3582 # - No empty padding records like the old format
3583 # (except the last record, which can be overwritten)
3584 # - new records are written append-only since SVN revision numbers
3585 # increase monotonically
3586 # - lookups on SVN revision number are done via a binary search
3587 # - Piping the file to xxd -c24 is a good way of dumping it for
3588 # viewing or editing (piped back through xxd -r), should the need
3589 # ever arise.
3590 # - The last record can be padding revision with an all-zero sha1
3591 # This is used to optimize fetch performance when using multiple
3592 # "fetch" directives in .git/config
3593 #
3594 # These files are disposable unless noMetadata or useSvmProps is set
3595
3596 sub _rev_map_set {
3597 my ($fh, $rev, $commit) = @_;
3598
3599 binmode $fh or croak "binmode: $!";
3600 my $size = (stat($fh))[7];
3601 ($size % 24) == 0 or croak "inconsistent size: $size";
3602
3603 my $wr_offset = 0;
3604 if ($size > 0) {
3605 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3606 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3607 $read == 24 or croak "read only $read bytes (!= 24)";
3608 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3609 if ($last_commit eq ('0' x40)) {
3610 if ($size >= 48) {
3611 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3612 $read = sysread($fh, $buf, 24) or
3613 croak "read: $!";
3614 $read == 24 or
3615 croak "read only $read bytes (!= 24)";
3616 ($last_rev, $last_commit) =
3617 unpack(rev_map_fmt, $buf);
3618 if ($last_commit eq ('0' x40)) {
3619 croak "inconsistent .rev_map\n";
3620 }
3621 }
3622 if ($last_rev >= $rev) {
3623 croak "last_rev is higher!: $last_rev >= $rev";
3624 }
3625 $wr_offset = -24;
3626 }
3627 }
3628 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3629 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3630 croak "write: $!";
3631 }
3632
3633 sub _rev_map_reset {
3634 my ($fh, $rev, $commit) = @_;
3635 my $c = _rev_map_get($fh, $rev);
3636 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3637 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3638 truncate $fh, $offset or croak "truncate: $!";
3639 }
3640
3641 sub mkfile {
3642 my ($path) = @_;
3643 unless (-e $path) {
3644 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3645 mkpath([$dir]) unless -d $dir;
3646 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3647 close $fh or die "Couldn't close (create) $path: $!\n";
3648 }
3649 }
3650
3651 sub rev_map_set {
3652 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3653 defined $commit or die "missing arg3\n";
3654 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3655 my $db = $self->map_path($uuid);
3656 my $db_lock = "$db.lock";
3657 my $sig;
3658 $update_ref ||= 0;
3659 if ($update_ref) {
3660 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3661 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3662 }
3663 mkfile($db);
3664
3665 $LOCKFILES{$db_lock} = 1;
3666 my $sync;
3667 # both of these options make our .rev_db file very, very important
3668 # and we can't afford to lose it because rebuild() won't work
3669 if ($self->use_svm_props || $self->no_metadata) {
3670 $sync = 1;
3671 copy($db, $db_lock) or die "rev_map_set(@_): ",
3672 "Failed to copy: ",
3673 "$db => $db_lock ($!)\n";
3674 } else {
3675 rename $db, $db_lock or die "rev_map_set(@_): ",
3676 "Failed to rename: ",
3677 "$db => $db_lock ($!)\n";
3678 }
3679
3680 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3681 or croak "Couldn't open $db_lock: $!\n";
3682 $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3683 _rev_map_set($fh, $rev, $commit);
3684 if ($sync) {
3685 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3686 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3687 }
3688 close $fh or croak $!;
3689 if ($update_ref) {
3690 $_head = $self;
3691 my $note = "";
3692 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3693 command_noisy('update-ref', '-m', "r$rev$note",
3694 $self->refname, $commit);
3695 }
3696 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3697 "$db_lock => $db ($!)\n";
3698 delete $LOCKFILES{$db_lock};
3699 if ($update_ref) {
3700 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3701 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3702 kill $sig, $$ if defined $sig;
3703 }
3704 }
3705
3706 # If want_commit, this will return an array of (rev, commit) where
3707 # commit _must_ be a valid commit in the archive.
3708 # Otherwise, it'll return the max revision (whether or not the
3709 # commit is valid or just a 0x40 placeholder).
3710 sub rev_map_max {
3711 my ($self, $want_commit) = @_;
3712 $self->rebuild;
3713 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3714 $want_commit ? ($r, $c) : $r;
3715 }
3716
3717 sub rev_map_max_norebuild {
3718 my ($self, $want_commit) = @_;
3719 my $map_path = $self->map_path;
3720 stat $map_path or return $want_commit ? (0, undef) : 0;
3721 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3722 binmode $fh or croak "binmode: $!";
3723 my $size = (stat($fh))[7];
3724 ($size % 24) == 0 or croak "inconsistent size: $size";
3725
3726 if ($size == 0) {
3727 close $fh or croak "close: $!";
3728 return $want_commit ? (0, undef) : 0;
3729 }
3730
3731 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3732 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3733 my ($r, $c) = unpack(rev_map_fmt, $buf);
3734 if ($want_commit && $c eq ('0' x40)) {
3735 if ($size < 48) {
3736 return $want_commit ? (0, undef) : 0;
3737 }
3738 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3739 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3740 ($r, $c) = unpack(rev_map_fmt, $buf);
3741 if ($c eq ('0'x40)) {
3742 croak "Penultimate record is all-zeroes in $map_path";
3743 }
3744 }
3745 close $fh or croak "close: $!";
3746 $want_commit ? ($r, $c) : $r;
3747 }
3748
3749 sub rev_map_get {
3750 my ($self, $rev, $uuid) = @_;
3751 my $map_path = $self->map_path($uuid);
3752 return undef unless -e $map_path;
3753
3754 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3755 my $c = _rev_map_get($fh, $rev);
3756 close($fh) or croak "close: $!";
3757 $c
3758 }
3759
3760 sub _rev_map_get {
3761 my ($fh, $rev) = @_;
3762
3763 binmode $fh or croak "binmode: $!";
3764 my $size = (stat($fh))[7];
3765 ($size % 24) == 0 or croak "inconsistent size: $size";
3766
3767 if ($size == 0) {
3768 return undef;
3769 }
3770
3771 my ($l, $u) = (0, $size - 24);
3772 my ($r, $c, $buf);
3773
3774 while ($l <= $u) {
3775 my $i = int(($l/24 + $u/24) / 2) * 24;
3776 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3777 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3778 my ($r, $c) = unpack(rev_map_fmt, $buf);
3779
3780 if ($r < $rev) {
3781 $l = $i + 24;
3782 } elsif ($r > $rev) {
3783 $u = $i - 24;
3784 } else { # $r == $rev
3785 return $c eq ('0' x 40) ? undef : $c;
3786 }
3787 }
3788 undef;
3789 }
3790
3791 # Finds the first svn revision that exists on (if $eq_ok is true) or
3792 # before $rev for the current branch. It will not search any lower
3793 # than $min_rev. Returns the git commit hash and svn revision number
3794 # if found, else (undef, undef).
3795 sub find_rev_before {
3796 my ($self, $rev, $eq_ok, $min_rev) = @_;
3797 --$rev unless $eq_ok;
3798 $min_rev ||= 1;
3799 my $max_rev = $self->rev_map_max;
3800 $rev = $max_rev if ($rev > $max_rev);
3801 while ($rev >= $min_rev) {
3802 if (my $c = $self->rev_map_get($rev)) {
3803 return ($rev, $c);
3804 }
3805 --$rev;
3806 }
3807 return (undef, undef);
3808 }
3809
3810 # Finds the first svn revision that exists on (if $eq_ok is true) or
3811 # after $rev for the current branch. It will not search any higher
3812 # than $max_rev. Returns the git commit hash and svn revision number
3813 # if found, else (undef, undef).
3814 sub find_rev_after {
3815 my ($self, $rev, $eq_ok, $max_rev) = @_;
3816 ++$rev unless $eq_ok;
3817 $max_rev ||= $self->rev_map_max;
3818 while ($rev <= $max_rev) {
3819 if (my $c = $self->rev_map_get($rev)) {
3820 return ($rev, $c);
3821 }
3822 ++$rev;
3823 }
3824 return (undef, undef);
3825 }
3826
3827 sub _new {
3828 my ($class, $repo_id, $ref_id, $path) = @_;
3829 unless (defined $repo_id && length $repo_id) {
3830 $repo_id = $Git::SVN::default_repo_id;
3831 }
3832 unless (defined $ref_id && length $ref_id) {
3833 $_prefix = '' unless defined($_prefix);
3834 $_[2] = $ref_id =
3835 "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3836 }
3837 $_[1] = $repo_id;
3838 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3839
3840 # Older repos imported by us used $GIT_DIR/svn/foo instead of
3841 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3842 if ($ref_id =~ m{^refs/remotes/(.*)}) {
3843 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3844 if (-d $old_dir && ! -d $dir) {
3845 $dir = $old_dir;
3846 }
3847 }
3848
3849 $_[3] = $path = '' unless (defined $path);
3850 mkpath([$dir]);
3851 bless {
3852 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3853 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3854 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3855 }
3856
3857 # for read-only access of old .rev_db formats
3858 sub unlink_rev_db_symlink {
3859 my ($self) = @_;
3860 my $link = $self->rev_db_path;
3861 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3862 if (-l $link) {
3863 unlink $link or croak "unlink: $link failed!";
3864 }
3865 }
3866
3867 sub rev_db_path {
3868 my ($self, $uuid) = @_;
3869 my $db_path = $self->map_path($uuid);
3870 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3871 or croak "map_path: $db_path does not contain '/.rev_map.' !";
3872 $db_path;
3873 }
3874
3875 # the new replacement for .rev_db
3876 sub map_path {
3877 my ($self, $uuid) = @_;
3878 $uuid ||= $self->ra_uuid;
3879 "$self->{map_root}.$uuid";
3880 }
3881
3882 sub uri_encode {
3883 my ($f) = @_;
3884 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3885 $f
3886 }
3887
3888 sub uri_decode {
3889 my ($f) = @_;
3890 $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3891 $f
3892 }
3893
3894 sub remove_username {
3895 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3896 }
3897
3898 package Git::SVN::Prompt;
3899 use strict;
3900 use warnings;
3901 require SVN::Core;
3902 use vars qw/$_no_auth_cache $_username/;
3903
3904 sub simple {
3905 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3906 $may_save = undef if $_no_auth_cache;
3907 $default_username = $_username if defined $_username;
3908 if (defined $default_username && length $default_username) {
3909 if (defined $realm && length $realm) {
3910 print STDERR "Authentication realm: $realm\n";
3911 STDERR->flush;
3912 }
3913 $cred->username($default_username);
3914 } else {
3915 username($cred, $realm, $may_save, $pool);
3916 }
3917 $cred->password(_read_password("Password for '" .
3918 $cred->username . "': ", $realm));
3919 $cred->may_save($may_save);
3920 $SVN::_Core::SVN_NO_ERROR;
3921 }
3922
3923 sub ssl_server_trust {
3924 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3925 $may_save = undef if $_no_auth_cache;
3926 print STDERR "Error validating server certificate for '$realm':\n";
3927 {
3928 no warnings 'once';
3929 # All variables SVN::Auth::SSL::* are used only once,
3930 # so we're shutting up Perl warnings about this.
3931 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3932 print STDERR " - The certificate is not issued ",
3933 "by a trusted authority. Use the\n",
3934 " fingerprint to validate ",
3935 "the certificate manually!\n";
3936 }
3937 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3938 print STDERR " - The certificate hostname ",
3939 "does not match.\n";
3940 }
3941 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3942 print STDERR " - The certificate is not yet valid.\n";
3943 }
3944 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3945 print STDERR " - The certificate has expired.\n";
3946 }
3947 if ($failures & $SVN::Auth::SSL::OTHER) {
3948 print STDERR " - The certificate has ",
3949 "an unknown error.\n";
3950 }
3951 } # no warnings 'once'
3952 printf STDERR
3953 "Certificate information:\n".
3954 " - Hostname: %s\n".
3955 " - Valid: from %s until %s\n".
3956 " - Issuer: %s\n".
3957 " - Fingerprint: %s\n",
3958 map $cert_info->$_, qw(hostname valid_from valid_until
3959 issuer_dname fingerprint);
3960 my $choice;
3961 prompt:
3962 print STDERR $may_save ?
3963 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3964 "(R)eject or accept (t)emporarily? ";
3965 STDERR->flush;
3966 $choice = lc(substr(<STDIN> || 'R', 0, 1));
3967 if ($choice =~ /^t$/i) {
3968 $cred->may_save(undef);
3969 } elsif ($choice =~ /^r$/i) {
3970 return -1;
3971 } elsif ($may_save && $choice =~ /^p$/i) {
3972 $cred->may_save($may_save);
3973 } else {
3974 goto prompt;
3975 }
3976 $cred->accepted_failures($failures);
3977 $SVN::_Core::SVN_NO_ERROR;
3978 }
3979
3980 sub ssl_client_cert {
3981 my ($cred, $realm, $may_save, $pool) = @_;
3982 $may_save = undef if $_no_auth_cache;
3983 print STDERR "Client certificate filename: ";
3984 STDERR->flush;
3985 chomp(my $filename = <STDIN>);
3986 $cred->cert_file($filename);
3987 $cred->may_save($may_save);
3988 $SVN::_Core::SVN_NO_ERROR;
3989 }
3990
3991 sub ssl_client_cert_pw {
3992 my ($cred, $realm, $may_save, $pool) = @_;
3993 $may_save = undef if $_no_auth_cache;
3994 $cred->password(_read_password("Password: ", $realm));
3995 $cred->may_save($may_save);
3996 $SVN::_Core::SVN_NO_ERROR;
3997 }
3998
3999 sub username {
4000 my ($cred, $realm, $may_save, $pool) = @_;
4001 $may_save = undef if $_no_auth_cache;
4002 if (defined $realm && length $realm) {
4003 print STDERR "Authentication realm: $realm\n";
4004 }
4005 my $username;
4006 if (defined $_username) {
4007 $username = $_username;
4008 } else {
4009 print STDERR "Username: ";
4010 STDERR->flush;
4011 chomp($username = <STDIN>);
4012 }
4013 $cred->username($username);
4014 $cred->may_save($may_save);
4015 $SVN::_Core::SVN_NO_ERROR;
4016 }
4017
4018 sub _read_password {
4019 my ($prompt, $realm) = @_;
4020 my $password = '';
4021 if (exists $ENV{GIT_ASKPASS}) {
4022 open(PH, "-|", $ENV{GIT_ASKPASS}, $prompt);
4023 $password = <PH>;
4024 $password =~ s/[\012\015]//; # \n\r
4025 close(PH);
4026 } else {
4027 print STDERR $prompt;
4028 STDERR->flush;
4029 require Term::ReadKey;
4030 Term::ReadKey::ReadMode('noecho');
4031 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
4032 last if $key =~ /[\012\015]/; # \n\r
4033 $password .= $key;
4034 }
4035 Term::ReadKey::ReadMode('restore');
4036 print STDERR "\n";
4037 STDERR->flush;
4038 }
4039 $password;
4040 }
4041
4042 package SVN::Git::Fetcher;
4043 use vars qw/@ISA/;
4044 use strict;
4045 use warnings;
4046 use Carp qw/croak/;
4047 use IO::File qw//;
4048 use vars qw/$_ignore_regex/;
4049
4050 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
4051 sub new {
4052 my ($class, $git_svn, $switch_path) = @_;
4053 my $self = SVN::Delta::Editor->new;
4054 bless $self, $class;
4055 if (exists $git_svn->{last_commit}) {
4056 $self->{c} = $git_svn->{last_commit};
4057 $self->{empty_symlinks} =
4058 _mark_empty_symlinks($git_svn, $switch_path);
4059 }
4060 $self->{ignore_regex} = eval { command_oneline('config', '--get',
4061 "svn-remote.$git_svn->{repo_id}.ignore-paths") };
4062 $self->{empty} = {};
4063 $self->{dir_prop} = {};
4064 $self->{file_prop} = {};
4065 $self->{absent_dir} = {};
4066 $self->{absent_file} = {};
4067 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
4068 $self->{pathnameencoding} = Git::config('svn.pathnameencoding');
4069 $self;
4070 }
4071
4072 # this uses the Ra object, so it must be called before do_{switch,update},
4073 # not inside them (when the Git::SVN::Fetcher object is passed) to
4074 # do_{switch,update}
4075 sub _mark_empty_symlinks {
4076 my ($git_svn, $switch_path) = @_;
4077 my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
4078 return {} if (!defined($bool)) || (defined($bool) && ! $bool);
4079
4080 my %ret;
4081 my ($rev, $cmt) = $git_svn->last_rev_commit;
4082 return {} unless ($rev && $cmt);
4083
4084 # allow the warning to be printed for each revision we fetch to
4085 # ensure the user sees it. The user can also disable the workaround
4086 # on the repository even while git svn is running and the next
4087 # revision fetched will skip this expensive function.
4088 my $printed_warning;
4089 chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
4090 my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
4091 local $/ = "\0";
4092 my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
4093 $pfx .= '/' if length($pfx);
4094 while (<$ls>) {
4095 chomp;
4096 s/\A100644 blob $empty_blob\t//o or next;
4097 unless ($printed_warning) {
4098 print STDERR "Scanning for empty symlinks, ",
4099 "this may take a while if you have ",
4100 "many empty files\n",
4101 "You may disable this with `",
4102 "git config svn.brokenSymlinkWorkaround ",
4103 "false'.\n",
4104 "This may be done in a different ",
4105 "terminal without restarting ",
4106 "git svn\n";
4107 $printed_warning = 1;
4108 }
4109 my $path = $_;
4110 my (undef, $props) =
4111 $git_svn->ra->get_file($pfx.$path, $rev, undef);
4112 if ($props->{'svn:special'}) {
4113 $ret{$path} = 1;
4114 }
4115 }
4116 command_close_pipe($ls, $ctx);
4117 \%ret;
4118 }
4119
4120 # returns true if a given path is inside a ".git" directory
4121 sub in_dot_git {
4122 $_[0] =~ m{(?:^|/)\.git(?:/|$)};
4123 }
4124
4125 # return value: 0 -- don't ignore, 1 -- ignore
4126 sub is_path_ignored {
4127 my ($self, $path) = @_;
4128 return 1 if in_dot_git($path);
4129 return 1 if defined($self->{ignore_regex}) &&
4130 $path =~ m!$self->{ignore_regex}!;
4131 return 0 unless defined($_ignore_regex);
4132 return 1 if $path =~ m!$_ignore_regex!o;
4133 return 0;
4134 }
4135
4136 sub set_path_strip {
4137 my ($self, $path) = @_;
4138 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
4139 }
4140
4141 sub open_root {
4142 { path => '' };
4143 }
4144
4145 sub open_directory {
4146 my ($self, $path, $pb, $rev) = @_;
4147 { path => $path };
4148 }
4149
4150 sub git_path {
4151 my ($self, $path) = @_;
4152 if (my $enc = $self->{pathnameencoding}) {
4153 require Encode;
4154 Encode::from_to($path, 'UTF-8', $enc);
4155 }
4156 if ($self->{path_strip}) {
4157 $path =~ s!$self->{path_strip}!! or
4158 die "Failed to strip path '$path' ($self->{path_strip})\n";
4159 }
4160 $path;
4161 }
4162
4163 sub delete_entry {
4164 my ($self, $path, $rev, $pb) = @_;
4165 return undef if $self->is_path_ignored($path);
4166
4167 my $gpath = $self->git_path($path);
4168 return undef if ($gpath eq '');
4169
4170 # remove entire directories.
4171 my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4172 =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
4173 if ($tree) {
4174 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4175 -r --name-only -z/,
4176 $tree);
4177 local $/ = "\0";
4178 while (<$ls>) {
4179 chomp;
4180 my $rmpath = "$gpath/$_";
4181 $self->{gii}->remove($rmpath);
4182 print "\tD\t$rmpath\n" unless $::_q;
4183 }
4184 print "\tD\t$gpath/\n" unless $::_q;
4185 command_close_pipe($ls, $ctx);
4186 } else {
4187 $self->{gii}->remove($gpath);
4188 print "\tD\t$gpath\n" unless $::_q;
4189 }
4190 $self->{empty}->{$path} = 0;
4191 undef;
4192 }
4193
4194 sub open_file {
4195 my ($self, $path, $pb, $rev) = @_;
4196 my ($mode, $blob);
4197
4198 goto out if $self->is_path_ignored($path);
4199
4200 my $gpath = $self->git_path($path);
4201 ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
4202 =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
4203 unless (defined $mode && defined $blob) {
4204 die "$path was not found in commit $self->{c} (r$rev)\n";
4205 }
4206 if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
4207 $mode = '120000';
4208 }
4209 out:
4210 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
4211 pool => SVN::Pool->new, action => 'M' };
4212 }
4213
4214 sub add_file {
4215 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
4216 my $mode;
4217
4218 if (!$self->is_path_ignored($path)) {
4219 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4220 delete $self->{empty}->{$dir};
4221 $mode = '100644';
4222 }
4223 { path => $path, mode_a => $mode, mode_b => $mode,
4224 pool => SVN::Pool->new, action => 'A' };
4225 }
4226
4227 sub add_directory {
4228 my ($self, $path, $cp_path, $cp_rev) = @_;
4229 goto out if $self->is_path_ignored($path);
4230 my $gpath = $self->git_path($path);
4231 if ($gpath eq '') {
4232 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
4233 -r --name-only -z/,
4234 $self->{c});
4235 local $/ = "\0";
4236 while (<$ls>) {
4237 chomp;
4238 $self->{gii}->remove($_);
4239 print "\tD\t$_\n" unless $::_q;
4240 }
4241 command_close_pipe($ls, $ctx);
4242 $self->{empty}->{$path} = 0;
4243 }
4244 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
4245 delete $self->{empty}->{$dir};
4246 $self->{empty}->{$path} = 1;
4247 out:
4248 { path => $path };
4249 }
4250
4251 sub change_dir_prop {
4252 my ($self, $db, $prop, $value) = @_;
4253 return undef if $self->is_path_ignored($db->{path});
4254 $self->{dir_prop}->{$db->{path}} ||= {};
4255 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
4256 undef;
4257 }
4258
4259 sub absent_directory {
4260 my ($self, $path, $pb) = @_;
4261 return undef if $self->is_path_ignored($path);
4262 $self->{absent_dir}->{$pb->{path}} ||= [];
4263 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
4264 undef;
4265 }
4266
4267 sub absent_file {
4268 my ($self, $path, $pb) = @_;
4269 return undef if $self->is_path_ignored($path);
4270 $self->{absent_file}->{$pb->{path}} ||= [];
4271 push @{$self->{absent_file}->{$pb->{path}}}, $path;
4272 undef;
4273 }
4274
4275 sub change_file_prop {
4276 my ($self, $fb, $prop, $value) = @_;
4277 return undef if $self->is_path_ignored($fb->{path});
4278 if ($prop eq 'svn:executable') {
4279 if ($fb->{mode_b} != 120000) {
4280 $fb->{mode_b} = defined $value ? 100755 : 100644;
4281 }
4282 } elsif ($prop eq 'svn:special') {
4283 $fb->{mode_b} = defined $value ? 120000 : 100644;
4284 } else {
4285 $self->{file_prop}->{$fb->{path}} ||= {};
4286 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4287 }
4288 undef;
4289 }
4290
4291 sub apply_textdelta {
4292 my ($self, $fb, $exp) = @_;
4293 return undef if $self->is_path_ignored($fb->{path});
4294 my $fh = $::_repository->temp_acquire('svn_delta');
4295 # $fh gets auto-closed() by SVN::TxDelta::apply(),
4296 # (but $base does not,) so dup() it for reading in close_file
4297 open my $dup, '<&', $fh or croak $!;
4298 my $base = $::_repository->temp_acquire('git_blob');
4299
4300 if ($fb->{blob}) {
4301 my ($base_is_link, $size);
4302
4303 if ($fb->{mode_a} eq '120000' &&
4304 ! $self->{empty_symlinks}->{$fb->{path}}) {
4305 print $base 'link ' or die "print $!\n";
4306 $base_is_link = 1;
4307 }
4308 retry:
4309 $size = $::_repository->cat_blob($fb->{blob}, $base);
4310 die "Failed to read object $fb->{blob}" if ($size < 0);
4311
4312 if (defined $exp) {
4313 seek $base, 0, 0 or croak $!;
4314 my $got = ::md5sum($base);
4315 if ($got ne $exp) {
4316 my $err = "Checksum mismatch: ".
4317 "$fb->{path} $fb->{blob}\n" .
4318 "expected: $exp\n" .
4319 " got: $got\n";
4320 if ($base_is_link) {
4321 warn $err,
4322 "Retrying... (possibly ",
4323 "a bad symlink from SVN)\n";
4324 $::_repository->temp_reset($base);
4325 $base_is_link = 0;
4326 goto retry;
4327 }
4328 die $err;
4329 }
4330 }
4331 }
4332 seek $base, 0, 0 or croak $!;
4333 $fb->{fh} = $fh;
4334 $fb->{base} = $base;
4335 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4336 }
4337
4338 sub close_file {
4339 my ($self, $fb, $exp) = @_;
4340 return undef if $self->is_path_ignored($fb->{path});
4341
4342 my $hash;
4343 my $path = $self->git_path($fb->{path});
4344 if (my $fh = $fb->{fh}) {
4345 if (defined $exp) {
4346 seek($fh, 0, 0) or croak $!;
4347 my $got = ::md5sum($fh);
4348 if ($got ne $exp) {
4349 die "Checksum mismatch: $path\n",
4350 "expected: $exp\n got: $got\n";
4351 }
4352 }
4353 if ($fb->{mode_b} == 120000) {
4354 sysseek($fh, 0, 0) or croak $!;
4355 my $rd = sysread($fh, my $buf, 5);
4356
4357 if (!defined $rd) {
4358 croak "sysread: $!\n";
4359 } elsif ($rd == 0) {
4360 warn "$path has mode 120000",
4361 " but it points to nothing\n",
4362 "converting to an empty file with mode",
4363 " 100644\n";
4364 $fb->{mode_b} = '100644';
4365 } elsif ($buf ne 'link ') {
4366 warn "$path has mode 120000",
4367 " but is not a link\n";
4368 } else {
4369 my $tmp_fh = $::_repository->temp_acquire(
4370 'svn_hash');
4371 my $res;
4372 while ($res = sysread($fh, my $str, 1024)) {
4373 my $out = syswrite($tmp_fh, $str, $res);
4374 defined($out) && $out == $res
4375 or croak("write ",
4376 Git::temp_path($tmp_fh),
4377 ": $!\n");
4378 }
4379 defined $res or croak $!;
4380
4381 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4382 Git::temp_release($tmp_fh, 1);
4383 }
4384 }
4385
4386 $hash = $::_repository->hash_and_insert_object(
4387 Git::temp_path($fh));
4388 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4389
4390 Git::temp_release($fb->{base}, 1);
4391 Git::temp_release($fh, 1);
4392 } else {
4393 $hash = $fb->{blob} or die "no blob information\n";
4394 }
4395 $fb->{pool}->clear;
4396 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4397 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4398 undef;
4399 }
4400
4401 sub abort_edit {
4402 my $self = shift;
4403 $self->{nr} = $self->{gii}->{nr};
4404 delete $self->{gii};
4405 $self->SUPER::abort_edit(@_);
4406 }
4407
4408 sub close_edit {
4409 my $self = shift;
4410 $self->{git_commit_ok} = 1;
4411 $self->{nr} = $self->{gii}->{nr};
4412 delete $self->{gii};
4413 $self->SUPER::close_edit(@_);
4414 }
4415
4416 package SVN::Git::Editor;
4417 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4418 use strict;
4419 use warnings;
4420 use Carp qw/croak/;
4421 use IO::File;
4422
4423 sub new {
4424 my ($class, $opts) = @_;
4425 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4426 die "$_ required!\n" unless (defined $opts->{$_});
4427 }
4428
4429 my $pool = SVN::Pool->new;
4430 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4431 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4432 $opts->{r}, $mods);
4433
4434 # $opts->{ra} functions should not be used after this:
4435 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
4436 $opts->{editor_cb}, $pool);
4437 my $self = SVN::Delta::Editor->new(@ce, $pool);
4438 bless $self, $class;
4439 foreach (qw/svn_path r tree_a tree_b/) {
4440 $self->{$_} = $opts->{$_};
4441 }
4442 $self->{url} = $opts->{ra}->{url};
4443 $self->{mods} = $mods;
4444 $self->{types} = $types;
4445 $self->{pool} = $pool;
4446 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4447 $self->{rm} = { };
4448 $self->{path_prefix} = length $self->{svn_path} ?
4449 "$self->{svn_path}/" : '';
4450 $self->{config} = $opts->{config};
4451 return $self;
4452 }
4453
4454 sub generate_diff {
4455 my ($tree_a, $tree_b) = @_;
4456 my @diff_tree = qw(diff-tree -z -r);
4457 if ($_cp_similarity) {
4458 push @diff_tree, "-C$_cp_similarity";
4459 } else {
4460 push @diff_tree, '-C';
4461 }
4462 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4463 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4464 push @diff_tree, $tree_a, $tree_b;
4465 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4466 local $/ = "\0";
4467 my $state = 'meta';
4468 my @mods;
4469 while (<$diff_fh>) {
4470 chomp $_; # this gets rid of the trailing "\0"
4471 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4472 ($::sha1)\s($::sha1)\s
4473 ([MTCRAD])\d*$/xo) {
4474 push @mods, { mode_a => $1, mode_b => $2,
4475 sha1_a => $3, sha1_b => $4,
4476 chg => $5 };
4477 if ($5 =~ /^(?:C|R)$/) {
4478 $state = 'file_a';
4479 } else {
4480 $state = 'file_b';
4481 }
4482 } elsif ($state eq 'file_a') {
4483 my $x = $mods[$#mods] or croak "Empty array\n";
4484 if ($x->{chg} !~ /^(?:C|R)$/) {
4485 croak "Error parsing $_, $x->{chg}\n";
4486 }
4487 $x->{file_a} = $_;
4488 $state = 'file_b';
4489 } elsif ($state eq 'file_b') {
4490 my $x = $mods[$#mods] or croak "Empty array\n";
4491 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4492 croak "Error parsing $_, $x->{chg}\n";
4493 }
4494 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4495 croak "Error parsing $_, $x->{chg}\n";
4496 }
4497 $x->{file_b} = $_;
4498 $state = 'meta';
4499 } else {
4500 croak "Error parsing $_\n";
4501 }
4502 }
4503 command_close_pipe($diff_fh, $ctx);
4504 \@mods;
4505 }
4506
4507 sub check_diff_paths {
4508 my ($ra, $pfx, $rev, $mods) = @_;
4509 my %types;
4510 $pfx .= '/' if length $pfx;
4511
4512 sub type_diff_paths {
4513 my ($ra, $types, $path, $rev) = @_;
4514 my @p = split m#/+#, $path;
4515 my $c = shift @p;
4516 unless (defined $types->{$c}) {
4517 $types->{$c} = $ra->check_path($c, $rev);
4518 }
4519 while (@p) {
4520 $c .= '/' . shift @p;
4521 next if defined $types->{$c};
4522 $types->{$c} = $ra->check_path($c, $rev);
4523 }
4524 }
4525
4526 foreach my $m (@$mods) {
4527 foreach my $f (qw/file_a file_b/) {
4528 next unless defined $m->{$f};
4529 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4530 if (length $pfx.$dir && ! defined $types{$dir}) {
4531 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4532 }
4533 }
4534 }
4535 \%types;
4536 }
4537
4538 sub split_path {
4539 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4540 }
4541
4542 sub repo_path {
4543 my ($self, $path) = @_;
4544 if (my $enc = $self->{pathnameencoding}) {
4545 require Encode;
4546 Encode::from_to($path, $enc, 'UTF-8');
4547 }
4548 $self->{path_prefix}.(defined $path ? $path : '');
4549 }
4550
4551 sub url_path {
4552 my ($self, $path) = @_;
4553 if ($self->{url} =~ m#^https?://#) {
4554 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4555 }
4556 $self->{url} . '/' . $self->repo_path($path);
4557 }
4558
4559 sub rmdirs {
4560 my ($self) = @_;
4561 my $rm = $self->{rm};
4562 delete $rm->{''}; # we never delete the url we're tracking
4563 return unless %$rm;
4564
4565 foreach (keys %$rm) {
4566 my @d = split m#/#, $_;
4567 my $c = shift @d;
4568 $rm->{$c} = 1;
4569 while (@d) {
4570 $c .= '/' . shift @d;
4571 $rm->{$c} = 1;
4572 }
4573 }
4574 delete $rm->{$self->{svn_path}};
4575 delete $rm->{''}; # we never delete the url we're tracking
4576 return unless %$rm;
4577
4578 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4579 $self->{tree_b});
4580 local $/ = "\0";
4581 while (<$fh>) {
4582 chomp;
4583 my @dn = split m#/#, $_;
4584 while (pop @dn) {
4585 delete $rm->{join '/', @dn};
4586 }
4587 unless (%$rm) {
4588 close $fh;
4589 return;
4590 }
4591 }
4592 command_close_pipe($fh, $ctx);
4593
4594 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4595 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4596 $self->close_directory($bat->{$d}, $p);
4597 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4598 print "\tD+\t$d/\n" unless $::_q;
4599 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4600 delete $bat->{$d};
4601 }
4602 }
4603
4604 sub open_or_add_dir {
4605 my ($self, $full_path, $baton) = @_;
4606 my $t = $self->{types}->{$full_path};
4607 if (!defined $t) {
4608 die "$full_path not known in r$self->{r} or we have a bug!\n";
4609 }
4610 {
4611 no warnings 'once';
4612 # SVN::Node::none and SVN::Node::file are used only once,
4613 # so we're shutting up Perl's warnings about them.
4614 if ($t == $SVN::Node::none) {
4615 return $self->add_directory($full_path, $baton,
4616 undef, -1, $self->{pool});
4617 } elsif ($t == $SVN::Node::dir) {
4618 return $self->open_directory($full_path, $baton,
4619 $self->{r}, $self->{pool});
4620 } # no warnings 'once'
4621 print STDERR "$full_path already exists in repository at ",
4622 "r$self->{r} and it is not a directory (",
4623 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4624 } # no warnings 'once'
4625 exit 1;
4626 }
4627
4628 sub ensure_path {
4629 my ($self, $path) = @_;
4630 my $bat = $self->{bat};
4631 my $repo_path = $self->repo_path($path);
4632 return $bat->{''} unless (length $repo_path);
4633 my @p = split m#/+#, $repo_path;
4634 my $c = shift @p;
4635 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4636 while (@p) {
4637 my $c0 = $c;
4638 $c .= '/' . shift @p;
4639 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4640 }
4641 return $bat->{$c};
4642 }
4643
4644 # Subroutine to convert a globbing pattern to a regular expression.
4645 # From perl cookbook.
4646 sub glob2pat {
4647 my $globstr = shift;
4648 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4649 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4650 return '^' . $globstr . '$';
4651 }
4652
4653 sub check_autoprop {
4654 my ($self, $pattern, $properties, $file, $fbat) = @_;
4655 # Convert the globbing pattern to a regular expression.
4656 my $regex = glob2pat($pattern);
4657 # Check if the pattern matches the file name.
4658 if($file =~ m/($regex)/) {
4659 # Parse the list of properties to set.
4660 my @props = split(/;/, $properties);
4661 foreach my $prop (@props) {
4662 # Parse 'name=value' syntax and set the property.
4663 if ($prop =~ /([^=]+)=(.*)/) {
4664 my ($n,$v) = ($1,$2);
4665 for ($n, $v) {
4666 s/^\s+//; s/\s+$//;
4667 }
4668 $self->change_file_prop($fbat, $n, $v);
4669 }
4670 }
4671 }
4672 }
4673
4674 sub apply_autoprops {
4675 my ($self, $file, $fbat) = @_;
4676 my $conf_t = ${$self->{config}}{'config'};
4677 no warnings 'once';
4678 # Check [miscellany]/enable-auto-props in svn configuration.
4679 if (SVN::_Core::svn_config_get_bool(
4680 $conf_t,
4681 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4682 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4683 0)) {
4684 # Auto-props are enabled. Enumerate them to look for matches.
4685 my $callback = sub {
4686 $self->check_autoprop($_[0], $_[1], $file, $fbat);
4687 };
4688 SVN::_Core::svn_config_enumerate(
4689 $conf_t,
4690 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4691 $callback);
4692 }
4693 }
4694
4695 sub A {
4696 my ($self, $m) = @_;
4697 my ($dir, $file) = split_path($m->{file_b});
4698 my $pbat = $self->ensure_path($dir);
4699 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4700 undef, -1);
4701 print "\tA\t$m->{file_b}\n" unless $::_q;
4702 $self->apply_autoprops($file, $fbat);
4703 $self->chg_file($fbat, $m);
4704 $self->close_file($fbat,undef,$self->{pool});
4705 }
4706
4707 sub C {
4708 my ($self, $m) = @_;
4709 my ($dir, $file) = split_path($m->{file_b});
4710 my $pbat = $self->ensure_path($dir);
4711 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4712 $self->url_path($m->{file_a}), $self->{r});
4713 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4714 $self->chg_file($fbat, $m);
4715 $self->close_file($fbat,undef,$self->{pool});
4716 }
4717
4718 sub delete_entry {
4719 my ($self, $path, $pbat) = @_;
4720 my $rpath = $self->repo_path($path);
4721 my ($dir, $file) = split_path($rpath);
4722 $self->{rm}->{$dir} = 1;
4723 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4724 }
4725
4726 sub R {
4727 my ($self, $m) = @_;
4728 my ($dir, $file) = split_path($m->{file_b});
4729 my $pbat = $self->ensure_path($dir);
4730 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4731 $self->url_path($m->{file_a}), $self->{r});
4732 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4733 $self->apply_autoprops($file, $fbat);
4734 $self->chg_file($fbat, $m);
4735 $self->close_file($fbat,undef,$self->{pool});
4736
4737 ($dir, $file) = split_path($m->{file_a});
4738 $pbat = $self->ensure_path($dir);
4739 $self->delete_entry($m->{file_a}, $pbat);
4740 }
4741
4742 sub M {
4743 my ($self, $m) = @_;
4744 my ($dir, $file) = split_path($m->{file_b});
4745 my $pbat = $self->ensure_path($dir);
4746 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4747 $pbat,$self->{r},$self->{pool});
4748 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4749 $self->chg_file($fbat, $m);
4750 $self->close_file($fbat,undef,$self->{pool});
4751 }
4752
4753 sub T { shift->M(@_) }
4754
4755 sub change_file_prop {
4756 my ($self, $fbat, $pname, $pval) = @_;
4757 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4758 }
4759
4760 sub _chg_file_get_blob ($$$$) {
4761 my ($self, $fbat, $m, $which) = @_;
4762 my $fh = $::_repository->temp_acquire("git_blob_$which");
4763 if ($m->{"mode_$which"} =~ /^120/) {
4764 print $fh 'link ' or croak $!;
4765 $self->change_file_prop($fbat,'svn:special','*');
4766 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4767 $self->change_file_prop($fbat,'svn:special',undef);
4768 }
4769 my $blob = $m->{"sha1_$which"};
4770 return ($fh,) if ($blob =~ /^0{40}$/);
4771 my $size = $::_repository->cat_blob($blob, $fh);
4772 croak "Failed to read object $blob" if ($size < 0);
4773 $fh->flush == 0 or croak $!;
4774 seek $fh, 0, 0 or croak $!;
4775
4776 my $exp = ::md5sum($fh);
4777 seek $fh, 0, 0 or croak $!;
4778 return ($fh, $exp);
4779 }
4780
4781 sub chg_file {
4782 my ($self, $fbat, $m) = @_;
4783 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4784 $self->change_file_prop($fbat,'svn:executable','*');
4785 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4786 $self->change_file_prop($fbat,'svn:executable',undef);
4787 }
4788 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4789 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4790 my $pool = SVN::Pool->new;
4791 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4792 if (-s $fh_a) {
4793 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4794 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4795 if (defined $res) {
4796 die "Unexpected result from send_txstream: $res\n",
4797 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4798 }
4799 } else {
4800 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4801 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4802 if ($got ne $exp_b);
4803 }
4804 Git::temp_release($fh_b, 1);
4805 Git::temp_release($fh_a, 1);
4806 $pool->clear;
4807 }
4808
4809 sub D {
4810 my ($self, $m) = @_;
4811 my ($dir, $file) = split_path($m->{file_b});
4812 my $pbat = $self->ensure_path($dir);
4813 print "\tD\t$m->{file_b}\n" unless $::_q;
4814 $self->delete_entry($m->{file_b}, $pbat);
4815 }
4816
4817 sub close_edit {
4818 my ($self) = @_;
4819 my ($p,$bat) = ($self->{pool}, $self->{bat});
4820 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4821 next if $_ eq '';
4822 $self->close_directory($bat->{$_}, $p);
4823 }
4824 $self->close_directory($bat->{''}, $p);
4825 $self->SUPER::close_edit($p);
4826 $p->clear;
4827 }
4828
4829 sub abort_edit {
4830 my ($self) = @_;
4831 $self->SUPER::abort_edit($self->{pool});
4832 }
4833
4834 sub DESTROY {
4835 my $self = shift;
4836 $self->SUPER::DESTROY(@_);
4837 $self->{pool}->clear;
4838 }
4839
4840 # this drives the editor
4841 sub apply_diff {
4842 my ($self) = @_;
4843 my $mods = $self->{mods};
4844 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4845 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4846 my $f = $m->{chg};
4847 if (defined $o{$f}) {
4848 $self->$f($m);
4849 } else {
4850 fatal("Invalid change type: $f");
4851 }
4852 }
4853 $self->rmdirs if $_rmdir;
4854 if (@$mods == 0) {
4855 $self->abort_edit;
4856 } else {
4857 $self->close_edit;
4858 }
4859 return scalar @$mods;
4860 }
4861
4862 package Git::SVN::Ra;
4863 use vars qw/@ISA $config_dir $_log_window_size/;
4864 use strict;
4865 use warnings;
4866 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4867
4868 BEGIN {
4869 # enforce temporary pool usage for some simple functions
4870 no strict 'refs';
4871 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4872 get_file/) {
4873 my $SUPER = "SUPER::$f";
4874 *$f = sub {
4875 my $self = shift;
4876 my $pool = SVN::Pool->new;
4877 my @ret = $self->$SUPER(@_,$pool);
4878 $pool->clear;
4879 wantarray ? @ret : $ret[0];
4880 };
4881 }
4882 }
4883
4884 sub _auth_providers () {
4885 [
4886 SVN::Client::get_simple_provider(),
4887 SVN::Client::get_ssl_server_trust_file_provider(),
4888 SVN::Client::get_simple_prompt_provider(
4889 \&Git::SVN::Prompt::simple, 2),
4890 SVN::Client::get_ssl_client_cert_file_provider(),
4891 SVN::Client::get_ssl_client_cert_prompt_provider(
4892 \&Git::SVN::Prompt::ssl_client_cert, 2),
4893 SVN::Client::get_ssl_client_cert_pw_file_provider(),
4894 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4895 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4896 SVN::Client::get_username_provider(),
4897 SVN::Client::get_ssl_server_trust_prompt_provider(
4898 \&Git::SVN::Prompt::ssl_server_trust),
4899 SVN::Client::get_username_prompt_provider(
4900 \&Git::SVN::Prompt::username, 2)
4901 ]
4902 }
4903
4904 sub escape_uri_only {
4905 my ($uri) = @_;
4906 my @tmp;
4907 foreach (split m{/}, $uri) {
4908 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4909 push @tmp, $_;
4910 }
4911 join('/', @tmp);
4912 }
4913
4914 sub escape_url {
4915 my ($url) = @_;
4916 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4917 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4918 $url = "$scheme://$domain$uri";
4919 }
4920 $url;
4921 }
4922
4923 sub new {
4924 my ($class, $url) = @_;
4925 $url =~ s!/+$!!;
4926 return $RA if ($RA && $RA->{url} eq $url);
4927
4928 ::_req_svn();
4929
4930 SVN::_Core::svn_config_ensure($config_dir, undef);
4931 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4932 my $config = SVN::Core::config_get_config($config_dir);
4933 $RA = undef;
4934 my $dont_store_passwords = 1;
4935 my $conf_t = ${$config}{'config'};
4936 {
4937 no warnings 'once';
4938 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4939 # produces warnings that variables are used only once.
4940 # I had not found the better way to shut them up, so
4941 # the warnings of type 'once' are disabled in this block.
4942 if (SVN::_Core::svn_config_get_bool($conf_t,
4943 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4944 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4945 1) == 0) {
4946 SVN::_Core::svn_auth_set_parameter($baton,
4947 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4948 bless (\$dont_store_passwords, "_p_void"));
4949 }
4950 if (SVN::_Core::svn_config_get_bool($conf_t,
4951 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4952 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4953 1) == 0) {
4954 $Git::SVN::Prompt::_no_auth_cache = 1;
4955 }
4956 } # no warnings 'once'
4957 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4958 config => $config,
4959 pool => SVN::Pool->new,
4960 auth_provider_callbacks => $callbacks);
4961 $self->{url} = $url;
4962 $self->{svn_path} = $url;
4963 $self->{repos_root} = $self->get_repos_root;
4964 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4965 $self->{cache} = { check_path => { r => 0, data => {} },
4966 get_dir => { r => 0, data => {} } };
4967 $RA = bless $self, $class;
4968 }
4969
4970 sub check_path {
4971 my ($self, $path, $r) = @_;
4972 my $cache = $self->{cache}->{check_path};
4973 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4974 return $cache->{data}->{$path};
4975 }
4976 my $pool = SVN::Pool->new;
4977 my $t = $self->SUPER::check_path($path, $r, $pool);
4978 $pool->clear;
4979 if ($r != $cache->{r}) {
4980 %{$cache->{data}} = ();
4981 $cache->{r} = $r;
4982 }
4983 $cache->{data}->{$path} = $t;
4984 }
4985
4986 sub get_dir {
4987 my ($self, $dir, $r) = @_;
4988 my $cache = $self->{cache}->{get_dir};
4989 if ($r == $cache->{r}) {
4990 if (my $x = $cache->{data}->{$dir}) {
4991 return wantarray ? @$x : $x->[0];
4992 }
4993 }
4994 my $pool = SVN::Pool->new;
4995 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4996 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4997 $pool->clear;
4998 if ($r != $cache->{r}) {
4999 %{$cache->{data}} = ();
5000 $cache->{r} = $r;
5001 }
5002 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
5003 wantarray ? (\%dirents, $r, $props) : \%dirents;
5004 }
5005
5006 sub DESTROY {
5007 # do not call the real DESTROY since we store ourselves in $RA
5008 }
5009
5010 # get_log(paths, start, end, limit,
5011 # discover_changed_paths, strict_node_history, receiver)
5012 sub get_log {
5013 my ($self, @args) = @_;
5014 my $pool = SVN::Pool->new;
5015
5016 # svn_log_changed_path_t objects passed to get_log are likely to be
5017 # overwritten even if only the refs are copied to an external variable,
5018 # so we should dup the structures in their entirety. Using an
5019 # externally passed pool (instead of our temporary and quickly cleared
5020 # pool in Git::SVN::Ra) does not help matters at all...
5021 my $receiver = pop @args;
5022 my $prefix = "/".$self->{svn_path};
5023 $prefix =~ s#/+($)##;
5024 my $prefix_regex = qr#^\Q$prefix\E#;
5025 push(@args, sub {
5026 my ($paths) = $_[0];
5027 return &$receiver(@_) unless $paths;
5028 $_[0] = ();
5029 foreach my $p (keys %$paths) {
5030 my $i = $paths->{$p};
5031 # Make path relative to our url, not repos_root
5032 $p =~ s/$prefix_regex//;
5033 my %s = map { $_ => $i->$_; }
5034 qw/copyfrom_path copyfrom_rev action/;
5035 if ($s{'copyfrom_path'}) {
5036 $s{'copyfrom_path'} =~ s/$prefix_regex//;
5037 }
5038 $_[0]{$p} = \%s;
5039 }
5040 &$receiver(@_);
5041 });
5042
5043
5044 # the limit parameter was not supported in SVN 1.1.x, so we
5045 # drop it. Therefore, the receiver callback passed to it
5046 # is made aware of this limitation by being wrapped if
5047 # the limit passed to is being wrapped.
5048 if ($SVN::Core::VERSION le '1.2.0') {
5049 my $limit = splice(@args, 3, 1);
5050 if ($limit > 0) {
5051 my $receiver = pop @args;
5052 push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
5053 }
5054 }
5055 my $ret = $self->SUPER::get_log(@args, $pool);
5056 $pool->clear;
5057 $ret;
5058 }
5059
5060 sub trees_match {
5061 my ($self, $url1, $rev1, $url2, $rev2) = @_;
5062 my $ctx = SVN::Client->new(auth => _auth_providers);
5063 my $out = IO::File->new_tmpfile;
5064
5065 # older SVN (1.1.x) doesn't take $pool as the last parameter for
5066 # $ctx->diff(), so we'll create a default one
5067 my $pool = SVN::Pool->new_default_sub;
5068
5069 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
5070 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
5071 $out->flush;
5072 my $ret = (($out->stat)[7] == 0);
5073 close $out or croak $!;
5074
5075 $ret;
5076 }
5077
5078 sub get_commit_editor {
5079 my ($self, $log, $cb, $pool) = @_;
5080 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
5081 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
5082 }
5083
5084 sub gs_do_update {
5085 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
5086 my $new = ($rev_a == $rev_b);
5087 my $path = $gs->{path};
5088
5089 if ($new && -e $gs->{index}) {
5090 unlink $gs->{index} or die
5091 "Couldn't unlink index: $gs->{index}: $!\n";
5092 }
5093 my $pool = SVN::Pool->new;
5094 $editor->set_path_strip($path);
5095 my (@pc) = split m#/#, $path;
5096 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
5097 1, $editor, $pool);
5098 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5099
5100 # Since we can't rely on svn_ra_reparent being available, we'll
5101 # just have to do some magic with set_path to make it so
5102 # we only want a partial path.
5103 my $sp = '';
5104 my $final = join('/', @pc);
5105 while (@pc) {
5106 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
5107 $sp .= '/' if length $sp;
5108 $sp .= shift @pc;
5109 }
5110 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
5111
5112 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
5113
5114 $reporter->finish_report($pool);
5115 $pool->clear;
5116 $editor->{git_commit_ok};
5117 }
5118
5119 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
5120 # svn_ra_reparent didn't work before 1.4)
5121 sub gs_do_switch {
5122 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
5123 my $path = $gs->{path};
5124 my $pool = SVN::Pool->new;
5125
5126 my $full_url = $self->{url};
5127 my $old_url = $full_url;
5128 $full_url .= '/' . $path if length $path;
5129 my ($ra, $reparented);
5130
5131 if ($old_url =~ m#^svn(\+ssh)?://# ||
5132 ($full_url =~ m#^https?://# &&
5133 escape_url($full_url) ne $full_url)) {
5134 $_[0] = undef;
5135 $self = undef;
5136 $RA = undef;
5137 $ra = Git::SVN::Ra->new($full_url);
5138 $ra_invalid = 1;
5139 } elsif ($old_url ne $full_url) {
5140 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
5141 $self->{url} = $full_url;
5142 $reparented = 1;
5143 }
5144
5145 $ra ||= $self;
5146 $url_b = escape_url($url_b);
5147 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
5148 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
5149 $reporter->set_path('', $rev_a, 0, @lock, $pool);
5150 $reporter->finish_report($pool);
5151
5152 if ($reparented) {
5153 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
5154 $self->{url} = $old_url;
5155 }
5156
5157 $pool->clear;
5158 $editor->{git_commit_ok};
5159 }
5160
5161 sub longest_common_path {
5162 my ($gsv, $globs) = @_;
5163 my %common;
5164 my $common_max = scalar @$gsv;
5165
5166 foreach my $gs (@$gsv) {
5167 my @tmp = split m#/#, $gs->{path};
5168 my $p = '';
5169 foreach (@tmp) {
5170 $p .= length($p) ? "/$_" : $_;
5171 $common{$p} ||= 0;
5172 $common{$p}++;
5173 }
5174 }
5175 $globs ||= [];
5176 $common_max += scalar @$globs;
5177 foreach my $glob (@$globs) {
5178 my @tmp = split m#/#, $glob->{path}->{left};
5179 my $p = '';
5180 foreach (@tmp) {
5181 $p .= length($p) ? "/$_" : $_;
5182 $common{$p} ||= 0;
5183 $common{$p}++;
5184 }
5185 }
5186
5187 my $longest_path = '';
5188 foreach (sort {length $b <=> length $a} keys %common) {
5189 if ($common{$_} == $common_max) {
5190 $longest_path = $_;
5191 last;
5192 }
5193 }
5194 $longest_path;
5195 }
5196
5197 sub gs_fetch_loop_common {
5198 my ($self, $base, $head, $gsv, $globs) = @_;
5199 return if ($base > $head);
5200 my $inc = $_log_window_size;
5201 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
5202 my $longest_path = longest_common_path($gsv, $globs);
5203 my $ra_url = $self->{url};
5204 my $find_trailing_edge;
5205 while (1) {
5206 my %revs;
5207 my $err;
5208 my $err_handler = $SVN::Error::handler;
5209 $SVN::Error::handler = sub {
5210 ($err) = @_;
5211 skip_unknown_revs($err);
5212 };
5213 sub _cb {
5214 my ($paths, $r, $author, $date, $log) = @_;
5215 [ $paths,
5216 { author => $author, date => $date, log => $log } ];
5217 }
5218 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
5219 sub { $revs{$_[1]} = _cb(@_) });
5220 if ($err) {
5221 print "Checked through r$max\r";
5222 } else {
5223 $find_trailing_edge = 1;
5224 }
5225 if ($err and $find_trailing_edge) {
5226 print STDERR "Path '$longest_path' ",
5227 "was probably deleted:\n",
5228 $err->expanded_message,
5229 "\nWill attempt to follow ",
5230 "revisions r$min .. r$max ",
5231 "committed before the deletion\n";
5232 my $hi = $max;
5233 while (--$hi >= $min) {
5234 my $ok;
5235 $self->get_log([$longest_path], $min, $hi,
5236 0, 1, 1, sub {
5237 $ok = $_[1];
5238 $revs{$_[1]} = _cb(@_) });
5239 if ($ok) {
5240 print STDERR "r$min .. r$ok OK\n";
5241 last;
5242 }
5243 }
5244 $find_trailing_edge = 0;
5245 }
5246 $SVN::Error::handler = $err_handler;
5247
5248 my %exists = map { $_->{path} => $_ } @$gsv;
5249 foreach my $r (sort {$a <=> $b} keys %revs) {
5250 my ($paths, $logged) = @{$revs{$r}};
5251
5252 foreach my $gs ($self->match_globs(\%exists, $paths,
5253 $globs, $r)) {
5254 if ($gs->rev_map_max >= $r) {
5255 next;
5256 }
5257 next unless $gs->match_paths($paths, $r);
5258 $gs->{logged_rev_props} = $logged;
5259 if (my $last_commit = $gs->last_commit) {
5260 $gs->assert_index_clean($last_commit);
5261 }
5262 my $log_entry = $gs->do_fetch($paths, $r);
5263 if ($log_entry) {
5264 $gs->do_git_commit($log_entry);
5265 }
5266 $INDEX_FILES{$gs->{index}} = 1;
5267 }
5268 foreach my $g (@$globs) {
5269 my $k = "svn-remote.$g->{remote}." .
5270 "$g->{t}-maxRev";
5271 Git::SVN::tmp_config($k, $r);
5272 }
5273 if ($ra_invalid) {
5274 $_[0] = undef;
5275 $self = undef;
5276 $RA = undef;
5277 $self = Git::SVN::Ra->new($ra_url);
5278 $ra_invalid = undef;
5279 }
5280 }
5281 # pre-fill the .rev_db since it'll eventually get filled in
5282 # with '0' x40 if something new gets committed
5283 foreach my $gs (@$gsv) {
5284 next if $gs->rev_map_max >= $max;
5285 next if defined $gs->rev_map_get($max);
5286 $gs->rev_map_set($max, 0 x40);
5287 }
5288 foreach my $g (@$globs) {
5289 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5290 Git::SVN::tmp_config($k, $max);
5291 }
5292 last if $max >= $head;
5293 $min = $max + 1;
5294 $max += $inc;
5295 $max = $head if ($max > $head);
5296 }
5297 Git::SVN::gc();
5298 }
5299
5300 sub get_dir_globbed {
5301 my ($self, $left, $depth, $r) = @_;
5302
5303 my @x = eval { $self->get_dir($left, $r) };
5304 return unless scalar @x == 3;
5305 my $dirents = $x[0];
5306 my @finalents;
5307 foreach my $de (keys %$dirents) {
5308 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5309 if ($depth > 1) {
5310 my @args = ("$left/$de", $depth - 1, $r);
5311 foreach my $dir ($self->get_dir_globbed(@args)) {
5312 push @finalents, "$de/$dir";
5313 }
5314 } else {
5315 push @finalents, $de;
5316 }
5317 }
5318 @finalents;
5319 }
5320
5321 sub match_globs {
5322 my ($self, $exists, $paths, $globs, $r) = @_;
5323
5324 sub get_dir_check {
5325 my ($self, $exists, $g, $r) = @_;
5326
5327 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5328 $g->{path}->{depth},
5329 $r);
5330
5331 foreach my $de (@dirs) {
5332 my $p = $g->{path}->full_path($de);
5333 next if $exists->{$p};
5334 next if (length $g->{path}->{right} &&
5335 ($self->check_path($p, $r) !=
5336 $SVN::Node::dir));
5337 next unless $p =~ /$g->{path}->{regex}/;
5338 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5339 $g->{ref}->full_path($de), 1);
5340 }
5341 }
5342 foreach my $g (@$globs) {
5343 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5344 if ($path->{action} =~ /^[AR]$/) {
5345 get_dir_check($self, $exists, $g, $r);
5346 }
5347 }
5348 foreach (keys %$paths) {
5349 if (/$g->{path}->{left_regex}/ &&
5350 !/$g->{path}->{regex}/) {
5351 next if $paths->{$_}->{action} !~ /^[AR]$/;
5352 get_dir_check($self, $exists, $g, $r);
5353 }
5354 next unless /$g->{path}->{regex}/;
5355 my $p = $1;
5356 my $pathname = $g->{path}->full_path($p);
5357 next if $exists->{$pathname};
5358 next if ($self->check_path($pathname, $r) !=
5359 $SVN::Node::dir);
5360 $exists->{$pathname} = Git::SVN->init(
5361 $self->{url}, $pathname, undef,
5362 $g->{ref}->full_path($p), 1);
5363 }
5364 my $c = '';
5365 foreach (split m#/#, $g->{path}->{left}) {
5366 $c .= "/$_";
5367 next unless ($paths->{$c} &&
5368 ($paths->{$c}->{action} =~ /^[AR]$/));
5369 get_dir_check($self, $exists, $g, $r);
5370 }
5371 }
5372 values %$exists;
5373 }
5374
5375 sub minimize_url {
5376 my ($self) = @_;
5377 return $self->{url} if ($self->{url} eq $self->{repos_root});
5378 my $url = $self->{repos_root};
5379 my @components = split(m!/!, $self->{svn_path});
5380 my $c = '';
5381 do {
5382 $url .= "/$c" if length $c;
5383 eval {
5384 my $ra = (ref $self)->new($url);
5385 my $latest = $ra->get_latest_revnum;
5386 $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5387 };
5388 } while ($@ && ($c = shift @components));
5389 $url;
5390 }
5391
5392 sub can_do_switch {
5393 my $self = shift;
5394 unless (defined $can_do_switch) {
5395 my $pool = SVN::Pool->new;
5396 my $rep = eval {
5397 $self->do_switch(1, '', 0, $self->{url},
5398 SVN::Delta::Editor->new, $pool);
5399 };
5400 if ($@) {
5401 $can_do_switch = 0;
5402 } else {
5403 $rep->abort_report($pool);
5404 $can_do_switch = 1;
5405 }
5406 $pool->clear;
5407 }
5408 $can_do_switch;
5409 }
5410
5411 sub skip_unknown_revs {
5412 my ($err) = @_;
5413 my $errno = $err->apr_err();
5414 # Maybe the branch we're tracking didn't
5415 # exist when the repo started, so it's
5416 # not an error if it doesn't, just continue
5417 #
5418 # Wonderfully consistent library, eh?
5419 # 160013 - svn:// and file://
5420 # 175002 - http(s)://
5421 # 175007 - http(s):// (this repo required authorization, too...)
5422 # More codes may be discovered later...
5423 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5424 my $err_key = $err->expanded_message;
5425 # revision numbers change every time, filter them out
5426 $err_key =~ s/\d+/\0/g;
5427 $err_key = "$errno\0$err_key";
5428 unless ($ignored_err{$err_key}) {
5429 warn "W: Ignoring error from SVN, path probably ",
5430 "does not exist: ($errno): ",
5431 $err->expanded_message,"\n";
5432 warn "W: Do not be alarmed at the above message ",
5433 "git-svn is just searching aggressively for ",
5434 "old history.\n",
5435 "This may take a while on large repositories\n";
5436 $ignored_err{$err_key} = 1;
5437 }
5438 return;
5439 }
5440 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5441 }
5442
5443 package Git::SVN::Log;
5444 use strict;
5445 use warnings;
5446 use POSIX qw/strftime/;
5447 use Time::Local;
5448 use constant commit_log_separator => ('-' x 72) . "\n";
5449 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5450 %rusers $show_commit $incremental/;
5451 my $l_fmt;
5452
5453 sub cmt_showable {
5454 my ($c) = @_;
5455 return 1 if defined $c->{r};
5456
5457 # big commit message got truncated by the 16k pretty buffer in rev-list
5458 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5459 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5460 @{$c->{l}} = ();
5461 my @log = command(qw/cat-file commit/, $c->{c});
5462
5463 # shift off the headers
5464 shift @log while ($log[0] ne '');
5465 shift @log;
5466
5467 # TODO: make $c->{l} not have a trailing newline in the future
5468 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5469
5470 (undef, $c->{r}, undef) = ::extract_metadata(
5471 (grep(/^git-svn-id: /, @log))[-1]);
5472 }
5473 return defined $c->{r};
5474 }
5475
5476 sub log_use_color {
5477 return $color || Git->repository->get_colorbool('color.diff');
5478 }
5479
5480 sub git_svn_log_cmd {
5481 my ($r_min, $r_max, @args) = @_;
5482 my $head = 'HEAD';
5483 my (@files, @log_opts);
5484 foreach my $x (@args) {
5485 if ($x eq '--' || @files) {
5486 push @files, $x;
5487 } else {
5488 if (::verify_ref("$x^0")) {
5489 $head = $x;
5490 } else {
5491 push @log_opts, $x;
5492 }
5493 }
5494 }
5495
5496 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5497 $gs ||= Git::SVN->_new;
5498 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5499 $gs->refname);
5500 push @cmd, '-r' unless $non_recursive;
5501 push @cmd, qw/--raw --name-status/ if $verbose;
5502 push @cmd, '--color' if log_use_color();
5503 push @cmd, @log_opts;
5504 if (defined $r_max && $r_max == $r_min) {
5505 push @cmd, '--max-count=1';
5506 if (my $c = $gs->rev_map_get($r_max)) {
5507 push @cmd, $c;
5508 }
5509 } elsif (defined $r_max) {
5510 if ($r_max < $r_min) {
5511 ($r_min, $r_max) = ($r_max, $r_min);
5512 }
5513 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5514 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5515 # If there are no commits in the range, both $c_max and $c_min
5516 # will be undefined. If there is at least 1 commit in the
5517 # range, both will be defined.
5518 return () if !defined $c_min || !defined $c_max;
5519 if ($c_min eq $c_max) {
5520 push @cmd, '--max-count=1', $c_min;
5521 } else {
5522 push @cmd, '--boundary', "$c_min..$c_max";
5523 }
5524 }
5525 return (@cmd, @files);
5526 }
5527
5528 # adapted from pager.c
5529 sub config_pager {
5530 if (! -t *STDOUT) {
5531 $ENV{GIT_PAGER_IN_USE} = 'false';
5532 $pager = undef;
5533 return;
5534 }
5535 chomp($pager = command_oneline(qw(var GIT_PAGER)));
5536 if ($pager eq 'cat') {
5537 $pager = undef;
5538 }
5539 $ENV{GIT_PAGER_IN_USE} = defined($pager);
5540 }
5541
5542 sub run_pager {
5543 return unless defined $pager;
5544 pipe my ($rfd, $wfd) or return;
5545 defined(my $pid = fork) or ::fatal "Can't fork: $!";
5546 if (!$pid) {
5547 open STDOUT, '>&', $wfd or
5548 ::fatal "Can't redirect to stdout: $!";
5549 return;
5550 }
5551 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5552 $ENV{LESS} ||= 'FRSX';
5553 exec $pager or ::fatal "Can't run pager: $! ($pager)";
5554 }
5555
5556 sub format_svn_date {
5557 # some systmes don't handle or mishandle %z, so be creative.
5558 my $t = shift || time;
5559 my $gm = timelocal(gmtime($t));
5560 my $sign = qw( + + - )[ $t <=> $gm ];
5561 my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5562 return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5563 }
5564
5565 sub parse_git_date {
5566 my ($t, $tz) = @_;
5567 # Date::Parse isn't in the standard Perl distro :(
5568 if ($tz =~ s/^\+//) {
5569 $t += tz_to_s_offset($tz);
5570 } elsif ($tz =~ s/^\-//) {
5571 $t -= tz_to_s_offset($tz);
5572 }
5573 return $t;
5574 }
5575
5576 sub set_local_timezone {
5577 if (defined $TZ) {
5578 $ENV{TZ} = $TZ;
5579 } else {
5580 delete $ENV{TZ};
5581 }
5582 }
5583
5584 sub tz_to_s_offset {
5585 my ($tz) = @_;
5586 $tz =~ s/(\d\d)$//;
5587 return ($1 * 60) + ($tz * 3600);
5588 }
5589
5590 sub get_author_info {
5591 my ($dest, $author, $t, $tz) = @_;
5592 $author =~ s/(?:^\s*|\s*$)//g;
5593 $dest->{a_raw} = $author;
5594 my $au;
5595 if ($::_authors) {
5596 $au = $rusers{$author} || undef;
5597 }
5598 if (!$au) {
5599 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5600 }
5601 $dest->{t} = $t;
5602 $dest->{tz} = $tz;
5603 $dest->{a} = $au;
5604 $dest->{t_utc} = parse_git_date($t, $tz);
5605 }
5606
5607 sub process_commit {
5608 my ($c, $r_min, $r_max, $defer) = @_;
5609 if (defined $r_min && defined $r_max) {
5610 if ($r_min == $c->{r} && $r_min == $r_max) {
5611 show_commit($c);
5612 return 0;
5613 }
5614 return 1 if $r_min == $r_max;
5615 if ($r_min < $r_max) {
5616 # we need to reverse the print order
5617 return 0 if (defined $limit && --$limit < 0);
5618 push @$defer, $c;
5619 return 1;
5620 }
5621 if ($r_min != $r_max) {
5622 return 1 if ($r_min < $c->{r});
5623 return 1 if ($r_max > $c->{r});
5624 }
5625 }
5626 return 0 if (defined $limit && --$limit < 0);
5627 show_commit($c);
5628 return 1;
5629 }
5630
5631 sub show_commit {
5632 my $c = shift;
5633 if ($oneline) {
5634 my $x = "\n";
5635 if (my $l = $c->{l}) {
5636 while ($l->[0] =~ /^\s*$/) { shift @$l }
5637 $x = $l->[0];
5638 }
5639 $l_fmt ||= 'A' . length($c->{r});
5640 print 'r',pack($l_fmt, $c->{r}),' | ';
5641 print "$c->{c} | " if $show_commit;
5642 print $x;
5643 } else {
5644 show_commit_normal($c);
5645 }
5646 }
5647
5648 sub show_commit_changed_paths {
5649 my ($c) = @_;
5650 return unless $c->{changed};
5651 print "Changed paths:\n", @{$c->{changed}};
5652 }
5653
5654 sub show_commit_normal {
5655 my ($c) = @_;
5656 print commit_log_separator, "r$c->{r} | ";
5657 print "$c->{c} | " if $show_commit;
5658 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5659 my $nr_line = 0;
5660
5661 if (my $l = $c->{l}) {
5662 while ($l->[$#$l] eq "\n" && $#$l > 0
5663 && $l->[($#$l - 1)] eq "\n") {
5664 pop @$l;
5665 }
5666 $nr_line = scalar @$l;
5667 if (!$nr_line) {
5668 print "1 line\n\n\n";
5669 } else {
5670 if ($nr_line == 1) {
5671 $nr_line = '1 line';
5672 } else {
5673 $nr_line .= ' lines';
5674 }
5675 print $nr_line, "\n";
5676 show_commit_changed_paths($c);
5677 print "\n";
5678 print $_ foreach @$l;
5679 }
5680 } else {
5681 print "1 line\n";
5682 show_commit_changed_paths($c);
5683 print "\n";
5684
5685 }
5686 foreach my $x (qw/raw stat diff/) {
5687 if ($c->{$x}) {
5688 print "\n";
5689 print $_ foreach @{$c->{$x}}
5690 }
5691 }
5692 }
5693
5694 sub cmd_show_log {
5695 my (@args) = @_;
5696 my ($r_min, $r_max);
5697 my $r_last = -1; # prevent dupes
5698 set_local_timezone();
5699 if (defined $::_revision) {
5700 if ($::_revision =~ /^(\d+):(\d+)$/) {
5701 ($r_min, $r_max) = ($1, $2);
5702 } elsif ($::_revision =~ /^\d+$/) {
5703 $r_min = $r_max = $::_revision;
5704 } else {
5705 ::fatal "-r$::_revision is not supported, use ",
5706 "standard 'git log' arguments instead";
5707 }
5708 }
5709
5710 config_pager();
5711 @args = git_svn_log_cmd($r_min, $r_max, @args);
5712 if (!@args) {
5713 print commit_log_separator unless $incremental || $oneline;
5714 return;
5715 }
5716 my $log = command_output_pipe(@args);
5717 run_pager();
5718 my (@k, $c, $d, $stat);
5719 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5720 while (<$log>) {
5721 if (/^${esc_color}commit -?($::sha1_short)/o) {
5722 my $cmt = $1;
5723 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5724 $r_last = $c->{r};
5725 process_commit($c, $r_min, $r_max, \@k) or
5726 goto out;
5727 }
5728 $d = undef;
5729 $c = { c => $cmt };
5730 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5731 get_author_info($c, $1, $2, $3);
5732 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5733 # ignore
5734 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5735 push @{$c->{raw}}, $_;
5736 } elsif (/^${esc_color}[ACRMDT]\t/) {
5737 # we could add $SVN->{svn_path} here, but that requires
5738 # remote access at the moment (repo_path_split)...
5739 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
5740 push @{$c->{changed}}, $_;
5741 } elsif (/^${esc_color}diff /o) {
5742 $d = 1;
5743 push @{$c->{diff}}, $_;
5744 } elsif ($d) {
5745 push @{$c->{diff}}, $_;
5746 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5747 $esc_color*[\+\-]*$esc_color$/x) {
5748 $stat = 1;
5749 push @{$c->{stat}}, $_;
5750 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5751 push @{$c->{stat}}, $_;
5752 $stat = undef;
5753 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
5754 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5755 } elsif (s/^${esc_color} //o) {
5756 push @{$c->{l}}, $_;
5757 }
5758 }
5759 if ($c && defined $c->{r} && $c->{r} != $r_last) {
5760 $r_last = $c->{r};
5761 process_commit($c, $r_min, $r_max, \@k);
5762 }
5763 if (@k) {
5764 ($r_min, $r_max) = ($r_max, $r_min);
5765 process_commit($_, $r_min, $r_max) foreach reverse @k;
5766 }
5767 out:
5768 close $log;
5769 print commit_log_separator unless $incremental || $oneline;
5770 }
5771
5772 sub cmd_blame {
5773 my $path = pop;
5774
5775 config_pager();
5776 run_pager();
5777
5778 my ($fh, $ctx, $rev);
5779
5780 if ($_git_format) {
5781 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5782 while (my $line = <$fh>) {
5783 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5784 # Uncommitted edits show up as a rev ID of
5785 # all zeros, which we can't look up with
5786 # cmt_metadata
5787 if ($1 !~ /^0+$/) {
5788 (undef, $rev, undef) =
5789 ::cmt_metadata($1);
5790 $rev = '0' if (!$rev);
5791 } else {
5792 $rev = '0';
5793 }
5794 $rev = sprintf('%-10s', $rev);
5795 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5796 }
5797 print $line;
5798 }
5799 } else {
5800 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5801 '--', $path);
5802 my ($sha1);
5803 my %authors;
5804 my @buffer;
5805 my %dsha; #distinct sha keys
5806
5807 while (my $line = <$fh>) {
5808 push @buffer, $line;
5809 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5810 $dsha{$1} = 1;
5811 }
5812 }
5813
5814 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5815
5816 foreach my $line (@buffer) {
5817 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5818 $rev = $s2r->{$1};
5819 $rev = '0' if (!$rev)
5820 }
5821 elsif ($line =~ /^author (.*)/) {
5822 $authors{$rev} = $1;
5823 $authors{$rev} =~ s/\s/_/g;
5824 }
5825 elsif ($line =~ /^\t(.*)$/) {
5826 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5827 }
5828 }
5829 }
5830 command_close_pipe($fh, $ctx);
5831 }
5832
5833 package Git::SVN::Migration;
5834 # these version numbers do NOT correspond to actual version numbers
5835 # of git nor git-svn. They are just relative.
5836 #
5837 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5838 #
5839 # v1 layout: .git/$id/info/url, refs/remotes/$id
5840 #
5841 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5842 #
5843 # v3 layout: .git/svn/$id, refs/remotes/$id
5844 # - info/url may remain for backwards compatibility
5845 # - this is what we migrate up to this layout automatically,
5846 # - this will be used by git svn init on single branches
5847 # v3.1 layout (auto migrated):
5848 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5849 # for backwards compatibility
5850 #
5851 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5852 # - this is only created for newly multi-init-ed
5853 # repositories. Similar in spirit to the
5854 # --use-separate-remotes option in git-clone (now default)
5855 # - we do not automatically migrate to this (following
5856 # the example set by core git)
5857 #
5858 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5859 # - newer, more-efficient format that uses 24-bytes per record
5860 # with no filler space.
5861 # - use xxd -c24 < .rev_map.$UUID to view and debug
5862 # - This is a one-way migration, repositories updated to the
5863 # new format will not be able to use old git-svn without
5864 # rebuilding the .rev_db. Rebuilding the rev_db is not
5865 # possible if noMetadata or useSvmProps are set; but should
5866 # be no problem for users that use the (sensible) defaults.
5867 use strict;
5868 use warnings;
5869 use Carp qw/croak/;
5870 use File::Path qw/mkpath/;
5871 use File::Basename qw/dirname basename/;
5872 use vars qw/$_minimize/;
5873
5874 sub migrate_from_v0 {
5875 my $git_dir = $ENV{GIT_DIR};
5876 return undef unless -d $git_dir;
5877 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5878 my $migrated = 0;
5879 while (<$fh>) {
5880 chomp;
5881 my ($id, $orig_ref) = ($_, $_);
5882 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5883 next unless -f "$git_dir/$id/info/url";
5884 my $new_ref = "refs/remotes/$id";
5885 if (::verify_ref("$new_ref^0")) {
5886 print STDERR "W: $orig_ref is probably an old ",
5887 "branch used by an ancient version of ",
5888 "git-svn.\n",
5889 "However, $new_ref also exists.\n",
5890 "We will not be able ",
5891 "to use this branch until this ",
5892 "ambiguity is resolved.\n";
5893 next;
5894 }
5895 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5896 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5897 command_noisy('update-ref', $new_ref, $orig_ref);
5898 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5899 $migrated++;
5900 }
5901 command_close_pipe($fh, $ctx);
5902 print STDERR "Done migrating from v0 layout...\n" if $migrated;
5903 $migrated;
5904 }
5905
5906 sub migrate_from_v1 {
5907 my $git_dir = $ENV{GIT_DIR};
5908 my $migrated = 0;
5909 return $migrated unless -d $git_dir;
5910 my $svn_dir = "$git_dir/svn";
5911
5912 # just in case somebody used 'svn' as their $id at some point...
5913 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5914
5915 print STDERR "Migrating from a git-svn v1 layout...\n";
5916 mkpath([$svn_dir]);
5917 print STDERR "Data from a previous version of git-svn exists, but\n\t",
5918 "$svn_dir\n\t(required for this version ",
5919 "($::VERSION) of git-svn) does not exist.\n";
5920 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5921 while (<$fh>) {
5922 my $x = $_;
5923 next unless $x =~ s#^refs/remotes/##;
5924 chomp $x;
5925 next unless -f "$git_dir/$x/info/url";
5926 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5927 next unless $u;
5928 my $dn = dirname("$git_dir/svn/$x");
5929 mkpath([$dn]) unless -d $dn;
5930 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5931 mkpath(["$git_dir/svn/svn"]);
5932 print STDERR " - $git_dir/$x/info => ",
5933 "$git_dir/svn/$x/info\n";
5934 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5935 croak "$!: $x";
5936 # don't worry too much about these, they probably
5937 # don't exist with repos this old (save for index,
5938 # and we can easily regenerate that)
5939 foreach my $f (qw/unhandled.log index .rev_db/) {
5940 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5941 }
5942 } else {
5943 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5944 rename "$git_dir/$x", "$git_dir/svn/$x" or
5945 croak "$!: $x";
5946 }
5947 $migrated++;
5948 }
5949 command_close_pipe($fh, $ctx);
5950 print STDERR "Done migrating from a git-svn v1 layout\n";
5951 $migrated;
5952 }
5953
5954 sub read_old_urls {
5955 my ($l_map, $pfx, $path) = @_;
5956 my @dir;
5957 foreach (<$path/*>) {
5958 if (-r "$_/info/url") {
5959 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5960 my $ref_id = $pfx . basename $_;
5961 my $url = ::file_to_s("$_/info/url");
5962 $l_map->{$ref_id} = $url;
5963 } elsif (-d $_) {
5964 push @dir, $_;
5965 }
5966 }
5967 foreach (@dir) {
5968 my $x = $_;
5969 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5970 read_old_urls($l_map, $x, $_);
5971 }
5972 }
5973
5974 sub migrate_from_v2 {
5975 my @cfg = command(qw/config -l/);
5976 return if grep /^svn-remote\..+\.url=/, @cfg;
5977 my %l_map;
5978 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5979 my $migrated = 0;
5980
5981 foreach my $ref_id (sort keys %l_map) {
5982 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5983 if ($@) {
5984 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5985 }
5986 $migrated++;
5987 }
5988 $migrated;
5989 }
5990
5991 sub minimize_connections {
5992 my $r = Git::SVN::read_all_remotes();
5993 my $new_urls = {};
5994 my $root_repos = {};
5995 foreach my $repo_id (keys %$r) {
5996 my $url = $r->{$repo_id}->{url} or next;
5997 my $fetch = $r->{$repo_id}->{fetch} or next;
5998 my $ra = Git::SVN::Ra->new($url);
5999
6000 # skip existing cases where we already connect to the root
6001 if (($ra->{url} eq $ra->{repos_root}) ||
6002 ($ra->{repos_root} eq $repo_id)) {
6003 $root_repos->{$ra->{url}} = $repo_id;
6004 next;
6005 }
6006
6007 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
6008 my $root_path = $ra->{url};
6009 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
6010 foreach my $path (keys %$fetch) {
6011 my $ref_id = $fetch->{$path};
6012 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
6013
6014 # make sure we can read when connecting to
6015 # a higher level of a repository
6016 my ($last_rev, undef) = $gs->last_rev_commit;
6017 if (!defined $last_rev) {
6018 $last_rev = eval {
6019 $root_ra->get_latest_revnum;
6020 };
6021 next if $@;
6022 }
6023 my $new = $root_path;
6024 $new .= length $path ? "/$path" : '';
6025 eval {
6026 $root_ra->get_log([$new], $last_rev, $last_rev,
6027 0, 0, 1, sub { });
6028 };
6029 next if $@;
6030 $new_urls->{$ra->{repos_root}}->{$new} =
6031 { ref_id => $ref_id,
6032 old_repo_id => $repo_id,
6033 old_path => $path };
6034 }
6035 }
6036
6037 my @emptied;
6038 foreach my $url (keys %$new_urls) {
6039 # see if we can re-use an existing [svn-remote "repo_id"]
6040 # instead of creating a(n ugly) new section:
6041 my $repo_id = $root_repos->{$url} || $url;
6042
6043 my $fetch = $new_urls->{$url};
6044 foreach my $path (keys %$fetch) {
6045 my $x = $fetch->{$path};
6046 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
6047 my $pfx = "svn-remote.$x->{old_repo_id}";
6048
6049 my $old_fetch = quotemeta("$x->{old_path}:".
6050 "$x->{ref_id}");
6051 command_noisy(qw/config --unset/,
6052 "$pfx.fetch", '^'. $old_fetch . '$');
6053 delete $r->{$x->{old_repo_id}}->
6054 {fetch}->{$x->{old_path}};
6055 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
6056 command_noisy(qw/config --unset/,
6057 "$pfx.url");
6058 push @emptied, $x->{old_repo_id}
6059 }
6060 }
6061 }
6062 if (@emptied) {
6063 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
6064 print STDERR <<EOF;
6065 The following [svn-remote] sections in your config file ($file) are empty
6066 and can be safely removed:
6067 EOF
6068 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
6069 }
6070 }
6071
6072 sub migration_check {
6073 migrate_from_v0();
6074 migrate_from_v1();
6075 migrate_from_v2();
6076 minimize_connections() if $_minimize;
6077 }
6078
6079 package Git::IndexInfo;
6080 use strict;
6081 use warnings;
6082 use Git qw/command_input_pipe command_close_pipe/;
6083
6084 sub new {
6085 my ($class) = @_;
6086 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
6087 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
6088 }
6089
6090 sub remove {
6091 my ($self, $path) = @_;
6092 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
6093 return ++$self->{nr};
6094 }
6095 undef;
6096 }
6097
6098 sub update {
6099 my ($self, $mode, $hash, $path) = @_;
6100 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
6101 return ++$self->{nr};
6102 }
6103 undef;
6104 }
6105
6106 sub DESTROY {
6107 my ($self) = @_;
6108 command_close_pipe($self->{gui}, $self->{ctx});
6109 }
6110
6111 package Git::SVN::GlobSpec;
6112 use strict;
6113 use warnings;
6114
6115 sub new {
6116 my ($class, $glob, $pattern_ok) = @_;
6117 my $re = $glob;
6118 $re =~ s!/+$!!g; # no need for trailing slashes
6119 my (@left, @right, @patterns);
6120 my $state = "left";
6121 my $die_msg = "Only one set of wildcard directories " .
6122 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
6123 for my $part (split(m|/|, $glob)) {
6124 if ($part =~ /\*/ && $part ne "*") {
6125 die "Invalid pattern in '$glob': $part\n";
6126 } elsif ($pattern_ok && $part =~ /[{}]/ &&
6127 $part !~ /^\{[^{}]+\}/) {
6128 die "Invalid pattern in '$glob': $part\n";
6129 }
6130 if ($part eq "*") {
6131 die $die_msg if $state eq "right";
6132 $state = "pattern";
6133 push(@patterns, "[^/]*");
6134 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
6135 die $die_msg if $state eq "right";
6136 $state = "pattern";
6137 my $p = quotemeta($1);
6138 $p =~ s/\\,/|/g;
6139 push(@patterns, "(?:$p)");
6140 } else {
6141 if ($state eq "left") {
6142 push(@left, $part);
6143 } else {
6144 push(@right, $part);
6145 $state = "right";
6146 }
6147 }
6148 }
6149 my $depth = @patterns;
6150 if ($depth == 0) {
6151 die "One '*' is needed in glob: '$glob'\n";
6152 }
6153 my $left = join('/', @left);
6154 my $right = join('/', @right);
6155 $re = join('/', @patterns);
6156 $re = join('\/',
6157 grep(length, quotemeta($left), "($re)", quotemeta($right)));
6158 my $left_re = qr/^\/\Q$left\E(\/|$)/;
6159 bless { left => $left, right => $right, left_regex => $left_re,
6160 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
6161 }
6162
6163 sub full_path {
6164 my ($self, $path) = @_;
6165 return (length $self->{left} ? "$self->{left}/" : '') .
6166 $path . (length $self->{right} ? "/$self->{right}" : '');
6167 }
6168
6169 __END__
6170
6171 Data structures:
6172
6173
6174 $remotes = { # returned by read_all_remotes()
6175 'svn' => {
6176 # svn-remote.svn.url=https://svn.musicpd.org
6177 url => 'https://svn.musicpd.org',
6178 # svn-remote.svn.fetch=mpd/trunk:trunk
6179 fetch => {
6180 'mpd/trunk' => 'trunk',
6181 },
6182 # svn-remote.svn.tags=mpd/tags/*:tags/*
6183 tags => {
6184 path => {
6185 left => 'mpd/tags',
6186 right => '',
6187 regex => qr!mpd/tags/([^/]+)$!,
6188 glob => 'tags/*',
6189 },
6190 ref => {
6191 left => 'tags',
6192 right => '',
6193 regex => qr!tags/([^/]+)$!,
6194 glob => 'tags/*',
6195 },
6196 }
6197 }
6198 };
6199
6200 $log_entry hashref as returned by libsvn_log_entry()
6201 {
6202 log => 'whitespace-formatted log entry
6203 ', # trailing newline is preserved
6204 revision => '8', # integer
6205 date => '2004-02-24T17:01:44.108345Z', # commit date
6206 author => 'committer name'
6207 };
6208
6209
6210 # this is generated by generate_diff();
6211 @mods = array of diff-index line hashes, each element represents one line
6212 of diff-index output
6213
6214 diff-index line ($m hash)
6215 {
6216 mode_a => first column of diff-index output, no leading ':',
6217 mode_b => second column of diff-index output,
6218 sha1_b => sha1sum of the final blob,
6219 chg => change type [MCRADT],
6220 file_a => original file name of a file (iff chg is 'C' or 'R')
6221 file_b => new/current file name of a file (any chg)
6222 }
6223 ;
6224
6225 # retval of read_url_paths{,_all}();
6226 $l_map = {
6227 # repository root url
6228 'https://svn.musicpd.org' => {
6229 # repository path # GIT_SVN_ID
6230 'mpd/trunk' => 'trunk',
6231 'mpd/tags/0.11.5' => 'tags/0.11.5',
6232 },
6233 }
6234
6235 Notes:
6236 I don't trust the each() function on unless I created %hash myself
6237 because the internal iterator may not have started at base.