sysdeps/powerpc/powerpc64/fpu/s_llroundf.S

   1 /* llroundf function.  PowerPC64 version.
   2    Copyright (C) 2004-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22 .LC0:   /* 2^23 */
  23         .tc FD_41600000_0[TC],0x4160000000000000
  24 .LC1:   /* 0.5 */
  25         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  26         .section        ".text"
  27
  28 /* long long [r3] llroundf (float x [fp1])
  29    IEEE 1003.1 llroundf function.  IEEE specifies "roundf to the nearest
  30    integer value, rounding halfway cases away from zero, regardless of
  31    the current rounding mode."  However PowerPC Architecture defines
  32    "roundf to Nearest" as "Choose the best approximation. In case of a
  33    tie, choose the one that is even (least significant bit o).".
  34    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  35    "round toward Zero" mode and round by adding +-0.5 before rounding
  36    to the integer value.
  37
  38    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  39    because adding +-0.5 in this case will cause an erroneous shift,
  40    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  41    if x is and odd number between +-(2^23 and 2^24-1) a shift and
  42    carry will erroneously round if biased with +-0.5.  Therefore if x
  43    is greater/less than +-2^23 we don't need to bias the number with
  44    +-0.5.  */
  45
  46 ENTRY (__llroundf)
  47         CALL_MCOUNT 0
  48         lfd     fp9,.LC0@toc(2) /* Load 2^23 into fpr9.  */
  49         lfd     fp10,.LC1@toc(2)/* Load 0.5 into fpr10.  */
  50         fabs    fp2,fp1         /* Get the absolute value of x.  */
  51         fsub    fp12,fp10,fp10  /* Compute 0.0 into fp12.  */
  52         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  53         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^23  */
  54         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  55         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  56         bge-    cr7,.Lnobias    /* 2^23 > x < -2^23 just convert with no bias.  */
  57         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  58         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  59         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  60 .Lconvert:
  61         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  62         stfd    fp4,-16(r1)
  63         nop
  64         nop
  65         nop
  66         ld      r3,-16(r1)      /* Load return as integer.  */
  67 .Lout:
  68         blr
  69 .Lretzero:                      /* 0.5 > x > -0.5  */
  70         li      r3,0            /* return 0.  */
  71         b       .Lout
  72 .Lnobias:
  73         fmr     fp3,fp1
  74         b       .Lconvert
  75         END (__llroundf)
  76
  77 strong_alias (__llroundf, __lroundf)
  78 weak_alias (__llroundf, llroundf)
  79 weak_alias (__lroundf, lroundf)
  80