sysdeps/powerpc/powerpc32/fpu/s_round.S

   1 /* round function.  PowerPC32 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        .rodata.cst8,"aM",@progbits,8
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26 .LC1:   /* 0.5 */
  27         .long 0x3f000000
  28
  29 /* double [fp1] round (double x [fp1])
  30    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "Round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  36    "Round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.  */
  38
  39         .section        ".text"
  40 ENTRY (__round)
  41         mffs    fp11            /* Save current FPU rounding mode.  */
  42 #ifdef SHARED
  43         mflr    r11
  44         cfi_register(lr,r11)
  45         SETUP_GOT_ACCESS(r9,got_label)
  46         addis   r9,r9,.LC0-got_label@ha
  47         addi    r9,r9,.LC0-got_label@l
  48         mtlr    r11
  49         cfi_same_value (lr)
  50         lfs     fp13,0(r9)
  51 #else
  52         lis     r9,.LC0@ha
  53         lfs     fp13,.LC0@l(r9)
  54 #endif
  55         fabs    fp0,fp1
  56         fsub    fp12,fp13,fp13  /* generate 0.0  */
  57         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  58         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  59         bnllr-  cr7
  60         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  61 #ifdef SHARED
  62         lfs     fp10,.LC1-.LC0(r9)
  63 #else
  64         lis     r9,.LC1@ha
  65         lfs     fp10,.LC1@l(r9)
  66 #endif
  67         ble-    cr6,.L4
  68         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  69         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  70         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  71         fabs    fp1,fp1         /* if (x == 0.0)  */
  72                                 /* x = 0.0; */
  73         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  74         blr
  75 .L4:
  76         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  77         bge-    cr6,.L9         /* if (x < 0.0)  */
  78         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  79         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  80         fnabs   fp1,fp1         /* if (x == 0.0)  */
  81                                 /* x = -0.0; */
  82 .L9:
  83         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  84         blr
  85         END (__round)
  86
  87 weak_alias (__round, round)
  88
  89 #ifdef NO_LONG_DOUBLE
  90 weak_alias (__round, roundl)
  91 strong_alias (__round, __roundl)
  92 #endif
  93 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  94 compat_symbol (libm, __round, roundl, GLIBC_2_1)
  95 #endif