sysdeps/powerpc/powerpc64/fpu/s_roundf.S

   1 /* roundf  function.  PowerPC64 version.
   2    Copyright (C) 2004-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <libm-alias-float.h>
  21
  22         .section        ".toc","aw"
  23         .p2align 3
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26 .LC1:   /* 0.5 */
  27         .long 0x3f000000
  28
  29         .section        ".text"
  30
  31 /* float [fp1] roundf  (float x [fp1])
  32    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  33    integer value, rounding halfway cases away from zero, regardless of
  34    the current rounding mode."  However PowerPC Architecture defines
  35    "Round to Nearest" as "Choose the best approximation. In case of a
  36    tie, choose the one that is even (least significant bit o).".
  37    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  38    "Round toward Zero" mode and round by adding +-0.5 before rounding
  39    to the integer value.  */
  40
  41 ENTRY (__roundf, 4)
  42         CALL_MCOUNT 0
  43         lfs     fp13,.LC0@toc(2)
  44         fabs    fp0,fp1
  45         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  46         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  47         mffs    fp11            /* Save current FPU rounding mode and
  48                                    "inexact" state.  */
  49         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  50         bnl-    cr7,.L10
  51         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  52         lfs     fp10,.LC1@toc(2)
  53         ble-    cr6,.L4
  54         fadds   fp1,fp1,fp10    /* x+= 0.5;  */
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  57         fabs    fp1,fp1         /* if (x == 0.0)  */
  58                                 /* x = 0.0; */
  59         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  60                                    "inexact" state.  */
  61         blr
  62 .L4:
  63         fsubs   fp9,fp1,fp10    /* x+= 0.5;  */
  64         bge-    cr6,.L9         /* if (x < 0.0)  */
  65         fsubs   fp1,fp9,fp13    /* x-= TWO23;  */
  66         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  67         fnabs   fp1,fp1         /* if (x == 0.0)  */
  68                                 /* x = -0.0; */
  69 .L9:
  70         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  71                                    "inexact" state.  */
  72         blr
  73 .L10:
  74         /* Ensure sNaN input is converted to qNaN.  */
  75         fcmpu   cr7,fp1,fp1
  76         beqlr   cr7
  77         fadds   fp1,fp1,fp1
  78         blr
  79         END (__roundf)
  80
  81 libm_alias_float (__round, round)
  82