sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <jmp_buf-ssp.h>
  22 #include <asm-syntax.h>
  23 #include <stap-probe.h>
  24
  25 #define PARMS   4               /* no space for saved regs */
  26 #define JMPBUF  PARMS
  27 #define SIGMSK  JMPBUF+4
  28
  29 /* Don't save shadow stack register if shadow stack isn't enabled.  */
  30 #if !SHSTK_ENABLED
  31 # undef SHADOW_STACK_POINTER_OFFSET
  32 #endif
  33
  34 ENTRY (__sigsetjmp)
  35
  36         movl JMPBUF(%esp), %eax
  37
  38         /* Save registers.  */
  39         movl %ebx, (JB_BX*4)(%eax)
  40         movl %esi, (JB_SI*4)(%eax)
  41         movl %edi, (JB_DI*4)(%eax)
  42         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%ecx)
  45 #endif
  46         movl %ecx, (JB_SP*4)(%eax)
  47         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  48         LIBC_PROBE (setjmp, 3, 4@%eax, -4@SIGMSK(%esp), 4@%ecx)
  49 #ifdef PTR_MANGLE
  50         PTR_MANGLE (%ecx)
  51 #endif
  52         movl %ecx, (JB_PC*4)(%eax)
  53         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  54
  55 #ifdef SHADOW_STACK_POINTER_OFFSET
  56 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  57         /* Check if Shadow Stack is enabled.  */
  58         testl $X86_FEATURE_1_SHSTK, %gs:FEATURE_1_OFFSET
  59         jz L(skip_ssp)
  60 # else
  61         xorl %ecx, %ecx
  62 # endif
  63         /* Get the current Shadow-Stack-Pointer and save it.  */
  64         rdsspd %ecx
  65         movl %ecx, SHADOW_STACK_POINTER_OFFSET(%eax)
  66 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  67 L(skip_ssp):
  68 # endif
  69 #endif
  70 #if IS_IN (rtld)
  71         /* In ld.so we never save the signal mask.  */
  72         xorl %eax, %eax
  73         ret
  74 #else
  75         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  76         jmp __sigjmp_save
  77 #endif
  78 END (__sigsetjmp)
  79 hidden_def (__sigsetjmp)