meta/recipes-graphics/mesa/mesa.inc

   1 SUMMARY = "A free implementation of the OpenGL API"
   2 DESCRIPTION = "Mesa is an open-source implementation of the OpenGL specification - \
   3 a system for rendering interactive 3D graphics.  \
   4 A variety of device drivers allows Mesa to be used in many different environments \
   5 ranging from software emulation to complete hardware acceleration for modern GPUs. \
   6 Mesa is used as part of the overall Direct Rendering Infrastructure and X.org \
   7 environment."
   8
   9 HOMEPAGE = "http://mesa3d.org"
  10 BUGTRACKER = "https://bugs.freedesktop.org"
  11 SECTION = "x11"
  12 LICENSE = "MIT"
  13 LIC_FILES_CHKSUM = "file://docs/license.rst;md5=9a383ee9f65a4e939d6630e9b067ff58"
  14
  15 PE = "2"
  16
  17 SRC_URI = "https://mesa.freedesktop.org/archive/mesa-${PV}.tar.xz \
  18            file://0001-meson.build-check-for-all-linux-host_os-combinations.patch \
  19            file://0002-meson.build-make-TLS-ELF-optional.patch \
  20            file://0001-meson-misdetects-64bit-atomics-on-mips-clang.patch \
  21            file://0001-futex.h-Define-__NR_futex-if-it-does-not-exist.patch \
  22            file://0001-util-format-Check-for-NEON-before-using-it.patch \
  23            "
  24
  25 SRC_URI[sha256sum] = "e6c41928b5b9917485bd67cec22d15e62cad7a358bf4c711a647979987601250"
  26
  27 UPSTREAM_CHECK_GITTAGREGEX = "mesa-(?P<pver>\d+(\.\d+)+)"
  28
  29 #because we cannot rely on the fact that all apps will use pkgconfig,
  30 #make eglplatform.h independent of MESA_EGL_NO_X11_HEADER
  31 do_install:append() {
  32     if ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'true', 'false', d)}; then
  33         sed -i -e 's/^#elif defined(__unix__) && defined(EGL_NO_X11)$/#elif defined(__unix__) \&\& defined(EGL_NO_X11) || ${@bb.utils.contains('PACKAGECONFIG', 'x11', '0', '1', d)}/' ${D}${includedir}/EGL/eglplatform.h
  34     fi
  35 }
  36
  37 DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native zlib chrpath-replacement-native python3-mako-native gettext-native"
  38 EXTRANATIVEPATH += "chrpath-native"
  39 PROVIDES = " \
  40     ${@bb.utils.contains('PACKAGECONFIG', 'opengl', 'virtual/libgl', '', d)} \
  41     ${@bb.utils.contains('PACKAGECONFIG', 'gles', 'virtual/libgles1 virtual/libgles2 virtual/libgles3', '', d)} \
  42     ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'virtual/egl', '', d)} \
  43     ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'virtual/libgbm', '', d)} \
  44     virtual/mesa \
  45     "
  46
  47 inherit meson pkgconfig python3native gettext features_check
  48
  49 BBCLASSEXTEND = "native nativesdk"
  50
  51 ANY_OF_DISTRO_FEATURES:class-target = "opengl vulkan"
  52
  53 PLATFORMS ??= "${@bb.utils.filter('PACKAGECONFIG', 'x11 wayland', d)}"
  54
  55 export YOCTO_ALTERNATE_EXE_PATH = "${STAGING_LIBDIR}/llvm${MESA_LLVM_RELEASE}/llvm-config"
  56 export YOCTO_ALTERNATE_MULTILIB_NAME = "${base_libdir}"
  57 export LLVM_CONFIG = "${STAGING_BINDIR_NATIVE}/llvm-config${MESA_LLVM_RELEASE}"
  58 export WANT_LLVM_RELEASE = "${MESA_LLVM_RELEASE}"
  59
  60 MESA_LLVM_RELEASE ?= "${LLVMVERSION}"
  61
  62 # set the MESA_BUILD_TYPE to either 'release' (default) or 'debug'
  63 # by default the upstream mesa sources build a debug release
  64 # here we assume the user will want a release build by default
  65 MESA_BUILD_TYPE ?= "release"
  66 def check_buildtype(d):
  67     _buildtype = d.getVar('MESA_BUILD_TYPE')
  68     if _buildtype not in ['release', 'debug']:
  69         bb.fatal("unknown build type (%s), please set MESA_BUILD_TYPE to either 'release' or 'debug'" % _buildtype)
  70     if _buildtype == 'debug':
  71         return 'debugoptimized'
  72     return 'plain'
  73 MESON_BUILDTYPE = "${@check_buildtype(d)}"
  74
  75 EXTRA_OEMESON = " \
  76     -Dshared-glapi=enabled \
  77     -Dgallium-opencl=disabled \
  78     -Dglx-read-only-text=true \
  79     -Dplatforms='${@",".join("${PLATFORMS}".split())}' \
  80 "
  81
  82 def strip_comma(s):
  83     return s.strip(',')
  84
  85 PACKAGECONFIG = " \
  86         gallium \
  87         ${@bb.utils.filter('DISTRO_FEATURES', 'x11 vulkan wayland', d)} \
  88         ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl egl gles gbm virgl', '', d)} \
  89         ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'dri3', '', d)} \
  90         ${@bb.utils.contains('DISTRO_FEATURES', 'x11 vulkan', 'dri3', '', d)} \
  91         ${@bb.utils.contains('TCLIBC', 'glibc', 'elf-tls', '', d)} \
  92 "
  93
  94 # "gbm" requires "opengl"
  95 PACKAGECONFIG[gbm] = "-Dgbm=enabled,-Dgbm=disabled"
  96
  97 X11_DEPS = "xorgproto virtual/libx11 libxext libxxf86vm libxdamage libxfixes xrandr"
  98 # "x11" requires "opengl"
  99 PACKAGECONFIG[x11] = ",-Dglx=disabled,${X11_DEPS}"
 100 PACKAGECONFIG[elf-tls] = "-Delf-tls=true, -Delf-tls=false"
 101 PACKAGECONFIG[xvmc] = "-Dgallium-xvmc=enabled,-Dgallium-xvmc=disabled,libxvmc"
 102 PACKAGECONFIG[wayland] = ",,wayland-native wayland libdrm wayland-protocols"
 103
 104 PACKAGECONFIG[dri3] = "-Ddri3=enabled, -Ddri3=disabled, xorgproto libxshmfence"
 105
 106 # Vulkan drivers need dri3 enabled
 107 # amd could be enabled as well but requires gallium-llvm with llvm >= 3.9
 108 VULKAN_DRIVERS = ""
 109 VULKAN_DRIVERS:append:x86:class-target = ",intel"
 110 VULKAN_DRIVERS:append:x86-64:class-target = ",intel"
 111 VULKAN_DRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'freedreno', ',freedreno', '', d)}"
 112 VULKAN_DRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'broadcom', ',broadcom', '', d)}"
 113 PACKAGECONFIG[vulkan] = "-Dvulkan-drivers=${@strip_comma('${VULKAN_DRIVERS}')}, -Dvulkan-drivers='',"
 114
 115 PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=false"
 116
 117 # "gles" requires "opengl"
 118 PACKAGECONFIG[gles] = "-Dgles1=enabled -Dgles2=enabled, -Dgles1=disabled -Dgles2=disabled"
 119
 120 # "egl" requires "opengl"
 121 PACKAGECONFIG[egl] = "-Degl=enabled, -Degl=disabled"
 122
 123 PACKAGECONFIG[broadcom] = ""
 124 PACKAGECONFIG[etnaviv] = ""
 125 PACKAGECONFIG[freedreno] = ""
 126 PACKAGECONFIG[kmsro] = ""
 127 PACKAGECONFIG[vc4] = ""
 128 PACKAGECONFIG[v3d] = ""
 129
 130 GALLIUMDRIVERS = "swrast"
 131 # gallium swrast was found to crash Xorg on startup in x32 qemu
 132 GALLIUMDRIVERS:x86-x32 = ""
 133 GALLIUMDRIVERS:append:x86:class-target = ",i915,iris,crocus"
 134 GALLIUMDRIVERS:append:x86-64:class-target = ",i915,iris,crocus"
 135
 136 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'etnaviv', ',etnaviv', '', d)}"
 137 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'freedreno', ',freedreno', '', d)}"
 138 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'kmsro', ',kmsro', '', d)}"
 139 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'vc4', ',vc4', '', d)}"
 140 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'v3d', ',v3d', '', d)}"
 141
 142 # radeonsi requires LLVM
 143 GALLIUMDRIVERS_RADEONSI = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',radeonsi', '', d)}"
 144 GALLIUMDRIVERS_LLVM = "r300,nouveau${GALLIUMDRIVERS_RADEONSI}"
 145 GALLIUMDRIVERS_LLVM:append:x86:class-target = ",svga"
 146 GALLIUMDRIVERS_LLVM:append:x86-64:class-target = ",svga"
 147
 148 PACKAGECONFIG[r600] = ""
 149 PACKAGECONFIG[virgl] = ""
 150
 151 GALLIUMDRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
 152 GALLIUMDRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',r600', '', d)}"
 153 GALLIUMDRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'virgl', ',virgl', '', d)}"
 154
 155 PACKAGECONFIG[gallium] = "-Dgallium-drivers=${@strip_comma('${GALLIUMDRIVERS}')}, -Dgallium-drivers='', libdrm"
 156 PACKAGECONFIG[gallium-llvm] = "-Dllvm=enabled -Dshared-llvm=enabled, -Dllvm=disabled, llvm${MESA_LLVM_RELEASE} llvm-native \
 157                                elfutils"
 158 PACKAGECONFIG[xa]  = "-Dgallium-xa=enabled, -Dgallium-xa=disabled"
 159 PACKAGECONFIG[va] = "-Dgallium-va=enabled,-Dgallium-va=disabled,libva-initial"
 160
 161 PACKAGECONFIG[vdpau] = "-Dgallium-vdpau=enabled,-Dgallium-vdpau=disabled,libvdpau"
 162
 163 PACKAGECONFIG[lima] = ""
 164 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'lima', ',lima', '', d)}"
 165
 166 PACKAGECONFIG[panfrost] = ""
 167 GALLIUMDRIVERS:append ="${@bb.utils.contains('PACKAGECONFIG', 'panfrost', ',panfrost', '', d)}"
 168
 169 PACKAGECONFIG[osmesa] = "-Dosmesa=true,-Dosmesa=false"
 170
 171 PACKAGECONFIG[unwind] = "-Dlibunwind=enabled,-Dlibunwind=disabled,libunwind"
 172
 173 PACKAGECONFIG[lmsensors] = "-Dlmsensors=enabled,-Dlmsensors=disabled,lmsensors"
 174
 175 # llvmpipe is slow if compiled with -fomit-frame-pointer (e.g. -O2)
 176 FULL_OPTIMIZATION:append = " -fno-omit-frame-pointer"
 177
 178 CFLAGS:append:armv5 = " -DMISSING_64BIT_ATOMICS"
 179 CFLAGS:append:armv6 = " -DMISSING_64BIT_ATOMICS"
 180
 181 # Remove the mesa dependency on mesa-dev, as mesa is empty
 182 RDEPENDS:${PN}-dev = ""
 183
 184 # Khronos documentation says that include/GLES2/gl2ext.h can be used for
 185 # OpenGL ES 3 specification as well as for OpenGL ES 2.
 186 # There can be applications including GLES2/gl2ext.h instead of GLES3/gl3ext.h
 187 # meaning we should probably bring in GLES2/gl2ext.h if someone asks for
 188 # development package of libgles3.
 189 RDEPENDS:libgles3-mesa-dev += "libgles2-mesa-dev"
 190
 191 PACKAGES =+ "libegl-mesa libegl-mesa-dev \
 192              libosmesa libosmesa-dev \
 193              libgl-mesa libgl-mesa-dev \
 194              libglapi libglapi-dev \
 195              libgbm libgbm-dev \
 196              libgles1-mesa libgles1-mesa-dev \
 197              libgles2-mesa libgles2-mesa-dev \
 198              libgles3-mesa libgles3-mesa-dev \
 199              libxatracker libxatracker-dev \
 200              mesa-megadriver mesa-vulkan-drivers \
 201              mesa-vdpau-drivers \
 202             "
 203
 204 do_install:append () {
 205     # Drivers never need libtool .la files
 206     rm -f ${D}${libdir}/dri/*.la
 207     rm -f ${D}${libdir}/egl/*.la
 208     rm -f ${D}${libdir}/gallium-pipe/*.la
 209     rm -f ${D}${libdir}/gbm/*.la
 210
 211     # it was packaged in libdricore9.1.3-1 and preventing upgrades when debian.bbclass was used
 212     chrpath --delete ${D}${libdir}/dri/*_dri.so || true
 213
 214     # libwayland-egl has been moved to wayland 1.15+
 215     rm -f ${D}${libdir}/libwayland-egl*
 216     rm -f ${D}${libdir}/pkgconfig/wayland-egl.pc
 217 }
 218
 219 # For the packages that make up the OpenGL interfaces, inject variables so that
 220 # they don't get Debian-renamed (which would remove the -mesa suffix), and
 221 # RPROVIDEs/RCONFLICTs on the generic libgl name.
 222 python __anonymous() {
 223     pkgconfig = (d.getVar('PACKAGECONFIG') or "").split()
 224     suffix = ""
 225     if "-native" in d.getVar("PN"):
 226         suffix = "-native"
 227     for p in (("egl", "libegl", "libegl1"),
 228               ("opengl", "libgl", "libgl1"),
 229               ("gles", "libgles1", "libglesv1-cm1"),
 230               ("gles", "libgles2", "libglesv2-2"),
 231               ("gles", "libgles3",)):
 232         if not p[0] in pkgconfig:
 233             continue
 234         mlprefix = d.getVar("MLPREFIX")
 235         fullp = mlprefix + p[1] + "-mesa" + suffix
 236         mlprefix = d.getVar("MLPREFIX")
 237         pkgs = " " + " ".join(mlprefix + x + suffix for x in p[1:])
 238         d.setVar("DEBIAN_NOAUTONAME:" + fullp, "1")
 239         d.appendVar("RREPLACES:" + fullp, pkgs)
 240         d.appendVar("RPROVIDES:" + fullp, pkgs)
 241         d.appendVar("RCONFLICTS:" + fullp, pkgs)
 242
 243         d.appendVar("RRECOMMENDS:" + fullp, " ${MLPREFIX}mesa-megadriver" + suffix)
 244
 245         # For -dev, the first element is both the Debian and original name
 246         fullp = mlprefix + p[1] + "-mesa-dev" + suffix
 247         pkgs = " " + mlprefix + p[1] + "-dev" + suffix
 248         d.setVar("DEBIAN_NOAUTONAME:" + fullp, "1")
 249         d.appendVar("RREPLACES:" + fullp, pkgs)
 250         d.appendVar("RPROVIDES:" + fullp, pkgs)
 251         d.appendVar("RCONFLICTS:" + fullp, pkgs)
 252 }
 253
 254 python mesa_populate_packages() {
 255     pkgs = ['mesa', 'mesa-dev', 'mesa-dbg']
 256     for pkg in pkgs:
 257         d.setVar("RPROVIDES:%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 258         d.setVar("RCONFLICTS:%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 259         d.setVar("RREPLACES:%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 260
 261     import re
 262     dri_drivers_root = oe.path.join(d.getVar('PKGD'), d.getVar('libdir'), "dri")
 263     if os.path.isdir(dri_drivers_root):
 264         dri_pkgs = sorted(os.listdir(dri_drivers_root))
 265         lib_name = d.expand("${MLPREFIX}mesa-megadriver")
 266         for p in dri_pkgs:
 267             m = re.match(r'^(.*)_dri\.so$', p)
 268             if m:
 269                 pkg_name = " ${MLPREFIX}mesa-driver-%s" % legitimize_package_name(m.group(1))
 270                 d.appendVar("RPROVIDES:%s" % lib_name, pkg_name)
 271                 d.appendVar("RCONFLICTS:%s" % lib_name, pkg_name)
 272                 d.appendVar("RREPLACES:%s" % lib_name, pkg_name)
 273
 274     pipe_drivers_root = os.path.join(d.getVar('libdir'), "gallium-pipe")
 275     do_split_packages(d, pipe_drivers_root, r'^pipe_(.*)\.so$', 'mesa-driver-pipe-%s', 'Mesa %s pipe driver', extra_depends='')
 276 }
 277
 278 PACKAGESPLITFUNCS:prepend = "mesa_populate_packages "
 279
 280 PACKAGES_DYNAMIC += "^mesa-driver-.*"
 281 PACKAGES_DYNAMIC:class-native = "^mesa-driver-.*-native"
 282
 283 FILES:mesa-megadriver = "${libdir}/dri/* ${datadir}/drirc.d/00-mesa-defaults.conf"
 284 FILES:mesa-vulkan-drivers = "${libdir}/libvulkan_*.so ${datadir}/vulkan"
 285 FILES:${PN}-vdpau-drivers = "${libdir}/vdpau/*.so.*"
 286 FILES:libegl-mesa = "${libdir}/libEGL.so.*"
 287 FILES:libgbm = "${libdir}/libgbm.so.*"
 288 FILES:libgles1-mesa = "${libdir}/libGLESv1*.so.*"
 289 FILES:libgles2-mesa = "${libdir}/libGLESv2.so.*"
 290 FILES:libgl-mesa = "${libdir}/libGL.so.*"
 291 FILES:libglapi = "${libdir}/libglapi.so.*"
 292 FILES:libosmesa = "${libdir}/libOSMesa.so.*"
 293 FILES:libxatracker = "${libdir}/libxatracker.so.*"
 294
 295 FILES:${PN}-dev = "${libdir}/pkgconfig/dri.pc ${includedir}/vulkan ${libdir}/vdpau/*.so"
 296 FILES:libegl-mesa-dev = "${libdir}/libEGL.* ${includedir}/EGL ${includedir}/KHR ${libdir}/pkgconfig/egl.pc"
 297 FILES:libgbm-dev = "${libdir}/libgbm.* ${libdir}/pkgconfig/gbm.pc ${includedir}/gbm.h"
 298 FILES:libgl-mesa-dev = "${libdir}/libGL.* ${includedir}/GL ${libdir}/pkgconfig/gl.pc"
 299 FILES:libglapi-dev = "${libdir}/libglapi.*"
 300 FILES:libgles1-mesa-dev = "${libdir}/libGLESv1*.* ${includedir}/GLES ${libdir}/pkgconfig/glesv1*.pc"
 301 FILES:libgles2-mesa-dev = "${libdir}/libGLESv2.* ${includedir}/GLES2 ${libdir}/pkgconfig/glesv2.pc"
 302 FILES:libgles3-mesa-dev = "${includedir}/GLES3"
 303 FILES:libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/GL/osmesa.h ${libdir}/pkgconfig/osmesa.pc"
 304 FILES:libxatracker-dev = "${libdir}/libxatracker.so ${libdir}/libxatracker.la \
 305                           ${includedir}/xa_tracker.h ${includedir}/xa_composite.h ${includedir}/xa_context.h \
 306                           ${libdir}/pkgconfig/xatracker.pc"
 307
 308 # Fix upgrade path from mesa to mesa-megadriver
 309 RREPLACES:mesa-megadriver = "mesa"
 310 RCONFLICTS:mesa-megadriver = "mesa"
 311 RPROVIDES:mesa-megadriver = "mesa"