sysdeps/unix/sysv/linux/ia64/setcontext.S

   1 /* Copyright (C) 2001-2015 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3      Contributed by David Mosberger-Tang <davidm@hpl.hp.com>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __setcontext (const ucontext_t *ucp)
  25
  26   Restores the machine context in UCP and thereby resumes execution
  27   in that context.
  28
  29   This implementation in intended to be used for *synchronous* context
  30   switches only.  Therefore, it does not have to restore anything
  31   other than the PRESERVED state.  */
  32
  33 ENTRY(__setcontext)
  34         .prologue
  35         .body
  36         alloc r11 = ar.pfs, 1, 0, 4, 0
  37
  38         // sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL):
  39
  40         mov r3 = SC_MASK
  41         mov out0 = SIG_SETMASK
  42         ;;
  43         add out1 = r3, in0
  44         mov out2 = 0
  45         mov out3 = 8    // sizeof kernel sigset_t
  46
  47         invala
  48         DO_CALL(__NR_rt_sigprocmask)
  49         add r2 = SC_NAT, r32
  50
  51         add r3 = SC_RNAT, r32                   // r3 <- &sc_ar_rnat
  52         add rPOS = SC_GR, r32                   // rPOS <- &sc_gr[0]
  53         ;;
  54         ld8 rNAT = [r2], (SC_BSP-SC_NAT)
  55         extr.u rPOS = rPOS, 3, 6                // get NaT bit number for r0
  56         ;;
  57         ld8 rBSP = [r2], (SC_UNAT-SC_BSP)
  58         ld8 rRNAT = [r3], (SC_FPSR-SC_RNAT)
  59         /*
  60          * Rotate NaT bits by rPOS positions to the left:
  61          */
  62         sub rCPOS = 64, rPOS
  63         ;;
  64         ld8 rUNAT = [r2], (SC_PFS-SC_UNAT)
  65         ld8 rFPSR = [r3], (SC_LC-SC_FPSR)
  66         shl rTMP = rNAT, rPOS
  67         ;;
  68         ld8 rPFS = [r2], (SC_PR-SC_PFS)
  69         ld8 rLC = [r3], (SC_BR+0*8-SC_LC)
  70         shr.u rNAT = rNAT, rCPOS
  71         ;;
  72         ld8 rPR = [r2], (SC_BR+1*8-SC_PR)
  73         ld8 rB0 = [r3], 16
  74         or rNAT = rNAT, rTMP
  75         ;;
  76         ld8 rB1 = [r2], 16
  77         ld8 rB2 = [r3], 16
  78         ;;
  79         mov.m ar.unat = rNAT
  80         mov.m rRSC = ar.rsc
  81         ;;
  82         ld8 rB3 = [r2], 16
  83         ld8 rB4 = [r3], (SC_GR+1*8-(SC_BR+4*8))
  84         ;;
  85         ld8 rB5 = [r2], (SC_GR+4*8-(SC_BR+5*8))
  86         ld8.fill r1 = [r3], (5*8 - 1*8)
  87         ;;
  88         ld8.fill r4 = [r2], 16
  89         ld8.fill r5 = [r3], 16
  90         mov b0 = rB0
  91         ;;
  92         ld8.fill r6 = [r2], 48
  93         ld8.fill r7 = [r3], (SC_FR+2*16-(SC_GR+7*8))
  94         ;;
  95         ld8.fill sp = [r2], (SC_FR+3*16-(SC_GR+12*8))
  96         mov.m ar.fpsr = rFPSR
  97         mov.i ar.pfs = rPFS
  98         ;;
  99         ldf.fill f3 = [r2], 16
 100         ldf.fill f2 = [r3], 48
 101         mov b1 = rB1
 102         ;;
 103         ldf.fill f4 = [r2], (16*16-4*16)
 104         ldf.fill f5 = [r3], (17*16-5*16)
 105         mov b2 = rB2
 106         ;;
 107         ldf.fill f16 = [r2], 32
 108         ldf.fill f17 = [r3], 32
 109         mov b3 = rB3
 110         ;;
 111         ldf.fill f18 = [r2], 32
 112         ldf.fill f19 = [r3], 32
 113         mov b4 = rB4
 114         ;;
 115         ldf.fill f20 = [r2], 32
 116         ldf.fill f21 = [r3], 32
 117         mov b5 = rB5
 118         ;;
 119         ldf.fill f22 = [r2], 32
 120         ldf.fill f23 = [r3], 32
 121         mov r8 = 0
 122         ;;
 123         ldf.fill f24 = [r2], 32
 124         ldf.fill f25 = [r3], 32
 125         mov r9 = 0
 126         ;;
 127         ldf.fill f26 = [r2], 32
 128         ldf.fill f27 = [r3], 32
 129         dep rTMP = 0, rRSC, 16, 14      // clear ar.rsc.loadrs
 130         ;;
 131         ldf.fill f28 = [r2], 32
 132         ldf.fill f29 = [r3], 32
 133         and rTMP = ~0x3, rTMP           // clear ar.rsc.mode
 134         ;;
 135         ldf.fill f30 = [r2], 32
 136         ldf.fill f31 = [r3], 32
 137         mov pr = rPR, -1
 138         ;;
 139         mov.m ar.rsc = rTMP             // put RSE into enforced lazy mode
 140         ;;
 141         loadrs                          // drop dirty partition
 142         ;;
 143         mov.m ar.bspstore = rBSP
 144         mov.m ar.unat = rUNAT
 145         mov.i ar.lc = rLC
 146         ;;
 147         mov.m ar.rnat = rRNAT
 148         mov.m ar.rsc = rRSC
 149         ret
 150 END(__setcontext)
 151
 152 weak_alias (__setcontext, setcontext)