m4/os.m4

   1 #
   2 # lldp_CHECK_OS
   3 #
   4 # List of supported OS.
   5 #
   6 AC_DEFUN([lldp_DEFINE_OS], [dnl
   7   case $host_os in
   8     $1)
   9       os="$2"
  10       AC_DEFINE_UNQUOTED(HOST_OS_$3, 1, [Host operating system is $2])
  11       ;;
  12   esac
  13   AM_CONDITIONAL(HOST_OS_$3, test x"$os" = x"$2")dnl
  14 ])
  15
  16 AC_DEFUN([lldp_CHECK_OS], [
  17   AC_CANONICAL_HOST
  18   AC_MSG_CHECKING([if host OS is supported])
  19
  20   lldp_DEFINE_OS(linux*, Linux, LINUX)
  21   lldp_DEFINE_OS(freebsd*|kfreebsd*, FreeBSD, FREEBSD)
  22   lldp_DEFINE_OS(dragonfly*, [DragonFly BSD], DRAGONFLY)
  23   lldp_DEFINE_OS(openbsd*, OpenBSD, OPENBSD)
  24   lldp_DEFINE_OS(netbsd*, NetBSD, NETBSD)
  25   lldp_DEFINE_OS(darwin*, [OS X], OSX)
  26   lldp_DEFINE_OS(solaris*, Solaris, SOLARIS)
  27
  28   if test x"$os" = x; then
  29      AC_MSG_RESULT(no)
  30      AC_MSG_ERROR([*** unsupported OS $host_os])
  31   fi
  32   AC_MSG_RESULT([yes ($os)])
  33 ])
  34
  35 # Enable some additional CFLAGS depending on the OS
  36 AC_DEFUN([lldp_CFLAGS_OS], [
  37   # Most of what we want can be enabled nowadays with _GNU_SOURCE
  38   AX_CFLAGS_GCC_OPTION([-D_GNU_SOURCE], [LLDP_CPPFLAGS])    dnl GNU systems (asprintf, ...)
  39
  40   case $host_os in
  41      solaris*)
  42        AX_CFLAGS_GCC_OPTION([-D__EXTENSIONS__], [LLDP_CPPFLAGS]) dnl (CMSG_*)
  43        AX_CFLAGS_GCC_OPTION([-D_XPG4_2], [LLDP_CPPFLAGS])        dnl (CMSG_*)
  44        ;;
  45      hpux*)
  46        AX_CFLAGS_GCC_OPTION([-D_XOPEN_SOURCE=500], [LLDP_CPPFLAGS])      dnl HP-UX
  47        AX_CFLAGS_GCC_OPTION([-D_XOPEN_SOURCE_EXTENDED], [LLDP_CPPFLAGS]) dnl HP-UX
  48        ;;
  49   esac
  50 ])