]> git.ipfire.org Git - thirdparty/kernel/stable.git/blob - arch/arm64/kernel/entry.S
projects / thirdparty / kernel / stable.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
arm64: entry.S: move SError handling into a C function for future expansion
[thirdparty/kernel/stable.git] / arch / arm64 / kernel / entry.S
1 /*
2 * Low-level exception handling code
3 *
4 * Copyright (C) 2012 ARM Ltd.
5 * Authors: Catalin Marinas <catalin.marinas@arm.com>
6 * Will Deacon <will.deacon@arm.com>
7 *
8 * This program is free software; you can redistribute it and/or modify
9 * it under the terms of the GNU General Public License version 2 as
10 * published by the Free Software Foundation.
11 *
12 * This program is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 * GNU General Public License for more details.
16 *
17 * You should have received a copy of the GNU General Public License
18 * along with this program. If not, see <http://www.gnu.org/licenses/>.
19 */
20
21 #include <linux/init.h>
22 #include <linux/linkage.h>
23
24 #include <asm/alternative.h>
25 #include <asm/assembler.h>
26 #include <asm/asm-offsets.h>
27 #include <asm/cpufeature.h>
28 #include <asm/errno.h>
29 #include <asm/esr.h>
30 #include <asm/irq.h>
31 #include <asm/processor.h>
32 #include <asm/ptrace.h>
33 #include <asm/thread_info.h>
34 #include <asm/asm-uaccess.h>
35 #include <asm/unistd.h>
36
37 /*
38 * Context tracking subsystem. Used to instrument transitions
39 * between user and kernel mode.
40 */
41 .macro ct_user_exit, syscall = 0
42 #ifdef CONFIG_CONTEXT_TRACKING
43 bl context_tracking_user_exit
44 .if \syscall == 1
45 /*
46 * Save/restore needed during syscalls. Restore syscall arguments from
47 * the values already saved on stack during kernel_entry.
48 */
49 ldp x0, x1, [sp]
50 ldp x2, x3, [sp, #S_X2]
51 ldp x4, x5, [sp, #S_X4]
52 ldp x6, x7, [sp, #S_X6]
53 .endif
54 #endif
55 .endm
56
57 .macro ct_user_enter
58 #ifdef CONFIG_CONTEXT_TRACKING
59 bl context_tracking_user_enter
60 #endif
61 .endm
62
63 /*
64 * Bad Abort numbers
65 *-----------------
66 */
67 #define BAD_SYNC 0
68 #define BAD_IRQ 1
69 #define BAD_FIQ 2
70 #define BAD_ERROR 3
71
72 .macro kernel_ventry label
73 .align 7
74 sub sp, sp, #S_FRAME_SIZE
75 #ifdef CONFIG_VMAP_STACK
76 /*
77 * Test whether the SP has overflowed, without corrupting a GPR.
78 * Task and IRQ stacks are aligned to (1 << THREAD_SHIFT).
79 */
80 add sp, sp, x0 // sp' = sp + x0
81 sub x0, sp, x0 // x0' = sp' - x0 = (sp + x0) - x0 = sp
82 tbnz x0, #THREAD_SHIFT, 0f
83 sub x0, sp, x0 // x0'' = sp' - x0' = (sp + x0) - sp = x0
84 sub sp, sp, x0 // sp'' = sp' - x0 = (sp + x0) - x0 = sp
85 b \label
86
87 0:
88 /*
89 * Either we've just detected an overflow, or we've taken an exception
90 * while on the overflow stack. Either way, we won't return to
91 * userspace, and can clobber EL0 registers to free up GPRs.
92 */
93
94 /* Stash the original SP (minus S_FRAME_SIZE) in tpidr_el0. */
95 msr tpidr_el0, x0
96
97 /* Recover the original x0 value and stash it in tpidrro_el0 */
98 sub x0, sp, x0
99 msr tpidrro_el0, x0
100
101 /* Switch to the overflow stack */
102 adr_this_cpu sp, overflow_stack + OVERFLOW_STACK_SIZE, x0
103
104 /*
105 * Check whether we were already on the overflow stack. This may happen
106 * after panic() re-enables interrupts.
107 */
108 mrs x0, tpidr_el0 // sp of interrupted context
109 sub x0, sp, x0 // delta with top of overflow stack
110 tst x0, #~(OVERFLOW_STACK_SIZE - 1) // within range?
111 b.ne __bad_stack // no? -> bad stack pointer
112
113 /* We were already on the overflow stack. Restore sp/x0 and carry on. */
114 sub sp, sp, x0
115 mrs x0, tpidrro_el0
116 #endif
117 b \label
118 .endm
119
120 .macro kernel_entry, el, regsize = 64
121 .if \regsize == 32
122 mov w0, w0 // zero upper 32 bits of x0
123 .endif
124 stp x0, x1, [sp, #16 * 0]
125 stp x2, x3, [sp, #16 * 1]
126 stp x4, x5, [sp, #16 * 2]
127 stp x6, x7, [sp, #16 * 3]
128 stp x8, x9, [sp, #16 * 4]
129 stp x10, x11, [sp, #16 * 5]
130 stp x12, x13, [sp, #16 * 6]
131 stp x14, x15, [sp, #16 * 7]
132 stp x16, x17, [sp, #16 * 8]
133 stp x18, x19, [sp, #16 * 9]
134 stp x20, x21, [sp, #16 * 10]
135 stp x22, x23, [sp, #16 * 11]
136 stp x24, x25, [sp, #16 * 12]
137 stp x26, x27, [sp, #16 * 13]
138 stp x28, x29, [sp, #16 * 14]
139
140 .if \el == 0
141 mrs x21, sp_el0
142 ldr_this_cpu tsk, __entry_task, x20 // Ensure MDSCR_EL1.SS is clear,
143 ldr x19, [tsk, #TSK_TI_FLAGS] // since we can unmask debug
144 disable_step_tsk x19, x20 // exceptions when scheduling.
145
146 mov x29, xzr // fp pointed to user-space
147 .else
148 add x21, sp, #S_FRAME_SIZE
149 get_thread_info tsk
150 /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
151 ldr x20, [tsk, #TSK_TI_ADDR_LIMIT]
152 str x20, [sp, #S_ORIG_ADDR_LIMIT]
153 mov x20, #TASK_SIZE_64
154 str x20, [tsk, #TSK_TI_ADDR_LIMIT]
155 /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
156 .endif /* \el == 0 */
157 mrs x22, elr_el1
158 mrs x23, spsr_el1
159 stp lr, x21, [sp, #S_LR]
160
161 /*
162 * In order to be able to dump the contents of struct pt_regs at the
163 * time the exception was taken (in case we attempt to walk the call
164 * stack later), chain it together with the stack frames.
165 */
166 .if \el == 0
167 stp xzr, xzr, [sp, #S_STACKFRAME]
168 .else
169 stp x29, x22, [sp, #S_STACKFRAME]
170 .endif
171 add x29, sp, #S_STACKFRAME
172
173 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
174 /*
175 * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
176 * EL0, there is no need to check the state of TTBR0_EL1 since
177 * accesses are always enabled.
178 * Note that the meaning of this bit differs from the ARMv8.1 PAN
179 * feature as all TTBR0_EL1 accesses are disabled, not just those to
180 * user mappings.
181 */
182 alternative_if ARM64_HAS_PAN
183 b 1f // skip TTBR0 PAN
184 alternative_else_nop_endif
185
186 .if \el != 0
187 mrs x21, ttbr0_el1
188 tst x21, #0xffff << 48 // Check for the reserved ASID
189 orr x23, x23, #PSR_PAN_BIT // Set the emulated PAN in the saved SPSR
190 b.eq 1f // TTBR0 access already disabled
191 and x23, x23, #~PSR_PAN_BIT // Clear the emulated PAN in the saved SPSR
192 .endif
193
194 __uaccess_ttbr0_disable x21
195 1:
196 #endif
197
198 stp x22, x23, [sp, #S_PC]
199
200 /* Not in a syscall by default (el0_svc overwrites for real syscall) */
201 .if \el == 0
202 mov w21, #NO_SYSCALL
203 str w21, [sp, #S_SYSCALLNO]
204 .endif
205
206 /*
207 * Set sp_el0 to current thread_info.
208 */
209 .if \el == 0
210 msr sp_el0, tsk
211 .endif
212
213 /*
214 * Registers that may be useful after this macro is invoked:
215 *
216 * x21 - aborted SP
217 * x22 - aborted PC
218 * x23 - aborted PSTATE
219 */
220 .endm
221
222 .macro kernel_exit, el
223 .if \el != 0
224 disable_daif
225
226 /* Restore the task's original addr_limit. */
227 ldr x20, [sp, #S_ORIG_ADDR_LIMIT]
228 str x20, [tsk, #TSK_TI_ADDR_LIMIT]
229
230 /* No need to restore UAO, it will be restored from SPSR_EL1 */
231 .endif
232
233 ldp x21, x22, [sp, #S_PC] // load ELR, SPSR
234 .if \el == 0
235 ct_user_enter
236 .endif
237
238 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
239 /*
240 * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
241 * PAN bit checking.
242 */
243 alternative_if ARM64_HAS_PAN
244 b 2f // skip TTBR0 PAN
245 alternative_else_nop_endif
246
247 .if \el != 0
248 tbnz x22, #22, 1f // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
249 .endif
250
251 __uaccess_ttbr0_enable x0
252
253 .if \el == 0
254 /*
255 * Enable errata workarounds only if returning to user. The only
256 * workaround currently required for TTBR0_EL1 changes are for the
257 * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
258 * corruption).
259 */
260 post_ttbr0_update_workaround
261 .endif
262 1:
263 .if \el != 0
264 and x22, x22, #~PSR_PAN_BIT // ARMv8.0 CPUs do not understand this bit
265 .endif
266 2:
267 #endif
268
269 .if \el == 0
270 ldr x23, [sp, #S_SP] // load return stack pointer
271 msr sp_el0, x23
272 #ifdef CONFIG_ARM64_ERRATUM_845719
273 alternative_if ARM64_WORKAROUND_845719
274 tbz x22, #4, 1f
275 #ifdef CONFIG_PID_IN_CONTEXTIDR
276 mrs x29, contextidr_el1
277 msr contextidr_el1, x29
278 #else
279 msr contextidr_el1, xzr
280 #endif
281 1:
282 alternative_else_nop_endif
283 #endif
284 .endif
285
286 msr elr_el1, x21 // set up the return data
287 msr spsr_el1, x22
288 ldp x0, x1, [sp, #16 * 0]
289 ldp x2, x3, [sp, #16 * 1]
290 ldp x4, x5, [sp, #16 * 2]
291 ldp x6, x7, [sp, #16 * 3]
292 ldp x8, x9, [sp, #16 * 4]
293 ldp x10, x11, [sp, #16 * 5]
294 ldp x12, x13, [sp, #16 * 6]
295 ldp x14, x15, [sp, #16 * 7]
296 ldp x16, x17, [sp, #16 * 8]
297 ldp x18, x19, [sp, #16 * 9]
298 ldp x20, x21, [sp, #16 * 10]
299 ldp x22, x23, [sp, #16 * 11]
300 ldp x24, x25, [sp, #16 * 12]
301 ldp x26, x27, [sp, #16 * 13]
302 ldp x28, x29, [sp, #16 * 14]
303 ldr lr, [sp, #S_LR]
304 add sp, sp, #S_FRAME_SIZE // restore sp
305 eret // return to kernel
306 .endm
307
308 .macro irq_stack_entry
309 mov x19, sp // preserve the original sp
310
311 /*
312 * Compare sp with the base of the task stack.
313 * If the top ~(THREAD_SIZE - 1) bits match, we are on a task stack,
314 * and should switch to the irq stack.
315 */
316 ldr x25, [tsk, TSK_STACK]
317 eor x25, x25, x19
318 and x25, x25, #~(THREAD_SIZE - 1)
319 cbnz x25, 9998f
320
321 ldr_this_cpu x25, irq_stack_ptr, x26
322 mov x26, #IRQ_STACK_SIZE
323 add x26, x25, x26
324
325 /* switch to the irq stack */
326 mov sp, x26
327 9998:
328 .endm
329
330 /*
331 * x19 should be preserved between irq_stack_entry and
332 * irq_stack_exit.
333 */
334 .macro irq_stack_exit
335 mov sp, x19
336 .endm
337
338 /*
339 * These are the registers used in the syscall handler, and allow us to
340 * have in theory up to 7 arguments to a function - x0 to x6.
341 *
342 * x7 is reserved for the system call number in 32-bit mode.
343 */
344 wsc_nr .req w25 // number of system calls
345 wscno .req w26 // syscall number
346 xscno .req x26 // syscall number (zero-extended)
347 stbl .req x27 // syscall table pointer
348 tsk .req x28 // current thread_info
349
350 /*
351 * Interrupt handling.
352 */
353 .macro irq_handler
354 ldr_l x1, handle_arch_irq
355 mov x0, sp
356 irq_stack_entry
357 blr x1
358 irq_stack_exit
359 .endm
360
361 .text
362
363 /*
364 * Exception vectors.
365 */
366 .pushsection ".entry.text", "ax"
367
368 .align 11
369 ENTRY(vectors)
370 kernel_ventry el1_sync_invalid // Synchronous EL1t
371 kernel_ventry el1_irq_invalid // IRQ EL1t
372 kernel_ventry el1_fiq_invalid // FIQ EL1t
373 kernel_ventry el1_error_invalid // Error EL1t
374
375 kernel_ventry el1_sync // Synchronous EL1h
376 kernel_ventry el1_irq // IRQ EL1h
377 kernel_ventry el1_fiq_invalid // FIQ EL1h
378 kernel_ventry el1_error // Error EL1h
379
380 kernel_ventry el0_sync // Synchronous 64-bit EL0
381 kernel_ventry el0_irq // IRQ 64-bit EL0
382 kernel_ventry el0_fiq_invalid // FIQ 64-bit EL0
383 kernel_ventry el0_error // Error 64-bit EL0
384
385 #ifdef CONFIG_COMPAT
386 kernel_ventry el0_sync_compat // Synchronous 32-bit EL0
387 kernel_ventry el0_irq_compat // IRQ 32-bit EL0
388 kernel_ventry el0_fiq_invalid_compat // FIQ 32-bit EL0
389 kernel_ventry el0_error_compat // Error 32-bit EL0
390 #else
391 kernel_ventry el0_sync_invalid // Synchronous 32-bit EL0
392 kernel_ventry el0_irq_invalid // IRQ 32-bit EL0
393 kernel_ventry el0_fiq_invalid // FIQ 32-bit EL0
394 kernel_ventry el0_error_invalid // Error 32-bit EL0
395 #endif
396 END(vectors)
397
398 #ifdef CONFIG_VMAP_STACK
399 /*
400 * We detected an overflow in kernel_ventry, which switched to the
401 * overflow stack. Stash the exception regs, and head to our overflow
402 * handler.
403 */
404 __bad_stack:
405 /* Restore the original x0 value */
406 mrs x0, tpidrro_el0
407
408 /*
409 * Store the original GPRs to the new stack. The orginal SP (minus
410 * S_FRAME_SIZE) was stashed in tpidr_el0 by kernel_ventry.
411 */
412 sub sp, sp, #S_FRAME_SIZE
413 kernel_entry 1
414 mrs x0, tpidr_el0
415 add x0, x0, #S_FRAME_SIZE
416 str x0, [sp, #S_SP]
417
418 /* Stash the regs for handle_bad_stack */
419 mov x0, sp
420
421 /* Time to die */
422 bl handle_bad_stack
423 ASM_BUG()
424 #endif /* CONFIG_VMAP_STACK */
425
426 /*
427 * Invalid mode handlers
428 */
429 .macro inv_entry, el, reason, regsize = 64
430 kernel_entry \el, \regsize
431 mov x0, sp
432 mov x1, #\reason
433 mrs x2, esr_el1
434 bl bad_mode
435 ASM_BUG()
436 .endm
437
438 el0_sync_invalid:
439 inv_entry 0, BAD_SYNC
440 ENDPROC(el0_sync_invalid)
441
442 el0_irq_invalid:
443 inv_entry 0, BAD_IRQ
444 ENDPROC(el0_irq_invalid)
445
446 el0_fiq_invalid:
447 inv_entry 0, BAD_FIQ
448 ENDPROC(el0_fiq_invalid)
449
450 el0_error_invalid:
451 inv_entry 0, BAD_ERROR
452 ENDPROC(el0_error_invalid)
453
454 #ifdef CONFIG_COMPAT
455 el0_fiq_invalid_compat:
456 inv_entry 0, BAD_FIQ, 32
457 ENDPROC(el0_fiq_invalid_compat)
458 #endif
459
460 el1_sync_invalid:
461 inv_entry 1, BAD_SYNC
462 ENDPROC(el1_sync_invalid)
463
464 el1_irq_invalid:
465 inv_entry 1, BAD_IRQ
466 ENDPROC(el1_irq_invalid)
467
468 el1_fiq_invalid:
469 inv_entry 1, BAD_FIQ
470 ENDPROC(el1_fiq_invalid)
471
472 el1_error_invalid:
473 inv_entry 1, BAD_ERROR
474 ENDPROC(el1_error_invalid)
475
476 /*
477 * EL1 mode handlers.
478 */
479 .align 6
480 el1_sync:
481 kernel_entry 1
482 mrs x1, esr_el1 // read the syndrome register
483 lsr x24, x1, #ESR_ELx_EC_SHIFT // exception class
484 cmp x24, #ESR_ELx_EC_DABT_CUR // data abort in EL1
485 b.eq el1_da
486 cmp x24, #ESR_ELx_EC_IABT_CUR // instruction abort in EL1
487 b.eq el1_ia
488 cmp x24, #ESR_ELx_EC_SYS64 // configurable trap
489 b.eq el1_undef
490 cmp x24, #ESR_ELx_EC_SP_ALIGN // stack alignment exception
491 b.eq el1_sp_pc
492 cmp x24, #ESR_ELx_EC_PC_ALIGN // pc alignment exception
493 b.eq el1_sp_pc
494 cmp x24, #ESR_ELx_EC_UNKNOWN // unknown exception in EL1
495 b.eq el1_undef
496 cmp x24, #ESR_ELx_EC_BREAKPT_CUR // debug exception in EL1
497 b.ge el1_dbg
498 b el1_inv
499
500 el1_ia:
501 /*
502 * Fall through to the Data abort case
503 */
504 el1_da:
505 /*
506 * Data abort handling
507 */
508 mrs x3, far_el1
509 inherit_daif pstate=x23, tmp=x2
510 clear_address_tag x0, x3
511 mov x2, sp // struct pt_regs
512 bl do_mem_abort
513
514 kernel_exit 1
515 el1_sp_pc:
516 /*
517 * Stack or PC alignment exception handling
518 */
519 mrs x0, far_el1
520 inherit_daif pstate=x23, tmp=x2
521 mov x2, sp
522 bl do_sp_pc_abort
523 ASM_BUG()
524 el1_undef:
525 /*
526 * Undefined instruction
527 */
528 inherit_daif pstate=x23, tmp=x2
529 mov x0, sp
530 bl do_undefinstr
531 ASM_BUG()
532 el1_dbg:
533 /*
534 * Debug exception handling
535 */
536 cmp x24, #ESR_ELx_EC_BRK64 // if BRK64
537 cinc x24, x24, eq // set bit '0'
538 tbz x24, #0, el1_inv // EL1 only
539 mrs x0, far_el1
540 mov x2, sp // struct pt_regs
541 bl do_debug_exception
542 kernel_exit 1
543 el1_inv:
544 // TODO: add support for undefined instructions in kernel mode
545 inherit_daif pstate=x23, tmp=x2
546 mov x0, sp
547 mov x2, x1
548 mov x1, #BAD_SYNC
549 bl bad_mode
550 ASM_BUG()
551 ENDPROC(el1_sync)
552
553 .align 6
554 el1_irq:
555 kernel_entry 1
556 enable_da_f
557 #ifdef CONFIG_TRACE_IRQFLAGS
558 bl trace_hardirqs_off
559 #endif
560
561 irq_handler
562
563 #ifdef CONFIG_PREEMPT
564 ldr w24, [tsk, #TSK_TI_PREEMPT] // get preempt count
565 cbnz w24, 1f // preempt count != 0
566 ldr x0, [tsk, #TSK_TI_FLAGS] // get flags
567 tbz x0, #TIF_NEED_RESCHED, 1f // needs rescheduling?
568 bl el1_preempt
569 1:
570 #endif
571 #ifdef CONFIG_TRACE_IRQFLAGS
572 bl trace_hardirqs_on
573 #endif
574 kernel_exit 1
575 ENDPROC(el1_irq)
576
577 #ifdef CONFIG_PREEMPT
578 el1_preempt:
579 mov x24, lr
580 1: bl preempt_schedule_irq // irq en/disable is done inside
581 ldr x0, [tsk, #TSK_TI_FLAGS] // get new tasks TI_FLAGS
582 tbnz x0, #TIF_NEED_RESCHED, 1b // needs rescheduling?
583 ret x24
584 #endif
585
586 /*
587 * EL0 mode handlers.
588 */
589 .align 6
590 el0_sync:
591 kernel_entry 0
592 mrs x25, esr_el1 // read the syndrome register
593 lsr x24, x25, #ESR_ELx_EC_SHIFT // exception class
594 cmp x24, #ESR_ELx_EC_SVC64 // SVC in 64-bit state
595 b.eq el0_svc
596 cmp x24, #ESR_ELx_EC_DABT_LOW // data abort in EL0
597 b.eq el0_da
598 cmp x24, #ESR_ELx_EC_IABT_LOW // instruction abort in EL0
599 b.eq el0_ia
600 cmp x24, #ESR_ELx_EC_FP_ASIMD // FP/ASIMD access
601 b.eq el0_fpsimd_acc
602 cmp x24, #ESR_ELx_EC_FP_EXC64 // FP/ASIMD exception
603 b.eq el0_fpsimd_exc
604 cmp x24, #ESR_ELx_EC_SYS64 // configurable trap
605 b.eq el0_sys
606 cmp x24, #ESR_ELx_EC_SP_ALIGN // stack alignment exception
607 b.eq el0_sp_pc
608 cmp x24, #ESR_ELx_EC_PC_ALIGN // pc alignment exception
609 b.eq el0_sp_pc
610 cmp x24, #ESR_ELx_EC_UNKNOWN // unknown exception in EL0
611 b.eq el0_undef
612 cmp x24, #ESR_ELx_EC_BREAKPT_LOW // debug exception in EL0
613 b.ge el0_dbg
614 b el0_inv
615
616 #ifdef CONFIG_COMPAT
617 .align 6
618 el0_sync_compat:
619 kernel_entry 0, 32
620 mrs x25, esr_el1 // read the syndrome register
621 lsr x24, x25, #ESR_ELx_EC_SHIFT // exception class
622 cmp x24, #ESR_ELx_EC_SVC32 // SVC in 32-bit state
623 b.eq el0_svc_compat
624 cmp x24, #ESR_ELx_EC_DABT_LOW // data abort in EL0
625 b.eq el0_da
626 cmp x24, #ESR_ELx_EC_IABT_LOW // instruction abort in EL0
627 b.eq el0_ia
628 cmp x24, #ESR_ELx_EC_FP_ASIMD // FP/ASIMD access
629 b.eq el0_fpsimd_acc
630 cmp x24, #ESR_ELx_EC_FP_EXC32 // FP/ASIMD exception
631 b.eq el0_fpsimd_exc
632 cmp x24, #ESR_ELx_EC_PC_ALIGN // pc alignment exception
633 b.eq el0_sp_pc
634 cmp x24, #ESR_ELx_EC_UNKNOWN // unknown exception in EL0
635 b.eq el0_undef
636 cmp x24, #ESR_ELx_EC_CP15_32 // CP15 MRC/MCR trap
637 b.eq el0_undef
638 cmp x24, #ESR_ELx_EC_CP15_64 // CP15 MRRC/MCRR trap
639 b.eq el0_undef
640 cmp x24, #ESR_ELx_EC_CP14_MR // CP14 MRC/MCR trap
641 b.eq el0_undef
642 cmp x24, #ESR_ELx_EC_CP14_LS // CP14 LDC/STC trap
643 b.eq el0_undef
644 cmp x24, #ESR_ELx_EC_CP14_64 // CP14 MRRC/MCRR trap
645 b.eq el0_undef
646 cmp x24, #ESR_ELx_EC_BREAKPT_LOW // debug exception in EL0
647 b.ge el0_dbg
648 b el0_inv
649 el0_svc_compat:
650 /*
651 * AArch32 syscall handling
652 */
653 adrp stbl, compat_sys_call_table // load compat syscall table pointer
654 mov wscno, w7 // syscall number in w7 (r7)
655 mov wsc_nr, #__NR_compat_syscalls
656 b el0_svc_naked
657
658 .align 6
659 el0_irq_compat:
660 kernel_entry 0, 32
661 b el0_irq_naked
662
663 el0_error_compat:
664 kernel_entry 0, 32
665 b el0_error_naked
666 #endif
667
668 el0_da:
669 /*
670 * Data abort handling
671 */
672 mrs x26, far_el1
673 enable_daif
674 ct_user_exit
675 clear_address_tag x0, x26
676 mov x1, x25
677 mov x2, sp
678 bl do_mem_abort
679 b ret_to_user
680 el0_ia:
681 /*
682 * Instruction abort handling
683 */
684 mrs x26, far_el1
685 enable_daif
686 ct_user_exit
687 mov x0, x26
688 mov x1, x25
689 mov x2, sp
690 bl do_mem_abort
691 b ret_to_user
692 el0_fpsimd_acc:
693 /*
694 * Floating Point or Advanced SIMD access
695 */
696 enable_daif
697 ct_user_exit
698 mov x0, x25
699 mov x1, sp
700 bl do_fpsimd_acc
701 b ret_to_user
702 el0_fpsimd_exc:
703 /*
704 * Floating Point or Advanced SIMD exception
705 */
706 enable_daif
707 ct_user_exit
708 mov x0, x25
709 mov x1, sp
710 bl do_fpsimd_exc
711 b ret_to_user
712 el0_sp_pc:
713 /*
714 * Stack or PC alignment exception handling
715 */
716 mrs x26, far_el1
717 enable_daif
718 ct_user_exit
719 mov x0, x26
720 mov x1, x25
721 mov x2, sp
722 bl do_sp_pc_abort
723 b ret_to_user
724 el0_undef:
725 /*
726 * Undefined instruction
727 */
728 enable_daif
729 ct_user_exit
730 mov x0, sp
731 bl do_undefinstr
732 b ret_to_user
733 el0_sys:
734 /*
735 * System instructions, for trapped cache maintenance instructions
736 */
737 enable_daif
738 ct_user_exit
739 mov x0, x25
740 mov x1, sp
741 bl do_sysinstr
742 b ret_to_user
743 el0_dbg:
744 /*
745 * Debug exception handling
746 */
747 tbnz x24, #0, el0_inv // EL0 only
748 mrs x0, far_el1
749 mov x1, x25
750 mov x2, sp
751 bl do_debug_exception
752 enable_daif
753 ct_user_exit
754 b ret_to_user
755 el0_inv:
756 enable_daif
757 ct_user_exit
758 mov x0, sp
759 mov x1, #BAD_SYNC
760 mov x2, x25
761 bl bad_el0_sync
762 b ret_to_user
763 ENDPROC(el0_sync)
764
765 .align 6
766 el0_irq:
767 kernel_entry 0
768 el0_irq_naked:
769 enable_da_f
770 #ifdef CONFIG_TRACE_IRQFLAGS
771 bl trace_hardirqs_off
772 #endif
773
774 ct_user_exit
775 irq_handler
776
777 #ifdef CONFIG_TRACE_IRQFLAGS
778 bl trace_hardirqs_on
779 #endif
780 b ret_to_user
781 ENDPROC(el0_irq)
782
783 el1_error:
784 kernel_entry 1
785 mrs x1, esr_el1
786 enable_dbg
787 mov x0, sp
788 bl do_serror
789 kernel_exit 1
790 ENDPROC(el1_error)
791
792 el0_error:
793 kernel_entry 0
794 el0_error_naked:
795 mrs x1, esr_el1
796 enable_dbg
797 mov x0, sp
798 bl do_serror
799 enable_daif
800 ct_user_exit
801 b ret_to_user
802 ENDPROC(el0_error)
803
804
805 /*
806 * This is the fast syscall return path. We do as little as possible here,
807 * and this includes saving x0 back into the kernel stack.
808 */
809 ret_fast_syscall:
810 disable_daif
811 str x0, [sp, #S_X0] // returned x0
812 ldr x1, [tsk, #TSK_TI_FLAGS] // re-check for syscall tracing
813 and x2, x1, #_TIF_SYSCALL_WORK
814 cbnz x2, ret_fast_syscall_trace
815 and x2, x1, #_TIF_WORK_MASK
816 cbnz x2, work_pending
817 enable_step_tsk x1, x2
818 kernel_exit 0
819 ret_fast_syscall_trace:
820 enable_daif
821 b __sys_trace_return_skipped // we already saved x0
822
823 /*
824 * Ok, we need to do extra processing, enter the slow path.
825 */
826 work_pending:
827 mov x0, sp // 'regs'
828 bl do_notify_resume
829 #ifdef CONFIG_TRACE_IRQFLAGS
830 bl trace_hardirqs_on // enabled while in userspace
831 #endif
832 ldr x1, [tsk, #TSK_TI_FLAGS] // re-check for single-step
833 b finish_ret_to_user
834 /*
835 * "slow" syscall return path.
836 */
837 ret_to_user:
838 disable_daif
839 ldr x1, [tsk, #TSK_TI_FLAGS]
840 and x2, x1, #_TIF_WORK_MASK
841 cbnz x2, work_pending
842 finish_ret_to_user:
843 enable_step_tsk x1, x2
844 kernel_exit 0
845 ENDPROC(ret_to_user)
846
847 /*
848 * SVC handler.
849 */
850 .align 6
851 el0_svc:
852 adrp stbl, sys_call_table // load syscall table pointer
853 mov wscno, w8 // syscall number in w8
854 mov wsc_nr, #__NR_syscalls
855 el0_svc_naked: // compat entry point
856 stp x0, xscno, [sp, #S_ORIG_X0] // save the original x0 and syscall number
857 enable_daif
858 ct_user_exit 1
859
860 ldr x16, [tsk, #TSK_TI_FLAGS] // check for syscall hooks
861 tst x16, #_TIF_SYSCALL_WORK
862 b.ne __sys_trace
863 cmp wscno, wsc_nr // check upper syscall limit
864 b.hs ni_sys
865 ldr x16, [stbl, xscno, lsl #3] // address in the syscall table
866 blr x16 // call sys_* routine
867 b ret_fast_syscall
868 ni_sys:
869 mov x0, sp
870 bl do_ni_syscall
871 b ret_fast_syscall
872 ENDPROC(el0_svc)
873
874 /*
875 * This is the really slow path. We're going to be doing context
876 * switches, and waiting for our parent to respond.
877 */
878 __sys_trace:
879 cmp wscno, #NO_SYSCALL // user-issued syscall(-1)?
880 b.ne 1f
881 mov x0, #-ENOSYS // set default errno if so
882 str x0, [sp, #S_X0]
883 1: mov x0, sp
884 bl syscall_trace_enter
885 cmp w0, #NO_SYSCALL // skip the syscall?
886 b.eq __sys_trace_return_skipped
887 mov wscno, w0 // syscall number (possibly new)
888 mov x1, sp // pointer to regs
889 cmp wscno, wsc_nr // check upper syscall limit
890 b.hs __ni_sys_trace
891 ldp x0, x1, [sp] // restore the syscall args
892 ldp x2, x3, [sp, #S_X2]
893 ldp x4, x5, [sp, #S_X4]
894 ldp x6, x7, [sp, #S_X6]
895 ldr x16, [stbl, xscno, lsl #3] // address in the syscall table
896 blr x16 // call sys_* routine
897
898 __sys_trace_return:
899 str x0, [sp, #S_X0] // save returned x0
900 __sys_trace_return_skipped:
901 mov x0, sp
902 bl syscall_trace_exit
903 b ret_to_user
904
905 __ni_sys_trace:
906 mov x0, sp
907 bl do_ni_syscall
908 b __sys_trace_return
909
910 .popsection // .entry.text
911
912 /*
913 * Special system call wrappers.
914 */
915 ENTRY(sys_rt_sigreturn_wrapper)
916 mov x0, sp
917 b sys_rt_sigreturn
918 ENDPROC(sys_rt_sigreturn_wrapper)
919
920 /*
921 * Register switch for AArch64. The callee-saved registers need to be saved
922 * and restored. On entry:
923 * x0 = previous task_struct (must be preserved across the switch)
924 * x1 = next task_struct
925 * Previous and next are guaranteed not to be the same.
926 *
927 */
928 ENTRY(cpu_switch_to)
929 mov x10, #THREAD_CPU_CONTEXT
930 add x8, x0, x10
931 mov x9, sp
932 stp x19, x20, [x8], #16 // store callee-saved registers
933 stp x21, x22, [x8], #16
934 stp x23, x24, [x8], #16
935 stp x25, x26, [x8], #16
936 stp x27, x28, [x8], #16
937 stp x29, x9, [x8], #16
938 str lr, [x8]
939 add x8, x1, x10
940 ldp x19, x20, [x8], #16 // restore callee-saved registers
941 ldp x21, x22, [x8], #16
942 ldp x23, x24, [x8], #16
943 ldp x25, x26, [x8], #16
944 ldp x27, x28, [x8], #16
945 ldp x29, x9, [x8], #16
946 ldr lr, [x8]
947 mov sp, x9
948 msr sp_el0, x1
949 ret
950 ENDPROC(cpu_switch_to)
951 NOKPROBE(cpu_switch_to)
952
953 /*
954 * This is how we return from a fork.
955 */
956 ENTRY(ret_from_fork)
957 bl schedule_tail
958 cbz x19, 1f // not a kernel thread
959 mov x0, x20
960 blr x19
961 1: get_thread_info tsk
962 b ret_to_user
963 ENDPROC(ret_from_fork)
964 NOKPROBE(ret_from_fork)
Mirror https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git