sysdeps/gnu/errlist-compat.awk

   1 # awk script to generate errlist-compat.c
   2 # Copyright (C) 2002 Free Software Foundation, Inc.
   3 # This file is part of the GNU C Library.
   4
   5 # The GNU C Library is free software; you can redistribute it and/or
   6 # modify it under the terms of the GNU Lesser General Public
   7 # License as published by the Free Software Foundation; either
   8 # version 2.1 of the License, or (at your option) any later version.
   9
  10 # The GNU C Library is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # Lesser General Public License for more details.
  14
  15 # You should have received a copy of the GNU Lesser General Public
  16 # License along with the GNU C Library; if not, write to the Free
  17 # Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307 USA.
  19
  20 #
  21 # This script takes the Versions file as input and looks for #errlist-compat
  22 # magic comments, which have the form:
  23 #       #errlist-compat NNN
  24 # where NNN is the number of elements in the sys_errlist for that version set.
  25 # We need the awk variable `maxerr' defined to the current size of sys_errlist.
  26 #
  27 # If there is no magic comment matching the current size, we barf.
  28 # Otherwise we generate code (errlist-compat.c) to define all the
  29 # necessary compatibility symbols for older, smaller versions of sys_errlist.
  30 #
  31
  32 # These two rules catch the Versions file contents.
  33 NF == 2 && $2 == "{" { last_version = $1; next }
  34 $1 == "#errlist-compat" {
  35   # Don't process any further Versions files
  36   ARGC = ARGIND + 1;
  37   cnt = $2 + 0;
  38   if (cnt < 100) {
  39     print "*** this line seems bogus:", $0 > "/dev/stderr";
  40     exit 1;
  41   }
  42   version[pos + 0] = cnt SUBSEP last_version;
  43   pos++;
  44   if (cnt < highest) {
  45     printf "*** %s #errlist-compat counts are not sorted\n", ARGV[ARGIND];
  46     exit 1;
  47   }
  48   if (cnt > highest)
  49     highest = cnt;
  50   highest_version = last_version;
  51   next;
  52 }
  53
  54 END {
  55   count = maxerr + 1;
  56
  57   if (highest != count) {
  58     printf "*** errlist.c count %d vs Versions sys_errlist@%s count %d\n", \
  59       count, highest_version, highest > "/dev/stderr";
  60     exit 1;
  61   }
  62
  63   lastv = "";
  64   for (n = 0; n < pos; ++n) {
  65     split(version[n], t, SUBSEP)
  66     v = t[2];
  67     gsub(/[^A-Z0-9_]/, "_", v);
  68     if (lastv != "")
  69       compat[lastv] = v;
  70     lastv = v;
  71     vcount[v] = t[1];
  72   }
  73
  74   print "/* This file was generated by errlist-compat.awk; DO NOT EDIT!  */\n";
  75   print "#include <shlib-compat.h>\n";
  76
  77   for (old in compat) {
  78     new = compat[old];
  79     n = vcount[old];
  80     printf "#if SHLIB_COMPAT (libc, %s, %s)\n", old, new;
  81     printf "# include <bits/wordsize.h>\n";
  82     printf "extern const char *const __sys_errlist_%s[];\n", old;
  83     printf "const int __sys_nerr_%s = %d;\n", old, n;
  84     printf "strong_alias (_sys_errlist_internal, __sys_errlist_%s)\n", old;
  85     printf "declare_symbol (__sys_errlist_%s, object, __WORDSIZE/8*%d)\n", \
  86       old, n;
  87     printf "compat_symbol (libc, __sys_errlist_%s, sys_errlist, %s);\n", \
  88       old, old;
  89     printf "compat_symbol (libc, __sys_nerr_%s, sys_nerr, %s);\n", old, old;
  90
  91     printf "extern const char *const ___sys_errlist_%s[];\n", old;
  92     printf "extern const int __sys_nerr_%s;\n", old;
  93     printf "strong_alias (__sys_errlist_%s, ___sys_errlist_%s)\n", old, old;
  94     printf "strong_alias (__sys_nerr_%s, ___sys_nerr_%s)\n", old, old;
  95     printf "compat_symbol (libc, ___sys_errlist_%s, _sys_errlist, %s);\n", \
  96       old, old;
  97     printf "compat_symbol (libc, ___sys_nerr_%s, _sys_nerr, %s);\n", old, old;
  98     printf "#endif\n\n";
  99   }
 100
 101   printf "\
 102 extern const char *const __sys_errlist_internal[];\n\
 103 extern const int __sys_nerr_internal;\n\
 104 strong_alias (_sys_errlist_internal, __sys_errlist_internal)\n\
 105 strong_alias (_sys_nerr_internal, __sys_nerr_internal)\n\
 106 versioned_symbol (libc, _sys_errlist_internal, sys_errlist, %s);\n\
 107 versioned_symbol (libc, __sys_errlist_internal, _sys_errlist, %s);\n\
 108 versioned_symbol (libc, _sys_nerr_internal, sys_nerr, %s);\n\
 109 versioned_symbol (libc, __sys_nerr_internal, _sys_nerr, %s);\n", \
 110     lastv, lastv, lastv, lastv;
 111 }