sysdeps/i386/fpu/s_frexp.S

   1 /* ix87 specific frexp implementation for double.
   2    Copyright (C) 1997-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include <libm-alias-double.h>
  22
  23         .section .rodata
  24
  25         .align ALIGNARG(4)
  26         .type two54,@object
  27 two54:  .byte 0, 0, 0, 0, 0, 0, 0x50, 0x43
  28         ASM_SIZE_DIRECTIVE(two54)
  29
  30 #ifdef PIC
  31 #define MO(op) op##@GOTOFF(%edx)
  32 #else
  33 #define MO(op) op
  34 #endif
  35
  36 #define PARMS   4               /* no space for saved regs */
  37 #define VAL0    PARMS
  38 #define VAL1    VAL0+4
  39 #define EXPP    VAL1+4
  40
  41         .text
  42 ENTRY (__frexp)
  43
  44         movl    VAL0(%esp), %ecx
  45         movl    VAL1(%esp), %eax
  46         movl    %eax, %edx
  47         andl    $0x7fffffff, %eax
  48         orl     %eax, %ecx
  49         jz      1f
  50         xorl    %ecx, %ecx
  51         cmpl    $0x7ff00000, %eax
  52         jae     1f
  53
  54         cmpl    $0x00100000, %eax
  55         jae     2f
  56
  57         fldl    VAL0(%esp)
  58 #ifdef  PIC
  59         LOAD_PIC_REG (dx)
  60 #endif
  61         fmull   MO(two54)
  62         movl    $-54, %ecx
  63         fstpl   VAL0(%esp)
  64         fwait
  65         movl    VAL1(%esp), %eax
  66         movl    %eax, %edx
  67         andl    $0x7fffffff, %eax
  68
  69 2:      shrl    $20, %eax
  70         andl    $0x800fffff, %edx
  71         subl    $1022, %eax
  72         orl     $0x3fe00000, %edx
  73         addl    %eax, %ecx
  74         movl    %edx, VAL1(%esp)
  75
  76         /* Store %ecx in the variable pointed to by the second argument,
  77            get the factor from the stack and return.  */
  78 1:      movl    EXPP(%esp), %eax
  79         fldl    VAL0(%esp)
  80         movl    %ecx, (%eax)
  81
  82         ret
  83 END (__frexp)
  84 libm_alias_double (__frexp, frexp)