sysdeps/powerpc/powerpc32/fpu/s_ceilf.S

   1 /* float ceil function.  PowerPC32 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        .rodata.cst4,"aM",@progbits,4
  22         .align  2
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25
  26         .section        ".text"
  27 ENTRY (__ceilf)
  28         mffs    fp11            /* Save current FPU rounding mode.  */
  29 #ifdef SHARED
  30         mflr    r11
  31         cfi_register(lr,r11)
  32         SETUP_GOT_ACCESS(r9,got_label)
  33         addis   r9,r9,.LC0-got_label@ha
  34         lfs     fp13,.LC0-got_label@l(r9)
  35         mtlr    r11
  36         cfi_same_value (lr)
  37 #else
  38         lis     r9,.LC0@ha
  39         lfs     fp13,.LC0@l(r9)
  40 #endif
  41         fabs    fp0,fp1
  42         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  43         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  44         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  45         bnllr-  cr7
  46         mtfsfi  7,2             /* Set rounding mode toward +inf.  */
  47         ble-    cr6,.L4
  48         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  49         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  50         fabs    fp1,fp1         /* if (x == 0.0)  */
  51                                 /* x = 0.0; */
  52         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  53         blr
  54 .L4:
  55         bge-    cr6,.L9         /* if (x < 0.0)  */
  56         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  57         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  58         fnabs   fp1,fp1         /* if (x == 0.0)  */
  59                                 /* x = -0.0; */
  60 .L9:
  61         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  62         blr
  63         END (__ceilf)
  64
  65 weak_alias (__ceilf, ceilf)
  66