sysdeps/powerpc/powerpc64/fpu/s_ceil.S

   1 /* ceil function.  PowerPC64 version.
   2    Copyright (C) 2004-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21 #include <libm-alias-double.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2**52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26         .section        ".text"
  27
  28 ENTRY (__ceil, 4)
  29         CALL_MCOUNT 0
  30         lfd     fp13,.LC0@toc(2)
  31         fabs    fp0,fp1
  32         fsub    fp12,fp13,fp13  /* generate 0.0  */
  33         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  34         mffs    fp11            /* Save current FPU rounding mode and
  35                                    "inexact" state.  */
  36         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  37         bnl-    cr7,.L10
  38         mtfsfi  7,2             /* Set rounding mode toward +inf.  */
  39         ble-    cr6,.L4
  40         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  41         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  42         fabs    fp1,fp1         /* if (x == 0.0)  */
  43                                 /* x = 0.0; */
  44         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  45                                    "inexact" state.  */
  46         blr
  47 .L4:
  48         bge-    cr6,.L9         /* if (x < 0.0)  */
  49         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  50         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  51         fnabs   fp1,fp1         /* if (x == 0.0)  */
  52                                 /* x = -0.0; */
  53 .L9:
  54         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  55                                    "inexact" state.  */
  56         blr
  57 .L10:
  58         /* Ensure sNaN input is converted to qNaN.  */
  59         fcmpu   cr7,fp1,fp1
  60         beqlr   cr7
  61         fadd    fp1,fp1,fp1
  62         blr
  63         END (__ceil)
  64
  65 libm_alias_double (__ceil, ceil)