sysdeps/sparc/sparc32/__longjmp.S

   1 /* Copyright (C) 1991-2018 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19
  20 #include <jmpbuf-offsets.h>
  21 #define ENV(base,reg) [%base + (reg * 4)]
  22 #define ST_FLUSH_WINDOWS 3
  23
  24 ENTRY(__longjmp)
  25         /* Store our arguments in global registers so we can still
  26            use them while unwinding frames and their register windows.  */
  27
  28         ld ENV(o0,JB_FP), %g3   /* Cache target FP in register %g3.  */
  29 #ifdef PTR_DEMANGLE
  30         PTR_DEMANGLE (%g3, %g3, %g4)
  31 #endif
  32         mov %o0, %g1            /* ENV in %g1 */
  33         orcc %o1, %g0, %g2      /* VAL in %g2 */
  34         be,a 0f                 /* Branch if zero; else skip delay slot.  */
  35          mov 1, %g2             /* Delay slot only hit if zero: VAL = 1.  */
  36 0:
  37         xor %fp, %g3, %o0
  38         add %fp, 512, %o1
  39         andncc %o0, 4095, %o0
  40         bne LOC(thread)
  41          cmp %o1, %g3
  42         bl LOC(thread)
  43
  44         /* Now we will loop, unwinding the register windows up the stack
  45            until the restored %fp value matches the target value in %g3.  */
  46
  47 LOC(loop):
  48         cmp %fp, %g3            /* Have we reached the target frame? */
  49         bl,a LOC(loop)          /* Loop while current fp is below target.  */
  50          restore                /* Unwind register window in delay slot.  */
  51         be,a LOC(found)         /* Better have hit it exactly.  */
  52          ld ENV(g1,JB_SP), %o0  /* Delay slot: extract target SP.  */
  53
  54 LOC(thread):
  55         save    %sp, -96, %sp
  56         /*
  57          * Do a "flush register windows trap".  The trap handler in the
  58          * kernel writes all the register windows to their stack slots, and
  59          * marks them all as invalid (needing to be sucked up from the
  60          * stack when used).  This ensures that all information needed to
  61          * unwind to these callers is in memory, not in the register
  62          * windows.
  63          */
  64         ta      ST_FLUSH_WINDOWS
  65 #ifdef PTR_DEMANGLE
  66         ld      ENV(g1,JB_PC), %g5 /* Set return PC. */
  67         ld      ENV(g1,JB_SP), %g1 /* Set saved SP on restore below. */
  68         PTR_DEMANGLE2 (%i7, %g5, %g4)
  69         PTR_DEMANGLE2 (%fp, %g1, %g4)
  70 #else
  71         ld      ENV(g1,JB_PC), %i7 /* Set return PC. */
  72         ld      ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */
  73 #endif
  74         jmp     %i7 + 8
  75          restore %g2, 0, %o0    /* Restore values from above register frame. */
  76
  77 LOC(found):
  78         /* We have unwound register windows so %fp matches the target.  */
  79 #ifdef PTR_DEMANGLE
  80         PTR_DEMANGLE2 (%sp, %o0, %g4)
  81 #else
  82         mov %o0, %sp            /* OK, install new SP.  */
  83 #endif
  84
  85 LOC(sp_ok):
  86         ld ENV(g1,JB_PC), %o0   /* Extract target return PC.  */
  87 #ifdef PTR_DEMANGLE
  88         PTR_DEMANGLE2 (%o0, %o0, %g4)
  89 #endif
  90         jmp %o0 + 8             /* Return there.  */
  91          mov %g2, %o0           /* Delay slot: set return value.  */
  92
  93 END(__longjmp)