sysdeps/powerpc/powerpc64/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2004-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This has been coded in assembler because GCC makes such a mess of it
  20    when it's coded in C.  */
  21
  22 #include <sysdep.h>
  23 #include <math_ldbl_opt.h>
  24 #include <libm-alias-double.h>
  25
  26         .section        ".toc","aw"
  27 .LC0:   /* 2**52 */
  28         .tc FD_43300000_0[TC],0x4330000000000000
  29         .section        ".text"
  30
  31 ENTRY (__rint, 4)
  32         CALL_MCOUNT 0
  33         lfd     fp13,.LC0@toc(2)
  34         fabs    fp0,fp1
  35         fsub    fp12,fp13,fp13  /* generate 0.0  */
  36         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  37         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  38         bnl     cr7,.L10
  39         bng     cr6,.L4
  40         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  41         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  42         fabs    fp1,fp1         /* if (x == 0.0)  */
  43         blr                     /* x = 0.0; */
  44 .L4:
  45         bnllr   cr6             /* if (x < 0.0)  */
  46         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  47         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  48         fnabs   fp1,fp1         /* if (x == 0.0)  */
  49         blr                     /* x = -0.0; */
  50 .L10:
  51         /* Ensure sNaN input is converted to qNaN.  */
  52         fcmpu   cr7,fp1,fp1
  53         beqlr   cr7
  54         fadd    fp1,fp1,fp1
  55         blr
  56         END (__rint)
  57
  58 libm_alias_double (__rint, rint)